├── README.asciidoc
├── doc
    └── lotr.txt
├── plugin
    └── lotr.vim
└── syntax
    └── lotr.vim


/README.asciidoc:
--------------------------------------------------------------------------------
 1 | LOTR
 2 | ----
 3 | 
 4 | __Lord of the Regs__
 5 | 
 6 | TIP: If you like vim-lotr and want to share the W00t!, I'm grateful for
 7 | https://www.gittip.com/bairuidahu/[tips] or
 8 | http://of-vim-and-vigor.blogspot.com/[beverages].
 9 | 
10 | LOTR displays a persistent view of your Vim `:registers` in a sidebar window.
11 | 
12 | == Commands
13 | 
14 | * `:LOTROpen`
15 | * `:LOTRClose`
16 | * `:LOTRToggle` also available through `<PLUG>LOTRToggle` which is mapped to `<leader>cr` by default.
17 | 
18 | == Within the LOTR window:
19 | 
20 | * `q` closes the LOTR window
21 | * `<space>` toggles zoom mode
22 | * `<cr>` returns to the prior window
23 | 
24 | == YankStack
25 | 
26 | LOTR now shows the :Yanks list from the YankStack plugin. +
27 | Disable this by adding this line to your `~/.vimrc`:
28 | 
29 |   let g:lotr_yankstack = 0
30 | 
31 | 


--------------------------------------------------------------------------------
/doc/lotr.txt:
--------------------------------------------------------------------------------
  1 | *lotr.txt*	Lord of the Regs
  2 | 
  3 | 
  4 | 			VIM REFERENCE MANUAL	by Barry Arthur
  5 | 
  6 | 
  7 | Help on using lotr                                                    *lotr*
  8 | 
  9 | 1. Introduction				|lotr-intro|
 10 | 2. Configuration			|lotr-configuration|
 11 | 3. Commands				|lotr-commands|
 12 | 4. LOTR Window Commands			|lotr-window-commands|
 13 | 
 14 | ==============================================================================
 15 |  1. INTRODUCTION                                                  *lotr-intro*
 16 | 
 17 | LOTR -- Lord of the Regs -- A persistent view of :registers in a sidebar window.
 18 | 
 19 | ==============================================================================
 20 |  2. CONFIGURATION                                         *lotr-configuration*
 21 | 
 22 | These options can be set in your |$MYVIMRC| to modify the behaviour of LOTR:
 23 | 
 24 | |'lotr_position'|	Position the LOTR window (left, right, top, bottom)
 25 | |'lotr_winsize'|	Width or height of the LOTR window
 26 | |'lotr_expand'|		Force GVim to widen if necessary to accommodate LOTR
 27 | |'lotr_yankstack'|	Show the :Yanks list from the YankStack plugin
 28 | 
 29 | ------------------------------------------------------------------------------
 30 |                                                              *'lotr_position'*
 31 | Values: string (left, right, top, bottom)                                    ~
 32 | Default: right                                                               ~
 33 | 
 34 | ------------------------------------------------------------------------------
 35 |                                                               *'lotr_winsize'*
 36 | Values: number                                                               ~
 37 | Default: 25                                                                  ~
 38 | 
 39 | ------------------------------------------------------------------------------
 40 |                                                                *'lotr_expand'*
 41 | Values: boolean                                                              ~
 42 | Default: 0                                                                   ~
 43 | 
 44 | By default the LOTR window will not cause GVim to resize to accommodate it.
 45 | 
 46 | ------------------------------------------------------------------------------
 47 |                                                         *'lotr_focus_on_open'*
 48 | Values: boolean                                                              ~
 49 | Default: 0                                                                   ~
 50 | 
 51 | By default the LOTR window will not take focus when opened.
 52 | 
 53 | ------------------------------------------------------------------------------
 54 |                                                              *'lotr_map_keys'*
 55 | Values: boolean                                                              ~
 56 | Default: 1                                                                   ~
 57 | 
 58 | By default LOTR will add key maps.
 59 | 
 60 | ------------------------------------------------------------------------------
 61 |                                                             *'lotr_yankstack'*
 62 | Values: boolean                                                              ~
 63 | Default: 1                                                                   ~
 64 | 
 65 | If installed, LOTR will show the YankStack list as shown by the :Yanks command.
 66 | 
 67 | ==============================================================================
 68 |  3. COMMANDS                                                   *lotr-commands*
 69 | 
 70 | The following commands are available:
 71 | 
 72 | `:LOTROpen`	Open the LOTR window
 73 | 
 74 | `:LOTRClose`	Close the LOTR window
 75 | 
 76 | `:LOTRToggle`	Toggle the open/close state of the LOTR window
 77 | 
 78 | 
 79 | The `:LOTRToggle` command is also available through `<PLUG>LOTRToggle`
 80 | which is mapped to `<leader>cr` by default. If `g:lotr_map_keys` is set
 81 | to 0 then the map will not be added. You can change this by adding a line
 82 | like this to your |$MYVIMRC|:
 83 | >
 84 |   nmap <leader>r <plug>LOTRToggle
 85 | <
 86 | 
 87 | 
 88 | ==============================================================================
 89 |  4. LOTR WINDOW COMMANDS                                *lotr-window-commands*
 90 | 
 91 | From within the LOTR window:
 92 | 
 93 | `<Enter>`	Jumps back to the prior window (|wincmd| p)
 94 | `<Space>`	Toggles zoom mode
 95 | `q`		Closes the LOTR window
 96 | 
 97 | 
 98 | Template From: https://github.com/dahu/Area-41/
 99 |  vim:tw=78:ts=8:ft=help:norl:
