├── CapsLock_Menu.ahk
└── README.md


/CapsLock_Menu.ahk:
--------------------------------------------------------------------------------
  1 | #NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
  2 | ; #Warn  ; Enable warnings to assist with detecting common errors.
  3 | SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
  4 | SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
  5 | #SingleInstance Force  ; Replaces the old instance automatically.
  6 | SetBatchLines -1  ; Run the script at maximum speed.
  7 | 
  8 | CapsLockMenu()
  9 | {
 10 | Menu, CapsLockMenu, Add
 11 | Menu, CapsLockMenu, Delete
 12 | Menu, CapsLockMenu, Add, CAPSLock Menu, ToggleCapsLock
 13 | Menu, CapsLockMenu, Add
 14 | Menu, CapsLockMenu, Add, CapsLock O&N, CapsLockOn
 15 | Menu, CapsLockMenu, Add, CapsLock &off, CapsLockOff
 16 | Menu, CapsLockMenu, Add
 17 | Menu, CapsLockMenu, Add, Paste as &Plain Text, PastePlain
 18 | Menu, CapsLockMenu, Add
 19 | Menu, ConvertCaseMenu, Add
 20 | Menu, ConvertCaseMenu, Delete
 21 | Menu, ConvertCaseMenu, Add, &Title Case, Title
 22 | Menu, ConvertCaseMenu, Add, Ca&pital Case, Capital
 23 | Menu, ConvertCaseMenu, Add, &Sentence case, Sentence
 24 | Menu, ConvertCaseMenu, Add
 25 | Menu, ConvertCaseMenu, Add, &UPPERCASE, Upper
 26 | Menu, ConvertCaseMenu, Add, lo&wercase, Lower
 27 | Menu, ConvertCaseMenu, Add, &camelCase, camel
 28 | Menu, ConvertCaseMenu, Add, &PascalCase, Pascal
 29 | Menu, ConvertCaseMenu, Add
 30 | Menu, ConvertCaseMenu, Add, &Dot.Case, Dot
 31 | Menu, ConvertCaseMenu, Add, S&nake_Case, Snake
 32 | Menu, ConvertCaseMenu, Add, &Kebab-Case, Kebab
 33 | Menu, ConvertCaseMenu, Add
 34 | Menu, ConvertCaseMenu, Add, iN&VERT cASE, Invert
 35 | Menu, ConvertCaseMenu, Add, &RaNdoM caSe, Random
 36 | Menu, ConvertCaseMenu, Add, &aLtErNaTiNg cAsE, Alternating
 37 | Menu, CapsLockMenu, Add, Con&vert Case, :ConvertCaseMenu
 38 | Menu, CapsLockMenu, Add
 39 | Menu, CapsLockMenu, Add, &Emoji Keyboard, OpenEmojiKeyboard
 40 | Menu, InsertLineMenu, Add
 41 | Menu, InsertLineMenu, Delete
 42 | Menu, InsertLineMenu, Add, &Light, LightHorizontalBoxDrawing
 43 | Menu, InsertLineMenu, Add, &Double, DoubleHorizontalBoxDrawing
 44 | Menu, CapsLockMenu, Add, Insert &Line, :InsertLineMenu
 45 | Menu, CapsLockMenu, Default, CapsLock Menu
 46 | Menu, CapsLockMenu, Show
 47 | }
 48 | 
 49 | CopyClipboard()
 50 | {
 51 |     global ClipSaved := ""
 52 |     ClipSaved := ClipboardAll  ; save original clipboard contents
 53 |     Clipboard := ""  ; start off empty to allow ClipWait to detect when the text has arrived
 54 |     Send {Ctrl down}c{Ctrl up}
 55 |     Sleep 150
 56 |     ClipWait, 1.5, 1
 57 |     if ErrorLevel
 58 |     {
 59 |         MsgBox, 262208, AutoHotkey, Copy to clipboard failed.
 60 |         Clipboard := ClipSaved  ; restore the original clipboard contents
 61 |         ClipSaved := ""  ; clear the variable
 62 |         return
 63 |     }
 64 | }
 65 | 
 66 | PastePlain()
 67 | {
 68 |     ClipSaved := ClipboardAll  ; save original clipboard contents
 69 |     Clipboard := Clipboard  ; remove formatting
 70 |     Send ^v  ; send the Ctrl+V command
 71 |     Sleep 100  ; give some time to finish paste (before restoring clipboard)
 72 |     Clipboard := ClipSaved  ; restore the original clipboard contents
 73 |     ClipSaved := ""  ; clear the variable
 74 | }
 75 | 
 76 | ; creating something that links the function to a specific state that can then be called by legacy commands
 77 | ToggleCapsLock(){
 78 |     return, CapsLockey(, True)
 79 | }
 80 | CapsLockOn(){
 81 |     return, CapsLockey(True)
 82 | }
 83 | CapsLockOff(){
 84 |     return, CapsLockey()
 85 | }
 86 | 
 87 | ; actual function that does the work
 88 | CapsLockey(state := false, toggle := false)
 89 | {
 90 |     ; list the messages for the message box to report what happened
 91 |     static messages := {0:"CapsLock Status: OFF", 1:"CapsLock Status: ON", "failed":"CapsLock operation failed"}
 92 |     
 93 |     ; decide whether how to set the state
 94 |     state := toggle ? !GetKeyState("CapsLock", "T") : state
 95 |     ;          1    2       3                       4   5
 96 |     /*
 97 |         1: Condition what should happen
 98 |         2: Ternary operator. Signals that to its left is a condition (1) that should be used to decide between the two possibilitys on the right of it (3 or 5)
 99 |         3: Getting the toggle keystate of CapsLock and invert it, to allow toggle functionality
100 |         4: Marker to signal that the true section of the ternary operation ends and the false section begins 
101 |         5: The state handed in the function call
102 |     */
103 |     SetCapsLockState % state
104 |     MsgBox, 262208, CapsLock Menu, % messages[(GetKeyState("CapsLock", "T") == state) ? state : "failed"]
105 | }
106 | 
107 | CopyClipboardCLM()
108 | {
109 |     global ClipSaved
110 |     WinGet, id, ID, A
111 |     WinGetClass, class, ahk_id %id%
112 |     if (class ~= "(Cabinet|Explore)WClass|Progman")
113 |         Send {F2}
114 |     Sleep 100
115 |     CopyClipboard()
116 |     if (ClipSaved != "")
117 |         Clipboard := Clipboard
118 |     else
119 |         Exit
120 | }
121 | 
122 | PasteClipboardCLM()
123 | {
124 |     global ClipSaved
125 |     WinGet, id, ID, A
126 |     WinGetClass, class, ahk_id %id%
127 |     if (class ~= "(Cabinet|Explore)WClass|Progman")
128 |         Send {F2}
129 |     Send ^v
130 |     Sleep 100
131 |     Clipboard := ClipSaved
132 |     ClipSaved := ""
133 | }
134 | 
135 | Title()
136 | {
137 |     ExcludeList := ["a", "about", "above", "after", "an", "and", "as", "at", "before", "but", "by", "for", "from", "nor", "of", "or", "so", "the", "to", "via", "with", "within", "without", "yet"]
138 |     ExactExcludeList := ["AutoHotkey", "iPad", "iPhone", "iPod", "OneNote", "USA"]
139 |     CopyClipboardCLM()
140 |     TitleCase := Format("{:T}", Clipboard)
141 |     for _, v in ExcludeList
142 |         TitleCase := RegexReplace(TitleCase, "i)(?<!\. |\? |\! |^)(" v ")(?!\.|\?|\!|$)\b", "$L1")
143 |     for _, v in ExactExcludeList
144 |         TitleCase := RegExReplace(TitleCase, "i)\b" v "\b", v)
145 |     TitleCase := RegexReplace(TitleCase, "im)\b(\d+)(st|nd|rd|th)\b", "$1$L{2}")
146 |     Clipboard := TitleCase
147 |     PasteClipboardCLM()
148 | }
149 | 
150 | Capital()
151 | {
152 |     ExactExcludeList := ["AutoHotkey", "iPad", "iPhone", "iPod", "OneNote", "USA"]
153 |     CopyClipboardCLM()
154 |     CapitalCase := Format("{:T}", Clipboard)
155 |     for _, v in ExactExcludeList
156 |         CapitalCase := RegExReplace(CapitalCase, "i)\b" v "\b", v)
157 |     Clipboard := CapitalCase
158 |     PasteClipboardCLM()
159 | }
160 | 
161 | Sentence()
162 | {
163 |     ExactExcludeList := ["AutoHotkey", "iPad", "iPhone", "iPod", "OneNote", "USA"]
164 |     CopyClipboardCLM()
165 |     StringLower, Clipboard, Clipboard
166 |     Clipboard := RegExReplace(Clipboard, "(((^|([.!?]\s+))[a-z])| i | i')", "$u1")
167 |     for _, v in ExactExcludeList
168 |         Clipboard := RegExReplace(Clipboard, "i)\b" v "\b", v)
169 |     PasteClipboardCLM()
170 | }
171 | 
172 | Upper()
173 | {
174 |     CopyClipboardCLM()
175 |     StringUpper, Clipboard, Clipboard
176 |     PasteClipboardCLM()
177 | }
178 | 
179 | Lower()
180 | {
181 |     CopyClipboardCLM()
182 |     StringLower, Clipboard, Clipboard
183 |     PasteClipboardCLM()
184 | }
185 | 
186 | camel()
187 | {
188 |     CopyClipboardCLM()
189 |     StringUpper, Clipboard, Clipboard, T
190 |     FirstChar := SubStr(Clipboard, 1, 1)
191 |     StringLower, FirstChar, FirstChar
192 |     camelCase := SubStr(Clipboard, 2)
193 |     camelCase := StrReplace(camelCase, A_Space)
194 |     Clipboard := FirstChar camelCase
195 |     PasteClipboardCLM()
196 | }
197 | 
198 | Pascal()
199 | {
200 |     CopyClipboardCLM()
201 |     StringUpper, Clipboard, Clipboard, T
202 |     Clipboard := StrReplace(Clipboard, A_Space)
203 |     PasteClipboardCLM()
204 | }
205 | 
206 | Dot()
207 | {
208 |     CopyClipboardCLM()
209 |     if RegExMatch(Clipboard, "\-|\_|\.") != "0"
210 |     {
211 |         Clipboard := RegExReplace(Clipboard, "\-|\_|\.", " ")
212 |         PasteClipboardCLM()
213 |     }
214 |     else
215 |     {
216 |         Clipboard := StrReplace(Clipboard, A_Space, ".")
217 |         PasteClipboardCLM()
218 |     }
219 | }
220 | 
221 | Snake()
222 | {
223 |     CopyClipboardCLM()
224 |     if RegExMatch(Clipboard, "\-|\_|\.") != "0"
225 |     {
226 |         Clipboard := RegExReplace(Clipboard, "\-|\_|\.", " ")
227 |         PasteClipboardCLM()
228 |     }
229 |     else
230 |     {
231 |         Clipboard := StrReplace(Clipboard, A_Space, "_")
232 |         PasteClipboardCLM()
233 |     }
234 | }
235 | 
236 | Kebab()
237 | {
238 |     CopyClipboardCLM()
239 |     if RegExMatch(Clipboard, "\-|\_|\.") != "0"
240 |     {
241 |         Clipboard := RegExReplace(Clipboard, "\-|\_|\.", " ")
242 |         PasteClipboardCLM()
243 |     }
244 |     else
245 |     {
246 |         Clipboard := StrReplace(Clipboard, A_Space, "-")
247 |         PasteClipboardCLM()
248 |     } 
249 | }
250 | 
251 | Invert()
252 | {
253 |     CopyClipboardCLM()
254 |     Inv_Char_Out := ""
255 |     Loop % StrLen(Clipboard)
256 |     {
257 |         Inv_Char := SubStr(Clipboard, A_Index, 1)
258 |         if Inv_Char is Upper
259 |             Inv_Char_Out := Inv_Char_Out Chr(Asc(Inv_Char) + 32)
260 |         else if Inv_Char is Lower
261 |             Inv_Char_Out := Inv_Char_Out Chr(Asc(Inv_Char) - 32)
262 |         else
263 |             Inv_Char_Out := Inv_Char_Out Inv_Char
264 |     }
265 |     Clipboard := Inv_Char_Out
266 |     PasteClipboardCLM()
267 | }
268 | 
269 | Random()
270 | {
271 |     CopyClipboardCLM()
272 |     RandomCase := ""
273 |     for _, v in StrSplit(Clipboard)
274 |     {
275 |         Random, r, 0, 1
276 |         RandomCase .= Format("{:" (r?"L":"U") "}", v)
277 |     }
278 |     Clipboard := RandomCase
279 |     PasteClipboardCLM()
280 | }
281 | 
282 | Alternating()
283 | {
284 |     CopyClipboardCLM()
285 |     Inv_Char_Out := ""
286 |     StringLower, Clipboard, Clipboard
287 |     Loop, Parse, Clipboard
288 |     {
289 |         if (Mod(A_Index, 2) = 0)
290 |             Inv_Char_Out .= Format("{1:U}", A_LoopField)
291 |         else
292 |             Inv_Char_Out .= Format("{1:L}", A_LoopField)
293 |     }
294 |     Clipboard := Inv_Char_Out
295 |     PasteClipboardCLM()
296 | }
297 | 
298 | OpenEmojiKeyboard()
299 | {
300 |     Send {LWin down}.
301 |     Send {LWin up}
302 | }
303 | 
304 | LightHorizontalBoxDrawing()
305 | {
306 |     InputBox, UserInput, Input, , , 150, 105
307 |     Loop %UserInput%
308 |         Send {U+2500}
309 | }
310 | 
311 | DoubleHorizontalBoxDrawing()
312 | {
313 |     InputBox, UserInput, Input, , , 150, 105
314 |     Loop %UserInput%
315 |         Send {U+2550}
316 | }
317 | 
318 | 
319 | $CapsLock::
320 |     KeyWait CapsLock, T0.25
321 |         if ErrorLevel
322 |             CapsLockMenu()
323 |         else
324 |         {
325 |             KeyWait CapsLock, D T0.25
326 |             if ErrorLevel
327 |                 CopyClipboard()
328 |             else
329 |                 Send ^v
330 |         }
331 |     KeyWait CapsLock
332 | return


