3 |
4 | ## A Clean, Modern, Bigscreen Interface for Pegasus Frontend
5 |
6 | If you are looking to use this theme, [Check out the website for this theme here.](https://fr75s.github.io/library/assets/SAFELY_REMOVABLE/website/main.html)
7 |
8 | Library is a clean, modern interface for [Pegasus Frontend](http://pegasus-frontend.org) that aims to provide a theme which doesn't emphasize text. Inspired partly by the Steam Deck's UI, this interface focuses more on providing the box art in organized categories, with little textual metadata.
9 |
10 | ***
11 |
12 | ## Installation
13 |
14 | [Full installation instructions are available here.](https://fr75s.github.io/library/assets/SAFELY_REMOVABLE/website/install.html)
15 |
16 | To install this theme, first download this repository (either through `git clone https://github.com/Fr75s/library.git` or through downloading this zip), then move (and extract if you downloaded the zip) to [your themes folder.](https://pegasus-frontend.org/docs/user-guide/installing-themes/) Finally, remove the SAFELY_REMOVABLE folder located within this theme's folder under assets.
17 |
18 | ***
19 |
20 | ## Special Thanks
21 |
22 | I used other themes as references while building Library. These themes are listed below.
23 |
24 | - https://github.com/valsou/neoretro: The framework I built this theme off of, used for the separate page file system and Colcon.qml.
25 | - https://github.com/TigraTT-Driver/shinretro: A theme which provided the functionality for portrait-style steam game box art and more. I didn't find out about this theme until Library was mostly complete.
26 | - https://github.com/PlayingKarrde/clearOS: A theme providing part of the search functionality of the theme.
27 |
28 | I would also like to thank the following people:
29 |
30 | [TigraTT-Driver](https://github.com/TigraTT-Driver/), who has contributed several new features to Library and who has provided the German translation.
31 |
32 | [waitingmoon](https://github.com/waitingmoon), who has provided the Japanese translation.
33 |
34 | ***
35 |
36 | ## Issues?
37 |
38 | If you find any issues or want to let me know of anything, feel free to open up an issue in this project. You may also want to check out the [Modifications Guide](https://github.com/Fr75s/library/blob/main/MODIFICATIONS.md) and see if I have placed a fix there. If not, then, once again, feel free to open up an issue, and I will fix it.
39 |
40 | If you know a language other than English, I encourage you to translate this theme. All relevant info is in the [Translation Section](https://github.com/Fr75s/library/blob/main/MODIFICATIONS.md) of the modifications guide and in Localization.qml.
41 |
42 | ***
43 |
44 | ## Screenshots
45 |
46 | The following shows some screenshots of the theme. All screenshots can be found on [The Pegasus Theme Gallery](https://pegasus-frontend.org/tools/themes/), or in [The SAFELY_REMOVABLE Directory.](https://github.com/Fr75s/library/tree/main/assets/SAFELY_REMOVABLE)
47 |
48 | 
49 | 
50 | 
51 | 
52 |
--------------------------------------------------------------------------------
/Theme/All.qml:
--------------------------------------------------------------------------------
1 | import QtQuick 2.15
2 | import QtMultimedia 5.15
3 | import QtQuick.Layouts 1.15
4 | import QtGraphicalEffects 1.15
5 | import QtQuick.Window 2.15
6 |
7 | import SortFilterProxyModel 0.2
8 |
9 | import "../GameItems"
10 | import "PegaKey"
11 |
12 | /*
13 | *
14 | * Note
15 | * This may be called all, but this has been revitalized to a search
16 | *
17 | */
18 |
19 | FocusScope {
20 | id: search
21 |
22 | property bool feed: false
23 | property bool searching: false
24 |
25 | // Converts the text in searchInput to a regex pattern
26 | function searchInputConvert(inputText) {
27 | if (settings["searchMode"] === "raw") {
28 | return inputText;
29 | } else {
30 | const specialSymbols = ["^", "$", "\\", ".", "*", "+", "?", "(", ")", "[", "]", "{", "}", "|", "/"];
31 | const capitals = /[A-Z]/g;
32 |
33 | if (settings["searchMode"] === "fuzzy") {
34 | let outputStr = "";
35 | for (let i = 0; i < inputText.length; i++) {
36 | if (inputText[i].match(capitals)) {
37 | // Make next letter match require to start at next word
38 | outputStr += "\\b" + inputText[i];
39 | } else if (specialSymbols.includes(inputText[i])) {
40 | // Escape special character
41 | outputStr += "\\" + inputText[i];
42 | } else {
43 | outputStr += inputText[i];
44 | }
45 | // Loose Matching
46 | outputStr += ".*";
47 | }
48 | console.log(JSON.stringify(outputStr));
49 | return outputStr;
50 | } else {
51 | // Escape special symbols
52 | let regexCleanText = inputText.split("");
53 | for (let i = regexCleanText.length - 1; i >= 0; i--) {
54 | if (specialSymbols.includes(regexCleanText[i])) {
55 | regexCleanText.splice(i, 0, "\\");
56 | }
57 | }
58 | let outputStr = "";
59 | for (let i = 0; i < regexCleanText.length; i++) {
60 | outputStr += regexCleanText[i];
61 | }
62 |
63 | // Add ^ to beginning of pattern if limited search
64 | if (settings["searchMode"] === "lim") {
65 | outputStr = "^" + outputStr;
66 | }
67 | return outputStr;
68 | }
69 | }
70 | }
71 |
72 | // Define Current Game
73 | SortFilterProxyModel {
74 | id: searchSort
75 | sourceModel: api.allGames
76 |
77 | // The searching functionality for the model
78 | filters: RegExpFilter {
79 | roleName: "title";
80 | // Limited search matches ^[term] rather than [term]
81 | pattern: searchInputConvert(searchInput.text);
82 | enabled: searchInput.text != "";
83 | caseSensitivity: Qt.CaseInsensitive;
84 | }
85 | }
86 |
87 | /*
88 | * Note: The bug pertaining to not being able to run or favorite games when searching was fixed
89 | * by changing searchSort.get(allView.currentIndex) to api.allGames.get(searchSort.mapToSource(allView.currentIndex)).
90 | * This fix is from clearOS.
91 | *
92 | */
93 |
94 | // The current game
95 | property var currentGameIndex: {
96 | if (searchSort.count == 0 || searchSort.count == api.allGames.count)
97 | return allView.currentIndex;
98 | else
99 | return searchSort.mapToSource(allView.currentIndex);
100 | }
101 | property var current: {
102 | return api.allGames.get(currentGameIndex);
103 | }
104 | property var feedCurrent
105 |
106 | //
107 | // Layouts
108 | //
109 |
110 | // Title
111 | Text {
112 | id: allTitle
113 | width: parent.width * .9
114 |
115 | y: parent.height * 0.075
116 |
117 | text: feed ? loc.all_feed : loc.all_search
118 | color: colors["text"]
119 |
120 | // Alignment
121 | horizontalAlignment: Text.AlignLeft
122 |
123 | font.family: gilroyLight.name
124 | font.pixelSize: parent.height * .05
125 |
126 | anchors.left: parent.left
127 | anchors.leftMargin: parent.width * 0.05
128 | }
129 |
130 |
131 |
132 | // Search Background, to indicate it is a search field
133 | // (outside of searchInput to prevent bug where searchInput text is under the bg)
134 | Rectangle {
135 | id: searchInputBG
136 |
137 | width: searchInput.width + (searchInput.height * .5)
138 | height: searchInput.height * 1.2
139 | anchors.centerIn: searchInput
140 |
141 | radius: height * .25
142 | visible: !feed
143 |
144 | gradient: Gradient {
145 | orientation: Gradient.Horizontal
146 | GradientStop { position: 0.0; color: colors["plainSetting"] }
147 | GradientStop { position: 1.0; color: colors["plainBG"] }
148 | }
149 |
150 | // Highlight when searching
151 | Rectangle {
152 | anchors.fill: parent
153 | radius: parent.radius
154 |
155 | visible: (menu == 1) && !(allView.focus)
156 |
157 | border.color: colors["accent"]
158 | border.width: 2
159 | color: "transparent"
160 | }
161 | }
162 |
163 | DropShadow {
164 | anchors.fill: searchInputBG
165 | source: searchInputBG
166 |
167 | visible: !settings["plainBG"] && !feed
168 | opacity: giShadowOp
169 |
170 | radius: giShadowRad
171 | samples: giShadowRad * 2 + 1
172 | z: searchInputBG.z - 1
173 | }
174 |
175 | // Search text input, used for searching
176 | // Its text property is what is used for searching
177 | TextInput {
178 | id: searchInput
179 | width: parent.width * .6
180 | height: parent.height * .06
181 |
182 | visible: !feed
183 | focus: false
184 |
185 | y: parent.height * 0.075
186 |
187 | color: colors["text"]
188 |
189 | // Alignment
190 | horizontalAlignment: Text.AlignLeft
191 | verticalAlignment: Text.AlignVCenter
192 |
193 | font.family: gilroyLight.name
194 | font.pixelSize: parent.height * .05
195 |
196 | selectByMouse: true;
197 |
198 | anchors.right: parent.right
199 | anchors.rightMargin: parent.width * 0.05
200 |
201 | // Indicator for the word, used to show the end of the text
202 | Rectangle {
203 | width: 1
204 | height: parent.height
205 |
206 | anchors.left: parent.left
207 | anchors.leftMargin: parent.contentWidth
208 |
209 | visible: (menu == 1) && !(allView.focus)
210 | }
211 |
212 | // Click control, invokes keyboard
213 | MouseArea {
214 | anchors.fill: parent
215 |
216 | onClicked: {
217 | keys.invokeNoFocus();
218 | parent.focus = true;
219 | searching = true;
220 | }
221 | }
222 |
223 | Keys.onEscapePressed: {
224 | keys.hide();
225 | }
226 |
227 | Keys.onPressed: {
228 | if (event.isAutoRepeat) {
229 | return
230 | }
231 |
232 | if (api.keys.isAccept(event)) {
233 | event.accepted = true;
234 | keys.hide();
235 | }
236 | }
237 | }
238 |
239 | /* The special keyboard implementation, instantiated here
240 | * This is the main way an actual implementation of this is shown.
241 | * The keyboard's functionality can be found by looking at the files in the PegaKey folder.
242 | *
243 | */
244 | Keyboard {
245 | id: keys
246 |
247 | // Width and height are defined in the keyboard
248 | anchors.fill: parent
249 | z: 20
250 |
251 | kcolors: colors["keyboard"]
252 |
253 | sfxSource: ".././assets/audio/type.wav"
254 | quietSfx: settings["quiet"];
255 | muteSfx: settings["nosfx"];
256 |
257 | // Adds key to input, unless it's a backspace or clear
258 | onSendKey: {
259 | if (text == "bksp") {
260 | if (searchInput.text.length > 0) {
261 | searchInput.text = searchInput.text.substring(0, searchInput.text.length - 1)
262 | }
263 | } else if (text == "CLEAR") {
264 | searchInput.text = ""
265 | } else {
266 | searchInput.text = searchInput.text + text;
267 | searchInput.forceLayout()
268 | }
269 | }
270 |
271 | // Invoke provides more functionality in the keyboard itself.
272 | onInvoked: {
273 | searching = true;
274 | }
275 |
276 | // More functionality is in the keyboard itself.
277 | // It also focuses the game view.
278 | onDone: {
279 | searching = false;
280 | allView.focus = (menu == 1) && !searching;
281 | }
282 | }
283 |
284 | // All View
285 | // See all games or searched games
286 | GridView {
287 | id: allView
288 | width: settings["wide"] ? height * (2.14) : height * (2)
289 | height: settings["wide"] ? parent.height * 0.7 : parent.height * 0.75 //* (Math.ceil(api.allGames.count / 6))
290 |
291 | // Rectangle {
292 | // anchors.fill: parent
293 | // opacity: 0.1
294 | // }
295 |
296 | anchors.top: parent.top
297 | anchors.topMargin: parent.height * .175
298 | anchors.horizontalCenter: parent.horizontalCenter
299 |
300 | visible: !feed
301 |
302 | // Grid
303 | cellWidth: getCellWidth(cellHeight, true)//settings["wide"] ? (cellHeight * (92/43)) : (cellHeight * (2/3))
304 | cellHeight: height / settings["gamesRows"]
305 |
306 | // Sets the model to everything if the search is empty or contains all games
307 | model: (searchSort.count == 0 || searchSort.count == api.allGames.count) ? api.allGames : searchSort
308 |
309 | delegate: Item {
310 | readonly property bool isCurrentItem: GridView.isCurrentItem
311 | // Once again, double focus indicates this game is selected
312 | readonly property bool doubleFocus: allView.focus && isCurrentItem
313 |
314 | width: GridView.view.cellWidth
315 | height: GridView.view.cellHeight
316 |
317 | Item {
318 | anchors {
319 | fill: parent
320 | margins: (doubleFocus) ? 0 : vpx(10)
321 | }
322 |
323 | Behavior on anchors.margins {
324 | SmoothedAnimation { velocity: marginAnimVel }
325 | }
326 |
327 | GINormal { }
328 |
329 | /*
330 | Loader {
331 | anchors.fill: parent
332 | asynchronous: true
333 | sourceComponent: GINormal { }
334 | active: all.focus
335 | visible: status === Loader.Ready
336 | }
337 | */
338 |
339 | // Click functionality
340 | MouseArea {
341 | anchors.fill: parent
342 | onClicked: {
343 | if (isCurrentItem) {
344 | launchGame(modelData)
345 | }
346 | else {
347 | allView.currentIndex = index
348 | if (!settings["nosfx"])
349 | sNav.play();
350 | if (searching)
351 | searching = false
352 | }
353 | }
354 | }
355 | }
356 |
357 |
358 | }
359 |
360 | clip: true
361 | focus: (menu == 1) && !searching
362 |
363 | // Invokes search if at top, otherwise move up
364 | Keys.onUpPressed: {
365 | if (!settings["nosfx"]) sNav.play();
366 | if (settings["wide"]) {
367 | if (allView.currentIndex < settings["gamesRows"])
368 | keys.invoke()
369 | } else {
370 | if (allView.currentIndex < (settings["gamesRows"] * 3))
371 | keys.invoke()
372 | }
373 | if (!searching)
374 | moveCurrentIndexUp()
375 | }
376 | // Move down with special behavior
377 | Keys.onDownPressed: {
378 | if (!settings["nosfx"]) sNav.play();
379 |
380 | // Go to last element if no element below on non-final row
381 | if (settings["wide"]) {
382 | if (allView.currentIndex + (settings["gamesRows"]) >= allView.count && allView.currentIndex % (settings["gamesRows"]) > (allView.count - 1) % (settings["gamesRows"]))
383 | allView.currentIndex = allView.count - 1;
384 | else {
385 | moveCurrentIndexDown();
386 | }
387 | } else {
388 | if (allView.currentIndex + (settings["gamesRows"] * 3) >= allView.count && allView.currentIndex % (settings["gamesRows"] * 3) > (allView.count - 1) % (settings["gamesRows"] * 3))
389 | allView.currentIndex = allView.count - 1;
390 | else {
391 | moveCurrentIndexDown();
392 | }
393 | }
394 | }
395 | // Move left/right
396 | Keys.onLeftPressed: { if (!settings["nosfx"]) sNav.play(); moveCurrentIndexLeft() }
397 | Keys.onRightPressed: { if (!settings["nosfx"]) sNav.play(); moveCurrentIndexRight() }
398 |
399 | Keys.onPressed: {
400 | if (event.isAutoRepeat) {
401 | return
402 | }
403 |
404 | // Launch Game
405 | if (api.keys.isAccept(event)) {
406 | event.accepted = true;
407 | if (!feed) {
408 | api.memory.set("tempSavedAllGame", currentGameIndex);
409 | launchGame(current);
410 | } else {
411 | launchGame(feedCurrent);
412 | }
413 | }
414 |
415 | // Favorite Game / Skip Game Video
416 | if (api.keys.isFilters(event)) {
417 | event.accepted = true;
418 | if (!feed) {
419 | if (!settings["nosfx"])
420 | sFav.play();
421 | current.favorite = !current.favorite;
422 | } else {
423 | feedNext();
424 | }
425 | }
426 |
427 | // Quick Search with X
428 | if (api.keys.isDetails(event)) {
429 | event.accepted = true;
430 | if (!feed) {
431 | keys.invoke()
432 | }
433 | }
434 | }
435 |
436 | Component.onCompleted: {
437 | positionViewAtIndex(currentIndex, GridView.Center);
438 | }
439 | }
440 |
441 |
442 | // Feed Stuff
443 | SortFilterProxyModel {
444 | id: gamesWithVideos;
445 |
446 | sourceModel: api.allGames;
447 | filters: [
448 | ExpressionFilter { expression: { assets.video !== ''; } }
449 | ]
450 | }
451 |
452 | Video {
453 | id: feedPlayer;
454 |
455 | width: parent.width * 0.75
456 | height: parent.height * 0.75
457 | autoPlay: true
458 |
459 | anchors.horizontalCenter: parent.horizontalCenter
460 | anchors.bottom: parent.bottom
461 | anchors.bottomMargin: parent.height * 0.1
462 |
463 | visible: feed
464 |
465 | fillMode: VideoOutput.PreserveAspectFit
466 |
467 | onStatusChanged: {
468 | if (status === MediaPlayer.InvalidMedia) {
469 | console.log("VIDEO INVALID");
470 | feedNext();
471 | }
472 | if (status === MediaPlayer.EndOfMedia) {
473 | console.log("VIDEO EOF");
474 | feedNext();
475 | }
476 | }
477 |
478 | MouseArea {
479 | anchors.fill: parent
480 |
481 | onClicked: {
482 | launchGame(feedCurrent)
483 | }
484 | }
485 | }
486 |
487 | Rectangle {
488 | id: feedPlayerBG
489 | anchors.centerIn: feedPlayer;
490 |
491 | width: feedPlayer.width
492 | height: feedPlayer.height
493 |
494 | visible: feedPlayer.visible
495 |
496 | z: feedPlayer.z - 1
497 |
498 | color: colors["plainBG"]
499 | }
500 |
501 | Text {
502 | id: feedInfoLabel
503 | width: parent.width * .9
504 |
505 | y: parent.height * 0.91
506 |
507 | text: loc.all_feed_instructions
508 | color: colors["text"]
509 |
510 | visible: feed
511 |
512 | // Alignment
513 | horizontalAlignment: Text.AlignHCenter
514 |
515 | font.family: gilroyLight.name
516 | font.pixelSize: parent.height * .025
517 |
518 | anchors.left: parent.left
519 | anchors.leftMargin: parent.width * 0.05
520 | }
521 |
522 | DropShadow {
523 | anchors.fill: feedPlayerBG;
524 | source: feedPlayerBG;
525 |
526 | visible: feedPlayerBG.visible
527 |
528 | opacity: giShadowOp
529 |
530 | radius: giShadowRad * 2
531 | samples: radius * 2 + 1
532 | z: feedPlayerBG.z - 1
533 | }
534 |
535 | Timer {
536 | id: feedRepeatTimer
537 |
538 | interval: 500
539 | repeat: false
540 | running: false
541 | }
542 |
543 | Keys.onPressed: {
544 | if (event.isAutoRepeat) {
545 | return
546 | }
547 |
548 | // Feed Mode
549 | if (api.keys.isPageUp(event)) {
550 | event.accepted = true;
551 |
552 | if (feedRepeatTimer.running == false) {
553 | feed = !feed;
554 | theme.isFeed = !theme.isFeed
555 |
556 | if (feed) {
557 | feedNext();
558 | } else {
559 | feedPlayer.stop();
560 | }
561 |
562 | feedRepeatTimer.start()
563 | }
564 |
565 | }
566 | }
567 |
568 | function feedNext() {
569 | const gindex = Math.floor(Math.random() * gamesWithVideos.count);
570 | feedCurrent = api.allGames.get(gamesWithVideos.mapToSource(gindex));
571 |
572 | console.log(feedCurrent.title);
573 | feedPlayer.source = feedCurrent.assets.video;
574 |
575 | console.log(feedPlayer.source);
576 | feedPlayer.play();
577 | }
578 |
579 | Component.onCompleted: {
580 | if (api.memory.has("tempSavedAllGame")) {
581 | if (!settings["forceHome"]) {
582 | allView.currentIndex = Math.min(api.memory.get("tempSavedAllGame"), searchSort.count === 0 ? api.allGames.count : searchSort.count);
583 | }
584 | api.memory.unset("tempSavedAllGame");
585 | }
586 | feedPlayer.stop();
587 | }
588 |
589 | Connections {
590 | target: theme
591 |
592 | function onVideoControl(pause) {
593 | if (pause) {
594 | feedPlayer.pause()
595 | } else if (feed) {
596 | feedPlayer.play()
597 | }
598 | }
599 | }
600 |
601 | }
602 |
--------------------------------------------------------------------------------
/Theme/Collections.qml:
--------------------------------------------------------------------------------
1 | import QtQuick 2.8
2 | import QtMultimedia 5.9
3 | import QtQuick.Layouts 1.15
4 | import QtGraphicalEffects 1.15
5 | import QtQuick.Window 2.15
6 |
7 | import SortFilterProxyModel 0.2
8 |
9 | import "../GameItems"
10 |
11 | FocusScope {
12 | id: collects
13 |
14 | /* gameView shows the games in a collection once clicked.
15 | * It sets the visible property of each GridView here.
16 | * false: Collections View
17 | * true: Game View
18 | */
19 | property bool gameView: false
20 |
21 | /* Sets whether or not you're in a collection
22 | * 0: Collections
23 | * 1: Games
24 | */
25 | property var collection: 0
26 |
27 | // Adds a delay to mouse clicks on the collection screen so that they don't immediately click a game
28 | property bool interact: true
29 |
30 | // Collections Title
31 | Text {
32 | id: tlText
33 | width: parent.width * .9
34 |
35 | y: parent.height * 0.075
36 |
37 | text: loc.collections_title
38 | color: colors["text"]
39 |
40 | font.family: gilroyLight.name
41 | font.pixelSize: parent.height * .05
42 |
43 | // Alignment
44 | horizontalAlignment: settings["centerTitles"] ? Text.AlignHCenter : Text.AlignLeft
45 |
46 | anchors.left: parent.left
47 | anchors.leftMargin: parent.width * 0.05
48 |
49 | opacity: gameView ? 0 : 1
50 | }
51 |
52 | // Games Title
53 | Text {
54 | id: llText
55 | width: parent.width * .9
56 |
57 | y: parent.height * 0.075
58 |
59 | text: collection.name
60 | color: colors["text"]
61 |
62 | font.family: gilroyLight.name
63 | font.pixelSize: parent.height * .05
64 |
65 | // Alignment
66 | horizontalAlignment: settings["centerTitles"] ? Text.AlignHCenter : Text.AlignLeft
67 |
68 | anchors.left: parent.left
69 | anchors.leftMargin: parent.width * 0.05
70 |
71 | opacity: gameView ? 1 : 0
72 | }
73 |
74 | // Clickable Mouse Navigation
75 | Item {
76 | height: parent.height * 0.075
77 | width: height
78 | y: parent.height * 0.075
79 | anchors.right: parent.right
80 | anchors.rightMargin: parent.width * 0.05
81 | visible: gameView && settings["mouseNav"]
82 | Behavior on y {
83 | SmoothedAnimation { velocity: animVel }
84 | }
85 | Text {
86 | text: icons.touch_up
87 | anchors.centerIn: parent
88 | font {
89 | family: icons.name;
90 | pixelSize: parent.height * .6
91 | }
92 | color: colors["text"]
93 | }
94 |
95 | MouseArea {
96 | anchors.fill: parent
97 | onClicked: {
98 | if (!settings["nosfx"])
99 | sBack.play();
100 | gameView = false;
101 | }
102 | }
103 | }
104 |
105 | /* collectionsView: Shows collections
106 | * Works just like a gameView, but has some key differences
107 | *
108 | */
109 | GridView {
110 | id: collectionsView
111 | width: height * (2)
112 | height: parent.height * 0.75 //* (Math.ceil(api.allGames.count / 6))
113 |
114 | anchors.top: parent.top
115 | anchors.topMargin: parent.height * .15
116 | anchors.horizontalCenter: parent.horizontalCenter
117 |
118 | cellWidth: (cellHeight * (2/3))
119 | cellHeight: height / settings["collectionRows"]
120 |
121 | // Collections model from Pegasus
122 | model: api.collections
123 |
124 | delegate: Item {
125 | readonly property bool isCurrentItem: GridView.isCurrentItem
126 | // doubleFocus again focuses the highlighted item
127 | readonly property bool doubleFocus: collectionsView.focus && isCurrentItem
128 |
129 | width: GridView.view.cellWidth
130 | height: GridView.view.cellHeight
131 |
132 | Item {
133 | anchors {
134 | fill: parent
135 | margins: (doubleFocus) ? 0 : vpx(10)
136 | }
137 |
138 | Behavior on anchors.margins {
139 | SmoothedAnimation { velocity: marginAnimVel }
140 | }
141 |
142 | /* Instead of GINormal, this view uses GICusart
143 | * This is to permit collection art to show rather than game art.
144 | */
145 | GICusart{ }
146 |
147 | /*
148 | Loader {
149 | anchors.fill: parent
150 | asynchronous: true
151 | sourceComponent: GICusart{}
152 | active: collects.focus
153 | visible: status === Loader.Ready
154 | }
155 | */
156 |
157 | // Click functionality
158 | MouseArea {
159 | anchors.fill: parent
160 |
161 | onClicked: {
162 | if (isCurrentItem) {
163 | if (!settings["nosfx"]) sAccept.play();
164 | collection = api.collections.get(collectionsView.currentIndex);
165 |
166 | // We set interact to false so that the click doesn't interact
167 | interact = false;
168 | gameView = true;
169 |
170 | // Timeout is .5s, enough to let go of the previous click
171 | setTimeout({interact = true}, 500)
172 | } else {
173 | if (!settings["nosfx"]) sNav.play();
174 | collectionsView.currentIndex = index;
175 | }
176 | }
177 | }
178 | }
179 | }
180 |
181 | clip: true
182 | focus: (menu == 2) && !(gameView)
183 | visible: !gameView
184 |
185 | // Go up
186 | Keys.onUpPressed: {
187 | if (!settings["nosfx"]) sNav.play();
188 | moveCurrentIndexUp();
189 | }
190 |
191 | // Go down with special property
192 | Keys.onDownPressed: {
193 | if (!settings["nosfx"]) sNav.play();
194 |
195 | // Go to last element if no element below on non-final row
196 | if (collectionsView.currentIndex + (settings["collectionRows"] * 3) >= collectionsView.count && collectionsView.currentIndex % (settings["collectionRows"] * 3) > (collectionsView.count - 1) % (settings["collectionRows"] * 3))
197 | collectionsView.currentIndex = collectionsView.count - 1;
198 | else {
199 | moveCurrentIndexDown();
200 | }
201 | }
202 | // Go left/right
203 | Keys.onLeftPressed: { if (!settings["nosfx"]) sNav.play(); moveCurrentIndexLeft() }
204 | Keys.onRightPressed: { if (!settings["nosfx"]) sNav.play(); moveCurrentIndexRight() }
205 |
206 | Keys.onPressed: {
207 | // Stop auto repeat: Don't open a game if A is held down.
208 | if (event.isAutoRepeat) {
209 | return
210 | }
211 |
212 | // Open the current collection
213 | if (api.keys.isAccept(event)) {
214 | if (!settings["nosfx"])
215 | sAccept.play();
216 | // Set the current Collection
217 | collection = api.collections.get(collectionsView.currentIndex)
218 | gameView = true
219 | }
220 | }
221 |
222 | Component.onCompleted: {
223 | positionViewAtIndex(currentIndex, GridView.Center);
224 | }
225 | }
226 |
227 | // Actual Games in a collection
228 | GridView {
229 | id: collectionGamesView
230 | width: settings["wide"] ? height * (2.14) : height * (2)
231 | height: settings["wide"] ? parent.height * 0.7 : parent.height * 0.75 //* (Math.ceil(api.allGames.count / 6))
232 |
233 | anchors.top: parent.top
234 | anchors.topMargin: parent.height * .15
235 | anchors.horizontalCenter: parent.horizontalCenter
236 |
237 | cellWidth: getCellWidth(cellHeight, true)//settings["wide"] ? (cellHeight * (92/43)) : (cellHeight * (2/3))
238 | cellHeight: height / settings["gamesRows"]
239 |
240 | // Games in the current collection is the model
241 | model: collection.games
242 |
243 | delegate: Item {
244 | readonly property bool isCurrentItem: GridView.isCurrentItem
245 | // Again, doubleFocus, doing the same thing
246 | readonly property bool doubleFocus: collectionGamesView.focus && isCurrentItem
247 |
248 | width: GridView.view.cellWidth
249 | height: GridView.view.cellHeight
250 |
251 | Item {
252 | anchors {
253 | fill: parent
254 | margins: (doubleFocus) ? 0 : vpx(10)
255 | }
256 |
257 | Behavior on anchors.margins {
258 | SmoothedAnimation { velocity: marginAnimVel }
259 | }
260 |
261 | GINormal { }
262 |
263 | /*
264 | Loader {
265 | anchors.fill: parent
266 | asynchronous: true
267 | sourceComponent: GINormal{}
268 | active: collects.focus
269 | visible: status === Loader.Ready
270 | }
271 | */
272 |
273 | // Click functionality
274 | MouseArea {
275 | anchors.fill: parent
276 | onClicked: {
277 | if (isCurrentItem) {
278 | api.memory.set("tempSavedCollection", collectionsView.currentIndex);
279 | api.memory.set("tempSavedCollectionGame", index);
280 | launchGame(modelData);
281 | }
282 | else {
283 | collectionGamesView.currentIndex = index;
284 | if (!settings["nosfx"])
285 | sNav.play();
286 | }
287 | }
288 | }
289 | }
290 | }
291 |
292 | clip: true
293 | focus: (menu == 2) && (gameView)
294 | visible: gameView
295 |
296 | // Move up, down, left & right like collectionsView
297 | Keys.onUpPressed: {
298 | if (!settings["nosfx"]) sNav.play();
299 | moveCurrentIndexUp();
300 | }
301 | Keys.onDownPressed: {
302 | if (!settings["nosfx"]) sNav.play();
303 |
304 | // Go to last element if no element below on non-final row
305 | if (settings["wide"]) {
306 | if (collectionGamesView.currentIndex + (settings["gamesRows"]) >= collectionGamesView.count && collectionGamesView.currentIndex % (settings["gamesRows"]) > (collectionGamesView.count - 1) % (settings["gamesRows"]))
307 | collectionGamesView.currentIndex = collectionGamesView.count - 1;
308 | else {
309 | moveCurrentIndexDown();
310 | }
311 | } else {
312 | if (collectionGamesView.currentIndex + (settings["gamesRows"] * 3) >= collectionGamesView.count && collectionGamesView.currentIndex % (settings["gamesRows"] * 3) > (collectionGamesView.count - 1) % (settings["gamesRows"] * 3))
313 | collectionGamesView.currentIndex = collectionGamesView.count - 1;
314 | else {
315 | moveCurrentIndexDown();
316 | }
317 | }
318 | }
319 | Keys.onLeftPressed: { if (!settings["nosfx"]) sNav.play(); moveCurrentIndexLeft() }
320 | Keys.onRightPressed: { if (!settings["nosfx"]) sNav.play(); moveCurrentIndexRight() }
321 |
322 | Keys.onPressed: {
323 | if (event.isAutoRepeat) {
324 | return
325 | }
326 |
327 | // Launch game, only on interact
328 | if (api.keys.isAccept(event)) {
329 | if (interact) {
330 | event.accepted = true;
331 | api.memory.set("tempSavedCollection", collectionsView.currentIndex);
332 | api.memory.set("tempSavedCollectionGame", collectionGamesView.currentIndex);
333 | launchGame(collection.games.get(collectionGamesView.currentIndex))
334 | }
335 | }
336 |
337 | // Go back to the collections
338 | if (api.keys.isCancel(event)) {
339 | if (!settings["nosfx"])
340 | sBack.play();
341 | event.accepted = true;
342 | gameView = false
343 | }
344 |
345 | // Favorite a game
346 | if (api.keys.isFilters(event)) {
347 | if (!settings["nosfx"])
348 | sFav.play();
349 | event.accepted = true;
350 | collection.games.get(collectionGamesView.currentIndex).favorite = !collection.games.get(collectionGamesView.currentIndex).favorite;
351 | }
352 | }
353 |
354 | Component.onCompleted: {
355 | positionViewAtIndex(currentIndex, GridView.Center);
356 | }
357 | }
358 |
359 | Component.onCompleted: {
360 | if (api.memory.has("tempSavedCollection")) {
361 | if (!settings["forceHome"]) {
362 | if (api.memory.get("tempSavedCollection") >= 0 &&
363 | api.memory.get("tempSavedCollection") < api.collections.count) {
364 | collectionsView.currentIndex = api.memory.get("tempSavedCollection");
365 |
366 | collection = api.collections.get(collectionsView.currentIndex);
367 | gameView = true;
368 |
369 | collectionGamesView.currentIndex = api.memory.get("tempSavedCollectionGame");
370 | }
371 | }
372 |
373 | api.memory.unset("tempSavedCollection")
374 | api.memory.unset("tempSavedCollectionGame")
375 | }
376 | }
377 |
378 | }
379 |
--------------------------------------------------------------------------------
/Theme/Home.qml:
--------------------------------------------------------------------------------
1 | import QtQuick 2.8
2 | import QtMultimedia 5.9
3 | import QtQuick.Layouts 1.15
4 | import QtGraphicalEffects 1.15
5 | import QtQuick.Window 2.15
6 |
7 | import SortFilterProxyModel 0.2
8 |
9 | import "../GameItems"
10 |
11 | FocusScope {
12 | id: home
13 |
14 | /* Focused changes the view for the home screen.
15 | * It scrolls the page to the favorites when they are focused.
16 | * 0: recent
17 | * 1: favorites
18 | */
19 | property int focused: 0
20 |
21 | // Add more recent games with moreRecents
22 | property int maxRecents: settings["moreRecent"] ? 20 : 10
23 |
24 | // Sort Recents
25 |
26 | // Sorts by recent games, includes all games
27 | SortFilterProxyModel {
28 | id: sort_last_played_base
29 | sourceModel: api.allGames
30 | sorters: RoleSorter { roleName: "lastPlayed"; sortOrder: Qt.DescendingOrder; }
31 | }
32 |
33 | // Sorts the recent games model up to maxRecents
34 | SortFilterProxyModel {
35 | id: recent
36 | sourceModel: sort_last_played_base
37 | filters: IndexFilter { minimumIndex: 0; maximumIndex: maxRecents; }
38 | }
39 |
40 | // Sort Favorites
41 |
42 | // Filters by all favorite games, sorting by ascending order.
43 | SortFilterProxyModel {
44 | id: favorites
45 | sourceModel: api.allGames
46 | sorters: RoleSorter { roleName: "sortBy"; sortOrder: Qt.AscendingOrder; }
47 | filters: ValueFilter { roleName: "favorite"; value: true; }
48 | }
49 |
50 | // Define Current Game
51 | /*
52 | property var currentGame: {
53 | if (focused == 0) // If on recent, set to the current recent view game.
54 | api.allGames.get(sort_last_played_base.mapToSource(recentView.currentIndex))
55 | if (focused == 1) // If on favorites, set to the current favorited game
56 | api.allGames.get(favorites.mapToSource(favoriteView.currentIndex))
57 | else
58 | return null
59 | }
60 | */
61 |
62 | // This is the y position of the whole UI. It moves the recent view out of the way when the favorites are focused.
63 | property var uiY: {
64 | if (focused == 1)
65 | parent.height * -0.4
66 | else
67 | parent.height * 0.15
68 | }
69 |
70 | // Animation velocity for the vertical movement
71 | property int animVel: 1200
72 |
73 | //
74 | // Layouts
75 | //
76 |
77 | // Recent Games Text
78 | Text {
79 | id: recentTitle
80 | width: parent.width * .9
81 |
82 | y: uiY - parent.height * 0.075
83 |
84 | text: loc.home_recent
85 | color: colors["text"]
86 |
87 | font.family: gilroyLight.name
88 | font.pixelSize: parent.height * .05
89 |
90 | // Alignment
91 | horizontalAlignment: settings["centerTitles"] ? Text.AlignHCenter : Text.AlignLeft
92 |
93 | anchors.left: parent.left
94 | anchors.leftMargin: parent.width * 0.05
95 |
96 | Behavior on y {
97 | SmoothedAnimation { velocity: animVel }
98 | }
99 | }
100 |
101 | // Favorite Games Text
102 | Text {
103 | id: favTitle
104 | width: parent.width * .9
105 |
106 | y: uiY + parent.height * 0.475
107 |
108 | text: loc.home_favorite
109 | color: colors["text"]
110 |
111 | font.family: gilroyLight.name
112 | font.pixelSize: parent.height * .05
113 |
114 | // Alignment
115 | horizontalAlignment: settings["centerTitles"] ? Text.AlignHCenter : Text.AlignLeft
116 |
117 | anchors.left: parent.left
118 | anchors.leftMargin: parent.width * 0.05
119 |
120 | Behavior on y {
121 | SmoothedAnimation { velocity: animVel }
122 | }
123 | }
124 |
125 | // Clickable icon to scroll back up
126 | Item {
127 | width: height
128 | height: parent.height * 0.1
129 | y: uiY + parent.height * 0.45
130 | anchors.right: parent.right
131 | anchors.rightMargin: parent.width * 0.05
132 | visible: settings["mouseNav"]
133 |
134 | Behavior on y {
135 | SmoothedAnimation { velocity: animVel }
136 | }
137 |
138 | Text {
139 | text: icons.touch_up
140 | anchors.centerIn: parent
141 | font {
142 | family: icons.name;
143 | pixelSize: parent.height * .6
144 | }
145 | color: colors["text"]
146 | }
147 |
148 | MouseArea {
149 | anchors.fill: parent
150 | onClicked: {
151 | if (focused == 1) {
152 | if (!settings["nosfx"])
153 | sNav.play();
154 | focused = 0;
155 | }
156 | }
157 | }
158 | }
159 |
160 | // Recent Games List
161 | // Shows all the games you've recently played.
162 | ListView {
163 | id: recentView
164 | width: parent.width * 0.9
165 | height: parent.height * 0.4
166 |
167 | y: uiY
168 |
169 | orientation: ListView.Horizontal
170 | model: recent
171 |
172 | displayMarginEnd: 20
173 |
174 | delegate: Item {
175 | readonly property bool isCurrentItem: ListView.isCurrentItem
176 | // doubleFocus property only selects game when the view and item is this one
177 | readonly property bool doubleFocus: recentView.focus && isCurrentItem
178 |
179 | // Set this game to be wide if wide mode is enabled,
180 | // OR if it is the first game and the override is disabled.
181 | width: settings["wide"] || (index == 0 && !settings["forceRecentNarrow"]) ? ListView.view.height * (settings["diffAspect"] ? 16/9 : 92/43) : ListView.view.height * (settings["diffAspect"] ? 3/4 : 2/3)
182 | height: ListView.view.height
183 |
184 | Item {
185 | id: gameItemRoot
186 |
187 | anchors {
188 | fill: parent
189 | margins: (doubleFocus) ? 0 : vpx(10)
190 | }
191 |
192 | Behavior on anchors.margins {
193 | SmoothedAnimation { velocity: marginAnimVel }
194 | }
195 |
196 | // wideHead is set based on forceRecentNarrow, changing art and visual
197 | // properties of the game
198 | GINormal { wideHead: !settings["forceRecentNarrow"] }
199 |
200 | /*
201 | Loader {
202 | anchors.fill: parent
203 | asynchronous: true
204 | sourceComponent: GINormal { wideHead: true }
205 | active: (home.focus)
206 | visible: status === Loader.Ready
207 | }
208 | */
209 |
210 | // Click Functionality
211 | MouseArea {
212 | anchors.fill: parent
213 | onClicked: {
214 | if (doubleFocus)
215 | launchGame(modelData);
216 | else
217 | if (focused == 1)
218 | focused = 0;
219 | if (!settings["nosfx"])
220 | sNav.play();
221 | recentView.currentIndex = index;
222 | }
223 | }
224 | }
225 | }
226 |
227 | // Instant scrolling
228 | highlightMoveDuration: 0
229 | highlightResizeDuration: 0
230 |
231 | anchors.right: parent.right
232 | anchors.rightMargin: parent.width * 0.05
233 |
234 | clip: false
235 | focus: (focused == 0) && (menu == 0)
236 |
237 | Behavior on y {
238 | SmoothedAnimation { velocity: animVel }
239 | }
240 |
241 | // Scroll down when down is pressed
242 | Keys.onDownPressed: {
243 | if (!settings["nosfx"]) sNav.play();
244 | focused = 1;
245 | }
246 |
247 | // Move left/right
248 | Keys.onLeftPressed: {
249 | if (!settings["nosfx"]) sNav.play();
250 | decrementCurrentIndex();
251 | }
252 | Keys.onRightPressed: {
253 | if (!settings["nosfx"]) sNav.play();
254 | incrementCurrentIndex();
255 | }
256 |
257 | // Game Actions
258 | Keys.onPressed: {
259 | if (event.isAutoRepeat) {
260 | return
261 | }
262 |
263 | // Launch the current Game
264 | if (api.keys.isAccept(event)) {
265 | event.accepted = true;
266 | launchGame(api.allGames.get(sort_last_played_base.mapToSource(recentView.currentIndex)))
267 | }
268 |
269 | // Favorite/Unfavorite the current game
270 | if (api.keys.isFilters(event)) {
271 | event.accepted = true;
272 | if (!settings["nosfx"])
273 | sFav.play();
274 |
275 | api.allGames.get(sort_last_played_base.mapToSource(recentView.currentIndex)).favorite = !api.allGames.get(sort_last_played_base.mapToSource(recentView.currentIndex)).favorite;
276 | }
277 | }
278 | }
279 |
280 | // Favorite Games List
281 | // Shows all the games you've favorited.
282 | GridView {
283 | id: favoriteView
284 | width: settings["wide"] ? height * (2.14) : height * (2)
285 | height: settings["wide"] ? parent.height * 0.7 : parent.height * 0.75 //* (Math.ceil(favorites.count / 6))
286 |
287 | y: uiY + parent.height * 0.575
288 | anchors.horizontalCenter: parent.horizontalCenter
289 |
290 | cellWidth: getCellWidth(cellHeight, true) //settings["wide"] ? (cellHeight * (92/43)) : (cellHeight * (2/3))
291 | cellHeight: height / settings["gamesRows"] /// (Math.ceil(favorites.count / 6))
292 |
293 | //currentIndex: 0
294 | model: favorites
295 |
296 | delegate: Item {
297 | readonly property bool isCurrentItem: GridView.isCurrentItem
298 | // doubleFocus property only selects game when the view and item is this one
299 | readonly property bool doubleFocus: favoriteView.focus && isCurrentItem
300 |
301 | width: GridView.view.cellWidth
302 | height: GridView.view.cellHeight
303 |
304 | Item {
305 | anchors {
306 | fill: parent
307 | margins: (doubleFocus) ? 0 : vpx(10)
308 | }
309 |
310 | Behavior on anchors.margins {
311 | SmoothedAnimation { velocity: marginAnimVel }
312 | }
313 |
314 | GINormal { }
315 |
316 | // Click behavior
317 | MouseArea {
318 | anchors.fill: parent
319 | onClicked: {
320 | if (doubleFocus)
321 | launchGame(modelData);
322 | else
323 | if (focused == 0)
324 | focused = 1;
325 | if (!settings["nosfx"])
326 | sNav.play();
327 | favoriteView.currentIndex = index;
328 | }
329 | }
330 | }
331 | }
332 |
333 | clip: true
334 | focus: (focused == 1) && (menu == 0)
335 |
336 | Behavior on y {
337 | SmoothedAnimation { velocity: animVel }
338 | }
339 |
340 | // Scroll back up if at the top, otherwise just move up
341 | Keys.onUpPressed: {
342 | if (!settings["nosfx"])
343 | sNav.play();
344 |
345 | /*
346 |
347 | TOP ROW:
348 | normal:
349 | n * 3 rows
350 | wide:
351 | n rows
352 |
353 | */
354 |
355 | if (settings["wide"]) {
356 | if (favoriteView.currentIndex < settings["gamesRows"])
357 | focused = 0
358 | } else {
359 | if (favoriteView.currentIndex < (settings["gamesRows"] * 3))
360 | focused = 0
361 | }
362 | if (focused == 1)
363 | moveCurrentIndexUp();
364 | }
365 |
366 | // Scroll down
367 | Keys.onDownPressed: {
368 | if (!settings["nosfx"]) sNav.play();
369 |
370 | // Go to last element if no element below on non-final row
371 | if (settings["wide"]) {
372 | if (favoriteView.currentIndex + (settings["gamesRows"]) >= favoriteView.count && favoriteView.currentIndex % (settings["gamesRows"]) > (favoriteView.count - 1) % (settings["gamesRows"]))
373 | favoriteView.currentIndex = favoriteView.count - 1;
374 | else {
375 | moveCurrentIndexDown();
376 | }
377 | } else {
378 | if (favoriteView.currentIndex + (settings["gamesRows"] * 3) >= favoriteView.count && favoriteView.currentIndex % (settings["gamesRows"] * 3) > (favoriteView.count - 1) % (settings["gamesRows"] * 3))
379 | favoriteView.currentIndex = favoriteView.count - 1;
380 | else {
381 | moveCurrentIndexDown();
382 | }
383 | }
384 | }
385 |
386 | // Move left/right
387 | Keys.onLeftPressed: {
388 | if (!settings["nosfx"]) sNav.play();
389 | moveCurrentIndexLeft();
390 | }
391 | Keys.onRightPressed: {
392 | if (!settings["nosfx"]) sNav.play();
393 | moveCurrentIndexRight();
394 | }
395 |
396 | // Game Actions
397 | Keys.onPressed: {
398 | if (event.isAutoRepeat) {
399 | return
400 | }
401 |
402 | // Launch selected game
403 | if (api.keys.isAccept(event)) {
404 | event.accepted = true;
405 | launchGame(api.allGames.get(favorites.mapToSource(favoriteView.currentIndex)))
406 | }
407 | }
408 | }
409 | }
410 |
--------------------------------------------------------------------------------
/Theme/PegaKey/KeyButton.qml:
--------------------------------------------------------------------------------
1 | import QtQuick 2.0
2 | import QtMultimedia 5.9
3 |
4 | Rectangle {
5 | /* KeyButton
6 | * Defines the default style for keyboard buttons as a RoundButton
7 | *
8 | */
9 |
10 | signal clicked
11 |
12 | id: btn
13 | radius: 16
14 |
15 | property var clickedColor: "#000000"
16 | property var regColor: "#FFFFFF"
17 | property var textColor: "#888888"
18 |
19 | color: clickArea.containsPress ? clickedColor : regColor
20 |
21 | property string label: ""
22 | property bool large: false
23 |
24 | Text {
25 | anchors.centerIn: parent
26 |
27 | text: label
28 | color: textColor
29 |
30 | font.family: gilroyLight.name
31 | font.pixelSize: large ? btn.height / 2 : btn.height / 5
32 | }
33 |
34 | MouseArea {
35 | id: clickArea
36 | anchors.fill: parent
37 |
38 | onPressed: {
39 | btn.clicked()
40 | }
41 | }
42 | }
43 |
--------------------------------------------------------------------------------
/Theme/PegaKey/Keyboard.qml:
--------------------------------------------------------------------------------
1 | import QtQuick 2.0
2 | import QtMultimedia 5.9
3 |
4 | Item {
5 |
6 | /* Keyboard
7 | * Keyboard.qml instantiates a KeyboardObject. It is not the keyboard itself.
8 | * It obviously shows and hides the keyboard, but it also converts several keys.
9 | *
10 | */
11 |
12 | id: kcreator
13 |
14 | focus: false
15 |
16 | // Signals
17 | signal invoked()
18 | signal sendKey(string text)
19 | signal done()
20 |
21 | // Default Keyboard Colors
22 | property var kcolors: {
23 | "bg": "#FFFFFF", // KEYBOARD: Background
24 | "key": "#DDDDDD", // KEYBOARD: Key Background
25 | "keyPush": "#BBBBBB", // KEYBOARD: Key Background when clicked
26 | "keyHighlight": "#121212", // KEYBOARD: Selected Key Highlight
27 | "text": "#121212" // KEYBOARD: Text
28 | }
29 |
30 | // Quick Character Setting
31 | property string back: "\u2190"
32 | property string enter: "\u2192"
33 | property string shiftc: "\u2191"
34 |
35 | property url sfxSource: ""
36 | property bool quietSfx: false
37 | property bool muteSfx: false
38 |
39 | // Typing Sound Effect
40 | SoundEffect {
41 | id: kSfx
42 | source: sfxSource
43 | volume: quietSfx ? 0.5 : 1.0
44 | }
45 |
46 | // Invokes the keyboard (shows it)
47 | function invoke() {
48 | keyboard.visible = true;
49 | keyboard.focus = true;
50 | // This allows the keyboard to immediately accept presses vs waiting to move the cursor
51 | keyboard.focusEnableKB();
52 | }
53 |
54 | function invokeNoFocus() {
55 | keyboard.visible = true;
56 | }
57 |
58 | function hide() {
59 | kcreator.done();
60 | keyboard.focus = false;
61 | keyboard.visible = false;
62 | }
63 |
64 | // The actual Keyboard Object Keyboard.qml shows
65 | KeyboardObject {
66 | id: keyboard
67 | visible: false
68 | colors: kcolors
69 |
70 | backChar: back
71 | enterChar: enter
72 | shiftChar: shiftc
73 |
74 | width: theme.width
75 | height: theme.height * 0.6
76 |
77 | anchors.bottom: parent.bottom
78 |
79 | // Send Key is a signal of KeyboardObject.qml as well.
80 | onSendKey: {
81 | if (!muteSfx) {
82 | kSfx.play();
83 | }
84 |
85 | if (text == back) { // Backspace Unicode Conversion
86 | kcreator.sendKey("bksp")
87 | } else if (text == enter) { // Enter Unicode Conversion
88 | keyboard.done()
89 | } else if (text == shiftc) { // Shift Unicode Conversion
90 | keyboard.shift = !keyboard.shift
91 | } else if (text == "&123" || text == "ABCD") { // Alt Conversion
92 | keyboard.alts = !keyboard.alts
93 | } else {
94 | kcreator.sendKey(text)
95 | if (keyboard.shift) {
96 | keyboard.shift = false
97 | }
98 | }
99 | }
100 |
101 | // Hides keyboard once done
102 | onDone: {
103 | hide();
104 | }
105 | }
106 |
107 | }
108 |
--------------------------------------------------------------------------------
/Theme/PegaKey/KeyboardObject.qml:
--------------------------------------------------------------------------------
1 | import QtQuick 2.0
2 | import QtMultimedia 5.9
3 |
4 | Item {
5 | id: kRoot
6 |
7 | /* KeyboardObject
8 | * The actual keyboard layout itself
9 | *
10 | */
11 |
12 | // Signals
13 | signal sendKey(string text)
14 | signal done()
15 |
16 |
17 |
18 | // Character Properties
19 | property string backChar: "bksp"
20 | property string enterChar: "enter"
21 | property string shiftChar: "shft"
22 |
23 |
24 | // Some properties that modify the characters
25 | property bool shift: false
26 | property bool alts: false
27 |
28 | // Quick Rowspacing and columnspacing for easy access (gutter)
29 | property real rowspacing: width * 0.005
30 | property real colspacing: rowspacing //height * 0.01
31 |
32 | // Highlight color
33 | property var colors: {}
34 |
35 | // Current Row & Column
36 | property int curRow: 0
37 | property int curCol: 0
38 |
39 | // Block clicking below keyboard
40 | MouseArea {anchors.fill: parent}
41 |
42 | // Background: Parent rectangle has roundness
43 | Rectangle {
44 | anchors.fill: parent
45 | color: colors["bg"]
46 |
47 | radius: height / 16
48 |
49 | Rectangle {
50 | anchors.fill: parent
51 | color: parent.color
52 |
53 | anchors.topMargin: height / 2
54 | }
55 | }
56 |
57 | // Move up/down keyboard
58 | Keys.onUpPressed: {
59 | if (curRow <= 0) {
60 | curRow = 3
61 | } else {
62 | curRow -= 1
63 | }
64 | }
65 | Keys.onDownPressed: {
66 | if (curRow >= 3) {
67 | curRow = 0
68 | } else {
69 | curRow += 1
70 | }
71 | }
72 |
73 | // Move left on the keyboard. Note that wider keys are hardcoded here.
74 | Keys.onLeftPressed: {
75 | if (curRow == 0) {
76 | if (curCol <= 0) {
77 | curCol = 10
78 | } else {
79 | curCol -= 1
80 | }
81 | } else if (curRow == 1) {
82 | if (curCol <= 0) {
83 | curCol = 10
84 | } else {
85 | curCol -= 1
86 | }
87 | if (curCol >= 9) {
88 | curCol -= 1
89 | }
90 | } else if (curRow == 2) {
91 | if (curCol <= 1) {
92 | curCol = 10
93 | } else {
94 | curCol -= 1
95 | }
96 | if (curCol >= 9) {
97 | curCol -= 1
98 | }
99 | } else if (curRow == 3) {
100 | if (curCol <= 1) {
101 | curCol = 10
102 | } else if (curCol >= 3 && curCol <= 7) {
103 | curCol = 2
104 | } else {
105 | curCol -= 1
106 | }
107 | if (curCol >= 9) {
108 | curCol -= 1
109 | }
110 | }
111 | }
112 |
113 | // Move right on the keyboard. Note that wider keys are hardcoded here as well.
114 | Keys.onRightPressed: {
115 | if (curRow == 0) {
116 | if (curCol >= 10) {
117 | curCol = 0
118 | } else {
119 | curCol += 1
120 | }
121 | } else if (curRow == 1) {
122 | if (curCol >= 9) {
123 | curCol = 0
124 | } else {
125 | curCol += 1
126 | }
127 | } else if (curRow == 2) {
128 | if (curCol >= 9) {
129 | curCol = 0
130 | } else {
131 | curCol += 1
132 | }
133 | if (curCol <= 1) {
134 | curCol += 1
135 | }
136 | } else if (curRow == 3) {
137 | if (curCol >= 3 && curCol <= 7) {
138 | curCol = 8
139 | } else if (curCol >= 9) {
140 | curCol = 0
141 | } else {
142 | curCol += 1
143 | }
144 | if (curCol <= 1) {
145 | curCol += 1
146 | }
147 | }
148 | }
149 |
150 | // Other keys
151 | Keys.onPressed: {
152 | // Space Shortcut
153 | if (api.keys.isFilters(event)) {
154 | kRoot.sendKey(" ")
155 | }
156 | // Backspace Shortcut
157 | if (api.keys.isDetails(event)) {
158 | kRoot.sendKey(backChar) // Backspace
159 | }
160 | // Exit Shortcut
161 | if (api.keys.isCancel(event)) {
162 | event.accepted = true;
163 | kRoot.done()
164 | }
165 | }
166 |
167 | Item {
168 | id: keymap
169 |
170 | // The actual keys on the keyboard
171 |
172 | anchors.fill: parent
173 | anchors.leftMargin: parent.width * 0.05
174 | anchors.rightMargin: parent.width * 0.05
175 |
176 | anchors.topMargin: parent.height * 0.025
177 | anchors.bottomMargin: parent.height * 0.1
178 |
179 | Column {
180 | // Keyboard Column, with rows
181 | spacing: colspacing
182 |
183 | Row { // QWERTYUIOP
184 | spacing: rowspacing
185 |
186 | Repeater {
187 | /* Repeaters repeat the keys
188 | * Models have the following properties
189 | * key: Lowercase letter (default)
190 | * alt: Alternate character
191 | * w: Key Width
192 | * il: Lower index (used for selection)
193 | * ih: Higher index (used for selection)
194 | *
195 | */
196 | model: [
197 | {key: "q", alt: "1", w: 1, il: 0, ih: 0},
198 | {key: "w", alt: "2", w: 1, il: 1, ih: 1},
199 | {key: "e", alt: "3", w: 1, il: 2, ih: 2},
200 | {key: "r", alt: "4", w: 1, il: 3, ih: 3},
201 | {key: "t", alt: "5", w: 1, il: 4, ih: 4},
202 | {key: "y", alt: "6", w: 1, il: 5, ih: 5},
203 | {key: "u", alt: "7", w: 1, il: 6, ih: 6},
204 | {key: "i", alt: "8", w: 1, il: 7, ih: 7},
205 | {key: "o", alt: "9", w: 1, il: 8, ih: 8},
206 | {key: "p", alt: "0", w: 1, il: 9, ih: 9},
207 | {key: backChar, alt: backChar, w: 1, il: 10, ih: 10}
208 | ]
209 |
210 | delegate: KeyButton {
211 | label: alts ? (modelData.alt) : (shift ? modelData.key.toUpperCase() : modelData.key)
212 |
213 | width: modelData.w * keymap.width / 11 - rowspacing
214 | height: keymap.height / 4 - colspacing
215 |
216 | focus: curRow == 0 && (curCol >= modelData.il && curCol <= modelData.ih)
217 |
218 | clickedColor:colors["keyPush"]
219 | regColor: colors["key"]
220 | textColor: colors["text"]
221 |
222 | // Key Highlight
223 | Rectangle {
224 | anchors.fill: parent
225 | radius: parent.radius
226 | border.width: 2
227 | border.color: colors["keyHighlight"]
228 | color: "transparent"
229 | visible: curRow == 0 && (curCol >= modelData.il && curCol <= modelData.ih)
230 | }
231 |
232 | // Sending the key (click)
233 | onClicked: {
234 | kRoot.sendKey(label);
235 | curRow = 0;
236 | curCol = modelData.il;
237 | }
238 |
239 | // Sending the key (button)
240 | Keys.onPressed: {
241 | if (api.keys.isAccept(event)) {
242 | kRoot.sendKey(label)
243 | }
244 | }
245 | }
246 |
247 | /* The same thing with the keys here is done with the rest of the Rows.
248 | *
249 | */
250 | }
251 | }
252 |
253 | Row { // ASDFGHJKL + Enter
254 | spacing: rowspacing
255 |
256 | Repeater {
257 | // Key model
258 | model: [
259 | {key: "a", alt: "!", w: 1, il: 0, ih: 0},
260 | {key: "s", alt: "@", w: 1, il: 1, ih: 1},
261 | {key: "d", alt: "#", w: 1, il: 2, ih: 2},
262 | {key: "f", alt: "$", w: 1, il: 3, ih: 3},
263 | {key: "g", alt: "%", w: 1, il: 4, ih: 4},
264 | {key: "h", alt: "&", w: 1, il: 5, ih: 5},
265 | {key: "j", alt: "*", w: 1, il: 6, ih: 6},
266 | {key: "k", alt: "(", w: 1, il: 7, ih: 7},
267 | {key: "l", alt: ")", w: 1, il: 8, ih: 8},
268 | {key: enterChar, alt: enterChar, w: 2, il: 9, ih: 10}
269 | ]
270 |
271 | // Button
272 | delegate: KeyButton {
273 | label: alts ? (modelData.alt) : (shift ? modelData.key.toUpperCase() : modelData.key)
274 |
275 | width: modelData.w * keymap.width / 11 - rowspacing
276 | height: keymap.height / 4 - colspacing
277 |
278 | focus: visible && curRow == 1 && (curCol >= modelData.il && curCol <= modelData.ih)
279 |
280 | clickedColor:colors["keyPush"]
281 | regColor: colors["key"]
282 | textColor: colors["text"]
283 |
284 | // Key send (click)
285 | onClicked: {
286 | kRoot.sendKey(label);
287 | curRow = 1;
288 | curCol = modelData.il;
289 | }
290 | // Key send (button)
291 | Keys.onPressed: {
292 | if (api.keys.isAccept(event)) {
293 | kRoot.sendKey(label)
294 | }
295 | }
296 |
297 | // Key Highlight
298 | Rectangle {
299 | anchors.fill: parent
300 | radius: parent.radius
301 | border.width: 2
302 | border.color: colors["keyHighlight"]
303 | color: "transparent"
304 | visible: curRow == 1 && (curCol >= modelData.il && curCol <= modelData.ih)
305 | }
306 | }
307 | }
308 | }
309 |
310 | Row { // sh + ZXCVBNM + sh
311 | spacing: rowspacing
312 |
313 | Repeater {
314 | model: [
315 | {key: shiftChar, alt: shiftChar, w: 2, il: 0, ih: 1},
316 | {key: "z", alt: "-", w: 1, il: 2, ih: 2},
317 | {key: "x", alt: "'", w: 1, il: 3, ih: 3},
318 | {key: "c", alt: '"', w: 1, il: 4, ih: 4},
319 | {key: "v", alt: "_", w: 1, il: 5, ih: 5},
320 | {key: "b", alt: ",", w: 1, il: 6, ih: 6},
321 | {key: "n", alt: "?", w: 1, il: 7, ih: 7},
322 | {key: "m", alt: "+", w: 1, il: 8, ih: 8},
323 | {key: shiftChar, alt: shiftChar, w: 2, il: 9, ih: 10}
324 | ]
325 |
326 | delegate: KeyButton {
327 | label: alts ? (modelData.alt) : (shift ? modelData.key.toUpperCase() : modelData.key)
328 |
329 | width: modelData.w * keymap.width / 11 - rowspacing
330 | height: keymap.height / 4 - colspacing
331 |
332 | focus: visible && curRow == 2 && (curCol >= modelData.il && curCol <= modelData.ih)
333 |
334 | clickedColor:colors["keyPush"]
335 | regColor: colors["key"]
336 | textColor: colors["text"]
337 |
338 | // Key send (click)
339 | onClicked: {
340 | kRoot.sendKey(label);
341 | curRow = 2;
342 | curCol = modelData.il;
343 | }
344 | // Key send (button)
345 | Keys.onPressed: {
346 | if (api.keys.isAccept(event)) {
347 | kRoot.sendKey(label)
348 | }
349 | }
350 |
351 | // Key Highlight
352 | Rectangle {
353 | anchors.fill: parent
354 | radius: parent.radius
355 | border.width: 2
356 | border.color: colors["keyHighlight"]
357 | color: "transparent"
358 | visible: curRow == 2 && (curCol >= modelData.il && curCol <= modelData.ih)
359 | }
360 | }
361 | }
362 | }
363 |
364 | Row { // sh + ZXCVBNM + sh
365 | spacing: rowspacing
366 |
367 | Repeater {
368 | model: [
369 | {key: "&123", alt: "ABCD", w: 2, il: 0, ih: 1},
370 | {key: ".", alt: ".", w: 1, il: 2, ih: 2},
371 | {key: " ", alt: " ", w: 5, il: 3, ih: 7},
372 | {key: "-", alt: "-", w: 1, il: 8, ih: 8},
373 | {key: "CLEAR", alt: "CLEAR", w: 2, il: 9, ih: 10}
374 | ]
375 |
376 | delegate: KeyButton {
377 | label: alts ? (modelData.alt) : (shift ? modelData.key.toUpperCase() : modelData.key)
378 |
379 | width: modelData.w * keymap.width / 11 - rowspacing
380 | height: keymap.height / 4 - colspacing
381 |
382 | focus: visible && curRow == 3 && (curCol >= modelData.il && curCol <= modelData.ih)
383 |
384 | clickedColor:colors["keyPush"]
385 | regColor: colors["key"]
386 | textColor: colors["text"]
387 |
388 | // Key send (click)
389 | onClicked: {
390 | kRoot.sendKey(label);
391 | curRow = 3;
392 | curCol = modelData.il;
393 | }
394 | // Key send (button)
395 | Keys.onPressed: {
396 | if (api.keys.isAccept(event)) {
397 | kRoot.sendKey(label)
398 | }
399 | }
400 |
401 | // Key Highlight
402 | Rectangle {
403 | anchors.fill: parent
404 | radius: parent.radius
405 | border.width: 2
406 | border.color: colors["keyHighlight"]
407 | color: "transparent"
408 | visible: curRow == 3 && (curCol >= modelData.il && curCol <= modelData.ih)
409 | }
410 | }
411 | }
412 | }
413 |
414 | }
415 | }
416 |
417 |
418 |
419 | function focusEnableKB() {
420 | if (curRow >= 3) {
421 | curRow = 0
422 | } else {
423 | curRow += 1
424 | }
425 | if (curRow <= 0) {
426 | curRow = 3
427 | } else {
428 | curRow -= 1
429 | }
430 | }
431 |
432 | }
433 |
--------------------------------------------------------------------------------
/assets/SAFELY_REMOVABLE/OLD_DOCUMENTATION.md:
--------------------------------------------------------------------------------
1 | # Warning
2 |
3 | This is old documentation that was the original intent for this theme's documentation. I have decided instead to make this into just comments.
4 |
5 |
6 |
7 | ## In Depth Editing Information
8 |
9 | This section will detail this theme fully, in order to allow you to have a greater understanding of this theme as well as QML. This will serve well for those who wish to perform heavy modifications of this theme or fork this theme. It is highly recommended that you take a look at the following sources at times while you look at this information:
10 |
11 | - [QtQuick QML Types](https://doc.qt.io/qt-5/qtquick-qmlmodule.html) (note that a quick search for the type followed by 'QML' will yield information for that type; not all types are here)
12 | - [Pegasus Frontend Theme API](https://pegasus-frontend.org/docs/themes/api/)
13 |
14 | ### theme.qml
15 |
16 | `theme.qml` can be divided into several parts. We first import all necessary QML modules, going from `QtQuick 2.8` to `SortFilterProxyModel 0.2`. Afterwards, we import other parts of the theme. To read more about these parts, see [Theme Folder Pages](#theme-folder-pages) and [Game Items](#game-items).
17 |
18 | The next few sections are described below.
19 | Library
6 | 11 | 12 | `; 13 | 14 | 15 | document.getElementById("footer").innerHTML = ` 16 |Theme & Website by Fr75s.
18 | 19 | Source Code 20 |
17 |
18 | 
20 |
21 | 
23 |
24 | 
26 |
27 | 
29 |
30 | 
32 |
33 | 
35 |
36 | 
38 |
39 | 
41 | Installing this theme is simple, and can be done with the following steps.
16 |First, download the theme's contents, which can be done by clicking the button below, or by downloading the zip file from the github page.
17 | 18 | Download 19 | 20 |Next, extract the contents of the .zip file to your themes folder: refer to the official Pegasus documentation for more information as to where exactly the themes folder is on your system.
21 | 22 |Finally, you may remove the SAFELY_REMOVABLE folder that's in the assets folder within the theme's folder, as it only provides screenshots and other resources not required to run the theme.
23 |
14 |
15 | Library is a clean, modern interface for Pegasus Frontend that aims to provide a useful theme that makes it quick to find and play games. Inspired partly by the Steam Deck's UI, this interface focuses more on displaying box art in organized categories with a minimal amount of text.
17 | 18 |Library aims to be easy to use once Pegasus itself is set up. While Pegasus Frontend is not the friendliest in terms of configuration, tools are available that can help you to at least get metadata for the theme. 19 | 20 | 21 |
Library has several toggleable options which allow you to easily modify parts of the theme. Options include a light mode, expanding the game width and more. Of course, you can always customize the QML files; we even provide a guide for some quick modifications to get started.
24 | 25 |Library is a theme that is quite simple to use, making it easy to search through your game library. It also uses little metadata: only the title, box art and another art/screenshot is needed for games to fully function.
27 | 28 |Library has several advanced features which other themes don't have, such as mouse-based navigation and a virtual keyboard for searching. These advanced features enhance your experience.
30 | 31 | 32 |I referred to other projects throughout the creation of this theme. These projects are listed below.
34 | 35 |I would also like to thank TigraTT-Driver, who has contributed several new features to Library and who has provided the German translation.
48 | 49 |