100 | 


--------------------------------------------------------------------------------
/plugin/lotr.vim:
--------------------------------------------------------------------------------
  1 | "" ============================================================================
  2 | " File:        lotr.vim
  3 | " Description: A persistent view of :registers in Vim
  4 | " Authors:     Barry Arthur <barry.arthur@gmail.com>
  5 | " Licence:     Vim licence
  6 | " Website:     http://dahu.github.com/vim-lotr/
  7 | " Note:        This plugin was heavily inspired by the 'Tagbar' plugin by
  8 | "              Jan Larres and uses great gobs of code from it.
  9 | "
 10 | " Original taglist copyright notice:
 11 | "              Permission is hereby granted to use and distribute this code,
 12 | "              with or without modifications, provided that this copyright
 13 | "              notice is copied with it. Like anything else that's free,
 14 | "              taglist.vim is provided *as is* and comes with no warranty of
 15 | "              any kind, either expressed or implied. In no event will the
 16 | "              copyright holder be liable for any damamges resulting from the
 17 | "              use of this software.
 18 | " ============================================================================
 19 | 
 20 | if &cp || exists('g:loaded_lotr')
 21 |   finish
 22 | endif
 23 | 
 24 | " Initialization {{{1
 25 | 
 26 | " Basic init {{{2
 27 | 
 28 | if v:version < 702
 29 |   echomsg 'LOTR: Vim version is too old, LOTR requires at least 7.2'
 30 |   finish
 31 | endif
 32 | 
 33 | let g:loaded_lotr = 1
 34 | 
 35 | if !exists('g:lotr_left')
 36 |   let g:lotr_left = 0
 37 | endif
 38 | 
 39 | if !exists('g:lotr_position')
 40 |   let g:lotr_position = g:lotr_left ? 'left' : 'right'
 41 | endif
 42 | 
 43 | if !exists('g:lotr_width')
 44 |   let g:lotr_width = 0
 45 | endif
 46 | 
 47 | if !exists('g:lotr_winsize')
 48 |   let g:lotr_winsize = g:lotr_width ? g:lotr_width : 25
 49 | endif
 50 | 
 51 | if !exists('g:lotr_expand')
 52 |   let g:lotr_expand = 0
 53 | endif
 54 | 
 55 | if !exists('g:lotr_focus_on_open')
 56 |   let g:lotr_focus_on_open = 0
 57 | endif
 58 | 
 59 | if !exists('g:lotr_map_keys')
 60 |   let g:lotr_map_keys = 1
 61 | endif
 62 | 
 63 | if !exists('g:lotr_yankstack')
 64 |   let g:lotr_yankstack = 1
 65 | endif
 66 | 
 67 | let s:autocommands_done        = 0
 68 | let s:source_autocommands_done = 0
 69 | let s:window_expanded          = 0
 70 | 
 71 | " Registers {{{2
 72 | function! LOTR_Regs()
 73 |   let core_regs = ['"', '-', '*', '+', '/']
 74 |   let regs = {}
 75 |   let reglist = []
 76 | 
 77 |   for reg in extend(extend(range(10), core_regs), map(range(26), 'nr2char(char2nr("a") + v:val)'))
 78 |     call extend(regs, {reg : getreg(reg)})
 79 |   endfor
 80 | 
 81 |   for reg in core_regs
 82 |     call add(reglist, reg . ' ' . substitute(regs[reg], '\n', '^J', 'g'))
 83 |   endfor
 84 | 
 85 |   call add(reglist, '')
 86 | 
 87 |   for reg in range(10)
 88 |     call add(reglist, reg . ' ' . substitute(regs[reg], '\n', '^J', 'g'))
 89 |   endfor
 90 | 
 91 |   call add(reglist, '')
 92 | 
 93 |   for regn in range(26)
 94 |     let reg = nr2char(char2nr('a') + regn)
 95 |     if (has_key(regs, reg)) && (regs[reg] != '')
 96 |       call add(reglist, reg . ' ' . substitute(regs[reg], '\n', '^J', 'g'))
 97 |     endif
 98 |   endfor
 99 | 
