├── .gitignore
├── .npmignore
├── .travis.yml
├── CHANGELOG.md
├── LICENSE
├── README.md
├── karma.conf.js
├── package.json
├── spec
    └── fixture_spec.coffee
└── src
    ├── adapter.coffee
    ├── fixture.coffee
    └── index.coffee


/.gitignore:
--------------------------------------------------------------------------------
1 | node_modules
2 | lib
3 | 


--------------------------------------------------------------------------------
/.npmignore:
--------------------------------------------------------------------------------
1 | src
2 | spec
3 | karma.conf.js
4 | Gruntfile.js
5 | 


--------------------------------------------------------------------------------
/.travis.yml:
--------------------------------------------------------------------------------
1 | language: node_js
2 | node_js:
3 |    - "0.10"
4 | 


--------------------------------------------------------------------------------
/CHANGELOG.md:
--------------------------------------------------------------------------------
 1 | # Change Log
 2 | 
 3 | ## [v0.2.6](https://github.com/billtrik/karma-fixture/tree/v0.2.6) (2016-02-13)
 4 | 
 5 | **Closed issues:**
 6 | 
 7 | - Modifying loaded fixture data permanently modifies fixture data [\#12](https://github.com/billtrik/karma-fixture/issues/12)
 8 | 
 9 | [Full Changelog](https://github.com/billtrik/karma-fixture/compare/v0.2.5...v0.2.6)
10 | 
11 | ## [v0.2.5](https://github.com/billtrik/karma-fixture/tree/v0.2.5) (2015-05-26)
12 | 
13 | **Closed issues:**
14 | 
15 | - Does not load json objects with escaped characters [\#7](https://github.com/billtrik/karma-fixture/issues/7)
16 | 
17 | [Full Changelog](https://github.com/billtrik/karma-fixture/compare/v0.2.4...v0.2.5)
18 | 
19 | ## [v0.2.4](https://github.com/billtrik/karma-fixture/tree/v0.2.4) (2015-05-18)
20 | 
21 | **Closed issues:**
22 | 
23 | - Don't eval() text in `<script>` if type isn't "text/javascript" or "application/javascript" [\#8](https://github.com/billtrik/karma-fixture/issues/8)
24 | 
25 | [Full Changelog](https://github.com/billtrik/karma-fixture/compare/v0.2.3...v0.2.4)
26 | 
27 | ## [v0.2.3](https://github.com/billtrik/karma-fixture/tree/v0.2.3) (2015-03-07)
28 | 
29 | [Full Changelog](https://github.com/billtrik/karma-fixture/compare/v0.2.2...v0.2.3)
30 | 
31 | **Closed issues:**
32 | 
33 | - Modify base path? [\#6](https://github.com/billtrik/karma-fixture/issues/6)
34 | 
35 | - Can't find variable: Fixture [\#1](https://github.com/billtrik/karma-fixture/issues/1)
36 | 
37 | **Implemented enhancements:**
38 | 
39 | - Add setter method for base
40 | 
41 | - Ignore base when searching for fixture, if fixture starts with '/'
42 | 
43 | - Add fixture's name to the not found error thrown
44 | 
45 | ## [v0.2.2](https://github.com/billtrik/karma-fixture/tree/v0.2.2) (2015-03-01)
46 | 
47 | [Full Changelog](https://github.com/billtrik/karma-fixture/compare/v0.2.1-1...v0.2.2)
48 | 
49 | **Closed issues:**
50 | 
51 | - Throw error when fixture not found? [\#5](https://github.com/billtrik/karma-fixture/issues/5)
52 | 
53 | - fixture.clear\(\) is really fixture.cleanup\(\) [\#4](https://github.com/billtrik/karma-fixture/issues/4)
54 | 
55 | **Merged pull requests:**
56 | 
57 | - Add step to setup in README [\#2](https://github.com/billtrik/karma-fixture/pull/2) ([martiansnoop](https://github.com/martiansnoop))
58 | 
59 | ## [v0.2.1-1](https://github.com/billtrik/karma-fixture/tree/v0.2.1-1) (2014-05-23)
60 | 
61 | [Full Changelog](https://github.com/billtrik/karma-fixture/compare/v0.2.1...v0.2.1-1)
62 | 
63 | ## [v0.2.1](https://github.com/billtrik/karma-fixture/tree/v0.2.1) (2014-05-23)
64 | 
65 | [Full Changelog](https://github.com/billtrik/karma-fixture/compare/v0.2.0...v0.2.1)
66 | 
67 | **Implemented enhancements:**
68 | 
69 | - Properly empty `fixture.json` array when loading JSON fixture with `append=false`
70 | 
71 | ## [v0.2.0](https://github.com/billtrik/karma-fixture/tree/v0.2.0) (2014-05-23)
72 | 
73 | [Full Changelog](https://github.com/billtrik/karma-fixture/compare/v0.1.0...v0.2.0)
74 | 
75 | **Implemented enhancements:**
76 | 
77 | - Update .load() to return either an array of results or the single result
78 | 
79 | - Enable Travis  CI for the project
80 | 
81 | ## [v0.1.0](https://github.com/billtrik/karma-fixture/tree/v0.1.0) (2014-05-23)
82 | 
83 | 
84 | 
85 | \* *This Change Log was automatically generated by [github_changelog_generator](https://github.com/skywinder/Github-Changelog-Generator)*
86 | 


--------------------------------------------------------------------------------
/LICENSE:
--------------------------------------------------------------------------------
 1 | The MIT License (MIT)
 2 | 
 3 | Copyright (c) 2014 Bill Trikalinos
 4 | 
 5 | Permission is hereby granted, free of charge, to any person obtaining a copy
 6 | of this software and associated documentation files (the "Software"), to deal
 7 | in the Software without restriction, including without limitation the rights
 8 | to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 9 | copies of the Software, and to permit persons to whom the Software is
10 | furnished to do so, subject to the following conditions:
11 | 
12 | The above copyright notice and this permission notice shall be included in all
13 | copies or substantial portions of the Software.
14 | 
15 | THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
16 | IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
17 | FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
18 | AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
19 | LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
20 | OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
21 | SOFTWARE.


--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
  1 | karma-fixture [![Build Status](https://travis-ci.org/billtrik/karma-fixture.svg?branch=master)](https://travis-ci.org/billtrik/karma-fixture) [![NPM version](https://badge.fury.io/js/karma-fixture.svg)](http://badge.fury.io/js/karma-fixture)
  2 | =============
  3 | 
  4 | A plugin for the Karma test runner that loads `.html` and `.json` fixtures.
  5 | 
  6 | It provides the same API as the teaspoon fixture package.
  7 | 
  8 | Installation
  9 | ------------
 10 | 
 11 | Install the plugin from npm:
 12 | 
 13 | ```sh
 14 | $ npm install karma-fixture --save-dev
 15 | ```
 16 | 
 17 | Add `fixture` to the `frameworks` array in your Karma configuration:
 18 | 
 19 | ```javascript
 20 | module.exports = function(config){
 21 |   config.set({
 22 |     // ...
 23 |     frameworks: ['mocha', 'fixture'],
 24 |     // ...
 25 | ```
 26 | 
 27 | You also have to register any/all fixtures inside your Karma configuration file.
 28 | If all your fixtures exist under a `fixtures/base/path/` folder, then you should include
 29 | all files of interest under this base path.
 30 | 
 31 | 
 32 | ```javascript
 33 | module.exports = function(config){
 34 |   config.set({
 35 |     // ...
 36 |     files: [
 37 |       {
 38 |         pattern: 'fixtures/base/path/**/*',
 39 |       },
 40 |       // ...
 41 |     ],
 42 |     // ...
 43 | ],
 44 | ```
 45 | 
 46 | Finally you have to add the `html2js` and `karma-json-fixtures-preprocessor` karma preprocessors:
 47 | 
 48 | ```sh
 49 | $ npm install karma-html2js-preprocessor --save-dev
 50 | $ npm install karma-json-fixtures-preprocessor --save-dev
 51 | ```
 52 | 
 53 | , configure Karma to load all html and JSON fixture files via those preprocessors:
 54 | 
 55 | ```javascript
 56 | module.exports = function(config){
 57 |   config.set({
 58 |     // ...
 59 |     preprocessors: {
 60 |       '**/*.html'   : ['html2js'],
 61 |       '**/*.json'   : ['json_fixtures']
 62 |     },
 63 |     // ...
 64 | ```
 65 | 
 66 | and then setup the `karma-json-fixtures-preprocessor` plugin:
 67 | 
 68 | ```javascript
 69 | module.exports = function(config){
 70 |   config.set({
 71 |     // ...
 72 |     jsonFixturesPreprocessor: {
 73 |       variableName: '__json__'
 74 |     },
 75 |     // ...
 76 | ```
 77 | 
 78 | ## Setup issues
 79 | 
 80 | 1. `Uncaught SyntaxError: Unexpected token :` error when loading JSON files
 81 | 
 82 |     This is probably due to improper config values for the 'karma-json-fixtures-preprocessor'.
 83 |     For more see: https://github.com/billtrik/karma-fixture/issues/15#issuecomment-274051710
 84 | 
 85 | 2. `Warning: No provider for "framework:fixture"!` 
 86 |    There is probably a `plugins` entry on your config. If that is the case you have to explicitly declare every single plugin that you plan to use in that array:
 87 | 
 88 | ```javascript
 89 | module.exports = function(config){
 90 |   config.set({
 91 |     // ...
 92 |     plugins: [
 93 |       'karma-fixture',
 94 |       'karma-html2js-preprocessor',
 95 |       'karma-json-fixtures-preprocessor',
 96 |       // ...
 97 |     ],
 98 |     // ...
 99 | ```
100 | 
101 | Implementation details
102 | -----
103 | 
104 | All html fixture files are pre-loaded as strings and placed inside the Karma-created `window.__html__` object and all json fixtures are loaded inside 
105 | `window.__json__`.
106 | 
107 | The fixture plugin is exposed in the `window.fixture` object on every test run.
108 | It loads fixture files from these objects and appends the created html inside the `window.fixture.el` element that gets created on start-up. It appends loaded JSONs inside the `fixture.json` array.
109 | 
110 | 
111 | Usage
112 | ------
113 | 
114 | Lets say you have the following fixture files:
115 | 
116 | - `fixtures/base/path/test1.html`
117 | 
118 |     ```html
119 |     <p>p</p>
120 |     <a href='#'>
121 |         <span>link</span>
122 |     </a>
123 |     ```
124 | 
125 | - `fixtures/base/path/json/test1.json`
126 |     ```javascript
127 |     "{"test":true}"
128 |     ```
129 | 
130 | You can use `fixture` inside your tests to handle the fixtures:
131 | 
132 | 
133 | ```javascript
134 | describe('some test that needs a fixture', function(){
135 |   // If base path is different from the default `spec/fixtures`
136 |   before(function(){
137 |     fixture.setBase('fixtures/base/path')
138 |   });
139 | 
140 |   beforeEach(function(){
141 |     this.result = fixture.load('test1.html', 'test1.json');
142 |   });
143 | 
144 |   afterEach(function(){
145 |     fixture.cleanup()
146 |   });
147 | 
148 |   it('plays with the html fixture', function(){
149 |     expect(fixture.el.firstChild).to.equal(this.result[0][0]);
150 |   });
151 | 
152 |   // ...
153 | });
154 | ```
155 | 
156 | API
157 | -------
158 | 
159 | * `fixture.el`
160 | 
161 |   Reference to the container element. Every html fixture loaded gets appended inside this container.
162 | 
163 | * `fixture.json`
164 | 
165 |   An array of all json objects imported from fixture templates.
166 | 
167 | 
168 | * `fixture.load(files..., append = false)`
169 | 
170 |   It takes multiple filenames as arguments. All filenames are loaded from within the base path.
171 | 
172 |   It loads and appends them inside the fixtures container element.
173 |   It returns an array with references to the newly created first level html elements.
174 |   When more than one are loaded, it returns an array of the above described format, for each loaded fixture.
175 | 
176 |   It takes an optional boolean argument which defaults to `false`.
177 |   If `false`, it empties the `window.fixture.el` container element and clears the `window.fixture.json` array.
178 |   If `true`, it just appends the requested fixture to the container.
179 | 
180 |   If your fixtures exist in a base path other than the default `spec/fixtures`,
181 |   you should call `fixture.setBase('fixtures/base/path')` in your specs, or load them
182 |   with their full, base included, filenames prefixed with a '/'.
183 | 
184 |   For example: `fixture.load('/my/other/base/path/fixture1.html')`
185 | 
186 |   Scenarios:
187 | 
188 |   **html fixture**
189 | 
190 |   It returns an array of all the first-level nodes created by the fixture file:
191 | 
192 |   ```javascript
193 |   html_fixture = fixture.load('test1.html');
194 |   // then
195 |   expect(html_fixture[0].innerHTML).to.equal('<p>p</p>')
196 |   // and
197 |   expect(html_fixture[1].innerHTML).to.equal('<a href="#"><span>link</span></a>')
198 |   ```
199 | 
200 |   **JSON fixture**
201 | 
202 |   It returns a valid object by JSON.parsing the passed json fixture file.
203 |   Also all JSON files loaded get appended to the `window.fixture.json` array:
204 | 
205 |   ```javascript
206 |   json_fixture = fixture.load('json/test1.json')
207 |   // then
208 |   expect(json_fixture).to.eql({"test":true})
209 |   // and
210 |   expect(fixture.json[0]).to.eql({"test":true})
211 |   ```
212 | 
213 |   **Multiple files**
214 | 
215 |   The result will be an array containing results of each loaded template:
216 | 
217 |   ```javascript
218 |   loaded_fixtures = fixture.load('test1.html', 'json/test1.json')
219 |   // then
220 |   expect(loaded_fixtures[0][0].innerHTML).to.equal('<p>p</p>')
221 |   // and
222 |   expect(loaded_fixtures[0][1].innerHTML).to.equal('<a href="#"><span>link</span></a>')
223 |   // and
224 |   expect(loaded_fixtures[1]).to.eql({"test":true})
225 |   // and
226 |   expect(fixture.json[0]).to.eql({"test":true})
227 |   ```
228 | 
229 | 
230 | * `fixture.set(html_strings, append=false)`
231 | 
232 |   It takes multiple html_strings as arguments and load them.
233 |   It returns the loaded result, or an array of more than one loaded results
234 | 
235 |   It takes a boolean argument with default value `false`.
236 |   If `false`, it empties the `window.fixture.el` container element and clears the `window.fixture.json` array.
237 | 
238 | 
239 |   ```javascript
240 |   result = fixture.set('<h1>test</h1>')
241 |   // then
242 |   expect(result[0].innerHTML).to.equal('<h1>test</h1>')
243 |   ```
244 | 
245 | * `fixture.cleanup()`
246 | 
247 |   It empties the `window.fixture.el` container element and clears the `window.fixture.json` array.
248 | 
249 | * `fixture.setBase(fixtureBasePath)`
250 | 
251 |   It set the base path under which all forthcoming fixtures will be loaded.
252 |   This can be bypassed by loading a fixture with its full, base included, filename prefixed with a '/'.
253 | 
254 | 
255 | License
256 | -------
257 | 
258 | The MIT License (MIT)
259 | 


--------------------------------------------------------------------------------
/karma.conf.js:
--------------------------------------------------------------------------------
 1 | // Karma configuration
 2 | // Generated on Fri May 16 2014 13:49:58 GMT+0300 (EEST)
 3 | 
 4 | module.exports = function(config) {
 5 |   config.set({
 6 |     basePath: '',
 7 |     frameworks: ['mocha', 'chai'],
 8 |     files: [
 9 |       'src/fixture.coffee',
10 |       {
11 |         pattern  : 'spec/**/*.coffee',
12 |         included : true,
13 |         served   : true,
14 |         watched  : true
15 |       }
16 |     ],
17 |     preprocessors: {
18 |       '**/*.coffee' : ['coffee']
19 |     },
20 |     coffeePreprocessor: {
21 |       options: {
22 |         bare: false
23 |       },
24 |     },
25 |     reporters: ['mocha'],
26 |     logLevel: config.LOG_INFO,
27 |     browsers: ['PhantomJS'],
28 |     autoWatch: false,
29 |     singleRun: true
30 |   });
31 | };
32 | 


--------------------------------------------------------------------------------
/package.json:
--------------------------------------------------------------------------------
 1 | {
 2 |   "name": "karma-fixture",
 3 |   "description": "A plugin for the Karma test runner that loads .html and .json fixtures",
 4 |   "keywords": [
 5 |     "karma",
 6 |     "karma-plugin",
 7 |     "fixtures",
 8 |     "fixture"
 9 |   ],
10 |   "version": "0.2.6",
11 |   "author": "Bill Trikalinos <billtrik@gmail.com>",
12 |   "homepage": "https://github.com/billtrik/karma-fixture",
13 |   "license": "MIT",
14 |   "main": "./lib/index.js",
15 |   "scripts": {
16 |     "test": "node ./node_modules/karma/bin/karma start --single-run",
17 |     "prepublish": "./node_modules/.bin/coffee -o lib -c src/*.coffee"
18 |   },
19 |   "repository": {
20 |     "type": "git",
21 |     "url": "https://github.com/billtrik/karma-fixture.git"
22 |   },
23 |   "bugs": {
24 |     "url": "https://github.com/billtrik/karma-fixture/issues"
25 |   },
26 |   "devDependencies": {
27 |     "coffee-script": "^1.7.1",
28 |     "karma": "^0.12.31",
29 |     "karma-chai": "^0.1.0",
30 |     "karma-cli": "0.0.4",
31 |     "karma-coffee-preprocessor": "^0.2.1",
32 |     "karma-mocha": "^0.1.3",
33 |     "karma-mocha-reporter": "^1.0.0",
34 |     "karma-phantomjs-launcher": "^0.1.4"
35 |   }
36 | }
37 | 


--------------------------------------------------------------------------------
/spec/fixture_spec.coffee:
--------------------------------------------------------------------------------
  1 | json_data =
  2 |   test1: 'check'
  3 |   test2: 'ok'
  4 | 
  5 | json_template = JSON.stringify json_data
  6 | escaped_json_template = JSON.stringify
  7 |   "myLink": "<a href=\"link.url\">Link</a>"
  8 | 
  9 | html_template1 = '<h1 id="tmpl">test</h1>'
 10 | html_template2 = '<h2 id="tmpl">test</h2><p>multiple</p>'
 11 | html_template3 = '<script>window.test_a_test = true</script>'
 12 | html_template4 = '<script type="text/javascript">window.test_b_test = true</script>'
 13 | html_template5 = '<script type="application/javascript">window.test_c_test = true</script>'
 14 | html_template6 = '<script type="text/x-custom">window.test_d_test = true</script>'
 15 | fixture_base = 'spec/fixtures'
 16 | 
 17 | load_template_as_karma_json_fixures = (name, string, base = fixture_base)->
 18 |   window.__json__ ?= {}
 19 |   window.__json__["#{base}/#{name}"] = JSON.parse(string)
 20 | 
 21 | load_template_as_karma_html2js = (name, string, base = fixture_base)->
 22 |   window.__html__ ?= {}
 23 |   window.__html__["#{base}/#{name}"] = string
 24 | 
 25 | cleanup_karma_html2js_templates = -> window.__html__ = {}
 26 | 
 27 | describe 'Fixture', ->
 28 |   before ->
 29 |     @Fixture = window.Fixture
 30 | 
 31 |   it 'is a function', ->
 32 |     expect(@Fixture).to.be.a 'function'
 33 | 
 34 |   describe 'instance', ->
 35 |     afterEach ->
 36 |       container = document.getElementById(@instance.id)
 37 |       container.parentElement.removeChild(container)
 38 |       @instance = null
 39 |       delete @instance
 40 | 
 41 |     it 'stores the id of the fixtures container in @id', ->
 42 |       @instance = new @Fixture()
 43 |       expect(@instance.id)
 44 |         .to.not.be.null
 45 | 
 46 |     it 'stores the base folder from where to load templates in @base', ->
 47 |       @instance = new @Fixture()
 48 |       expect(@instance.base)
 49 |         .to.not.be.null
 50 | 
 51 |     it "has a default value of '#{fixture_base}' for the base", ->
 52 |       @instance = new @Fixture()
 53 |       expect(@instance.base)
 54 |         .to.equal fixture_base
 55 | 
 56 |     it 'receives a param that changes the base value', ->
 57 |       @instance = new @Fixture('checkcheck')
 58 |       expect(@instance.base)
 59 |         .to.equal 'checkcheck'
 60 | 
 61 |     it 'receives the base folder from where to load templates as option', ->
 62 |       @instance = new @Fixture()
 63 | 
 64 |     it 'has an empty array to store json fixtures in @json', ->
 65 |       @instance = new @Fixture()
 66 |       expect(@instance.json)
 67 |         .to.be.an('array')
 68 |         .and.to.be.empty
 69 | 
 70 |     it 'has created the fixtures container element', ->
 71 |       @instance = new @Fixture()
 72 |       container = document.getElementById @instance.id
 73 |       expect(container).to.not.be.null
 74 | 
 75 |     it 'has a reference to the fixtures container element in @el', ->
 76 |       @instance = new @Fixture()
 77 |       container = document.getElementById @instance.id
 78 |       expect(@instance.el).to.equal(container)
 79 | 
 80 |   describe 'API', ->
 81 |     beforeEach ->
 82 |       @instance = new @Fixture()
 83 |       @fixture_cont = @instance.el
 84 | 
 85 |     afterEach ->
 86 |       container = document.getElementById(@instance.id)
 87 |       container.parentElement.removeChild(container)
 88 |       @instance = null
 89 |       delete @instance
 90 | 
 91 |     describe '#load()', ->
 92 |       beforeEach ->
 93 |         load_template_as_karma_html2js 'html1', html_template1
 94 |         load_template_as_karma_html2js 'html2', html_template2
 95 |         load_template_as_karma_html2js 'html3', html_template3
 96 |         load_template_as_karma_html2js 'html4', html_template4
 97 |         load_template_as_karma_html2js 'html5', html_template5
 98 |         load_template_as_karma_html2js 'html6', html_template6
 99 |         load_template_as_karma_json_fixures 'json.json', json_template
100 |         load_template_as_karma_json_fixures 'escaped_json.json', escaped_json_template
101 | 
102 |       afterEach ->
103 |         cleanup_karma_html2js_templates()
104 | 
105 |       it 'creates DOM elements inside the container from the template whose name is passed as the first param', ->
106 |         @instance.load 'html1'
107 |         expect(@fixture_cont.children.length).to.equal 1
108 | 
109 |       it 'accepts an "append" boolean as second param', ->
110 |         @instance.load 'html1', true
111 |         expect(@fixture_cont.children.length).to.equal 1
112 | 
113 |       it 'appends new template to existing one if append is true', ->
114 |         @instance.load 'html1', false
115 |         @instance.load 'html2', true
116 |         @instance.load 'html1', true
117 |         expect(@fixture_cont.children.length).to.equal 4
118 | 
119 |       it 'replaces older templates with new one if append is false', ->
120 |         @instance.load 'html1', false
121 |         @instance.load 'html2', false
122 |         @instance.load 'html1', false
123 |         expect(@fixture_cont.children.length).to.equal 1
124 | 
125 |       it 'has a default value of false', ->
126 |         @instance.load 'html1'
127 |         @instance.load 'html1'
128 |         expect(@fixture_cont.children.length).to.equal 1
129 | 
130 |       it 'returns an array with a list of newly created dom nodes per template', ->
131 |         dom_nodes = @instance.load('html1')
132 | 
133 |         expect(dom_nodes[0])
134 |           .to.equal @fixture_cont.firstChild
135 | 
136 |       it 'returns references to all firstChildren nodes created by the template', ->
137 |         dom_nodes = @instance.load('html2')
138 | 
139 |         expect(dom_nodes.length)
140 |           .to.equal(@fixture_cont.children.length)
141 |           .to.equal(2)
142 | 
143 |       it 'throws when template does not exist', ->
144 |         fn = => @instance.load('notExistingFixture')
145 |         fixture_path = "#{@instance.base}/notExistingFixture"
146 |         expect(fn).to.throw(ReferenceError, "Cannot find fixture '#{fixture_path}'")
147 | 
148 |       it 'ignores base if fixture name starts with \'/\'', ->
149 |         load_template_as_karma_html2js 'html4', '<p>test</p>', 'test_base'
150 | 
151 |         @instance.load('/test_base/html4')
152 |         expect(@fixture_cont.innerHTML).to.equal('<p>test</p>')
153 | 
154 |       context 'when template contains <script> tags without type', ->
155 |         beforeEach ->
156 |           @instance.load 'html3'
157 | 
158 |         it 'places the script tag intact', ->
159 |           expect(@fixture_cont.innerHTML).to.equal html_template3
160 | 
161 |         it 'executes the javascript', ->
162 |           expect(window.test_a_test).to.equal true
163 | 
164 |       context 'when template contains <script> tags with text/javascript type', ->
165 |         beforeEach ->
166 |           @instance.load 'html4'
167 | 
168 |         it 'places the script tag intact', ->
169 |           expect(@fixture_cont.innerHTML).to.equal html_template4
170 | 
171 |         it 'executes the javascript', ->
172 |           expect(window.test_b_test).to.equal true
173 | 
174 |       context 'when template contains <script> tags with application/javascript type', ->
175 |         beforeEach ->
176 |           @instance.load 'html5'
177 | 
178 |         it 'places the script tag intact', ->
179 |           expect(@fixture_cont.innerHTML).to.equal html_template5
180 | 
181 |         it 'executes the javascript', ->
182 |           expect(window.test_c_test).to.equal true
183 | 
184 |       context 'when template contains <script> tags with text/x-custom type', ->
185 |         beforeEach ->
186 |           @instance.load 'html6'
187 | 
188 |         it 'places the script tag intact', ->
189 |           expect(@fixture_cont.innerHTML).to.equal html_template6
190 | 
191 |         it 'does not execute the javascript', ->
192 |           expect(window.test_d_test).to.equal undefined
193 | 
194 |       context 'when multiple templates are requested', ->
195 |         beforeEach ->
196 |           @result = @instance.load 'html1', 'html2'
197 | 
198 |         it 'accepts multiple templates as params', ->
199 |           expect(@fixture_cont.children.length).to.equal 3
200 | 
201 |         it 'returns multiple template\'s results in an array', ->
202 |           expect(@result.length).to.equal(2)
203 | 
204 |         it 'returns references to all firstChildren nodes created by all the templates', ->
205 |           expect(@result[1][1])
206 |             .to.equal @fixture_cont.children[2]
207 | 
208 |       context 'when it loads json template', ->
209 |         it 'returns the json object', ->
210 |           result = @instance.load 'json.json'
211 |           expect(result).to.include json_data
212 | 
213 |         it 'retrieves json templates from window.__json__', ->
214 |           result = @instance.load 'json.json'
215 |           expect(result).to.eql(window.__json__["#{fixture_base}/json.json"])
216 | 
217 |         it 'returns a copy of the json data', ->
218 |           result = @instance.load 'json.json'
219 |           expect(result).to.not.equal(window.__json__["#{fixture_base}/json.json"])
220 | 
221 |         it 'loads the json template into fixture.json', ->
222 |           @instance.load 'json.json'
223 |           expect(@instance.json[0]).to.include json_data
224 | 
225 |         it 'returns multiple json objects', ->
226 |           result = @instance.load 'json.json', 'json.json'
227 |           expect(result.length).to.equal 2
228 | 
229 |         it 'loads multiple json templates into fixture.json', ->
230 |           result = @instance.load 'json.json', 'json.json'
231 |           expect(@instance.json.length).to.equal 2
232 | 
233 |         it 'does not pesists mutations on json data between loads', ->
234 |           result = @instance.load 'json.json'
235 |           expect(result.test1).to.equal 'check'
236 |           result.test1 = 'checkcheck'
237 | 
238 |           result = @instance.load 'json.json'
239 |           expect(result.test1).to.equal 'check'
240 | 
241 |       context 'when it loads json template with escaped characters', ->
242 |         it 'does not throw', ->
243 |           func = -> @instance.load 'escaped_json.json'
244 |           expect(func).to.not.throw
245 | 
246 |         it 'creates properly unescaped data', ->
247 |           result = @instance.load 'escaped_json.json'
248 |           expect(result.myLink).to.eql('<a href=\"link.url\">Link</a>')
249 |           expect(result.myLink.indexOf('\\')).to.equal(-1);
250 | 
251 |       context 'json and html templates', ->
252 |         beforeEach ->
253 |           @result = @instance.load 'html1', 'json.json'
254 | 
255 |         it 'returns both templates', ->
256 |           expect(@result.length).to.equal 2
257 | 
258 |         it 'pushes the json obj to fixture.json', ->
259 |           expect(@instance.json[0]).to.include json_data
260 | 
261 |     describe '#set()', ->
262 |       it 'accepts a string as first param and creates a dom element', ->
263 |         @instance.set html_template1
264 |         expect(@fixture_cont.innerHTML).to.equal html_template1
265 | 
266 |       it 'accepts an append boolean as second param', ->
267 |         @instance.set html_template1, true
268 |         expect(@fixture_cont.children.length).to.equal 1
269 | 
270 |       it 'appends new template to existing one if append is true', ->
271 |         @instance.set html_template1, false
272 |         @instance.set html_template2, true
273 |         @instance.set html_template1, true
274 |         expect(@fixture_cont.children.length).to.equal 4
275 | 
276 |       it 'replaces older templates with new one if append is false', ->
277 |         @instance.set html_template1, false
278 |         @instance.set html_template2, false
279 |         @instance.set html_template1, false
280 |         expect(@fixture_cont.children.length).to.equal 1
281 | 
282 |       it 'has a default value of false', ->
283 |         @instance.set html_template1
284 |         @instance.set html_template1
285 |         expect(@fixture_cont.children.length).to.equal 1
286 | 
287 |       it 'appends and returns an array with a list of newly created dom nodes per template', ->
288 |         dom_nodes = @instance.set(html_template2)
289 | 
290 |         expect(dom_nodes[0]).to.equal @fixture_cont.firstChild
291 |         expect(dom_nodes[1]).to.equal @fixture_cont.firstChild.nextSibling
292 | 
293 |       it 'appends and returns an array of arrays of newly created dom nodes for multiple templates', ->
294 |         dom_nodes = @instance.set(html_template1, html_template2)
295 | 
296 |         expect(dom_nodes[0][0]).to.equal @fixture_cont.firstChild
297 |         expect(dom_nodes[1][0]).to.equal @fixture_cont.firstChild.nextSibling
298 |         expect(dom_nodes[1][1]).to.equal @fixture_cont.firstChild.nextSibling.nextSibling
299 | 
300 |       it 'returns references to all firstChildren nodes created by the template', ->
301 |         dom_nodes = @instance.set(html_template2)
302 | 
303 |         expect(dom_nodes.length)
304 |           .to.equal(@fixture_cont.children.length)
305 |           .to.equal(2)
306 | 
307 |       context 'when template contains <script> tags', ->
308 |         beforeEach ->
309 |           @result = @instance.set html_template3
310 | 
311 |         it 'places the script tag intact', ->
312 |           expect(@fixture_cont.innerHTML).to.equal html_template3
313 | 
314 |         it 'executes the javascript', ->
315 |           expect(window.test_a_test).to.equal true
316 | 
317 |       context 'when multiple templates are requested', ->
318 |         beforeEach ->
319 |           @result = @instance.set html_template1, html_template2
320 | 
321 |         it 'accepts multiple templates as params', ->
322 |           expect(@fixture_cont.children.length).to.equal 3
323 | 
324 |         it 'returns multiple template\'s results in an array', ->
325 |           expect(@result.length).to.equal(2)
326 | 
327 |         it 'returns references to all firstChildren nodes created by all the templates', ->
328 |           expect(@result[1][1])
329 |             .to.equal @fixture_cont.children[2]
330 | 
331 |     describe '#cleanup()', ->
332 |       beforeEach ->
333 |         load_template_as_karma_html2js 'html1', html_template1
334 |         load_template_as_karma_html2js 'html2', html_template2
335 |         load_template_as_karma_html2js 'json.json', json_template
336 | 
337 |         @result = @instance.load 'html1', 'json.json'
338 |         @instance.cleanup()
339 | 
340 |       afterEach ->
341 |         cleanup_karma_html2js_templates()
342 | 
343 |       it 'resets @json to an empty array', ->
344 |         expect(@instance.json)
345 |           .to.be.an('array')
346 |           .and.to.be.empty
347 | 
348 |       it 'empties fixture container', ->
349 |         expect(@fixture_cont.innerHTML).to.equal ''
350 | 
351 |     describe '#setBase()', ->
352 |       beforeEach ->
353 |         @lastBase = @instance.base
354 |         @testBase = 'test_base'
355 |         @instance.setBase(@testBase)
356 | 
357 |       afterEach ->
358 |         @instance.base = @lastBase
359 |         cleanup_karma_html2js_templates()
360 | 
361 |       it 'sets passed param as basepath for fixtures', ->
362 |         expect(@instance.base).to.equal(@testBase)
363 | 
364 |       it 'searches later loaded fixtures under this basepath', ->
365 |         load_template_as_karma_html2js 'html1', html_template1
366 |         fn = => @instance.load('html1')
367 |         expect(fn).to.throw(ReferenceError, "Cannot find fixture '#{@testBase}/html1'")
368 | 
369 |         load_template_as_karma_html2js 'html2', html_template2, @testBase
370 |         @instance.load('html2')
371 |         expect(@fixture_cont.children.length).to.equal 2
372 | 
373 | 


--------------------------------------------------------------------------------
/src/adapter.coffee:
--------------------------------------------------------------------------------
1 | this.fixture = new Fixture()
2 | 


--------------------------------------------------------------------------------
/src/fixture.coffee:
--------------------------------------------------------------------------------
  1 | class Fixture
  2 | 
  3 |   constructor: (@base = 'spec/fixtures', @id = 'fixture_container') ->
  4 |     @json = []
  5 |     @scriptTypes = {
  6 |       'application/ecmascript': 1,
  7 |       'application/javascript': 1,
  8 |       'application/x-ecmascript': 1,
  9 |       'application/x-javascript': 1,
 10 |       'text/ecmascript': 1,
 11 |       'text/javascript': 1,
 12 |       'text/javascript1.0': 1,
 13 |       'text/javascript1.1': 1,
 14 |       'text/javascript1.2': 1,
 15 |       'text/javascript1.3': 1,
 16 |       'text/javascript1.4': 1,
 17 |       'text/javascript1.5': 1,
 18 |       'text/jscript': 1,
 19 |       'text/livescript': 1,
 20 |       'text/x-ecmascript': 1,
 21 |       'text/x-javascript': 1
 22 |     }
 23 | 
 24 |     @el = window[@id] or (=>
 25 |       container = document.createElement 'div'
 26 |       container.setAttribute 'id', @id
 27 |       document.body.appendChild container
 28 |     )()
 29 | 
 30 |   load: (filenames..., append = false) ->
 31 |     __html__ = window.__html__ || {}
 32 |     __json__ = window.__json__ || {}
 33 | 
 34 |     unless typeof append is 'boolean'
 35 |       filenames.push append
 36 |       append = false
 37 | 
 38 |     @cleanup() if append is false
 39 | 
 40 |     # return created fixtures in an array
 41 |     results = []
 42 |     for filename in filenames
 43 |       if filename[0] is '/'
 44 |         fixture_path = filename.substr(1)
 45 |       else
 46 |         fixture_path = "#{@base}/#{filename}"
 47 | 
 48 |       # JSON
 49 |       if filename.indexOf('.json') isnt -1
 50 |         json = __json__[filename.replace('.json', '')] or
 51 |                __json__[filename] or
 52 |                __json__[fixture_path] or
 53 |                __json__["#{@base}/#{filename.replace('.json', '')}"]
 54 | 
 55 |         @_throwNoFixture(fixture_path) unless json?
 56 | 
 57 |         try
 58 |           json = JSON.parse JSON.stringify(json)
 59 |         catch ignore
 60 | 
 61 |         @json.push json
 62 |         results.push json
 63 |       else if __html__[fixture_path]
 64 |         results.push @_appendFixture __html__[fixture_path]
 65 |       else
 66 |         @_throwNoFixture(fixture_path) unless string?
 67 | 
 68 |     results = results[0] if results.length is 1
 69 |     return results
 70 | 
 71 |   set: (strings..., append = false)->
 72 |     unless typeof append is 'boolean'
 73 |       strings.push append
 74 |       append = false
 75 | 
 76 |     @cleanup() if append is false
 77 | 
 78 |     results = []
 79 |     for string in strings
 80 |       results.push @_appendFixture string
 81 | 
 82 |     results = results[0] if results.length is 1
 83 |     return results
 84 | 
 85 |   cleanup: ->
 86 |     @json = []
 87 |     @el.innerHTML = ''
 88 | 
 89 |   setBase: (@base)->
 90 | 
 91 |   _appendFixture: (html_string) ->
 92 |     temp_div = document.createElement 'div'
 93 |     temp_div.innerHTML = html_string
 94 | 
 95 |     results = []
 96 |     while i = temp_div.firstChild
 97 |       if i.nodeType isnt 1
 98 |         temp_div.removeChild i
 99 |       else
100 |         @el.appendChild(i)
101 |         results.push i
102 |         eval (i.innerText || i.textContent) if i.nodeName is 'SCRIPT' and (!i.type or @scriptTypes[i.type])
103 |     return results
104 | 
105 |   _throwNoFixture: (fixture_path)->
106 |     throw new ReferenceError "Cannot find fixture '#{fixture_path}'"
107 | 
108 | if typeof exports is 'object'
109 |   module.exports = Fixture
110 | else if typeof define is 'function' and define.amd
111 |   define 'fixture', [], -> Fixture
112 | else
113 |   this['Fixture'] = Fixture
114 | 


--------------------------------------------------------------------------------
/src/index.coffee:
--------------------------------------------------------------------------------
 1 | path = require('path')
 2 | 
 3 | adapter_path = path.join(__dirname, 'adapter.js')
 4 | framework_path = path.join(__dirname, 'fixture.js')
 5 | 
 6 | pattern = (file)->
 7 |   pattern  : file
 8 |   included : true
 9 |   served   : true
10 |   watched  : false
11 | 
12 | framework = (files)->
13 |   files.unshift pattern(adapter_path)
14 |   files.unshift pattern(framework_path)
15 |   return
16 | 
17 | 
18 | framework.$inject = ['config.files']
19 | module.exports = {'framework:fixture': ['factory', framework]}
20 | 


--------------------------------------------------------------------------------