├── INSTALL.md
├── LICENSE.md
├── README.md
├── after
├── plugin
│ └── omni.vim
└── syntax
│ ├── css.vim
│ ├── gitcommit.vim
│ ├── html.vim
│ ├── javascript.vim
│ ├── javascriptreact.vim
│ ├── json.vim
│ ├── lua.vim
│ ├── markdown.vim
│ ├── ocaml.vim
│ ├── perl.vim
│ ├── php.vim
│ ├── plantuml.vim
│ ├── python.vim
│ ├── ruby.vim
│ ├── rust.vim
│ ├── sass.vim
│ ├── sh.vim
│ ├── tex.vim
│ ├── typescript.vim
│ ├── typescriptreact.vim
│ ├── vim.vim
│ ├── xml.vim
│ └── yaml.vim
├── autoload
├── airline
│ └── themes
│ │ └── omni.vim
├── lightline
│ └── colorscheme
│ │ └── omni.vim
└── omni.vim
├── colors
└── omni.vim
└── screenshot.png
/INSTALL.md:
--------------------------------------------------------------------------------
1 | 1. Create theme folder (in case you don't have yet):
2 |
3 | ```
4 | mkdir -p ~/.vim/pack/themes/start
5 | ```
6 |
7 | 2. Navigate to the folder above:
8 |
9 | ```
10 | cd ~/.vim/pack/themes/start
11 | ```
12 |
13 | 3. Clone the repository using the "omni" name:
14 |
15 | ```
16 | git clone https://github.com/GuiLra/vim omni
17 | ```
18 |
19 | 4. Create configuration file (in case you don't have yet):
20 |
21 | ```
22 | touch ~/.vimrc
23 | ```
24 |
25 | 5. Edit the `~/.vimrc` file with the following content:
26 |
27 | ```
28 | packadd! omni
29 | syntax enable
30 | colorscheme omni
31 | ```
32 |
--------------------------------------------------------------------------------
/LICENSE.md:
--------------------------------------------------------------------------------
1 | The MIT License (MIT)
2 |
3 | Copyright (c) 2016 Dracula Theme
4 |
5 | Permission is hereby granted, free of charge, to any person obtaining a copy
6 | of this software and associated documentation files (the "Software"), to deal
7 | in the Software without restriction, including without limitation the rights
8 | to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
9 | copies of the Software, and to permit persons to whom the Software is
10 | furnished to do so, subject to the following conditions:
11 |
12 | The above copyright notice and this permission notice shall be included in all
13 | copies or substantial portions of the Software.
14 |
15 | THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
16 | IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
17 | FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
18 | AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
19 | LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
20 | OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
21 | SOFTWARE.
22 |
--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
1 |
2 |
3 | 
4 |
5 | Omni for Vim
6 |
7 |
8 |
9 |
10 | Dark theme for Vim
11 |
12 |
13 |
14 | 
15 |
16 | 
17 |
18 |
19 |
20 | Install •
21 | Team •
22 | License
23 |
24 |
25 |
26 | 
27 |
28 |
29 | ## Install
30 |
31 | All instructions can be found at [INSTALL.md](./INSTALL.md).
32 |
33 | ## Team
34 |
35 | This theme is maintained by the following person(s) and a bunch of [awesome contributors](https://github.com/GuiLra/tilix-omni/graphs/contributors).
36 |
37 | | [](https://github.com/GuiLra) |
38 | | ------------------------------------------------------------------------------------------------ |
39 | | [Guilherme Leandro](https://github.com/GuiLra) |
40 |
41 | ## License
42 |
43 | [MIT License](./LICENSE.md)
44 |
--------------------------------------------------------------------------------
/after/plugin/omni.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort()
2 | finish
3 | endif
4 |
5 | " Fzf: {{{
6 | if exists('g:loaded_fzf') && ! exists('g:fzf_colors')
7 | let g:fzf_colors = {
8 | \ 'fg': ['fg', 'Normal'],
9 | \ 'bg': ['bg', 'Normal'],
10 | \ 'hl': ['fg', 'Search'],
11 | \ 'fg+': ['fg', 'Normal'],
12 | \ 'bg+': ['bg', 'Normal'],
13 | \ 'hl+': ['fg', 'OmniOrange'],
14 | \ 'info': ['fg', 'OmniPurple'],
15 | \ 'border': ['fg', 'Ignore'],
16 | \ 'prompt': ['fg', 'OmniGreen'],
17 | \ 'pointer': ['fg', 'Exception'],
18 | \ 'marker': ['fg', 'Keyword'],
19 | \ 'spinner': ['fg', 'Label'],
20 | \ 'header': ['fg', 'Comment'],
21 | \}
22 | endif
23 | "}}}
24 | " ALE: {{{
25 | if exists('g:ale_enabled')
26 | hi! link ALEError OmniErrorLine
27 | hi! link ALEWarning OmniWarnLine
28 | hi! link ALEInfo OmniInfoLine
29 |
30 | hi! link ALEErrorSign OmniRed
31 | hi! link ALEWarningSign OmniOrange
32 | hi! link ALEInfoSign OmniCyan
33 |
34 | hi! link ALEVirtualTextError Comment
35 | hi! link ALEVirtualTextWarning Comment
36 | endif
37 | " }}}
38 | " CTrlP: {{{
39 | if exists('g:loaded_ctrlp')
40 | hi! link CtrlPMatch IncSearch
41 | hi! link CtrlPBufferHid Normal
42 | endif
43 | " }}}
44 |
45 | " vim: fdm=marker ts=2 sts=2 sw=2 fdl=0:
46 |
--------------------------------------------------------------------------------
/after/syntax/css.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('css')
2 | finish
3 | endif
4 |
5 | hi! link cssAttrComma Delimiter
6 | hi! link cssAttrRegion OmniPink
7 | hi! link cssAttributeSelector OmniGreenItalic
8 | hi! link cssBraces Delimiter
9 | hi! link cssFunctionComma Delimiter
10 | hi! link cssNoise OmniPink
11 | hi! link cssProp OmniCyan
12 | hi! link cssPseudoClass OmniPink
13 | hi! link cssPseudoClassId OmniGreenItalic
14 | hi! link cssUnitDecorators OmniPink
15 | hi! link cssVendor OmniGreenItalic
16 |
--------------------------------------------------------------------------------
/after/syntax/gitcommit.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('gitcommit')
2 | finish
3 | endif
4 |
5 | " The following two are misnomers. Colors are correct.
6 | hi! link diffFile OmniGreen
7 | hi! link diffNewFile OmniRed
8 |
9 | hi! link diffAdded OmniGreen
10 | hi! link diffLine OmniCyanItalic
11 | hi! link diffRemoved OmniRed
12 |
13 |
--------------------------------------------------------------------------------
/after/syntax/html.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('html')
2 | finish
3 | endif
4 |
5 | hi! link htmlTag OmniFg
6 | hi! link htmlArg OmniGreenItalic
7 | hi! link htmlTitle OmniFg
8 | hi! link htmlH1 OmniFg
9 | hi! link htmlSpecialChar OmniPurple
10 |
--------------------------------------------------------------------------------
/after/syntax/javascript.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('javascript', 'javascriptreact', 'javascript.jsx')
2 | finish
3 | endif
4 |
5 | hi! link javaScriptBraces Delimiter
6 | hi! link javaScriptNumber Constant
7 | hi! link javaScriptNull Constant
8 | hi! link javaScriptFunction Keyword
9 |
10 | " pangloss/vim-javascript {{{
11 |
12 | hi! link jsArrowFunction Operator
13 | hi! link jsClassMethodType Keyword
14 | hi! link jsDestructuringAssignment OmniOrangeItalic
15 | hi! link jsDocParam OmniOrangeItalic
16 | hi! link jsDocTags Keyword
17 | hi! link jsDocType Type
18 | hi! link jsDocTypeBrackets OmniCyan
19 | hi! link jsFuncArgOperator Operator
20 | hi! link jsFunction Keyword
21 | hi! link jsTemplateBraces Special
22 |
23 | "}}}
24 |
25 | " maxmellon/vim-jsx-pretty {{{
26 |
27 | hi! link jsxTag Keyword
28 | hi! link jsxTagName Keyword
29 | hi! link jsxComponentName Type
30 | hi! link jsxCloseTag Type
31 | hi! link jsxAttrib OmniGreenItalic
32 | hi! link jsxCloseString Identifier
33 | hi! link jsxOpenPunct Identifier
34 |
35 | " }}}
36 |
37 | " vim: fdm=marker ts=2 sts=2 sw=2 fdl=0:
38 |
--------------------------------------------------------------------------------
/after/syntax/javascriptreact.vim:
--------------------------------------------------------------------------------
1 | runtime! syntax/javascript.vim
2 |
--------------------------------------------------------------------------------
/after/syntax/json.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('json')
2 | finish
3 | endif
4 |
5 | hi! link jsonKeyword OmniCyan
6 | hi! link jsonKeywordMatch OmniPink
7 |
--------------------------------------------------------------------------------
/after/syntax/lua.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('lua')
2 | finish
3 | endif
4 |
5 | hi! link luaFunc OmniCyan
6 | hi! link luaTable OmniFg
7 |
--------------------------------------------------------------------------------
/after/syntax/markdown.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('markdown', 'mkd')
2 | finish
3 | endif
4 |
5 | if b:current_syntax ==# 'mkd'
6 | " plasticboy/vim-markdown {{{1
7 | hi! link htmlBold OmniOrangeBold
8 | hi! link htmlBoldItalic OmniOrangeBoldItalic
9 | hi! link htmlH1 OmniPurpleBold
10 | hi! link htmlItalic OmniYellowItalic
11 | hi! link mkdBlockquote OmniYellowItalic
12 | hi! link mkdBold OmniOrangeBold
13 | hi! link mkdBoldItalic OmniOrangeBoldItalic
14 | hi! link mkdCode OmniGreen
15 | hi! link mkdCodeEnd OmniGreen
16 | hi! link mkdCodeStart OmniGreen
17 | hi! link mkdHeading OmniPurpleBold
18 | hi! link mkdInlineUrl OmniLink
19 | hi! link mkdItalic OmniYellowItalic
20 | hi! link mkdLink OmniPink
21 | hi! link mkdListItem OmniCyan
22 | hi! link mkdRule OmniComment
23 | hi! link mkdUrl OmniLink
24 | "}}}1
25 | elseif b:current_syntax ==# 'markdown'
26 | " Builtin: {{{1
27 | hi! link markdownBlockquote OmniCyan
28 | hi! link markdownBold OmniOrangeBold
29 | hi! link markdownBoldItalic OmniOrangeBoldItalic
30 | hi! link markdownCodeBlock OmniGreen
31 | hi! link markdownCode OmniGreen
32 | hi! link markdownCodeDelimiter OmniGreen
33 | hi! link markdownH1 OmniPurpleBold
34 | hi! link markdownH2 markdownH1
35 | hi! link markdownH3 markdownH1
36 | hi! link markdownH4 markdownH1
37 | hi! link markdownH5 markdownH1
38 | hi! link markdownH6 markdownH1
39 | hi! link markdownHeadingDelimiter markdownH1
40 | hi! link markdownHeadingRule markdownH1
41 | hi! link markdownItalic OmniYellowItalic
42 | hi! link markdownLinkText OmniPink
43 | hi! link markdownListMarker OmniCyan
44 | hi! link markdownOrderedListMarker OmniCyan
45 | hi! link markdownRule OmniComment
46 | hi! link markdownUrl OmniLink
47 | "}}}
48 | endif
49 |
50 | " vim: fdm=marker ts=2 sts=2 sw=2 fdl=0:
51 |
--------------------------------------------------------------------------------
/after/syntax/ocaml.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('ocaml')
2 | finish
3 | endif
4 |
5 | hi! link ocamlModule Type
6 | hi! link ocamlModPath Normal
7 | hi! link ocamlLabel OmniOrangeItalic
8 |
--------------------------------------------------------------------------------
/after/syntax/perl.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('perl')
2 | finish
3 | endif
4 |
5 | " Regex
6 | hi! link perlMatchStartEnd OmniRed
7 |
8 | " Builtin functions
9 | hi! link perlOperator OmniCyan
10 | hi! link perlStatementFiledesc OmniCyan
11 | hi! link perlStatementFiles OmniCyan
12 | hi! link perlStatementFlow OmniCyan
13 | hi! link perlStatementHash OmniCyan
14 | hi! link perlStatementIOfunc OmniCyan
15 | hi! link perlStatementIPC OmniCyan
16 | hi! link perlStatementList OmniCyan
17 | hi! link perlStatementMisc OmniCyan
18 | hi! link perlStatementNetwork OmniCyan
19 | hi! link perlStatementNumeric OmniCyan
20 | hi! link perlStatementProc OmniCyan
21 | hi! link perlStatementPword OmniCyan
22 | hi! link perlStatementRegexp OmniCyan
23 | hi! link perlStatementScalar OmniCyan
24 | hi! link perlStatementSocket OmniCyan
25 | hi! link perlStatementTime OmniCyan
26 | hi! link perlStatementVector OmniCyan
27 |
28 | " Highlighting for quoting constructs, tied to existing option in vim-perl
29 | if get(g:, 'perl_string_as_statement', 0)
30 | hi! link perlStringStartEnd OmniRed
31 | endif
32 |
33 | " Signatures
34 | hi! link perlSignature OmniOrangeItalic
35 | hi! link perlSubPrototype OmniOrangeItalic
36 |
37 | " Hash keys
38 | hi! link perlVarSimpleMemberName OmniPurple
39 |
--------------------------------------------------------------------------------
/after/syntax/php.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('php')
2 | finish
3 | endif
4 |
5 | hi! link phpClass Type
6 | hi! link phpClasses Type
7 | hi! link phpDocTags OmniCyanItalic
8 | hi! link phpFunction Function
9 | hi! link phpParent Normal
10 | hi! link phpSpecialFunction OmniCyan
11 |
--------------------------------------------------------------------------------
/after/syntax/plantuml.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('plantuml')
2 | finish
3 | endif
4 |
5 | hi! link plantumlClassPrivate SpecialKey
6 | hi! link plantumlClassProtected OmniOrange
7 | hi! link plantumlClassPublic Function
8 | hi! link plantumlColonLine String
9 | hi! link plantumlDirectedOrVerticalArrowLR Constant
10 | hi! link plantumlDirectedOrVerticalArrowRL Constant
11 | hi! link plantumlHorizontalArrow Constant
12 | hi! link plantumlSkinParamKeyword OmniCyan
13 | hi! link plantumlTypeKeyword Keyword
14 |
--------------------------------------------------------------------------------
/after/syntax/python.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('python')
2 | finish
3 | endif
4 |
5 | hi! link pythonBuiltinObj Type
6 | hi! link pythonBuiltinObject Type
7 | hi! link pythonBuiltinType Type
8 | hi! link pythonClassVar OmniPurpleItalic
9 | hi! link pythonExClass Type
10 | hi! link pythonNone Type
11 | hi! link pythonRun Comment
12 |
--------------------------------------------------------------------------------
/after/syntax/ruby.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('ruby')
2 | finish
3 | endif
4 |
5 | if ! exists('g:ruby_operators')
6 | let g:ruby_operators=1
7 | endif
8 |
9 | hi! link rubyBlockArgument OmniOrangeItalic
10 | hi! link rubyBlockParameter OmniOrangeItalic
11 | hi! link rubyCurlyBlock OmniPink
12 | hi! link rubyGlobalVariable OmniPurple
13 | hi! link rubyInstanceVariable OmniPurpleItalic
14 | hi! link rubyInterpolationDelimiter OmniPink
15 | hi! link rubyRegexpDelimiter OmniRed
16 | hi! link rubyStringDelimiter OmniYellow
17 |
--------------------------------------------------------------------------------
/after/syntax/rust.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('rust')
2 | finish
3 | endif
4 |
5 | hi! link rustCommentLineDoc Comment
6 |
--------------------------------------------------------------------------------
/after/syntax/sass.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('sass')
2 | finish
3 | endif
4 |
5 | hi! link sassClass cssClassName
6 | hi! link sassClassChar cssClassNameDot
7 | hi! link sassId cssIdentifier
8 | hi! link sassIdChar cssIdentifier
9 | hi! link sassInterpolationDelimiter OmniPink
10 | hi! link sassMixinName Function
11 | hi! link sassProperty cssProp
12 | hi! link sassVariableAssignment Operator
13 |
--------------------------------------------------------------------------------
/after/syntax/sh.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('bash', 'ksh', 'posix', 'sh')
2 | finish
3 | endif
4 |
5 | hi! link shCommandSub NONE
6 | hi! link shEscape OmniRed
7 | hi! link shParen NONE
8 | hi! link shParenError NONE
9 |
--------------------------------------------------------------------------------
/after/syntax/tex.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('tex')
2 | finish
3 | endif
4 |
5 | hi! link texBeginEndName OmniOrangeItalic
6 | hi! link texBoldItalStyle OmniOrangeBoldItalic
7 | hi! link texBoldStyle OmniOrangeBold
8 | hi! link texInputFile OmniOrangeItalic
9 | hi! link texItalStyle OmniYellowItalic
10 | hi! link texLigature OmniPurple
11 | hi! link texMath OmniPurple
12 | hi! link texMathMatcher OmniPurple
13 | hi! link texMathSymbol OmniPurple
14 | hi! link texRefZone OmniBgDarker
15 | hi! link texSpecialChar OmniPurple
16 | hi! link texSubscripts OmniPurple
17 | hi! link texTitle OmniFgBold
18 |
--------------------------------------------------------------------------------
/after/syntax/typescript.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('typescript', 'typescriptreact', 'typescript.tsx')
2 | finish
3 | endif
4 |
5 | " HerringtonDarkholme/yats.vim {{{
6 |
7 | hi! link typescriptAliasDeclaration Type
8 | hi! link typescriptArrayMethod Function
9 | hi! link typescriptArrowFunc Operator
10 | hi! link typescriptArrowFuncArg OmniOrangeItalic
11 | hi! link typescriptAssign Operator
12 | hi! link typescriptBOMWindowProp Constant
13 | hi! link typescriptBinaryOp Operator
14 | hi! link typescriptBraces Delimiter
15 | hi! link typescriptCall typescriptArrowFuncArg
16 | hi! link typescriptClassHeritage Type
17 | hi! link typescriptClassName Type
18 | hi! link typescriptDateMethod OmniCyan
19 | hi! link typescriptDateStaticMethod Function
20 | hi! link typescriptDecorator OmniGreenItalic
21 | hi! link typescriptDefaultParam Operator
22 | hi! link typescriptES6SetMethod OmniCyan
23 | hi! link typescriptEndColons Delimiter
24 | hi! link typescriptEnum Type
25 | hi! link typescriptEnumKeyword Keyword
26 | hi! link typescriptFuncComma Delimiter
27 | hi! link typescriptFuncKeyword Keyword
28 | hi! link typescriptFuncType OmniOrangeItalic
29 | hi! link typescriptFuncTypeArrow Operator
30 | hi! link typescriptGlobal Type
31 | hi! link typescriptGlobalMethod OmniCyan
32 | hi! link typescriptGlobalObjects Type
33 | hi! link typescriptIdentifier OmniPurpleItalic
34 | hi! link typescriptInterfaceHeritage Type
35 | hi! link typescriptInterfaceName Type
36 | hi! link typescriptInterpolationDelimiter Keyword
37 | hi! link typescriptKeywordOp Keyword
38 | hi! link typescriptLogicSymbols Operator
39 | hi! link typescriptMember Identifier
40 | hi! link typescriptMemberOptionality Special
41 | hi! link typescriptObjectColon Special
42 | hi! link typescriptObjectLabel Identifier
43 | hi! link typescriptObjectSpread Operator
44 | hi! link typescriptOperator Operator
45 | hi! link typescriptParamImpl OmniOrangeItalic
46 | hi! link typescriptParens Delimiter
47 | hi! link typescriptPredefinedType Type
48 | hi! link typescriptRestOrSpread Operator
49 | hi! link typescriptTernaryOp Operator
50 | hi! link typescriptTypeAnnotation Special
51 | hi! link typescriptTypeCast Operator
52 | hi! link typescriptTypeParameter OmniOrangeItalic
53 | hi! link typescriptTypeReference Type
54 | hi! link typescriptUnaryOp Operator
55 | hi! link typescriptVariable Keyword
56 |
57 | " }}}
58 |
--------------------------------------------------------------------------------
/after/syntax/typescriptreact.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('typescriptreact', 'typescript.tsx')
2 | finish
3 | endif
4 |
5 | runtime! syntax/typescript.vim
6 |
7 | hi! link tsxAttrib OmniGreenItalic
8 | hi! link tsxEqual Operator
9 | hi! link tsxIntrinsicTagName Keyword
10 | hi! link tsxTagName Type
11 |
12 | " maxmellon/vim-jsx-pretty {{{
13 |
14 | hi! link jsxTag Keyword
15 | hi! link jsxTagName Keyword
16 | hi! link jsxComponentName Type
17 | hi! link jsxCloseTag Type
18 | hi! link jsxAttrib OmniGreenItalic
19 | hi! link jsxCloseString Identifier
20 | hi! link jsxOpenPunct Identifier
21 |
22 | " }}}
23 |
--------------------------------------------------------------------------------
/after/syntax/vim.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('vim')
2 | finish
3 | endif
4 |
5 | hi! link vimAutoCmdSfxList Type
6 | hi! link vimAutoEventList Type
7 | hi! link vimEnvVar Constant
8 | hi! link vimFunction Function
9 | hi! link vimHiBang Keyword
10 | hi! link vimOption Type
11 | hi! link vimSetMod Keyword
12 | hi! link vimSetSep Delimiter
13 | hi! link vimUserAttrbCmpltFunc Function
14 | hi! link vimUserFunc Function
15 |
--------------------------------------------------------------------------------
/after/syntax/xml.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('xml')
2 | finish
3 | endif
4 |
5 | hi! link xmlAttrib OmniGreenItalic
6 | hi! link xmlEqual Operator
7 | hi! link xmlTag Delimiter
8 | hi! link xmlTagName Statement
9 |
10 | " Fixes missing highlight over end tags
11 | syn region xmlTagName
12 | \ matchgroup=xmlTag start=+"']\@=+
13 | \ matchgroup=xmlTag end=+>+
14 |
--------------------------------------------------------------------------------
/after/syntax/yaml.vim:
--------------------------------------------------------------------------------
1 | if omni#should_abort('yaml')
2 | finish
3 | endif
4 |
5 | hi! link yamlAlias OmniGreenItalicUnderline
6 | hi! link yamlAnchor OmniPinkItalic
7 | hi! link yamlBlockMappingKey OmniCyan
8 | hi! link yamlFlowCollection OmniPink
9 | hi! link yamlFlowIndicator Delimiter
10 | hi! link yamlNodeTag OmniPink
11 | hi! link yamlPlainScalar OmniYellow
12 |
13 |
--------------------------------------------------------------------------------
/autoload/airline/themes/omni.vim:
--------------------------------------------------------------------------------
1 | " Omni Airline Theme: {{{
2 | "
3 | " Copyright 2016, All rights reserved
4 | "
5 | " Code licensed under the MIT license
6 | "
7 | "}}}
8 | " Helpers: {{{
9 |
10 | " Takes a foreground color name, background color name, and optionally one or
11 | " more attr-list items as input, transforms it to the format accepted by
12 | " airline#themes#generate_color_map and returns that value
13 | func! s:clr(fg, bg, ...)
14 | let l:fg = g:omni#palette[a:fg]
15 | let l:bg = g:omni#palette[a:bg]
16 | return [ l:fg[0], l:bg[0], l:fg[1], l:bg[1] ] +
17 | \ filter(copy(a:000), 'type(v:val) == 1 && len(v:val) > 0')
18 | endfunc
19 |
20 | " Takes three ['fg', 'bg'] color lists and optionally a dictionary of extra
21 | " key-value pairs and returns the value generated by
22 | " airline#themes#generate_color_map after optionally merging the dictionary of
23 | " extra key-value pairs.
24 | "
25 | " a:a -> airline_a, airline_x
26 | " a:b -> airline_b, airline_y
27 | " a:c -> airline_c, airline_z
28 | func! s:color_map(a, b, c, ...)
29 | if a:0 == 0
30 | return call('airline#themes#generate_color_map', [call('s:clr', a:a), call('s:clr', a:b), call('s:clr', a:c)])
31 | else
32 | return call('extend', [ call('airline#themes#generate_color_map', [call('s:clr', a:a), call('s:clr', a:b), call('s:clr', a:c)]) ] + a:000)
33 | endif
34 | endfunc
35 |
36 | "}}}
37 |
38 | let g:airline#themes#omni#palette = {
39 | \ 'normal': s:color_map(
40 | \ ['bg', 'purple'],
41 | \ ['fg', 'comment'],
42 | \ ['fg', 'selection'],
43 | \ {
44 | \ 'airline_warning': s:clr('bg', 'orange'),
45 | \ 'airline_error': s:clr('bg', 'red'),
46 | \ },
47 | \ ),
48 | \ 'normal_modified': s:color_map(
49 | \ ['bg', 'purple'],
50 | \ ['fg', 'comment'],
51 | \ ['fg', 'bgdark'],
52 | \ {
53 | \ 'airline_warning': s:clr('bg', 'orange'),
54 | \ 'airline_error': s:clr('bg', 'red'),
55 | \ },
56 | \ ),
57 | \ 'insert': s:color_map(
58 | \ ['bg', 'green'],
59 | \ ['fg', 'comment'],
60 | \ ['fg', 'selection'],
61 | \ {
62 | \ 'airline_warning': s:clr('bg', 'orange'),
63 | \ 'airline_error': s:clr('bg', 'red'),
64 | \ },
65 | \ ),
66 | \ 'insert_modified': s:color_map(
67 | \ ['bg', 'green'],
68 | \ ['fg', 'comment'],
69 | \ ['fg', 'bgdark'],
70 | \ {
71 | \ 'airline_warning': s:clr('bg', 'orange'),
72 | \ 'airline_error': s:clr('bg', 'red'),
73 | \ },
74 | \ ),
75 | \ 'replace': s:color_map(
76 | \ ['bg', 'orange'],
77 | \ ['fg', 'comment'],
78 | \ ['fg', 'selection'],
79 | \ {
80 | \ 'airline_warning': s:clr('bg', 'orange'),
81 | \ 'airline_error': s:clr('bg', 'red'),
82 | \ },
83 | \ ),
84 | \ 'replace_modified': s:color_map(
85 | \ ['bg', 'orange'],
86 | \ ['fg', 'comment'],
87 | \ ['fg', 'bgdark'],
88 | \ {
89 | \ 'airline_warning': s:clr('bg', 'orange'),
90 | \ 'airline_error': s:clr('bg', 'red'),
91 | \ },
92 | \ ),
93 | \ 'visual': s:color_map(
94 | \ ['bg', 'yellow'],
95 | \ ['fg', 'comment'],
96 | \ ['fg', 'selection'],
97 | \ {
98 | \ 'airline_warning': s:clr('bg', 'orange'),
99 | \ 'airline_error': s:clr('bg', 'red'),
100 | \ },
101 | \ ),
102 | \ 'visual_modified': s:color_map(
103 | \ ['bg', 'yellow'],
104 | \ ['fg', 'comment'],
105 | \ ['fg', 'bgdark'],
106 | \ {
107 | \ 'airline_warning': s:clr('bg', 'orange'),
108 | \ 'airline_error': s:clr('bg', 'red'),
109 | \ },
110 | \ ),
111 | \ 'inactive': s:color_map(
112 | \ ['bg', 'comment'],
113 | \ ['fg', 'bgdark'],
114 | \ ['fg', 'selection'],
115 | \ {
116 | \ 'airline_warning': s:clr('bg', 'orange'),
117 | \ 'airline_error': s:clr('bg', 'red'),
118 | \ },
119 | \ ),
120 | \ 'terminal': s:color_map(
121 | \ ['bg', 'green'],
122 | \ ['fg', 'comment'],
123 | \ ['fg', 'selection'],
124 | \ {
125 | \ 'airline_term': s:clr('fg', 'selection'),
126 | \ },
127 | \ ),
128 | \}
129 |
130 | " Extensions: {{{
131 | " Tabline: {{{
132 | if get(g:, 'airline#extensions#tabline#enabled', 0)
133 | let g:airline#themes#omni#palette.tabline = {
134 | \ 'airline_tabfill': s:clr('bg', 'bglight'),
135 | \
136 | \ 'airline_tab': s:clr('comment', 'bg'),
137 | \ 'airline_tabsel': s:clr('bg', 'purple'),
138 | \ 'airline_tabmod': s:clr('green', 'bg'),
139 | \
140 | \ 'airline_tab_right': s:clr('comment', 'bg'),
141 | \ 'airline_tabsel_right': s:clr('fg', 'bg', ),
142 | \ 'airline_tabmod_right': s:clr('green', 'bg'),
143 | \}
144 | endif
145 | "}}}
146 | " CtrlP: {{{2
147 | if exists('g:loaded_ctrlp')
148 | let g:airline#themes#omni#palette.ctrlp = airline#extensions#ctrlp#generate_color_map(
149 | \ s:clr('fg', 'selection'),
150 | \ s:clr('fg', 'comment'),
151 | \ s:clr('fg', 'purple'),
152 | \)
153 | endif
154 | "}}}2
155 | "}}}
156 |
157 | " vim: fdm=marker ts=2 sts=2 sw=2 fdl=0:
158 |
--------------------------------------------------------------------------------
/autoload/lightline/colorscheme/omni.vim:
--------------------------------------------------------------------------------
1 | " =============================================================================
2 | " Filename: autoload/lightline/colorscheme/omni.vim
3 | " Author: GuiLra
4 | " License: MIT License
5 | " Last Change: 2020/07/24
6 | " =============================================================================
7 |
8 | let s:black = g:omni#palette.bg
9 | let s:gray = g:omni#palette.selection
10 | let s:white = g:omni#palette.fg
11 | let s:darkblue = g:omni#palette.comment
12 | let s:cyan = g:omni#palette.cyan
13 | let s:green = g:omni#palette.green
14 | let s:orange = g:omni#palette.orange
15 | let s:purple = g:omni#palette.purple
16 | let s:red = g:omni#palette.red
17 | let s:yellow = g:omni#palette.yellow
18 |
19 | if exists('g:lightline')
20 |
21 | let s:p = {'normal': {}, 'inactive': {}, 'insert': {}, 'replace': {}, 'visual': {}, 'tabline': {}}
22 | let s:p.normal.left = [ [ s:black, s:purple ], [ s:cyan, s:gray ] ]
23 | let s:p.normal.right = [ [ s:black, s:purple ], [ s:white, s:darkblue ] ]
24 | let s:p.inactive.right = [ [ s:black, s:darkblue ], [ s:white, s:black ] ]
25 | let s:p.inactive.left = [ [ s:cyan, s:black ], [ s:white, s:black ] ]
26 | let s:p.insert.left = [ [ s:black, s:green ], [ s:cyan, s:gray ] ]
27 | let s:p.replace.left = [ [ s:black, s:red ], [ s:cyan, s:gray ] ]
28 | let s:p.visual.left = [ [ s:black, s:orange ], [ s:cyan, s:gray ] ]
29 | let s:p.normal.middle = [ [ s:white, s:gray ] ]
30 | let s:p.inactive.middle = [ [ s:white, s:gray ] ]
31 | let s:p.tabline.left = [ [ s:darkblue, s:gray ] ]
32 | let s:p.tabline.tabsel = [ [ s:cyan, s:black ] ]
33 | let s:p.tabline.middle = [ [ s:darkblue, s:gray ] ]
34 | let s:p.tabline.right = copy(s:p.normal.right)
35 | let s:p.normal.error = [ [ s:red, s:black ] ]
36 | let s:p.normal.warning = [ [ s:yellow, s:black ] ]
37 |
38 | let g:lightline#colorscheme#omni#palette = lightline#colorscheme#flatten(s:p)
39 |
40 | endif
41 |
42 | " vim: fdm=marker ts=2 sts=2 sw=2 fdl=0:
43 |
--------------------------------------------------------------------------------
/autoload/omni.vim:
--------------------------------------------------------------------------------
1 | " Palette: {{{
2 |
3 | let g:omni#palette = {}
4 | let g:omni#palette.fg = ['#E1E1E6', 253]
5 |
6 | let g:omni#palette.bglighter = ['#252131', 238]
7 | let g:omni#palette.bglight = ['#201B2D', 230]
8 | let g:omni#palette.bg = ['#191622', 236]
9 | let g:omni#palette.bgdark = ['#13111B', 234]
10 | let g:omni#palette.bgdarker = ['#15121E', 234]
11 |
12 | let g:omni#palette.comment = ['#483C67', 61]
13 | let g:omni#palette.selection = ['#41414D', 239]
14 | let g:omni#palette.subtle = ['#201B2D', 238]
15 |
16 | let g:omni#palette.cyan = ['#78D1E1', 120]
17 | let g:omni#palette.green = ['#67e480', 103]
18 | let g:omni#palette.orange = ['#E89E64', 232]
19 | let g:omni#palette.pink = ['#FF79C6', 212]
20 | let g:omni#palette.purple = ['#988BC7', 141]
21 | let g:omni#palette.red = ['#E96379', 203]
22 | let g:omni#palette.yellow = ['#e7de79', 228]
23 |
24 | "
25 | " ANSI
26 | "
27 | let g:omni#palette.color_0 = '#201B2D'
28 | let g:omni#palette.color_1 = '#FF79C6'
29 | let g:omni#palette.color_2 = '#67e480'
30 | let g:omni#palette.color_3 = '#e7de79'
31 | let g:omni#palette.color_4 = '#78D1E1'
32 | let g:omni#palette.color_5 = '#988bc7'
33 | let g:omni#palette.color_6 = '#A1EFE4'
34 | let g:omni#palette.color_7 = '#E1E1E6'
35 | let g:omni#palette.color_8 = '#626483'
36 | let g:omni#palette.color_9 = '#ed4556'
37 | let g:omni#palette.color_10 = '#00F769'
38 | let g:omni#palette.color_11 = '#e7de79'
39 | let g:omni#palette.color_12 = '#78D1E1'
40 | let g:omni#palette.color_13 = '#988bc7'
41 | let g:omni#palette.color_14 = '#A4FFFF'
42 | let g:omni#palette.color_15 = '#F7F7FB'
43 |
44 | " }}}
45 |
46 | " Helper function that takes a variadic list of filetypes as args and returns
47 | " whether or not the execution of the ftplugin should be aborted.
48 | func! omni#should_abort(...)
49 | if ! exists('g:colors_name') || g:colors_name !=# 'omni'
50 | return 1
51 | elseif a:0 > 0 && (! exists('b:current_syntax') || index(a:000, b:current_syntax) == -1)
52 | return 1
53 | endif
54 | return 0
55 | endfunction
56 |
57 | " vim: fdm=marker ts=2 sts=2 sw=2 fdl=0:
58 |
--------------------------------------------------------------------------------
/colors/omni.vim:
--------------------------------------------------------------------------------
1 | " Omni Theme: {{{
2 | "
3 | " Copyright 2016, All rights reserved
4 | "
5 | " Code licensed under the MIT license
6 | " http://zenorocha.mit-license.org
7 | "
8 | scriptencoding utf8
9 | " }}}
10 |
11 | " Configuration: {{{
12 |
13 | if v:version > 580
14 | highlight clear
15 | if exists('syntax_on')
16 | syntax reset
17 | endif
18 | endif
19 |
20 | let g:colors_name = 'omni'
21 |
22 | if !(has('termguicolors') && &termguicolors) && !has('gui_running') && &t_Co != 256
23 | finish
24 | endif
25 |
26 | " Palette: {{{2
27 |
28 | let s:fg = g:omni#palette.fg
29 |
30 | let s:bglighter = g:omni#palette.bglighter
31 | let s:bglight = g:omni#palette.bglight
32 | let s:bg = g:omni#palette.bg
33 | let s:bgdark = g:omni#palette.bgdark
34 | let s:bgdarker = g:omni#palette.bgdarker
35 |
36 | let s:comment = g:omni#palette.comment
37 | let s:selection = g:omni#palette.selection
38 | let s:subtle = g:omni#palette.subtle
39 |
40 | let s:cyan = g:omni#palette.cyan
41 | let s:green = g:omni#palette.green
42 | let s:orange = g:omni#palette.orange
43 | let s:pink = g:omni#palette.pink
44 | let s:purple = g:omni#palette.purple
45 | let s:red = g:omni#palette.red
46 | let s:yellow = g:omni#palette.yellow
47 |
48 | let s:none = ['NONE', 'NONE']
49 |
50 | if has('terminal')
51 | let g:terminal_ansi_colors = []
52 | for s:i in range(16)
53 | call add(g:terminal_ansi_colors, g:omni#palette['color_' . s:i])
54 | endfor
55 | endif
56 |
57 | " }}}2
58 | " User Configuration: {{{2
59 |
60 | if !exists('g:omni_bold')
61 | let g:omni_bold = 1
62 | endif
63 |
64 | if !exists('g:omni_italic')
65 | let g:omni_italic = 1
66 | endif
67 |
68 | if !exists('g:omni_underline')
69 | let g:omni_underline = 1
70 | endif
71 |
72 | if !exists('g:omni_undercurl') && g:omni_underline != 0
73 | let g:omni_undercurl = 1
74 | endif
75 |
76 | if !exists('g:omni_inverse')
77 | let g:omni_inverse = 1
78 | endif
79 |
80 | if !exists('g:omni_colorterm')
81 | let g:omni_colorterm = 1
82 | endif
83 |
84 | "}}}2
85 | " Script Helpers: {{{2
86 |
87 | let s:attrs = {
88 | \ 'bold': g:omni_bold == 1 ? 'bold' : 0,
89 | \ 'italic': g:omni_italic == 1 ? 'italic' : 0,
90 | \ 'underline': g:omni_underline == 1 ? 'underline' : 0,
91 | \ 'undercurl': g:omni_undercurl == 1 ? 'undercurl' : 0,
92 | \ 'inverse': g:omni_inverse == 1 ? 'inverse' : 0,
93 | \}
94 |
95 | function! s:h(scope, fg, ...) " bg, attr_list, special
96 | let l:fg = copy(a:fg)
97 | let l:bg = get(a:, 1, ['NONE', 'NONE'])
98 |
99 | let l:attr_list = filter(get(a:, 2, ['NONE']), 'type(v:val) == 1')
100 | let l:attrs = len(l:attr_list) > 0 ? join(l:attr_list, ',') : 'NONE'
101 |
102 | " Falls back to coloring foreground group on terminals because
103 | " nearly all do not support undercurl
104 | let l:special = get(a:, 3, ['NONE', 'NONE'])
105 | if l:special[0] !=# 'NONE' && l:fg[0] ==# 'NONE' && !has('gui_running')
106 | let l:fg[0] = l:special[0]
107 | let l:fg[1] = l:special[1]
108 | endif
109 |
110 | let l:hl_string = [
111 | \ 'highlight', a:scope,
112 | \ 'guifg=' . l:fg[0], 'ctermfg=' . l:fg[1],
113 | \ 'guibg=' . l:bg[0], 'ctermbg=' . l:bg[1],
114 | \ 'gui=' . l:attrs, 'cterm=' . l:attrs,
115 | \ 'guisp=' . l:special[0],
116 | \]
117 |
118 | execute join(l:hl_string, ' ')
119 | endfunction
120 |
121 | "}}}2
122 | " Omni Highlight Groups: {{{2
123 |
124 | call s:h('OmniBgLight', s:none, s:bglight)
125 | call s:h('OmniBgLighter', s:none, s:bglighter)
126 | call s:h('OmniBgDark', s:none, s:bgdark)
127 | call s:h('OmniBgDarker', s:none, s:bgdarker)
128 |
129 | call s:h('OmniFg', s:fg)
130 | call s:h('OmniFgUnderline', s:fg, s:none, [s:attrs.underline])
131 | call s:h('OmniFgBold', s:fg, s:none, [s:attrs.bold])
132 |
133 | call s:h('OmniComment', s:comment)
134 | call s:h('OmniCommentBold', s:comment, s:none, [s:attrs.bold])
135 |
136 | call s:h('OmniSelection', s:none, s:selection)
137 |
138 | call s:h('OmniSubtle', s:subtle)
139 |
140 | call s:h('OmniCyan', s:cyan)
141 | call s:h('OmniCyanItalic', s:cyan, s:none, [s:attrs.italic])
142 |
143 | call s:h('OmniGreen', s:green)
144 | call s:h('OmniGreenBold', s:green, s:none, [s:attrs.bold])
145 | call s:h('OmniGreenItalic', s:green, s:none, [s:attrs.italic])
146 | call s:h('OmniGreenItalicUnderline', s:green, s:none, [s:attrs.italic, s:attrs.underline])
147 |
148 | call s:h('OmniOrange', s:orange)
149 | call s:h('OmniOrangeBold', s:orange, s:none, [s:attrs.bold])
150 | call s:h('OmniOrangeItalic', s:orange, s:none, [s:attrs.italic])
151 | call s:h('OmniOrangeBoldItalic', s:orange, s:none, [s:attrs.bold, s:attrs.italic])
152 | call s:h('OmniOrangeInverse', s:bg, s:orange)
153 |
154 | call s:h('OmniPink', s:pink)
155 | call s:h('OmniPinkItalic', s:pink, s:none, [s:attrs.italic])
156 |
157 | call s:h('OmniPurple', s:purple)
158 | call s:h('OmniPurpleBold', s:purple, s:none, [s:attrs.bold])
159 | call s:h('OmniPurpleItalic', s:purple, s:none, [s:attrs.italic])
160 |
161 | call s:h('OmniRed', s:red)
162 | call s:h('OmniRedInverse', s:fg, s:red)
163 |
164 | call s:h('OmniYellow', s:yellow)
165 | call s:h('OmniYellowItalic', s:yellow, s:none, [s:attrs.italic])
166 |
167 | call s:h('OmniError', s:red, s:none, [], s:red)
168 |
169 | call s:h('OmniErrorLine', s:none, s:none, [s:attrs.undercurl], s:red)
170 | call s:h('OmniWarnLine', s:none, s:none, [s:attrs.undercurl], s:orange)
171 | call s:h('OmniInfoLine', s:none, s:none, [s:attrs.undercurl], s:cyan)
172 |
173 | call s:h('OmniTodo', s:cyan, s:none, [s:attrs.bold, s:attrs.inverse])
174 | call s:h('OmniSearch', s:green, s:none, [s:attrs.inverse])
175 | call s:h('OmniBoundary', s:comment, s:bgdark)
176 | call s:h('OmniLink', s:cyan, s:none, [s:attrs.underline])
177 |
178 | call s:h('OmniDiffChange', s:orange, s:none)
179 | call s:h('OmniDiffText', s:bg, s:orange)
180 | call s:h('OmniDiffDelete', s:red, s:bgdark)
181 |
182 | " }}}2
183 |
184 | " }}}
185 | " User Interface: {{{
186 |
187 | set background=dark
188 |
189 | " Required as some plugins will overwrite
190 | call s:h('Normal', s:fg, g:omni_colorterm || has('gui_running') ? s:bg : s:none )
191 | call s:h('StatusLine', s:none, s:bglighter, [s:attrs.bold])
192 | call s:h('StatusLineNC', s:none, s:bglight)
193 | call s:h('StatusLineTerm', s:none, s:bglighter, [s:attrs.bold])
194 | call s:h('StatusLineTermNC', s:none, s:bglight)
195 | call s:h('WildMenu', s:bg, s:purple, [s:attrs.bold])
196 | call s:h('CursorLine', s:none, s:subtle)
197 |
198 | hi! link ColorColumn OmniBgDark
199 | hi! link CursorColumn CursorLine
200 | hi! link CursorLineNr OmniYellow
201 | hi! link DiffAdd OmniGreen
202 | hi! link DiffAdded DiffAdd
203 | hi! link DiffChange OmniDiffChange
204 | hi! link DiffDelete OmniDiffDelete
205 | hi! link DiffRemoved DiffDelete
206 | hi! link DiffText OmniDiffText
207 | hi! link Directory OmniPurpleBold
208 | hi! link ErrorMsg OmniRedInverse
209 | hi! link FoldColumn OmniSubtle
210 | hi! link Folded OmniBoundary
211 | hi! link IncSearch OmniOrangeInverse
212 | call s:h('LineNr', s:comment)
213 | hi! link MoreMsg OmniFgBold
214 | hi! link NonText OmniSubtle
215 | hi! link Pmenu OmniBgDark
216 | hi! link PmenuSbar OmniBgDark
217 | hi! link PmenuSel OmniSelection
218 | hi! link PmenuThumb OmniSelection
219 | hi! link Question OmniFgBold
220 | hi! link Search OmniSearch
221 | call s:h('SignColumn', s:comment)
222 | hi! link TabLine OmniBoundary
223 | hi! link TabLineFill OmniBgDarker
224 | hi! link TabLineSel Normal
225 | hi! link Title OmniGreenBold
226 | hi! link VertSplit OmniBoundary
227 | hi! link Visual OmniSelection
228 | hi! link VisualNOS Visual
229 | hi! link WarningMsg OmniOrangeInverse
230 |
231 | " }}}
232 | " Syntax: {{{
233 |
234 | " Required as some plugins will overwrite
235 | call s:h('MatchParen', s:green, s:none, [s:attrs.underline])
236 | call s:h('Conceal', s:cyan, s:none)
237 |
238 | " Neovim uses SpecialKey for escape characters only. Vim uses it for that, plus whitespace.
239 | if has('nvim')
240 | hi! link SpecialKey OmniRed
241 | hi! link LspDiagnosticsUnderline OmniFgUnderline
242 | hi! link LspDiagnosticsInformation OmniCyan
243 | hi! link LspDiagnosticsHint OmniCyan
244 | hi! link LspDiagnosticsError OmniError
245 | hi! link LspDiagnosticsWarning OmniOrange
246 | hi! link LspDiagnosticsUnderlineError OmniErrorLine
247 | hi! link LspDiagnosticsUnderlineHint OmniInfoLine
248 | hi! link LspDiagnosticsUnderlineInformation OmniInfoLine
249 | hi! link LspDiagnosticsUnderlineWarning OmniWarnLine
250 | else
251 | hi! link SpecialKey OmniSubtle
252 | endif
253 |
254 | hi! link Comment OmniComment
255 | hi! link Underlined OmniFgUnderline
256 | hi! link Todo OmniTodo
257 |
258 | hi! link Error OmniError
259 | hi! link SpellBad OmniErrorLine
260 | hi! link SpellLocal OmniWarnLine
261 | hi! link SpellCap OmniInfoLine
262 | hi! link SpellRare OmniInfoLine
263 |
264 | hi! link Constant OmniPurple
265 | hi! link String OmniYellow
266 | hi! link Character OmniPink
267 | hi! link Number Constant
268 | hi! link Boolean Constant
269 | hi! link Float Constant
270 |
271 | hi! link Identifier OmniFg
272 | hi! link Function OmniGreen
273 |
274 | hi! link Statement OmniPink
275 | hi! link Conditional OmniPink
276 | hi! link Repeat OmniPink
277 | hi! link Label OmniPink
278 | hi! link Operator OmniPink
279 | hi! link Keyword OmniPink
280 | hi! link Exception OmniPink
281 |
282 | hi! link PreProc OmniPink
283 | hi! link Include OmniPink
284 | hi! link Define OmniPink
285 | hi! link Macro OmniPink
286 | hi! link PreCondit OmniPink
287 | hi! link StorageClass OmniPink
288 | hi! link Structure OmniPink
289 | hi! link Typedef OmniPink
290 |
291 | hi! link Type OmniCyanItalic
292 |
293 | hi! link Delimiter OmniFg
294 |
295 | hi! link Special OmniPink
296 | hi! link SpecialComment OmniCyanItalic
297 | hi! link Tag OmniCyan
298 | hi! link helpHyperTextJump OmniLink
299 | hi! link helpCommand OmniPurple
300 | hi! link helpExample OmniGreen
301 | hi! link helpBacktick Special
302 |
303 | "}}}
304 |
305 | " vim: fdm=marker ts=2 sts=2 sw=2 fdl=0 et:
306 |
--------------------------------------------------------------------------------
/screenshot.png:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/GuiLra/vim/50d9040a85ef81a0a1c78eb806cbd388cc2ef7ed/screenshot.png
--------------------------------------------------------------------------------