├── .gitignore
├── README.md
└── csv-to-xml_v3.xsl


/.gitignore:
--------------------------------------------------------------------------------
1 | *.class
2 | 
3 | # Package Files #
4 | *.jar
5 | *.war
6 | *.ear
7 | 


--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
 1 | csv-tools
 2 | =========
 3 | 
 4 | Tools for working with CSV files.
 5 | 
 6 | At the moment just csv-to-xml_v3.xsl which is an XSLT 2.0 Stylesheet for transforming CSV files to XML.
 7 | 
 8 | How to use
 9 | ==========
10 | You need to supply the $pathToCSV parameter to the transformation to
11 | instruct it on where to find your CSV file when you run the transform.
12 | To run the Transform you must set 'main' as the initial template.
13 | 
14 | 
15 | Example using Saxon:
16 | 
17 | java -jar saxonhe-9.3.0.4-j.jar pathToCSV=/tmp/a.csv -xsl:csv-to-xml_v3.xsl -it:main -o:/tmp/a.xml
18 | 
19 | The above transforms the file /tmp/a.csv to the file /tmp/a.xml
20 | 


--------------------------------------------------------------------------------
/csv-to-xml_v3.xsl:
--------------------------------------------------------------------------------
 1 | <?xml version="1.0" encoding="UTF-8"?>
 2 | <!--
 3 | 	This is a modified work from The National Archives
 4 | 	based on an original work by Andrew Welch.
 5 | 	This could be considered version 3 of Andrew's work
 6 | 
 7 | 	Andrews Original Intro
 8 | 	======================
 9 | 
10 | 	A CSV to XML transform
11 | 	Version 2
12 | 	Andrew Welch
13 | 	http://andrewjwelch.com
14 | 	
15 | 	Modify or supply the $pathToCSV parameter and run the transform
16 | 	using "main" as the initial template.
17 | 	
18 | 	For bug reports or modification requests contact me at andrew.j.welch@gmail.com
19 | 
20 | 	
21 | 	Modification by the National Archives
22 | 	=====================================
23 | 
24 | 	** Modified so output is UTF-8 declared. Adam Retter 2011-11-17
25 | 	** Modified to terminate processing if the input file cannot be found. Adam Retter 2011-11-17 
26 | 	** Modified so that pathToCSV parameter is mandatory. Adam Retter 2011-12-08
27 | 	** Modified to work on CSV files that have either Unix (LF) or Windows (CRLF) line endings. Adam Retter 2011-12-08
28 | 	** Modified to skip empty row in-case of trailing line ending. Adam Retter 2011-12-08
29 | -->
30 |   		
31 | <xsl:stylesheet version="2.0"
32 | 	xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
33 | 	xmlns:xs="http://www.w3.org/2001/XMLSchema"
34 | 	xmlns:fn="fn"
35 | 	exclude-result-prefixes="xs fn">
36 | 
37 | 	<xsl:output method="xml" omit-xml-declaration="no" byte-order-mark="no" media-type="application/xml" version="1.0" indent="yes" encoding="UTF-8"/>
38 | 	
39 | 	<!-- e.g. file:///c:/csv.csv -->
40 | 	<xsl:param name="pathToCSV" as="xs:string"/>
41 | 	
42 | 	<xsl:function name="fn:getTokens" as="xs:string+">
43 | 		<xsl:param name="str" as="xs:string"/>
44 | 			<xsl:analyze-string select="concat($str, ',')" regex='(("[^"]*")+|[^,]*),'>
45 | 				<xsl:matching-substring>
46 | 					<xsl:sequence select='replace(regex-group(1), "^""|""$|("")""", "$1")'/>
47 | 				</xsl:matching-substring>
48 | 			</xsl:analyze-string>
49 | 	</xsl:function>
50 | 	
51 | 	<xsl:template match="/" name="main">
52 | 		<xsl:choose>
53 | 			<xsl:when test="unparsed-text-available($pathToCSV)">
54 | 				<xsl:variable name="csv" select="unparsed-text($pathToCSV)"/>
55 | 				<xsl:variable name="lines" select="tokenize($csv, '(&#xa;)|(&#xd;&#xa;)')" as="xs:string+"/>
56 | 				<xsl:variable name="elemNames" select="fn:getTokens($lines[1])" as="xs:string+"/>
57 | 				<root>
58 | 					<xsl:for-each select="$lines[position() > 1][. != '']">
59 | 						<row>
60 | 							<xsl:variable name="lineItems" select="fn:getTokens(.)" as="xs:string+"/>
61 | 	
62 | 							<xsl:for-each select="$elemNames">
63 | 								<xsl:variable name="pos" select="position()"/>
64 | 								<elem name="{.}">
65 | 									<xsl:value-of select="$lineItems[$pos]"/>
66 | 								</elem>
67 | 							</xsl:for-each>
68 | 						</row>
69 | 					</xsl:for-each>
70 | 				</root>
71 | 			</xsl:when>
72 | 			<xsl:otherwise>
73 | 				<xsl:message terminate="yes">
74 | 					<xsl:text>Cannot locate : </xsl:text><xsl:value-of select="$pathToCSV"/>
75 | 				</xsl:message>
76 | 			</xsl:otherwise>
77 | 		</xsl:choose>
78 | 	</xsl:template>
79 | 
80 | </xsl:stylesheet>
81 | 


--------------------------------------------------------------------------------