├── .gitignore
├── .gitmodules
├── README.md
└── src
    ├── Lib
        ├── OSD.ahk
        └── RapidHotkey.ahk
    ├── Script.ahk
    ├── Script.ico
    ├── hotkeys
        ├── clipboardSearch.ahk
        ├── mouse.ahk
        ├── speedtest.ahk
        ├── spotify.ahk
        ├── valorant.ahk
        ├── voicemeeter.ahk
        └── wt.ahk
    └── other
        └── OfficeToPDF
            ├── .gitignore
            ├── GUI.ahk
            ├── OfficeToPDF.ahk
            ├── OfficeToPDF.ico
            └── README.md


/.gitignore:
--------------------------------------------------------------------------------
1 | Script.exe
2 | *.gif
3 | *.zip
4 | bin
5 | .vscode
6 | config.json
7 | spotifyEdgeProfile


--------------------------------------------------------------------------------
/.gitmodules:
--------------------------------------------------------------------------------
1 | [submodule "src/Lib/SpotifyFreeAPI"]
2 | 	path = src/Lib/SpotifyFreeAPI
3 | 	url = https://github.com/SaifAqqad/SpotifyFreeAPI.ahk.git
4 | 


--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
1 | <h1 align="center">
2 |   AHK_Script
3 | </h1>
4 | 