--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
 1 | # CapsLock Menu
 2 | 
 3 | ![CapsLock_Menu_01](https://user-images.githubusercontent.com/80262347/112947889-8d18cc80-9161-11eb-918b-42e3e173df32.png)
 4 | 
 5 | Extend CapsLock Functionality Using AutoHotkey:
 6 | - Single Click = Ctrl+C (Copy)
 7 | - Double Click = Ctrl+V (Paste)
 8 | - Long Press = CapsLock Menu
 9 | 
10 | 
11 | # Features
12 | 
13 | ![CapsLock_Menu_02](https://user-images.githubusercontent.com/80262347/112947923-97d36180-9161-11eb-85a0-0b5579d52801.png)
14 | 
15 | - Toggle CapsLock ON/off
16 | - Paste as Plain Text
17 | - Convert Selected Text to:
18 |   - Title Case (recognize & un-capitalizes the words in editable exclusion list)
19 |   - Capital Case
20 |   - Sentence case
21 |   - UPPERCASE
22 |   - lowercase
23 |   - camelCase
24 |   - PascalCase
25 |   - Dot.Case
26 |   - Snake_Case
27 |   - Kebab-Case
28 |   - iNVERT cASE
29 |   - RaNdoM caSe
30 |   - aLtErNaTiNg cAsE
31 |   
32 |   ![CapsLock_Menu_03](https://user-images.githubusercontent.com/80262347/112947967-a6217d80-9161-11eb-9871-64c402b35b19.png)
33 | 
34 | - Emoji Keyboard
35 | 
36 |   ![Emoji_Keyboard](https://user-images.githubusercontent.com/80262347/112948600-77f06d80-9162-11eb-8123-e2716211d292.png)
37 | 
38 | - Insert Light or Double Horizontal Line (generated based on number of user input)
39 | 
40 |   e.g.
41 |   
42 |   ![CapsLock_Menu_04](https://user-images.githubusercontent.com/80262347/112948001-b20d3f80-9161-11eb-8f53-4613e8e13247.png)
43 |   
44 |   5 will generate ───── (Light) or ═════ (Double) Horizontal Line
45 |   
46 |   10 will generate ────────── (Light) or ══════════ (Double) Horizontal Line
47 | 


--------------------------------------------------------------------------------