100 |   if g:lotr_yankstack && exists(':Yanks')
101 |     redir => yankstack_regs
102 |     silent! Yanks
103 |     redir END
104 | 
105 |     call add(reglist, '')
106 | 
107 |     for regline in split(yankstack_regs, "\n")[1:]
108 |       let [reg; text] = matchlist(regline, '\(^\d\+\)\%(\s\+\(.*\)\)\?')[1:2]
109 |       call add(reglist, printf("%2d", reg) . ' ' . substitute(text[0], '\n', '^J', 'g'))
110 |     endfor
111 |   endif
112 | 
113 |   return reglist
114 | endfunction
115 | 
116 | function! s:CreateAutocommands() "{{{2
117 |   augroup LOTR_AutoCmds
118 |     autocmd!
119 |     autocmd BufEnter               __LOTR__  nested call s:QuitIfOnlyWindow()
120 |     autocmd BufUnload              __LOTR__         call s:CleanUp()
121 |     autocmd CursorHold,CursorMoved *                call s:AutoUpdate()
122 |   augroup END
123 | 
124 |   let s:autocommands_done = 1
125 | endfunction
126 | 
127 | function! s:MapKeys() "{{{2
128 |   nnoremap <script> <silent> <buffer> <CR>    :wincmd p<cr>
129 |   nnoremap <script> <silent> <buffer> <space> :call <SID>ZoomWindow()<CR>
130 |   nnoremap <script> <silent> <buffer> q       :call <SID>CloseWindow()<CR>
131 | endfunction
132 | 
133 | " Window management {{{1
134 | " Window management code shamelessly stolen from the Tagbar plugin:
135 | " http://www.vim.org/scripts/script.php?script_id=3465
136 | 
137 | function! s:ToggleWindow() "{{{2
138 |   let lotr_winnr = bufwinnr("__LOTR__")
139 |   if lotr_winnr != -1
140 |     call s:CloseWindow()
141 |   else
142 |     call s:OpenWindow()
143 |   endif
144 | endfunction
145 | 
146 | function! s:OpenWindow() "{{{2
147 |   " do nothing if the LOTR window is already open
148 |   let lotr_winnr = bufwinnr('__LOTR__')
149 |   if lotr_winnr != -1
150 |     return
151 |   endif
152 |   if !s:IsWindowValidToSplit()
153 |     return
154 |   endif
155 |   let s:lotr_regs = LOTR_Regs()
156 | 
157 |   " Expand the Vim window to accomodate for the LOTR window if requested
158 |   if g:lotr_expand && !s:window_expanded && has('gui_running')
159 |     let &columns += g:lotr_winsize + 1
160 |     let s:window_expanded = 1
161 |   endif
162 | 
163 |   let openpos = {
164 |         \ 'top'    : 'topleft',  'left'  : 'topleft vertical',
165 |         \ 'bottom' : 'botright', 'right' : 'botright vertical'}
166 |         \[g:lotr_position] . ' '
167 |   exe 'silent keepalt ' . openpos . g:lotr_winsize . ' split ' . '__LOTR__'
168 |   call s:InitWindow()
169 |   if !g:lotr_focus_on_open
170 |     wincmd p
171 |   endif
172 | endfunction
173 | 
174 | function! s:InitWindow() "{{{2
175 |   setlocal noreadonly " in case the "view" mode is used
176 |   setlocal buftype=nofile
177 |   setlocal bufhidden=hide
178 |   setlocal noswapfile
179 |   setlocal nobuflisted
180 |   setlocal nomodifiable
181 |   setlocal filetype=lotr
182 |   setlocal nolist
183 |   setlocal nonumber
184 |   setlocal nowrap
185 |   setlocal winfixwidth
186 |   setlocal textwidth=0
187 | 
188 |   if exists('+relativenumber')
189 |     setlocal norelativenumber
190 |   endif
191 | 
192 |   setlocal nofoldenable
193 |   setlocal foldcolumn=0
194 |   " Reset fold settings in case a plugin set them globally to something
195 |   " expensive. Apparently 'foldexpr' gets executed even if 'foldenable' is
196 |   " off, and then for every appended line (like with :put).
197 |   setlocal foldmethod&
198 |   setlocal foldexpr&
199 | 
200 |   let s:is_maximized = 0
201 | 
202 |   let cpoptions_save = &cpoptions
203 |   set cpoptions&vim
204 | 
205 |   if !hasmapto('CloseWindow', 'n')
206 |     call s:MapKeys()
207 |   endif
208 | 
209 |   if !s:autocommands_done
210 |     call s:CreateAutocommands()
211 |   endif
212 | 
213 |   setlocal statusline=\ [LOTR]
214 | 
215 |   call s:RenderContent()
216 | 
217 |   let &cpoptions = cpoptions_save
218 | endfunction
219 | 
220 | function! s:CloseWindow() "{{{2
221 |   let lotr_winnr = bufwinnr('__LOTR__')
222 |   if lotr_winnr == -1
223 |     return
224 |   endif
225 | 
226 |   let lotr_bufnr = winbufnr(lotr_winnr)
227 | 
228 |   if winnr() == lotr_winnr
229 |     if winbufnr(2) != -1
230 |       " Other windows are open, only close the LOTR one
231 |       close
232 |     endif
233 |   else
234 |     " Go to the LOTR window, close it and then come back to the
235 |     " original window
236 |     let curbufnr = bufnr('%')
237 |     execute lotr_winnr . 'wincmd w'
238 |     close
239 |     " Need to jump back to the original window only if we are not
240 |     " already in that window
241 |     let winnum = bufwinnr(curbufnr)
242 |     if winnr() != winnum
243 |       exe winnum . 'wincmd w'
244 |     endif
245 |   endif
246 | 
247 |   " If the Vim window has been expanded, and LOTR is not open in any other
248 |   " tabpages, shrink the window again
249 |   if s:window_expanded
250 |     let tablist = []
251 |     for i in range(tabpagenr('$'))
252 |       call extend(tablist, tabpagebuflist(i + 1))
253 |     endfor
254 | 
255 |     if index(tablist, lotr_bufnr) == -1
256 |       let &columns -= g:lotr_winsize + 1
257 |       let s:window_expanded = 0
258 |     endif
259 |   endif
260 | endfunction
261 | 
262 | function! s:ZoomWindow() "{{{2
263 |   if g:lotr_position == 'top' || g:lotr_position == 'bottom'
264 |     if s:is_maximized
265 |       execute 'resize ' . g:lotr_winsize
266 |       let s:is_maximized = 0
267 |     else
268 |       resize
269 |       let s:is_maximized = 1
270 |     endif
271 |   else
272 |     if s:is_maximized
273 |       execute 'vert resize ' . g:lotr_winsize
274 |       let s:is_maximized = 0
275 |     else
276 |       vert resize
277 |       let s:is_maximized = 1
278 |     endif
279 |   endif
280 | endfunction
281 | 
282 | " Display {{{1
283 | function! s:RenderContent() "{{{2
284 |   " only update the LOTR window if we're in normal mode
285 |   if mode(1) != 'n'
286 |     return
287 |   endif
288 |   if !s:IsWindowValidToSplit()
289 |     return
290 |   endif
291 |   let lotr_winnr = bufwinnr('__LOTR__')
292 | 
293 |   if &filetype == 'lotr'
294 |     let in_lotr = 1
295 |   else
296 |     let in_lotr = 0
297 |     let s:lotr_regs = LOTR_Regs()
298 |     let prevwinnr = winnr()
299 |     execute lotr_winnr . 'wincmd w'
300 |   endif
301 | 
302 |   let lazyredraw_save = &lazyredraw
303 |   set lazyredraw
304 |   let eventignore_save = &eventignore
305 |   set eventignore=all
306 | 
307 |   setlocal modifiable
308 | 
309 |   silent %delete _
310 | 
311 |   call s:PrintRegs()
312 | 
313 |   setlocal nomodifiable
314 | 
315 |   let &lazyredraw  = lazyredraw_save
316 |   let &eventignore = eventignore_save
317 | 
318 |   if !in_lotr
319 |     execute prevwinnr . 'wincmd w'
320 |   endif
321 | endfunction
322 | 
323 | function! s:PrintRegs() "{{{2
324 |   call setline(1, s:lotr_regs)
325 | endfunction
326 | 
327 | " User Actions {{{1
328 | 
329 | " Helper Functions {{{1
330 | 
331 | function! s:CleanUp() "{{{2
332 |   silent autocmd! LOTR_AutoCmds
333 |   unlet s:is_maximized
334 |   " unlet s:compare_typeinfo
335 | endfunction
336 | 
337 | function! s:QuitIfOnlyWindow() "{{{2
338 |   " Before quitting Vim, delete the LOTR buffer so that
339 |   " the '0 mark is correctly set to the previous buffer.
340 |   if winbufnr(2) == -1
341 |     " Check if there is more than one tab page
342 |     if tabpagenr('$') == 1
343 |       bdelete
344 |       quit
345 |     else
346 |       close
347 |     endif
348 |   endif
349 | endfunction
350 | 
351 | function! s:AutoUpdate() " {{{2
352 |   " Don't do anything if LOTR is not open or if we're in the LOTR window
353 |   let lotr_winnr = bufwinnr('__LOTR__')
354 |   if lotr_winnr == -1
355 |     return
356 |   endif
357 |   let pos = getpos('.')
358 |   call s:RenderContent()
359 |   call setpos('.', pos)
360 | endfunction
361 | 
362 | function! s:IsWindowValidToSplit() " {{{2
363 |   " Error if we try to split command window
364 |   " Returns 1 if we should proceed to open LOTR window.
365 |   " TODO: if we are in the command or some other invalid window,
366 |   " first move to a 'good' window for the splitting?
367 |   if exists("*getcmdwintype") && getcmdwintype() != ""
368 |     echomsg "Cannot open LOTR from the command window"
369 |     return 0
370 |   elseif bufname('%') == "[Command Line]"
371 |     echomsg "Cannot open LOTR from the command window"
372 |     return 0
373 |   endif
374 |   return 1
375 | endfunction
376 | 
377 | " Maps {{{1
378 | nnoremap <plug>LOTRToggle :LOTRToggle<cr>
379 | 
380 | if g:lotr_map_keys && ! hasmapto('<plug>LOTRToggle')
381 |   nmap <leader>cr <plug>LOTRToggle
382 | endif
383 | 
384 | " Commands {{{1
385 | command! -bar -nargs=0 LOTRToggle        call s:ToggleWindow()
386 | command! -bar -nargs=0 LOTROpen          call s:OpenWindow()
387 | command! -bar -nargs=0 LOTRClose         call s:CloseWindow()
388 | 
389 | " Modeline {{{1
390 | " vim: ts=8 sw=2 sts=2 et foldenable foldmethod=marker foldcolumn=1
391 | 