--------------------------------------------------------------------------------
/src/Lib/OSD.ahk:
--------------------------------------------------------------------------------
  1 | Class OSD {
  2 |     static ACCENT:= {"-1":"4D5565" ; MAIN ACCENT
  3 |     ,"0":"DC3545" ; OFF ACCENT
  4 |     ,"1":"007BFF"} ; ON ACCENT
  5 | 
  6 |     __New(pos:="", excludeFullscreen:=0, posEditorCallback:=""){      
  7 |         this.excludeFullscreen:= excludeFullscreen
  8 |         this.state:= 0
  9 |         ;get the primary monitor resolution
 10 |         SysGet, res, Monitor
 11 |         this.screenHeight:= resBottom
 12 |         this.screenWidth:= resRight
 13 |         ;get the primary monitor scaling
 14 |         this.scale:= A_ScreenDPI/96
 15 |         ;set the OSD width and height
 16 |         this.width:= Format("{:i}", 250 * this.scale)
 17 |         this.height:= Format("{:i}", 40 * this.scale)
 18 |         ;set the default pos object
 19 |         pos:= pos? pos : {x:-1,y:-1}
 20 |         ;get the final pos object
 21 |         this.pos:= this.getPosObj(pos.x, pos.y)
 22 |         ;set up bound func objects 
 23 |         this.hideFunc:= objBindMethod(this, "hide")
 24 |         this.onDragFunc:= objBindMethod(this, "__onDrag")
 25 |         this.onRClickFunc:= objBindMethod(this, "__onRClick")
 26 |         this.posEditorCallback:= posEditorCallback
 27 | 
 28 |         ;set the initial OSD theme
 29 |         this.setTheme(0)
 30 |         ;create the OSD window
 31 |         this.create()
 32 |     }
 33 | 
 34 |     ; creates the OSD window
 35 |     create(){
 36 |         Gui, New, +Hwndhwnd, OSD 
 37 |         this.hwnd:= hwnd
 38 |         Gui, +AlwaysOnTop -SysMenu +ToolWindow -caption -Border 
 39 |         Gui, Margin, 15
 40 |         Gui, Color, % this.theme, % OSD.ACCENT["-1"]
 41 |         Gui, Font,% Format("s{:i} w500 c{}", 12*this.scale, OSD.ACCENT["-1"]), Segoe UI Variable
 42 |         Gui, Add, Text,% Format("HwndtxtHwnd w{} Center", this.width-30)
 43 |         this.hwndTxt:= txtHwnd
 44 |     }
 45 | 
 46 |     ; hides and destroys the OSD window
 47 |     destroy(){
 48 |         Gui,% this.hwnd ":Default"
 49 |         this.hide()
 50 |         Gui, Destroy
 51 |         this.hwnd:= ""
 52 |         this.hwndTxt:=""
 53 |     }
 54 | 
 55 |     ; shows the OSD window with the specified text and accent
 56 |     show(text,accent:=-1){
 57 |         ;if the window can't be shown -> return
 58 |         if(!this.canShow())
 59 |             return
 60 |         ;if the window does not exist -> create it first
 61 |         if(!this.hwnd)
 62 |             this.create()
 63 |         Gui, % this.hwnd ":Default" ;set the default window
 64 |         ;set the accent/theme colors
 65 |         if(color:=OSD.ACCENT[accent ""])
 66 |             accent:=color
 67 |         Gui, Color, % this.theme, % accent
 68 |         Gui, Font,% Format("s{:i} w500 c{}", 12*this.scale, accent)
 69 |         GuiControl, Font, % this.hwndTxt
 70 |         text:= this.processText(text)
 71 |         GuiControl, Text, % this.hwndTxt, %text%
 72 |         Gui, +LastFound
 73 |         Winset, Redraw
 74 |         ;show the OSD
 75 |         Gui, Show, % Format("w{} NoActivate NA x{} y{}", this.width, this.pos.x, this.pos.y)
 76 |         ;make the OSD corners rounded
 77 |         WinGetPos,,,Width, Height, % "ahk_id " . this.hwnd
 78 |         WinSet, Region, % Format("w{} h{} 0-0 R{3:i}-{3:i}", Width, Height, 15*this.scale ), % "ahk_id " . this.hwnd
 79 |         ;set the OSD transparency
 80 |         WinSet, Transparent, 252, % "ahk_id " . this.hwnd
 81 |         return this.state:= 1
 82 |     }
 83 | 
 84 |     ; shows the OSD window with the specified text and accent
 85 |     ; and activates a timer to hide it
 86 |     showAndHide(text, accent:=-1, seconds:=1){
 87 |         hideFunc:= this.hideFunc
 88 |         this.show(text,accent)
 89 |         SetTimer, % hideFunc,% "-" . seconds*1000
 90 |     }
 91 | 
 92 |     ; shows a draggable OSD window with the specified text and accent
 93 |     showDraggable(text, accent:=-1){
 94 |         Gui,% this.hwnd ":Default"
 95 |         this.show(text, accent)
 96 |         OnMessage(0x201, this.onDragFunc)
 97 |     }
 98 | 
 99 |     ; shows a draggable OSD window to set the position
100 |     showPosEditor(){
101 |         Gui,% this.hwnd ":Default"
102 |         this.showdraggable("RClick to confirm")
103 |         OnMessage(0x205, this.onRClickFunc)
104 |     }
105 | 
106 |     ; hides the OSD window
107 |     hide(){
108 |         if(!this.hwnd)
109 |             return
110 |         Gui, % this.hwnd ":Default"
111 |         OnMessage(0x201, this.onDragFunc, 0)
112 |         OnMessage(0x205, this.onRClickFunc, 0)
113 |         Gui, Hide
114 |         this.state:= 0
115 |     }
116 | 
117 |     canShow(){
118 |         return this.excludeFullscreen? !this.isWindowFullscreen() : 1
119 |     }
120 | 
121 |     setTheme(theme:=""){
122 |         if(theme != this.theme)
123 |             this.theme:= theme? (theme=1? "232323" : theme) : "f2f2f2"
124 |     }
125 | 
126 |     processText(text){
127 |         if (StrLen(text)>28)
128 |             text:= SubStr(text, 1, 26) . Chr(0x2026) ; fix overflow with ellipsis
129 |         return text
130 |     }
131 | 
132 |     isWindowFullscreen(win:="A"){
133 |         winID := WinExist(win)
134 |         if(!winID)
135 |             return 0
136 |         WinGet style, Style, ahk_id %WinID%
137 |         WinGetPos ,,,winW,winH, %winTitle%
138 |         return !((style & 0x20800000) or WinActive("ahk_class Progman") 
139 |             or WinActive("ahk_class WorkerW") or winH < A_ScreenHeight or winW < A_ScreenWidth)
140 |     }
141 | 
142 |     getPosObj(x:=-1,y:=-1){
143 |         p_obj:= {}
144 |         p_obj.x:= x=-1? Round(this.screenWidth/2 - this.width/2) : x
145 |         p_obj.y:= y=-1? this.screenHeight * 0.9 : y
146 |         return p_obj
147 |     }
148 | 
149 |     __onDrag(wParam, lParam, msg, hwnd){
150 |         if(hwnd = this.hwnd)
151 |             PostMessage, 0xA1, 2,,, % "ahk_id " this.hwnd
152 |     }
153 | 
154 |     __onRClick(wParam, lParam, msg, hwnd){
155 |         if(hwnd != this.hwnd)
156 |             return
157 |         WinGetPos, xPos,yPos
158 |         this.hide()
159 |         this.pos.x:= xPos
160 |         this.pos.y:= yPos
161 |         if(IsFunc(this.posEditorCallback))
162 |             this.posEditorCallback.Call(xPos,yPos)
163 |     }
164 | }


