└── PKGBUILD


/PKGBUILD:
--------------------------------------------------------------------------------
 1 | # Maintainer: Marek Kubica <marek@xivilization.net>
 2 | # Contributor: Serge Zirukin <ftrvxmtrx@gmail.com>
 3 | # Contributor: Sergei Lebedev <superbobry@gmail.com>
 4 | # Contributor: Thomas S Hatch <thatch45 at gmail dot com>
 5 | # Contributor: Sebastian Wiesner <lunaryorn googlemail com>
 6 | # Contributor: Benjamin Andresen <benny(at)klapmuetz(dot)org>
 7 | #              Sylvester Johansson <syljo361(at)gmail(dot)org>
 8 | 
 9 | pkgname=ocaml-ounit
10 | _pkgname=ounit
11 | pkgver=2.0.0
12 | pkgrel=1
13 | arch=('i686' 'x86_64')
14 | license=('MIT')
15 | pkgdesc="Unit testing framework for OCaml"
16 | url="http://ounit.forge.ocamlcore.org"
17 | depends=('ocaml')
18 | makedepends=('ocaml-findlib')
19 | options=('!strip')
20 | source=("http://forge.ocamlcore.org/frs/download.php/1258/$_pkgname-$pkgver.tar.gz")
21 | sha512sums=('e12c8fb534ef88de7a83a34e5a578060a90abfce601d8532408412a56e843f69b89cfd6ce69bd7c5519e9a04e306d46339e9b8f13975727a3458afe20cd776d0')
22 | 
23 | build() {
24 |   cd "$srcdir/$_pkgname-$pkgver"
25 | 
26 |   ./configure --disable-debug --prefix /usr --destdir "$pkgdir"
27 |   make all
28 | }
29 | 
30 | package() {
31 |   cd "$srcdir/$_pkgname-$pkgver"
32 |   export OCAMLFIND_DESTDIR="$pkgdir$(ocamlfind printconf destdir)"
33 |   install -dm 755 "$OCAMLFIND_DESTDIR"
34 |   make install
35 |   install -Dm 644 LICENSE.txt "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
36 | }
37 | 


--------------------------------------------------------------------------------