--------------------------------------------------------------------------------
/syntax/lotr.vim:
--------------------------------------------------------------------------------
 1 | " Vim syntax plugin.
 2 | " Language:	LOTR - Lord of the Regs
 3 | " Maintainer:	Barry Arthur <barry.arthur@gmail.com>
 4 | " Version:	0.1
 5 | " Description:	Persistent view of Vim :registers
 6 | " Last Change:	2014-12-26
 7 | " License:	Vim License (see :help license)
 8 | " Location:	syntax/lotr.vim
 9 | " Website:	https://github.com/dahu/lotr
10 | "
11 | " See lotr.txt for help. This can be accessed by doing:
12 | "
13 | " :helptags ~/.vim/doc
14 | " :help lotr
15 | 
16 | " Quit when a (custom) syntax file was already loaded
17 | if exists("b:current_syntax")
18 |   finish
19 | endif
20 | 
21 | " Allow use of line continuation.
22 | let s:save_cpo = &cpo
23 | set cpo&vim
24 | 
25 | syn match lotrRegSpecial  "^[-"*+/]"
26 | syn match lotrRegNumbered "^[0-9]"
27 | syn match lotrRegLettered "^[a-z]"
28 | syn match lotrYankStacked "^ [0-9]\|^[1-9][0-9]\+"
29 | syn match lotrNewline     "\^J"
30 | 
31 | hi def link lotrRegSpecial	Constant
32 | hi def link lotrRegNumbered	Special
33 | hi def link lotrRegLettered	Identifier
34 | hi def link lotrYankStacked	Function
35 | hi def link lotrNewline		NonText
36 | 
37 | let b:current_syntax = "lotr"
38 | 
39 | let &cpo = s:save_cpo
40 | unlet s:save_cpo
41 | 
42 | " Template From: https://github.com/dahu/Area-41/
43 | " vim: set sw=2 sts=2 et fdm=marker:
44 | 


--------------------------------------------------------------------------------