--------------------------------------------------------------------------------
/src/Lib/RapidHotkey.ahk:
--------------------------------------------------------------------------------
 1 | RapidHotkey(keystroke, times="2", delay=0.2, IsLabel=0)
 2 | {
 3 | 	Pattern := Morse(delay*1000)
 4 | 	If (StrLen(Pattern) < 2 and Chr(Asc(times)) != "1")
 5 | 		Return
 6 | 	If (times = "" and InStr(keystroke, """"))
 7 | 	{
 8 | 		Loop, Parse, keystroke,""	
 9 | 			If (StrLen(Pattern) = A_Index+1)
10 | 				continue := A_Index, times := StrLen(Pattern)
11 | 	}
12 | 	Else if (RegExMatch(times, "^\d+$") and InStr(keystroke, """"))
13 | 	{
14 | 		Loop, Parse, keystroke,""
15 | 			If (StrLen(Pattern) = A_Index+times-1)
16 | 				times := StrLen(Pattern), continue := A_Index
17 | 	}
18 | 	Else if InStr(times, """")
19 | 	{
20 | 		Loop, Parse, times,""
21 | 			If (StrLen(Pattern) = A_LoopField)
22 | 				continue := A_Index, times := A_LoopField
23 | 	}
24 | 	Else if (times = "")
25 | 		continue := 1, times := 2
26 | 	Else if (times = StrLen(Pattern))
27 | 		continue = 1
28 | 	If !continue
29 | 		Return
30 | 	Loop, Parse, keystroke,""
31 | 		If (continue = A_Index)
32 | 			keystr := A_LoopField
33 | 	Loop, Parse, IsLabel,""
34 | 		If (continue = A_Index)
35 | 			IsLabel := A_LoopField
36 | 	hotkey := RegExReplace(A_ThisHotkey, "[\*\~\$\#\+\!\^]")
37 | 	IfInString, hotkey, %A_Space%
38 | 		StringTrimLeft, hotkey,hotkey,% InStr(hotkey,A_Space,1,0)
39 | 	backspace := "{BS " times "}"
40 | 	keywait = Ctrl|Alt|Shift|LWin|RWin
41 | 	Loop, Parse, keywait, |
42 | 		KeyWait, %A_LoopField%
43 | 	If ((!IsLabel or (IsLabel and IsLabel(keystr))) and InStr(A_ThisHotkey, "~") and !RegExMatch(A_ThisHotkey
44 | 	, "i)\^[^\!\d]|![^\d]|#|Control|Ctrl|LCtrl|RCtrl|Shift|RShift|LShift|RWin|LWin|Alt|LAlt|RAlt|Escape|BackSpace|F\d\d?|"
45 | 	. "Insert|Esc|Escape|BS|Delete|Home|End|PgDn|PgUp|Up|Down|Left|Right|ScrollLock|CapsLock|NumLock|AppsKey|"
46 | 	. "PrintScreen|CtrlDown|Pause|Break|Help|Sleep|Browser_Back|Browser_Forward|Browser_Refresh|Browser_Stop|"
47 | 	. "Browser_Search|Browser_Favorites|Browser_Home|Volume_Mute|Volume_Down|Volume_Up|MButton|RButton|LButton|"
48 | 	. "Media_Next|Media_Prev|Media_Stop|Media_Play_Pause|Launch_Mail|Launch_Media|Launch_App1|Launch_App2"))
49 | 		Send % backspace
50 | 	If (WinExist("AHK_class #32768") and hotkey = "RButton")
51 | 		WinClose, AHK_class #32768
52 | 	If !IsLabel
53 | 		Send % keystr
54 | 	else if IsLabel(keystr)
55 | 		Gosub, %keystr%
56 | 	Return
57 | }	
58 | Morse(timeout = 400) { ;by Laszo -> http://www.autohotkey.com/forum/viewtopic.php?t=16951 (Modified to return: KeyWait %key%, T%tout%)
59 |    tout := timeout/1000
60 |    key := RegExReplace(A_ThisHotKey,"[\*\~\$\#\+\!\^]")
61 |    IfInString, key, %A_Space%
62 | 		StringTrimLeft, key, key,% InStr(key,A_Space,1,0)
63 | 	If Key in Shift,Win,Ctrl,Alt
64 | 		key1:="{L" key "}{R" key "}"
65 |    Loop {
66 |       t := A_TickCount
67 |       KeyWait %key%, T%tout%
68 | 		Pattern .= A_TickCount-t > timeout
69 | 		If(ErrorLevel)
70 | 			Return Pattern
71 |     If key in Capslock,LButton,RButton,MButton,ScrollLock,CapsLock,NumLock
72 |       KeyWait,%key%,T%tout% D
73 |     else if Asc(A_ThisHotkey)=36
74 | 		KeyWait,%key%,T%tout% D
75 |     else
76 |       Input,pressed,T%tout% L1 V,{%key%}%key1%
77 | 	If (ErrorLevel="Timeout" or ErrorLevel=1)
78 | 		Return Pattern
79 | 	else if (ErrorLevel="Max")
80 | 		Return
81 |    }
82 | }


--------------------------------------------------------------------------------
/src/Script.ahk:
--------------------------------------------------------------------------------
 1 | ;@Ahk2Exe-SetMainIcon Script.ico
 2 | ;@Ahk2Exe-Base Unicode 64*
 3 | 
 4 | #Include <SpotifyFreeAPI\src\SpotifyFreeAPI>
 5 | #Include <OSD>
 6 | #Include <RapidHotkey>
 7 | #MaxThreadsBuffer, On
 8 | SetBatchLines, -1
 9 | SetWorkingDir, %A_ScriptDir%
10 | tray_init()
11 | 
12 | global osd_obj:= new OSD("",1)
13 | , tts:= ComObjCreate("SAPI.SpVoice")
14 | osd_obj.setTheme("0A0E14")
15 | if(A_TickCount<40000)
16 |     sleep 15000
17 | global spotify:= new SpotifyAPI()
18 | osd_obj.showAndHide("Connected to Spotify","1ED760",1)
19 | 
20 | #Include, %A_ScriptDir%\hotkeys
21 | #Include, spotify.ahk
22 | #Include, valorant.ahk
23 | #Include, wt.ahk
24 | #Include, mouse.ahk
25 | #Include, speedtest.ahk
26 | #Include, clipboardSearch.ahk
27 | 
28 | 
29 | tray_init(){
30 |     Menu, Tray, NoStandard
31 |     fObj:= Func("tray_toggleAutoStart")
32 |     Menu, Tray, add, Start on boot, % fObj
33 |     Menu, Tray, % tray_autoStartEnabled()? "Check" : "Uncheck", Start on boot
34 |     fObj:= Func("tray_suspend")
35 |     Menu, Tray, add, Suspend Hotkeys, % fObj
36 |     fObj:= Func("tray_reload")
37 |     Menu, Tray, add, Reload Script, % fObj
38 |     fObj:= Func("tray_exit")
39 |     Menu, Tray, add, Exit, % fObj
40 | }
41 | 
42 | tray_reload(){
43 |     Reload
44 | }
45 | 
46 | tray_suspend(){
47 |     Suspend, -1
48 | }
49 | 
50 | tray_exit(){
51 |     ExitApp, 0
52 | }
53 | 
54 | tray_toggleAutoStart(){
55 |     if(tray_autoStartEnabled())
56 |         RegDelete, HKCU\Software\Microsoft\Windows\CurrentVersion\Run, AHK_Script
57 |     else
58 |         RegWrite, REG_SZ, HKCU\Software\Microsoft\Windows\CurrentVersion\Run, AHK_Script, "%A_ScriptFullPath%"
59 |     Menu, Tray, % tray_autoStartEnabled()? "Check" : "Uncheck", Start on boot
60 | }
61 | 
62 | tray_autoStartEnabled(){
63 |     Try RegRead, val, HKCU\Software\Microsoft\Windows\CurrentVersion\Run, AHK_Script
64 |     return val? 1 : 0
65 | }


--------------------------------------------------------------------------------
/src/Script.ico:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/SaifAqqad/AHK_Script/2b3dfa445ed700d0975d79d4d7c3993c1c3cc321/src/Script.ico


--------------------------------------------------------------------------------
/src/hotkeys/clipboardSearch.ahk:
--------------------------------------------------------------------------------
 1 | ; copy and google the highlighted text
 2 | !Space::
 3 |     clipboard:=""
 4 |     SendInput {CTRLDOWN}c{CTRLUP}
 5 |     ClipWait, 1
 6 |     if(clipboard){
 7 |         txt:= UrlEncode(clipboard)
 8 |         Run https://www.google.com/search?hl=en&q=%txt%,, UseErrorLevel
 9 |     }else
10 |         osd_obj.showAndHide("Search failed",,2)
11 | Return 
12 | 
13 | ; https://autohotkey.com/board/topic/35660-url-encoding-function/
14 | UrlEncode( String ){
15 | 	OldFormat := A_FormatInteger
16 | 	SetFormat, Integer, H
17 | 
18 | 	Loop, Parse, String 
19 |     {
20 | 		if A_LoopField is alnum 
21 |         {
22 | 			Out .= A_LoopField
23 | 			continue
24 | 		}
25 | 		Hex := SubStr( Asc( A_LoopField ), 3 )
26 | 		Out .= "%" . ( StrLen( Hex ) = 1 ? "0" . Hex : Hex )
27 | 	}
28 | 	SetFormat, Integer, %OldFormat%
29 | 	return Out
30 | }


--------------------------------------------------------------------------------
/src/hotkeys/mouse.ahk:
--------------------------------------------------------------------------------
 1 | ; mouse right scroll button
 2 | F22::WheelRight
 3 | 
 4 | ; mouse left scroll button
 5 | F23::WheelLeft
 6 | 
 7 | ; under-mouse button
 8 | F24::
 9 |     WinGet, active_pid, PID , A
10 |     Process, Close, %active_pid%
11 | return


--------------------------------------------------------------------------------
/src/hotkeys/speedtest.ahk:
--------------------------------------------------------------------------------
1 | F7::
2 |     WinKill, ahk_exe speedtest.exe
3 |     Run, speedtest.exe
4 | return
5 | 


--------------------------------------------------------------------------------
/src/hotkeys/spotify.ahk:
--------------------------------------------------------------------------------
 1 | DetectHiddenWindows, On
 2 | Global SPOTIFY_EXE:= "Spotify.exe"
 3 | 
 4 | <!Up::
 5 | Try vol:= spotify.SetVolume(10,1)
 6 | osd_obj.showAndHide("Spotify Volume: " vol,"1ED760",1)
 7 | return
 8 | 
 9 | <!Down::
10 | Try vol:= spotify.SetVolume(-10,1)
11 | osd_obj.showAndHide("Spotify Volume: " vol,"1ED760",1)
12 | return
13 | 
14 | <!Right::
15 | Try spotify.NextTrack()
16 | SetTimer, showPlaying, -200
17 | return
18 | 
19 | <!Left::
20 | Try spotify.PreviousTrack()
21 | SetTimer, showPlaying, -200
22 | return
23 | 
24 | *~Media_Play_Pause::RapidHotkey("call_runSpotify",2,0.4,1)
25 | 
26 | call_runSpotify:
27 | runSpotify()
28 | return
29 | 
30 | runSpotify(){
31 |     Try{
32 |         ; if spotify is running -> get the PID
33 |         WinGet, sPID, PID , ahk_exe %SPOTIFY_EXE%
34 |         if(!sPID){ ; if not, run spotify
35 |             Run, % getSpotifyFullPath() , %A_AppData%,, sPID
36 |             WinWait, ahk_exe %SPOTIFY_EXE%,, 5
37 |             WinShow, ahk_exe %SPOTIFY_EXE%
38 |         }
39 |         WinActivate, ahk_exe %SPOTIFY_EXE%
40 |         return 1
41 |     } Catch {
42 |         return 0
43 |     }
44 | }
45 | 
46 | getSpotifyFullPath(){
47 |     p_path:= A_Args[1]
48 |     if(!p_path){
49 |         ; works regardless of where spotify is installed
50 |         RegRead, p_path, HKCR\spotify\shell\open\command
51 |         SplitPath, p_path,, p_path
52 |         p_path:= StrReplace(p_path, """") "\" SPOTIFY_EXE
53 |     }
54 |     return p_path
55 | }
56 | 
57 | showPlaying(){
58 |     Try {
59 |         track:= spotify.GetCurrentTrackInfo()
60 |         osd_obj.showAndHide(track.item.artists[1].name " - " track.item.name,"1ED760",2)
61 |     }
62 | }


--------------------------------------------------------------------------------
/src/hotkeys/valorant.ahk:
--------------------------------------------------------------------------------
1 | ; VALORANT hotkeys
2 | #If, WinActive("ahk_exe VALORANT-Win64-Shipping.exe")
3 | 
4 | ;disable capslock,winkey
5 | *CapsLock::
6 | *LWin::
7 | Return
8 | 
9 | #If


--------------------------------------------------------------------------------
/src/hotkeys/voicemeeter.ahk:
--------------------------------------------------------------------------------
 1 | ; mic gain limit
 2 | vm.strip[2].gain_limit:= -10
 3 | cMode:=0
 4 | 
 5 | Volume_Up::osd_obj.showAndHide("A1 gain: " ++vm.bus[1].gain,1,2)
 6 | Volume_Down::osd_obj.showAndHide("A1 gain: " --vm.bus[1].gain,0,2)
 7 | 
 8 | <!Volume_Up::osd_obj.showAndHide("Media gain: " ++vm.strip[5].gain,1,2)
 9 | <!Volume_Down::osd_obj.showAndHide("Media gain: " --vm.strip[5].gain,0,2)
10 | 
11 | ;set A1 to headphones
12 | *<!1::
13 | vm.bus[1].device["ks"]:="Corsair"
14 | osd_obj.showAndHide("Headphone audio")
15 | Sleep, 1000
16 | tts.Speak("Headphone audio")
17 | return
18 | 
19 | ;set A1 to monitor
20 | *<!2::
21 | vm.bus[1].device["wdm"]:="AMD"
22 | osd_obj.showAndHide("Monitor audio")
23 | Sleep, 1000
24 | tts.Speak("Monitor audio")
25 | return
26 | 
27 | ;reverse A1
28 | <^<!F::
29 | _str:=""
30 | switch vm.bus[1].mono {
31 |     case 0: _str:="reverse"
32 |             vm.bus[1].Mono:=2
33 |     case 2: _str:="Stereo"
34 |             vm.bus[1].Mono:=0
35 | }
36 | osd_obj.showAndHide("A1 set to " _str)
37 | tts.Speak("Audio set to " _str)
38 | return
39 | 
40 | ; hold-to-mute A1 and mic
41 | ~*Esc::
42 | osd_obj.show("EMERGENCY MUTE")
43 | vm.bus[1].mute:=1
44 | vm.strip[2].mute:=1
45 | KeyWait, Esc
46 | vm.bus[1].mute:=0
47 | vm.strip[2].mute:=0
48 | osd_obj.hide()
49 | return
50 | 
51 | ; VALORANT specific
52 | #If, WinExist("ahk_exe VALORANT-Win64-Shipping.exe")
53 | ;clutch mode
54 | <^<!C::
55 | if(cMode){
56 |     vm.strip[4].solo:=vm.strip[4].gain:=vm.strip[2].mute:= 0
57 |     tts.speak("clutch mode off")
58 | }else{
59 |     vm.strip[4].solo:= vm.strip[2].mute:= 1
60 |     vm.strip[4].gain:= 3
61 |     tts.speak("clutch mode on")
62 | }
63 | cMode:= !cMode
64 | return
65 | #If
66 | 
67 | ; toggle recording
68 | <^CtrlBreak::
69 | if(!vm.recorder.record){ ;not recording
70 |     vm.recorder.record:= 1
71 |     tts.speak("Recording")
72 | }else { ; recording
73 |     vm.recorder.stop:= 1
74 |     tts.speak("Recording stopped")
75 | }
76 | return
77 | 
78 | Pause::vm.recorder.replay:=1


--------------------------------------------------------------------------------
/src/hotkeys/wt.ahk:
--------------------------------------------------------------------------------
 1 | ;windows terminal hotkey
 2 | *#T::
 3 | newTab:= GetKeyState("Alt")
 4 | WinGet, wtPID, PID, ahk_exe WindowsTerminal.exe
 5 | if(!wtPID){
 6 |      Run, wt.exe, %A_Desktop%\..\, UseErrorLevel
 7 |      WinWait, ahk_exe WindowsTerminal.exe,,4
 8 |      Sleep, 500
 9 | }
10 | if(newTab){
11 |      Run, wt.exe -w 0 nt, %A_Desktop%\..\, UseErrorLevel
12 | }
13 | ; activate the wt window & focus the input to the window
14 | fCount:=0
15 | focusInput:
16 | Try{
17 |      WinActivate, ahk_exe WindowsTerminal.exe ahk_class CASCADIA_HOSTING_WINDOW_CLASS
18 |      ControlFocus, Windows.UI.Input.InputSite.WindowClass1, ahk_exe WindowsTerminal.exe
19 | }catch{
20 |      Sleep, 20
21 |      if(++fCount<4)
22 |           Goto, focusInput
23 | }
24 | return


--------------------------------------------------------------------------------
/src/other/OfficeToPDF/.gitignore:
--------------------------------------------------------------------------------
1 | *.exe


--------------------------------------------------------------------------------
/src/other/OfficeToPDF/GUI.ahk:
--------------------------------------------------------------------------------
 1 | Global GUI_state:=0
 2 | Global GUI_prog:=
 3 | Global GUI_txt:=
 4 | GUI_spawn(prog,txt,GUI_accent:=-1){
 5 |     if (GUI_state = 0){
 6 |         GUI_Theme:=191919
 7 |         GUI_Accent:= ( GUI_Accent = -1 ? GUI_getSysAccent() : GUI_Accent )
 8 |         SetFormat, integer, d
 9 |         Gui, Color, %GUI_Theme%, %GUI_Accent%
10 |         Gui, +AlwaysOnTop -SysMenu +ToolWindow -caption -Border
11 |         WinSet, Transparent, 230, ahk_class AutoHotkeyGUI
12 |         Gui, Font, s11, Segoe UI
13 |         Gui, Add, Text, c%GUI_Accent% vGUI_txt W165 Center, %txt%
14 |         if (prog!=-1)
15 |             Gui, Add, Progress, W165 c%GUI_Accent% Background%GUI_Theme% vGUI_prog, %prog%
16 |         SysGet, MonitorWorkArea, MonitorWorkArea, 0
17 |         GUI_yPos:= MonitorWorkAreaBottom * 0.90
18 |         Gui, Show, AutoSize NoActivate xCenter y%GUI_yPos%
19 |         GUI_state:= 1
20 |     }else{
21 |         if (prog!=-1)
22 |             GuiControl,, GUI_prog, %prog%
23 |         GuiControl,, GUI_txt, %txt%
24 |     }
25 | }
26 | GUI_getSysAccent(){
27 |     RegRead, GUI_sysAccent, HKCU\SOFTWARE\Microsoft\Windows\DWM, ColorizationColor 
28 |     SetFormat, integer, hex
29 |     GUI_sysAccent := GUI_sysAccent+0
30 |     StringRight, GUI_sysAccent, GUI_sysAccent, 6
31 |     Return GUI_sysAccent
32 | }
33 | GUI_destroy(){
34 |     Gui, Destroy
35 |     GUI_state := 0
36 | }


--------------------------------------------------------------------------------
/src/other/OfficeToPDF/OfficeToPDF.ahk:
--------------------------------------------------------------------------------
 1 | #SingleInstance, off
 2 | #Include GUI.ahk
 3 | Global fCount := A_Args.Length()
 4 | Global sCount := 0
 5 | SetFormat, FloatFast, 0.2
 6 | Loop, %fCount%
 7 | {
 8 |     fProg:= ((A_Index-1) / fCount)*100
 9 |     GUI_spawn(fProg,"Converting file " . A_Index . "/" . fCount)
10 |     if (handle(A_Args[A_Index]))
11 |         sCount+=1
12 |     else{
13 |         GUI_spawn(-1,"Unsupported file :(")
14 |         Sleep,1500
15 |     }
16 | }
17 | GUI_spawn(100, sCount . "/" . fCount . " File(s) converted")
18 | Sleep, 2500
19 | GUI_destroy()
20 | ExitApp
21 | 
22 | handle(inFile){
23 |     SplitPath, inFile,, inDir, inExt, inName
24 |     Switch inExt
25 |     {
26 |         case "pdf":
27 |             pdfOptimizer(inFile,inDir,inName)
28 |         case "pptx","ppt","odp","powerpoint","powerpointx","powerpointm","pot","potm","potx","pps","ppsx","ppsm": ;powerpoint
29 |             pptTopdf(inFile,inDir,inName)
30 |         case "rtf","odt","doc","dot","docx","dotx","docm","dotm","txt","html","htm","wpd": ;word
31 |             wrdTopdf(inFile,inDir,inName)
32 |         case "xls","xlsx","xl","xlsm","xlsb","xlam","xltx","xltm","xlt","htm","html","mht","mhtml","xml","xla","xlm","xlw": ;excel
33 |             excelTopdf(inFile,inDir,inName)
34 |         Default:
35 |             return 0
36 |     }
37 |     return 1
38 | }
39 | pptTopdf(fPath,path,name){
40 |     powerpoint := ComObjCreate("Powerpoint.Application")
41 |     powerpointFile := powerpoint.Presentations.Open(fPath,,,0)
42 |     powerpointFile.SaveAs( path . "\" . name . ".pdf" , 32 )
43 |     powerpoint.Quit()
44 | }
45 | wrdTopdf(fPath,path,name){
46 |     word := ComObjCreate("Word.Application")
47 |     wordFile := word.Documents.Open(fPath,,,,,,,,,,,0)
48 |     wordFile.SaveAs2( path . "\" . name . ".pdf" , 17 )
49 |     word.Quit()
50 | }
51 | excelTopdf(fPath,path,name){
52 |     excel := ComObjCreate("Excel.Application")
53 |     excel.Visible := 0
54 |     excel.DisplayAlerts := 0
55 |     excelFile := excel.Workbooks.open(fPath)
56 |     excelFile.ExportAsFixedFormat(0, path . "\" . name . ".pdf")
57 |     excel.Quit()
58 | }
59 | pdfOptimizer(fPath,path,name){
60 |     outputFileName := path . "\" . name . "-optimized.pdf"
61 |     RunWait, gs -dBATCH -dNOPAUSE -q -sDEVICE=pdfwrite -dFastWebView -sOUTPUTFILE="%outputFileName%"  "%fPath%",,Hide
62 | }


--------------------------------------------------------------------------------
/src/other/OfficeToPDF/OfficeToPDF.ico:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/SaifAqqad/AHK_Script/2b3dfa445ed700d0975d79d4d7c3993c1c3cc321/src/other/OfficeToPDF/OfficeToPDF.ico


--------------------------------------------------------------------------------
/src/other/OfficeToPDF/README.md:
--------------------------------------------------------------------------------
 1 | <h1 align="center">
 2 |   OfficeToPDF
 3 | </h1>
 4 | <p align="center">
 5 |  Convert Office documents to PDF format 
 6 | </p>
 7 | 
 8 | ## Install using Scoop:
 9 | 
10 | 1. Install scoop.sh using powershell
11 |     
12 |         iwr -useb get.scoop.sh | iex
13 | 2. Add my bucket to scoop
14 |         
15 |         scoop bucket add utils https://github.com/SaifAqqad/utils.git
16 | 3. Install OfficeToPDF
17 | 
18 |         scoop install officetopdf
19 | 
20 | ## Usage: 
21 | 1. Select the files you want to convert.
22 | 2. Right click --> Send to --> PDF file.
23 | 


--------------------------------------------------------------------------------