├── bitmaps
    └── togglebg.png
├── README.mkd
├── doc
    ├── tags
    └── solarized.txt
├── autoload
    └── togglebg.vim
└── colors
    └── solarized.vim


/bitmaps/togglebg.png:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/frankier/neovim-colors-solarized-truecolor-only/HEAD/bitmaps/togglebg.png


--------------------------------------------------------------------------------
/README.mkd:
--------------------------------------------------------------------------------
 1 | This is a version of https://github.com/altercation/vim-colors-solarized
 2 | modified to always use true color (24 bit rgb). This means it will work with
 3 | neovim with the following:
 4 | 
 5 |     set termguicolors
 6 |     set background=light " or dark
 7 |     colorscheme solarized
 8 | 
 9 | Normally this wouldn't work with neovim (as of writing) since `gui_running` is always false during initialisation.
10 | 
11 | For more info see the original.
12 | 
13 | All above + it fixes the SignColumn issue referenced here: https://github.com/neomake/neomake/issues/6
14 | 


--------------------------------------------------------------------------------
/doc/tags:
--------------------------------------------------------------------------------
 1 | 'solarized_bold'	solarized.txt	/*'solarized_bold'*
 2 | 'solarized_contrast'	solarized.txt	/*'solarized_contrast'*
 3 | 'solarized_degrade'	solarized.txt	/*'solarized_degrade'*
 4 | 'solarized_hitrail'	solarized.txt	/*'solarized_hitrail'*
 5 | 'solarized_italic'	solarized.txt	/*'solarized_italic'*
 6 | 'solarized_menu'	solarized.txt	/*'solarized_menu'*
 7 | 'solarized_termcolors'	solarized.txt	/*'solarized_termcolors'*
 8 | 'solarized_termtrans'	solarized.txt	/*'solarized_termtrans'*
 9 | 'solarized_underline'	solarized.txt	/*'solarized_underline'*
10 | 'solarized_visibility'	solarized.txt	/*'solarized_visibility'*
11 | before	solarized.txt	/*before*
12 | solarized	solarized.txt	/*solarized*
13 | solarized-colors	solarized.txt	/*solarized-colors*
14 | solarized-colorscheme	solarized.txt	/*solarized-colorscheme*
15 | solarized-help	solarized.txt	/*solarized-help*
16 | solarized-install	solarized.txt	/*solarized-install*
17 | solarized-menu	solarized.txt	/*solarized-menu*
18 | solarized-options	solarized.txt	/*solarized-options*
19 | solarized-term	solarized.txt	/*solarized-term*
20 | solarized-togglebg	solarized.txt	/*solarized-togglebg*
21 | solarized.vim	solarized.txt	/*solarized.vim*
22 | toggle-background	solarized.txt	/*toggle-background*
23 | toggle-bg	solarized.txt	/*toggle-bg*
24 | togglebg	solarized.txt	/*togglebg*
25 | urxvt	solarized.txt	/*urxvt*
26 | vim-colors-solarized	solarized.txt	/*vim-colors-solarized*
27 | without	solarized.txt	/*without*
28 | 


--------------------------------------------------------------------------------
/autoload/togglebg.vim:
--------------------------------------------------------------------------------
 1 | " Toggle Background
 2 | " Modified:     2011 Apr 29
 3 | " Maintainer:   Ethan Schoonover
 4 | " License:      OSI approved MIT license
 5 | 
 6 | if exists("g:loaded_togglebg")
 7 |     finish
 8 | endif
 9 | let g:loaded_togglebg = 1
10 | 
11 | " noremap is a bit misleading here if you are unused to vim mapping.
12 | " in fact, there is remapping, but only of script locally defined remaps, in 
13 | " this case <SID>TogBG. The <script> argument modifies the noremap scope in 
14 | " this regard (and the noremenu below).
15 | nnoremap <unique> <script> <Plug>ToggleBackground <SID>TogBG
16 | inoremap <unique> <script> <Plug>ToggleBackground <ESC><SID>TogBG<ESC>a
17 | vnoremap <unique> <script> <Plug>ToggleBackground <ESC><SID>TogBG<ESC>gv
18 | nnoremenu <script> Window.Toggle\ Background <SID>TogBG
19 | inoremenu <script> Window.Toggle\ Background <ESC><SID>TogBG<ESC>a
20 | vnoremenu <script> Window.Toggle\ Background <ESC><SID>TogBG<ESC>gv
21 | tmenu Window.Toggle\ Background Toggle light and dark background modes
22 | nnoremenu <script> ToolBar.togglebg <SID>TogBG
23 | inoremenu <script> ToolBar.togglebg <ESC><SID>TogBG<ESC>a
24 | vnoremenu <script> ToolBar.togglebg <ESC><SID>TogBG<ESC>gv
25 | tmenu ToolBar.togglebg Toggle light and dark background modes
26 | noremap <SID>TogBG  :call <SID>TogBG()<CR>
27 | 
28 | function! s:TogBG()
29 |     let &background = ( &background == "dark"? "light" : "dark" )
30 |     if exists("g:colors_name")
31 |         exe "colorscheme " . g:colors_name
32 |     endif
33 | endfunction
34 | 
35 | if !exists(":ToggleBG")
36 |     command ToggleBG :call s:TogBG()
37 | endif
38 | 
39 | function! ToggleBackground()
40 |     echo "Please update your ToggleBackground mapping. ':help togglebg' for information."
41 | endfunction
42 | 
43 | function! togglebg#map(mapActivation)
44 |     try
45 |         exe "silent! nmap <unique> ".a:mapActivation." <Plug>ToggleBackground"
46 |         exe "silent! imap <unique> ".a:mapActivation." <Plug>ToggleBackground"
47 |         exe "silent! vmap <unique> ".a:mapActivation." <Plug>ToggleBackground"
48 |     finally
49 |         return 0
50 |     endtry
51 | endfunction
52 | 
53 | if !exists("no_plugin_maps") && !hasmapto('<Plug>ToggleBackground')
54 |     call togglebg#map("<F5>")
55 | endif
56 | 


--------------------------------------------------------------------------------
/doc/solarized.txt:
--------------------------------------------------------------------------------
  1 | *solarized.vim* for Vim version 7.3 or newer. Modified: 2011 May 05
  2 | 
  3 | 
  4 | 		Solarized Vim Colorscheme by Ethan Schoonover ~
  5 | 
  6 | Solarized Colorscheme					   *solarized*
  7 | 							   *solarized-help*
  8 | 							   *solarized-colors*
  9 | 							   *solarized-colorscheme*
 10 | 							   *vim-colors-solarized*
 11 | 
 12 | Solarized is a carefully designed selective contrast colorscheme with dual
 13 | light and dark modes that runs in both GUI, 256 and 16 color modes.
 14 | 
 15 | See the homepage at http://ethanschoonover.com/solarized for screenshots and 
 16 | details.
 17 | 
 18 | 0. Install				|solarized-install|
 19 | 1. Solarized Menu			|solarized-menu|
 20 | 2. Options				|solarized-options|
 21 | 3. Toggle Background			|solarized-togglebg|
 22 | 4. Terminal Issues			|solarized-term|
 23 | 
 24 | ==============================================================================
 25 | 0. Install						*solarized-install*
 26 | 
 27 | Note: I recommend using Tim Pope's pathogen plugin to install this 
 28 | colorscheme. See https://github.com/tpope/vim-pathogen . If you've installed 
 29 | pathogen properly you can install Solarized with the following commands, 
 30 | followed by the .vimrc configuration below.
 31 | 
 32 | 	$ cd ~/.vim/bundle
 33 | 	$ git clone https://github.com/altercation/vim-colors-solarized.git
 34 | 
 35 | If you aren't using pathogen, you can use the following three steps to install 
 36 | Solarized:
 37 | 
 38 | 1.  Download the solarized distribution (available on the homepage above)
 39 |     and unarchive the file.
 40 | 
 41 | 2.  Move `solarized.vim` to your `.vim/colors` directory.
 42 | 
 43 | 3.  Move each of the files in each subdirectories to the corresponding .vim
 44 |     subdirectory (e.g. autoload/togglebg.vim goes into your .vim/autoload
 45 |     directory as .vim/autoload/togglebg.vim).
 46 | 
 47 | 
 48 | After installation, place the following lines in your .vimrc:
 49 | 
 50 | 	syntax enable
 51 | 	set background=dark
 52 | 	colorscheme solarized
 53 | 
 54 | or, for the light background mode of Solarized:
 55 | 
 56 | 	syntax enable
 57 | 	set background=light
 58 | 	colorscheme solarized
 59 | 
 60 | ==============================================================================
 61 | 1. Solarized Menu					*solarized-menu*
 62 | 
 63 | Solarized makes available a menu when used in Vim GUI mode (gvim, macvim).  
 64 | This menu includes many of the options detailed below so that you can test out 
 65 | different values quickly without modifying your .vimrc file. If you wish to 
 66 | turn off this menu permanently, simply place the following line in your .vimrc 
 67 | above the "colorscheme solarized" line.
 68 | 
 69 | 	let g:solarized_menu=0
 70 | 
 71 | ==============================================================================
 72 | 2. Toggle Background					*solarized-togglebg*
 73 | 							*toggle-bg* *togglebg*
 74 | 							*toggle-background*
 75 | 
 76 | Solarized comes with Toggle Background, a simple plugin to switch between 
 77 | light and dark background modes and reset the colorscheme. This is most useful 
 78 | for colorschemes that support both light and dark modes and in terminals or 
 79 | gui vim windows where the background will be properly set.
 80 | 
 81 | Toggle Background can be accessed by:
 82 | 
 83 |     * the Solarized menu (in Vim gui mode)
 84 |     * the Window menu (in Vim gui mode, even if the Solarized menu is off)
 85 |     * the "yin/yang" toolbar button (in Vim gui mode)
 86 |     * the default mapping of <F5>
 87 |     * custom key mapping you set in your .vimrc (see below)
 88 |     * command line via ":ToggleBG" (no quotes)
 89 | 
 90 | Toggle Background starts with a default mapping to function key <F5>. If you 
 91 | are already using this in a mapping, Toggle Background will not map itself to 
 92 | a default and you will have to map it manually in your .vimrc file, or 
 93 | remove/change your existing <F5> mapping to another value. To customize the 
 94 | keyboard mapping in your .vimrc file, use the following line, changing the 
 95 | "<F5>" value to the key or key combination you wish to use:
 96 | 
 97 | 	call togglebg#map("<F5>")
 98 | 
 99 | Note that you'll want to use a single function key or equivalent if you want 
100 | the plugin to work in all modes (normal, insert, visual).
101 | 
102 | When using the plugin during normal, visual, or insert mode, there should be 
103 | no interruption in workflow. However, if you activate the plugin during 
104 | REPLACE mode, you will switch to standard insert mode (you will leave the 
105 | overwrite replace mode).
106 | 
107 | ==============================================================================
108 | 3. Solarized Terminal Issues				*solarized-term*
109 | 
110 | If you are going to use Solarized in Terminal mode (i.e. not in a GUI version 
111 | like gvim or macvim), **please please please** consider setting your terminal 
112 | emulator's colorscheme to used the Solarized palette. I've included palettes 
113 | for some popular terminal emulator as well as Xdefaults in the official 
114 | Solarized download available from the Solarized homepage listed at the top of 
115 | this help document. If you use Solarized *without* these colors, Solarized 
116 | will need to be told to degrade its colorscheme to a set compatible with the 
117 | limited 256 terminal palette (whereas by using the terminal's 16 ansi color 
118 | values, you can set the correct, specific values for the Solarized palette).
119 | 
120 | If you do use the custom terminal colors, solarized.vim should work out of 
121 | the box for you. If you are using a terminal emulator that supports 256 
122 | colors and don't want to use the custom Solarized terminal colors, you will 
123 | need to use the degraded 256 colorscheme. To do so, simply add the following 
124 | line *before* the `colorschem solarized` line:
125 | 
126 |     let g:solarized_termcolors=256
127 | 
128 | Again, I recommend just changing your terminal colors to Solarized values 
129 | either manually or via one of the many terminal schemes available for import.
130 | 
131 | ==============================================================================
132 | 4. Solarized Options					*solarized-options*
133 | 
134 | 
135 | AUTOGENERATE OPTIONS
136 | 
137 | You can easily modify and experiment with Solarized display options using the 
138 | Solarized menu when using Vim in gui mode. Once you have things set to your 
139 | liking, you can autogenerate the current option list in a format ready for 
140 | insertion into your .vimrc file using the Solarized menu "Autogenerate 
141 | Options" command or at the command line with:
142 | 
143 |     :SolarizedOptions
144 | 
145 | 
146 | OPTION LIST
147 | 
148 | Set these in your vimrc file prior to calling the colorscheme.
149 | 
150 | option name               default     optional
151 | ------------------------------------------------
152 | g:solarized_termcolors=   16      |   256
153 | g:solarized_termtrans =   0       |   1
154 | g:solarized_degrade   =   0       |   1
155 | g:solarized_bold      =   1       |   0
156 | g:solarized_underline =   1       |   0
157 | g:solarized_italic    =   1       |   0
158 | g:solarized_contrast  =   "normal"|   "high" or "low"
159 | g:solarized_visibility=   "normal"|   "high" or "low"
160 | g:solarized_hitrail   =   0       |   1
161 | g:solarized_menu      =   1       |   0
162 | ------------------------------------------------
163 | 
164 | 
165 | OPTION DETAILS
166 | 
167 | ------------------------------------------------
168 | g:solarized_termcolors=   256     |   16		*'solarized_termcolors'*
169 | ------------------------------------------------
170 | The most important option if you are using vim in terminal (non gui) mode!
171 | This tells Solarized to use the 256 degraded color mode if running in a 256
172 | color capable terminal.  Otherwise, if set to `16` it will use the terminal
173 | emulators colorscheme (best option as long as you've set the emulators colors
174 | to the Solarized palette).
175 | 
176 | If you are going to use Solarized in Terminal mode (i.e. not in a GUI
177 | version like gvim or macvim), **please please please** consider setting your
178 | terminal emulator's colorscheme to used the Solarized palette. I've included
179 | palettes for some popular terminal emulator as well as Xdefaults in the
180 | official Solarized download available from:
181 | http://ethanschoonover.com/solarized . If you use Solarized without these
182 | colors, Solarized will by default use an approximate set of 256 colors.  It
183 | isn't bad looking and has been extensively tweaked, but it's still not quite
184 | the real thing.
185 | 
186 | ------------------------------------------------
187 | g:solarized_termtrans =   0       |   1			*'solarized_termtrans'*
188 | ------------------------------------------------
189 | If you use a terminal emulator with a transparent background and Solarized
190 | isn't displaying the background color transparently, set this to 1 and
191 | Solarized will use the default (transparent) background of the terminal
192 | emulator. *urxvt* required this in my testing; iTerm2 did not.
193 | 
194 | Note that on Mac OS X Terminal.app, solarized_termtrans is set to 1 by 
195 | default as this is almost always the best option. The only exception to this 
196 | is if the working terminfo file supports 256 colors (xterm-256color).
197 | 
198 | ------------------------------------------------
199 | g:solarized_degrade   =   0       |   1			*'solarized_degrade'*
200 | ------------------------------------------------
201 | For test purposes only; forces Solarized to use the 256 degraded color mode
202 | to test the approximate color values for accuracy.
203 | 
204 | ------------------------------------------------
205 | g:solarized_bold      =   1       |   0			*'solarized_bold'*
206 | ------------------------------------------------
207 | ------------------------------------------------
208 | g:solarized_underline =   1       |   0			*'solarized_underline'*
209 | ------------------------------------------------
210 | ------------------------------------------------
211 | g:solarized_italic    =   1       |   0			*'solarized_italic'*
212 | ------------------------------------------------
213 | If you wish to stop Solarized from displaying bold, underlined or
214 | italicized typefaces, simply assign a zero value to the appropriate
215 | variable, for example: `let g:solarized_italic=0`
216 | 
217 | ------------------------------------------------
218 | g:solarized_contrast  =   "normal"|   "high" or "low"	*'solarized_contrast'*
219 | ------------------------------------------------
220 | Stick with normal! It's been carefully tested. Setting this option to high
221 | or low does use the same Solarized palette but simply shifts some values up
222 | or down in order to expand or compress the tonal range displayed.
223 | 
224 | ------------------------------------------------
225 | g:solarized_visibility =  "normal"|   "high" or "low" *'solarized_visibility'*
226 | ------------------------------------------------
227 | Special characters such as trailing whitespace, tabs, newlines, when 
228 | displayed using ":set list" can be set to one of three levels depending on 
229 | your needs.
230 | 
231 | ------------------------------------------------
232 | g:solarized_hitrail   =   0       |   1			*'solarized_hitrail'*
233 | ------------------------------------------------
234 | Visibility can make listchar entities more visible, but if one has set 
235 | cursorline on, these same listchar values standout somewhat less due to the 
236 | background color of the cursorline. g:solarized_hitrail enables highlighting 
237 | of trailing spaces (only one of the listchar types, but a particularly 
238 | important one) while in the cursoline in a different manner in order to make 
239 | them more visible. This may not work consistently as Solarized is using 
240 | a pattern match than can be overridden by a more encompassing syntax-native 
241 | match such as a comment line.
242 | 
243 | 
244 | ------------------------------------------------
245 | g:solarized_menu       =  1       |   0			*'solarized_menu'*
246 | ------------------------------------------------
247 | Solarized includes a menu providing access to several of the above
248 | display related options, including contrast and visibility. This allows
249 | for an easy method of testing different values quickly before settling
250 | on a final assignment for your .vimrc. If you wish to turn off this menu,
251 | assign g:solarized_menu a value of 0.
252 | 
253 | 
254 |  vim:tw=78:noet:ts=8:ft=help:norl:
255 | 


--------------------------------------------------------------------------------
/colors/solarized.vim:
--------------------------------------------------------------------------------
  1 | " Name:     Solarized vim colorscheme
  2 | " Author:   Ethan Schoonover <es@ethanschoonover.com>
  3 | " URL:      http://ethanschoonover.com/solarized
  4 | "           (see this url for latest release & screenshots)
  5 | " License:  OSI approved MIT license (see end of this file)
  6 | " Created:  In the middle of the night
  7 | " Modified: 2011 May 05
  8 | "
  9 | " Usage "{{{
 10 | "
 11 | " ---------------------------------------------------------------------
 12 | " ABOUT:
 13 | " ---------------------------------------------------------------------
 14 | " Solarized is a carefully designed selective contrast colorscheme with dual
 15 | " light and dark modes that runs in both GUI, 256 and 16 color modes.
 16 | "
 17 | " See the homepage above for screenshots and details.
 18 | "
 19 | " ---------------------------------------------------------------------
 20 | " OPTIONS:
 21 | " ---------------------------------------------------------------------
 22 | " See the "solarized.txt" help file included with this colorscheme (in the 
 23 | " "doc" subdirectory) for information on options, usage, the Toggle Background 
 24 | " function and more. If you have already installed Solarized, this is available 
 25 | " from the Solarized menu and command line as ":help solarized"
 26 | "
 27 | " ---------------------------------------------------------------------
 28 | " INSTALLATION:
 29 | " ---------------------------------------------------------------------
 30 | " Two options for installation: manual or pathogen
 31 | "
 32 | " MANUAL INSTALLATION OPTION:
 33 | " ---------------------------------------------------------------------
 34 | "
 35 | " 1.  Download the solarized distribution (available on the homepage above)
 36 | "     and unarchive the file.
 37 | " 2.  Move `solarized.vim` to your `.vim/colors` directory.
 38 | " 3.  Move each of the files in each subdirectories to the corresponding .vim
 39 | "     subdirectory (e.g. autoload/togglebg.vim goes into your .vim/autoload 
 40 | "     directory as .vim/autoload/togglebg.vim).
 41 | "
 42 | " RECOMMENDED PATHOGEN INSTALLATION OPTION:
 43 | " ---------------------------------------------------------------------
 44 | "
 45 | " 1.  Download and install Tim Pope's Pathogen from:
 46 | "     https://github.com/tpope/vim-pathogen
 47 | "
 48 | " 2.  Next, move or clone the `vim-colors-solarized` directory so that it is
 49 | "     a subdirectory of the `.vim/bundle` directory.
 50 | "
 51 | "     a. **clone with git:**
 52 | "
 53 | "       $ cd ~/.vim/bundle
 54 | "       $ git clone git://github.com/altercation/vim-colors-solarized.git
 55 | "
 56 | "     b. **or move manually into the pathogen bundle directory:**
 57 | "         In the parent directory of vim-colors-solarized:
 58 | "
 59 | "         $ mv vim-colors-solarized ~/.vim/bundle/
 60 | "
 61 | " MODIFY VIMRC:
 62 | "
 63 | " After either Option 1 or Option 2 above, put the following two lines in your
 64 | " .vimrc:
 65 | "
 66 | "     syntax enable
 67 | "     set background=dark
 68 | "     colorscheme solarized
 69 | "
 70 | " or, for the light background mode of Solarized:
 71 | "
 72 | "     syntax enable
 73 | "     set background=light
 74 | "     colorscheme solarized
 75 | "
 76 | " I like to have a different background in GUI and terminal modes, so I can use
 77 | " the following if-then. However, I find vim's background autodetection to be
 78 | " pretty good and, at least with MacVim, I can leave this background value
 79 | " assignment out entirely and get the same results.
 80 | "
 81 | "     if has('gui_running')
 82 | "       set background=light
 83 | "     else
 84 | "       set background=dark
 85 | "     endif
 86 | "
 87 | " See the Solarized homepage at http://ethanschoonover.com/solarized for
 88 | " screenshots which will help you select either the light or dark background.
 89 | "
 90 | " ---------------------------------------------------------------------
 91 | " COLOR VALUES
 92 | " ---------------------------------------------------------------------
 93 | " Download palettes and files from: http://ethanschoonover.com/solarized
 94 | "
 95 | " L\*a\*b values are canonical (White D65, Reference D50), other values are
 96 | " matched in sRGB space.
 97 | "
 98 | " SOLARIZED HEX     16/8 TERMCOL  XTERM/HEX   L*A*B      sRGB        HSB
 99 | " --------- ------- ---- -------  ----------- ---------- ----------- -----------
100 | " base03    #002b36  8/4 brblack  234 #1c1c1c 15 -12 -12   0  43  54 193 100  21
101 | " base02    #073642  0/4 black    235 #262626 20 -12 -12   7  54  66 192  90  26
102 | " base01    #586e75 10/7 brgreen  240 #4e4e4e 45 -07 -07  88 110 117 194  25  46
103 | " base00    #657b83 11/7 bryellow 241 #585858 50 -07 -07 101 123 131 195  23  51
104 | " base0     #839496 12/6 brblue   244 #808080 60 -06 -03 131 148 150 186  13  59
105 | " base1     #93a1a1 14/4 brcyan   245 #8a8a8a 65 -05 -02 147 161 161 180   9  63
106 | " base2     #eee8d5  7/7 white    254 #d7d7af 92 -00  10 238 232 213  44  11  93
107 | " base3     #fdf6e3 15/7 brwhite  230 #ffffd7 97  00  10 253 246 227  44  10  99
108 | " yellow    #b58900  3/3 yellow   136 #af8700 60  10  65 181 137   0  45 100  71
109 | " orange    #cb4b16  9/3 brred    166 #d75f00 50  50  55 203  75  22  18  89  80
110 | " red       #dc322f  1/1 red      160 #d70000 50  65  45 220  50  47   1  79  86
111 | " magenta   #d33682  5/5 magenta  125 #af005f 50  65 -05 211  54 130 331  74  83
112 | " violet    #6c71c4 13/5 brmagenta 61 #5f5faf 50  15 -45 108 113 196 237  45  77
113 | " blue      #268bd2  4/4 blue      33 #0087ff 55 -10 -45  38 139 210 205  82  82
114 | " cyan      #2aa198  6/6 cyan      37 #00afaf 60 -35 -05  42 161 152 175  74  63
115 | " green     #859900  2/2 green     64 #5f8700 60 -20  65 133 153   0  68 100  60
116 | "
117 | " ---------------------------------------------------------------------
118 | " COLORSCHEME HACKING
119 | " ---------------------------------------------------------------------
120 | "
121 | " Useful commands for testing colorschemes:
122 | " :source $VIMRUNTIME/syntax/hitest.vim
123 | " :help highlight-groups
124 | " :help cterm-colors
125 | " :help group-name
126 | "
127 | " Useful links for developing colorschemes:
128 | " http://www.vim.org/scripts/script.php?script_id=2937
129 | " http://vimcasts.org/episodes/creating-colorschemes-for-vim/
130 | " http://www.frexx.de/xterm-256-notes/"
131 | "
132 | " }}}
133 | " Environment Specific Overrides "{{{
134 | " Allow or disallow certain features based on current terminal emulator or 
135 | " environment.
136 | 
137 | let s:terminal_italic=1
138 | 
139 | " }}}
140 | " Default option values"{{{
141 | " ---------------------------------------------------------------------
142 | " s:options_list is used to autogenerate a list of all non-default options 
143 | " using "call SolarizedOptions()" or with the "Generate .vimrc commands" 
144 | " Solarized menu option. See the "Menus" section below for the function itself.
145 | let s:options_list=[
146 |             \'" this block of commands has been autogenerated by solarized.vim and',
147 |             \'" includes the current, non-default Solarized option values.',
148 |             \'" To use, place these commands in your .vimrc file (replacing any',
149 |             \'" existing colorscheme commands). See also ":help solarized"',
150 |             \'',
151 |             \'" ------------------------------------------------------------------',
152 |             \'" Solarized Colorscheme Config',
153 |             \'" ------------------------------------------------------------------',
154 |             \]
155 | let s:colorscheme_list=[
156 |             \'syntax enable',
157 |             \'set background='.&background,
158 |             \'colorscheme solarized',
159 |             \]
160 | let s:defaults_list=[
161 |             \'" ------------------------------------------------------------------',
162 |             \'',
163 |             \'" The following items are available options, but do not need to be',
164 |             \'" included in your .vimrc as they are currently set to their defaults.',
165 |             \''
166 |             \]
167 | let s:lazycat_list=[
168 |             \'" lazy method of appending this onto your .vimrc ":w! >> ~/.vimrc"',
169 |             \'" ------------------------------------------------------------------',
170 |             \]
171 | 
172 | function! s:SetOption(name,default)
173 |     if type(a:default) == type(0)
174 |         let l:wrap=''
175 |         let l:ewrap=''
176 |     else
177 |         let l:wrap='"'
178 |         let l:ewrap='\"'
179 |     endif
180 |     if !exists("g:solarized_".a:name) || g:solarized_{a:name}==a:default
181 |         exe 'let g:solarized_'.a:name.'='.l:wrap.a:default.l:wrap.'"'
182 |         exe 'call add(s:defaults_list, "\" let g:solarized_'.a:name.'='.l:ewrap.g:solarized_{a:name}.l:ewrap.'")'
183 |     else
184 |         exe 'call add(s:options_list,  "let g:solarized_'.a:name.'='.l:ewrap.g:solarized_{a:name}.l:ewrap.'    \"default value is '.a:default.'")'
185 |     endif
186 | endfunction
187 | 
188 | if ($TERM_PROGRAM ==? "apple_terminal" && &t_Co < 256)
189 |     let s:solarized_termtrans_default = 1
190 | else
191 |     let s:solarized_termtrans_default = 0
192 | endif
193 | call s:SetOption("termtrans",s:solarized_termtrans_default)
194 | call s:SetOption("degrade",0)
195 | call s:SetOption("bold",1)
196 | call s:SetOption("underline",1)
197 | call s:SetOption("italic",1) " note that we need to override this later if the terminal doesn't support
198 | call s:SetOption("termcolors",16)
199 | call s:SetOption("contrast","normal")
200 | call s:SetOption("visibility","normal")
201 | call s:SetOption("diffmode","normal")
202 | call s:SetOption("hitrail",0)
203 | call s:SetOption("menu",1)
204 | 
205 | "}}}
206 | " Colorscheme initialization "{{{
207 | " ---------------------------------------------------------------------
208 | hi clear
209 | if exists("syntax_on")
210 |   syntax reset
211 | endif
212 | let colors_name = "solarized"
213 | 
214 | "}}}
215 | " GUI & CSApprox hexadecimal palettes"{{{
216 | " ---------------------------------------------------------------------
217 | "
218 | " Set both gui and terminal color values in separate conditional statements
219 | " Due to possibility that CSApprox is running (though I suppose we could just
220 | " leave the hex values out entirely in that case and include only cterm colors)
221 | " We also check to see if user has set solarized (force use of the
222 | " neutral gray monotone palette component)
223 | if (g:solarized_degrade == 0)
224 |     let s:vmode       = "gui"
225 |     let s:base03      = "#002b36"
226 |     let s:base02      = "#073642"
227 |     let s:base01      = "#586e75"
228 |     let s:base00      = "#657b83"
229 |     let s:base0       = "#839496"
230 |     let s:base1       = "#93a1a1"
231 |     let s:base2       = "#eee8d5"
232 |     let s:base3       = "#fdf6e3"
233 |     let s:yellow      = "#b58900"
234 |     let s:orange      = "#cb4b16"
235 |     let s:red         = "#dc322f"
236 |     let s:magenta     = "#d33682"
237 |     let s:violet      = "#6c71c4"
238 |     let s:blue        = "#268bd2"
239 |     let s:cyan        = "#2aa198"
240 |     "let s:green       = "#859900" "original
241 |     let s:green       = "#719e07" "experimental
242 | elseif (g:solarized_degrade == 1)
243 |     " These colors are identical to the 256 color mode. They may be viewed
244 |     " while in gui mode via "let g:solarized_degrade=1", though this is not
245 |     " recommened and is for testing only.
246 |     let s:vmode       = "gui"
247 |     let s:base03      = "#1c1c1c"
248 |     let s:base02      = "#262626"
249 |     let s:base01      = "#4e4e4e"
250 |     let s:base00      = "#585858"
251 |     let s:base0       = "#808080"
252 |     let s:base1       = "#8a8a8a"
253 |     let s:base2       = "#d7d7af"
254 |     let s:base3       = "#ffffd7"
255 |     let s:yellow      = "#af8700"
256 |     let s:orange      = "#d75f00"
257 |     let s:red         = "#af0000"
258 |     let s:magenta     = "#af005f"
259 |     let s:violet      = "#5f5faf"
260 |     let s:blue        = "#0087ff"
261 |     let s:cyan        = "#00afaf"
262 |     let s:green       = "#5f8700"
263 | endif
264 | "}}}
265 | " Formatting options and null values for passthrough effect "{{{
266 | " ---------------------------------------------------------------------
267 |     let s:none            = "NONE"
268 |     let s:none            = "NONE"
269 |     let s:t_none          = "NONE"
270 |     let s:n               = "NONE"
271 |     let s:c               = ",undercurl"
272 |     let s:r               = ",reverse"
273 |     let s:s               = ",standout"
274 |     let s:ou              = ""
275 |     let s:ob              = ""
276 | "}}}
277 | " Background value based on termtrans setting "{{{
278 | " ---------------------------------------------------------------------
279 | if (g:solarized_termtrans == 0)
280 |     let s:back        = s:base03
281 | else
282 |     let s:back        = "NONE"
283 | endif
284 | "}}}
285 | " Alternate light scheme "{{{
286 | " ---------------------------------------------------------------------
287 | if &background == "light"
288 |     let s:temp03      = s:base03
289 |     let s:temp02      = s:base02
290 |     let s:temp01      = s:base01
291 |     let s:temp00      = s:base00
292 |     let s:base03      = s:base3
293 |     let s:base02      = s:base2
294 |     let s:base01      = s:base1
295 |     let s:base00      = s:base0
296 |     let s:base0       = s:temp00
297 |     let s:base1       = s:temp01
298 |     let s:base2       = s:temp02
299 |     let s:base3       = s:temp03
300 |     if (s:back != "NONE")
301 |         let s:back    = s:base03
302 |     endif
303 | endif
304 | "}}}
305 | " Optional contrast schemes "{{{
306 | " ---------------------------------------------------------------------
307 | if g:solarized_contrast == "high"
308 |     let s:base01      = s:base00
309 |     let s:base00      = s:base0
310 |     let s:base0       = s:base1
311 |     let s:base1       = s:base2
312 |     let s:base2       = s:base3
313 |     let s:back        = s:back
314 | endif
315 | if g:solarized_contrast == "low"
316 |     let s:back        = s:base02
317 |     let s:ou          = ",underline"
318 | endif
319 | "}}}
320 | " Overrides dependent on user specified values and environment "{{{
321 | " ---------------------------------------------------------------------
322 | if (g:solarized_bold == 0 || &t_Co == 8 )
323 |     let s:b           = ""
324 |     let s:bb          = ",bold"
325 | else
326 |     let s:b           = ",bold"
327 |     let s:bb          = ""
328 | endif
329 | 
330 | if g:solarized_underline == 0
331 |     let s:u           = ""
332 | else
333 |     let s:u           = ",underline"
334 | endif
335 | 
336 | if g:solarized_italic == 0 || s:terminal_italic == 0
337 |     let s:i           = ""
338 | else
339 |     let s:i           = ",italic"
340 | endif
341 | "}}}
342 | " Highlighting primitives"{{{
343 | " ---------------------------------------------------------------------
344 | 
345 | exe "let s:bg_none      = ' ".s:vmode."bg=".s:none   ."'"
346 | exe "let s:bg_back      = ' ".s:vmode."bg=".s:back   ."'"
347 | exe "let s:bg_base03    = ' ".s:vmode."bg=".s:base03 ."'"
348 | exe "let s:bg_base02    = ' ".s:vmode."bg=".s:base02 ."'"
349 | exe "let s:bg_base01    = ' ".s:vmode."bg=".s:base01 ."'"
350 | exe "let s:bg_base00    = ' ".s:vmode."bg=".s:base00 ."'"
351 | exe "let s:bg_base0     = ' ".s:vmode."bg=".s:base0  ."'"
352 | exe "let s:bg_base1     = ' ".s:vmode."bg=".s:base1  ."'"
353 | exe "let s:bg_base2     = ' ".s:vmode."bg=".s:base2  ."'"
354 | exe "let s:bg_base3     = ' ".s:vmode."bg=".s:base3  ."'"
355 | exe "let s:bg_green     = ' ".s:vmode."bg=".s:green  ."'"
356 | exe "let s:bg_yellow    = ' ".s:vmode."bg=".s:yellow ."'"
357 | exe "let s:bg_orange    = ' ".s:vmode."bg=".s:orange ."'"
358 | exe "let s:bg_red       = ' ".s:vmode."bg=".s:red    ."'"
359 | exe "let s:bg_magenta   = ' ".s:vmode."bg=".s:magenta."'"
360 | exe "let s:bg_violet    = ' ".s:vmode."bg=".s:violet ."'"
361 | exe "let s:bg_blue      = ' ".s:vmode."bg=".s:blue   ."'"
362 | exe "let s:bg_cyan      = ' ".s:vmode."bg=".s:cyan   ."'"
363 | 
364 | exe "let s:fg_none      = ' ".s:vmode."fg=".s:none   ."'"
365 | exe "let s:fg_back      = ' ".s:vmode."fg=".s:back   ."'"
366 | exe "let s:fg_base03    = ' ".s:vmode."fg=".s:base03 ."'"
367 | exe "let s:fg_base02    = ' ".s:vmode."fg=".s:base02 ."'"
368 | exe "let s:fg_base01    = ' ".s:vmode."fg=".s:base01 ."'"
369 | exe "let s:fg_base00    = ' ".s:vmode."fg=".s:base00 ."'"
370 | exe "let s:fg_base0     = ' ".s:vmode."fg=".s:base0  ."'"
371 | exe "let s:fg_base1     = ' ".s:vmode."fg=".s:base1  ."'"
372 | exe "let s:fg_base2     = ' ".s:vmode."fg=".s:base2  ."'"
373 | exe "let s:fg_base3     = ' ".s:vmode."fg=".s:base3  ."'"
374 | exe "let s:fg_green     = ' ".s:vmode."fg=".s:green  ."'"
375 | exe "let s:fg_yellow    = ' ".s:vmode."fg=".s:yellow ."'"
376 | exe "let s:fg_orange    = ' ".s:vmode."fg=".s:orange ."'"
377 | exe "let s:fg_red       = ' ".s:vmode."fg=".s:red    ."'"
378 | exe "let s:fg_magenta   = ' ".s:vmode."fg=".s:magenta."'"
379 | exe "let s:fg_violet    = ' ".s:vmode."fg=".s:violet ."'"
380 | exe "let s:fg_blue      = ' ".s:vmode."fg=".s:blue   ."'"
381 | exe "let s:fg_cyan      = ' ".s:vmode."fg=".s:cyan   ."'"
382 | 
383 | exe "let s:fmt_none     = ' ".s:vmode."=NONE".          " term=NONE".    "'"
384 | exe "let s:fmt_bold     = ' ".s:vmode."=NONE".s:b.      " term=NONE".s:b."'"
385 | exe "let s:fmt_bldi     = ' ".s:vmode."=NONE".s:b.      " term=NONE".s:b."'"
386 | exe "let s:fmt_undr     = ' ".s:vmode."=NONE".s:u.      " term=NONE".s:u."'"
387 | exe "let s:fmt_undb     = ' ".s:vmode."=NONE".s:u.s:b.  " term=NONE".s:u.s:b."'"
388 | exe "let s:fmt_undi     = ' ".s:vmode."=NONE".s:u.      " term=NONE".s:u."'"
389 | exe "let s:fmt_uopt     = ' ".s:vmode."=NONE".s:ou.     " term=NONE".s:ou."'"
390 | exe "let s:fmt_curl     = ' ".s:vmode."=NONE".s:c.      " term=NONE".s:c."'"
391 | exe "let s:fmt_ital     = ' ".s:vmode."=NONE".s:i.      " term=NONE".s:i."'"
392 | exe "let s:fmt_stnd     = ' ".s:vmode."=NONE".s:s.      " term=NONE".s:s."'"
393 | exe "let s:fmt_revr     = ' ".s:vmode."=NONE".s:r.      " term=NONE".s:r."'"
394 | exe "let s:fmt_revb     = ' ".s:vmode."=NONE".s:r.s:b.  " term=NONE".s:r.s:b."'"
395 | " revbb (reverse bold for bright colors) is only set to actual bold in low 
396 | " color terminals (t_co=8, such as OS X Terminal.app) and should only be used 
397 | " with colors 8-15.
398 | exe "let s:fmt_revbb    = ' ".s:vmode."=NONE".s:r.s:bb.   " term=NONE".s:r.s:bb."'"
399 | exe "let s:fmt_revbbu   = ' ".s:vmode."=NONE".s:r.s:bb.s:u." term=NONE".s:r.s:bb.s:u."'"
400 | 
401 | exe "let s:sp_none      = ' guisp=".s:none   ."'"
402 | exe "let s:sp_back      = ' guisp=".s:back   ."'"
403 | exe "let s:sp_base03    = ' guisp=".s:base03 ."'"
404 | exe "let s:sp_base02    = ' guisp=".s:base02 ."'"
405 | exe "let s:sp_base01    = ' guisp=".s:base01 ."'"
406 | exe "let s:sp_base00    = ' guisp=".s:base00 ."'"
407 | exe "let s:sp_base0     = ' guisp=".s:base0  ."'"
408 | exe "let s:sp_base1     = ' guisp=".s:base1  ."'"
409 | exe "let s:sp_base2     = ' guisp=".s:base2  ."'"
410 | exe "let s:sp_base3     = ' guisp=".s:base3  ."'"
411 | exe "let s:sp_green     = ' guisp=".s:green  ."'"
412 | exe "let s:sp_yellow    = ' guisp=".s:yellow ."'"
413 | exe "let s:sp_orange    = ' guisp=".s:orange ."'"
414 | exe "let s:sp_red       = ' guisp=".s:red    ."'"
415 | exe "let s:sp_magenta   = ' guisp=".s:magenta."'"
416 | exe "let s:sp_violet    = ' guisp=".s:violet ."'"
417 | exe "let s:sp_blue      = ' guisp=".s:blue   ."'"
418 | exe "let s:sp_cyan      = ' guisp=".s:cyan   ."'"
419 | 
420 | "}}}
421 | " Basic highlighting"{{{
422 | " ---------------------------------------------------------------------
423 | " note that link syntax to avoid duplicate configuration doesn't work with the
424 | " exe compiled formats
425 | 
426 | exe "hi! Normal"         .s:fmt_none   .s:fg_base0  .s:bg_back
427 | 
428 | exe "hi! Comment"        .s:fmt_ital   .s:fg_base01 .s:bg_none
429 | "       *Comment         any comment
430 | 
431 | exe "hi! Constant"       .s:fmt_none   .s:fg_cyan   .s:bg_none
432 | "       *Constant        any constant
433 | "        String          a string constant: "this is a string"
434 | "        Character       a character constant: 'c', '\n'
435 | "        Number          a number constant: 234, 0xff
436 | "        Boolean         a boolean constant: TRUE, false
437 | "        Float           a floating point constant: 2.3e10
438 | 
439 | exe "hi! Identifier"     .s:fmt_none   .s:fg_blue   .s:bg_none
440 | "       *Identifier      any variable name
441 | "        Function        function name (also: methods for classes)
442 | "
443 | exe "hi! Statement"      .s:fmt_none   .s:fg_green  .s:bg_none
444 | "       *Statement       any statement
445 | "        Conditional     if, then, else, endif, switch, etc.
446 | "        Repeat          for, do, while, etc.
447 | "        Label           case, default, etc.
448 | "        Operator        "sizeof", "+", "*", etc.
449 | "        Keyword         any other keyword
450 | "        Exception       try, catch, throw
451 | 
452 | exe "hi! PreProc"        .s:fmt_none   .s:fg_orange .s:bg_none
453 | "       *PreProc         generic Preprocessor
454 | "        Include         preprocessor #include
455 | "        Define          preprocessor #define
456 | "        Macro           same as Define
457 | "        PreCondit       preprocessor #if, #else, #endif, etc.
458 | 
459 | exe "hi! Type"           .s:fmt_none   .s:fg_yellow .s:bg_none
460 | "       *Type            int, long, char, etc.
461 | "        StorageClass    static, register, volatile, etc.
462 | "        Structure       struct, union, enum, etc.
463 | "        Typedef         A typedef
464 | 
465 | exe "hi! Special"        .s:fmt_none   .s:fg_red    .s:bg_none
466 | "       *Special         any special symbol
467 | "        SpecialChar     special character in a constant
468 | "        Tag             you can use CTRL-] on this
469 | "        Delimiter       character that needs attention
470 | "        SpecialComment  special things inside a comment
471 | "        Debug           debugging statements
472 | 
473 | exe "hi! Underlined"     .s:fmt_none   .s:fg_violet .s:bg_none
474 | "       *Underlined      text that stands out, HTML links
475 | 
476 | exe "hi! Ignore"         .s:fmt_none   .s:fg_none   .s:bg_none
477 | "       *Ignore          left blank, hidden  |hl-Ignore|
478 | 
479 | exe "hi! Error"          .s:fmt_bold   .s:fg_red    .s:bg_none
480 | "       *Error           any erroneous construct
481 | 
482 | exe "hi! Todo"           .s:fmt_bold   .s:fg_magenta.s:bg_none
483 | "       *Todo            anything that needs extra attention; mostly the
484 | "                        keywords TODO FIXME and XXX
485 | "
486 | "}}}
487 | " Extended highlighting "{{{
488 | " ---------------------------------------------------------------------
489 | if      (g:solarized_visibility=="high")
490 |     exe "hi! SpecialKey" .s:fmt_revr   .s:fg_red    .s:bg_none
491 |     exe "hi! NonText"    .s:fmt_bold   .s:fg_red    .s:bg_none
492 | elseif  (g:solarized_visibility=="low")
493 |     exe "hi! SpecialKey" .s:fmt_bold   .s:fg_base02 .s:bg_none
494 |     exe "hi! NonText"    .s:fmt_bold   .s:fg_base02 .s:bg_none
495 | else
496 |     exe "hi! SpecialKey" .s:fmt_bold   .s:fg_base00 .s:bg_base02
497 |     exe "hi! NonText"    .s:fmt_bold   .s:fg_base00 .s:bg_none
498 | endif
499 | exe "hi! StatusLine"     .s:fmt_none   .s:fg_base1  .s:bg_base02 .s:fmt_revbb
500 | exe "hi! StatusLineNC"   .s:fmt_none   .s:fg_base00 .s:bg_base02 .s:fmt_revbb
501 | exe "hi! Visual"         .s:fmt_none   .s:fg_base01 .s:bg_base03 .s:fmt_revbb
502 | exe "hi! Directory"      .s:fmt_none   .s:fg_blue   .s:bg_none
503 | exe "hi! ErrorMsg"       .s:fmt_revr   .s:fg_red    .s:bg_none
504 | exe "hi! IncSearch"      .s:fmt_stnd   .s:fg_orange .s:bg_none
505 | exe "hi! Search"         .s:fmt_revr   .s:fg_yellow .s:bg_none
506 | exe "hi! MoreMsg"        .s:fmt_none   .s:fg_blue   .s:bg_none
507 | exe "hi! ModeMsg"        .s:fmt_none   .s:fg_blue   .s:bg_none
508 | exe "hi! LineNr"         .s:fmt_none   .s:fg_base01 .s:bg_base02
509 | exe "hi! Question"       .s:fmt_bold   .s:fg_cyan   .s:bg_none
510 | exe "hi! VertSplit"  .s:fmt_none   .s:fg_base00 .s:bg_base00
511 | exe "hi! Title"          .s:fmt_bold   .s:fg_orange .s:bg_none
512 | exe "hi! VisualNOS"      .s:fmt_stnd   .s:fg_none   .s:bg_base02 .s:fmt_revbb
513 | exe "hi! WarningMsg"     .s:fmt_bold   .s:fg_red    .s:bg_none
514 | exe "hi! WildMenu"       .s:fmt_none   .s:fg_base2  .s:bg_base02 .s:fmt_revbb
515 | exe "hi! Folded"         .s:fmt_undb   .s:fg_base0  .s:bg_base02  .s:sp_base03
516 | exe "hi! FoldColumn"     .s:fmt_none   .s:fg_base0  .s:bg_base02
517 | if      (g:solarized_diffmode=="high")
518 | exe "hi! DiffAdd"        .s:fmt_revr   .s:fg_green  .s:bg_none
519 | exe "hi! DiffChange"     .s:fmt_revr   .s:fg_yellow .s:bg_none
520 | exe "hi! DiffDelete"     .s:fmt_revr   .s:fg_red    .s:bg_none
521 | exe "hi! DiffText"       .s:fmt_revr   .s:fg_blue   .s:bg_none
522 | elseif  (g:solarized_diffmode=="low")
523 | exe "hi! DiffAdd"        .s:fmt_undr   .s:fg_green  .s:bg_none   .s:sp_green
524 | exe "hi! DiffChange"     .s:fmt_undr   .s:fg_yellow .s:bg_none   .s:sp_yellow
525 | exe "hi! DiffDelete"     .s:fmt_bold   .s:fg_red    .s:bg_none
526 | exe "hi! DiffText"       .s:fmt_undr   .s:fg_blue   .s:bg_none   .s:sp_blue
527 | else " normal
528 | exe "hi! DiffAdd"        .s:fmt_bold   .s:fg_green  .s:bg_base02 .s:sp_green
529 | exe "hi! DiffChange"     .s:fmt_bold   .s:fg_yellow .s:bg_base02 .s:sp_yellow
530 | exe "hi! DiffDelete"     .s:fmt_bold   .s:fg_red    .s:bg_base02
531 | exe "hi! DiffText"       .s:fmt_bold   .s:fg_blue   .s:bg_base02 .s:sp_blue
532 | endif
533 | hi! link SignColumn LineNr
534 | exe "hi! Conceal"        .s:fmt_none   .s:fg_blue   .s:bg_none
535 | exe "hi! SpellBad"       .s:fmt_curl   .s:fg_none   .s:bg_none    .s:sp_red
536 | exe "hi! SpellCap"       .s:fmt_curl   .s:fg_none   .s:bg_none    .s:sp_violet
537 | exe "hi! SpellRare"      .s:fmt_curl   .s:fg_none   .s:bg_none    .s:sp_cyan
538 | exe "hi! SpellLocal"     .s:fmt_curl   .s:fg_none   .s:bg_none    .s:sp_yellow
539 | exe "hi! Pmenu"          .s:fmt_none   .s:fg_base0  .s:bg_base02  .s:fmt_revbb
540 | exe "hi! PmenuSel"       .s:fmt_none   .s:fg_base01 .s:bg_base2   .s:fmt_revbb
541 | exe "hi! PmenuSbar"      .s:fmt_none   .s:fg_base2  .s:bg_base0   .s:fmt_revbb
542 | exe "hi! PmenuThumb"     .s:fmt_none   .s:fg_base0  .s:bg_base03  .s:fmt_revbb
543 | exe "hi! TabLine"        .s:fmt_undr   .s:fg_base0  .s:bg_base02  .s:sp_base0
544 | exe "hi! TabLineFill"    .s:fmt_undr   .s:fg_base0  .s:bg_base02  .s:sp_base0
545 | exe "hi! TabLineSel"     .s:fmt_undr   .s:fg_base01 .s:bg_base2   .s:sp_base0  .s:fmt_revbbu
546 | exe "hi! CursorColumn"   .s:fmt_none   .s:fg_none   .s:bg_base02
547 | exe "hi! CursorLine"     .s:fmt_uopt   .s:fg_none   .s:bg_base02  .s:sp_base1
548 | exe "hi! CursorLineNr"   .s:fmt_uopt   .s:fg_none   .s:bg_base02
549 | exe "hi! ColorColumn"    .s:fmt_none   .s:fg_none   .s:bg_base02
550 | exe "hi! Cursor"         .s:fmt_none   .s:fg_base03 .s:bg_base0
551 | hi! link lCursor Cursor
552 | exe "hi! MatchParen"     .s:fmt_bold   .s:fg_red    .s:bg_base01
553 | 
554 | "}}}
555 | " vim syntax highlighting "{{{
556 | " ---------------------------------------------------------------------
557 | "exe "hi! vimLineComment" . s:fg_base01 .s:bg_none   .s:fmt_ital
558 | "hi! link vimComment Comment
559 | "hi! link vimLineComment Comment
560 | hi! link vimVar Identifier
561 | hi! link vimFunc Function
562 | hi! link vimUserFunc Function
563 | hi! link helpSpecial Special
564 | hi! link vimSet Normal
565 | hi! link vimSetEqual Normal
566 | exe "hi! vimCommentString"  .s:fmt_none    .s:fg_violet .s:bg_none
567 | exe "hi! vimCommand"        .s:fmt_none    .s:fg_yellow .s:bg_none
568 | exe "hi! vimCmdSep"         .s:fmt_bold    .s:fg_blue   .s:bg_none
569 | exe "hi! helpExample"       .s:fmt_none    .s:fg_base1  .s:bg_none
570 | exe "hi! helpOption"        .s:fmt_none    .s:fg_cyan   .s:bg_none
571 | exe "hi! helpNote"          .s:fmt_none    .s:fg_magenta.s:bg_none
572 | exe "hi! helpVim"           .s:fmt_none    .s:fg_magenta.s:bg_none
573 | exe "hi! helpHyperTextJump" .s:fmt_undr    .s:fg_blue   .s:bg_none
574 | exe "hi! helpHyperTextEntry".s:fmt_none    .s:fg_green  .s:bg_none
575 | exe "hi! vimIsCommand"      .s:fmt_none    .s:fg_base00 .s:bg_none
576 | exe "hi! vimSynMtchOpt"     .s:fmt_none    .s:fg_yellow .s:bg_none
577 | exe "hi! vimSynType"        .s:fmt_none    .s:fg_cyan   .s:bg_none
578 | exe "hi! vimHiLink"         .s:fmt_none    .s:fg_blue   .s:bg_none
579 | exe "hi! vimHiGroup"        .s:fmt_none    .s:fg_blue   .s:bg_none
580 | exe "hi! vimGroup"          .s:fmt_undb    .s:fg_blue   .s:bg_none
581 |  "}}}
582 | " diff highlighting "{{{
583 | " ---------------------------------------------------------------------
584 | hi! link diffAdded Statement
585 | hi! link diffLine Identifier
586 | "}}}
587 | " git & gitcommit highlighting "{{{
588 | "git
589 | "exe "hi! gitDateHeader"
590 | "exe "hi! gitIdentityHeader"
591 | "exe "hi! gitIdentityKeyword"
592 | "exe "hi! gitNotesHeader"
593 | "exe "hi! gitReflogHeader"
594 | "exe "hi! gitKeyword"
595 | "exe "hi! gitIdentity"
596 | "exe "hi! gitEmailDelimiter"
597 | "exe "hi! gitEmail"
598 | "exe "hi! gitDate"
599 | "exe "hi! gitMode"
600 | "exe "hi! gitHashAbbrev"
601 | "exe "hi! gitHash"
602 | "exe "hi! gitReflogMiddle"
603 | "exe "hi! gitReference"
604 | "exe "hi! gitStage"
605 | "exe "hi! gitType"
606 | "exe "hi! gitDiffAdded"
607 | "exe "hi! gitDiffRemoved"
608 | "gitcommit
609 | "exe "hi! gitcommitSummary"      
610 | exe "hi! gitcommitComment"      .s:fmt_ital     .s:fg_base01    .s:bg_none
611 | hi! link gitcommitUntracked gitcommitComment
612 | hi! link gitcommitDiscarded gitcommitComment
613 | hi! link gitcommitSelected  gitcommitComment
614 | exe "hi! gitcommitUnmerged"     .s:fmt_bold     .s:fg_green     .s:bg_none
615 | exe "hi! gitcommitOnBranch"     .s:fmt_bold     .s:fg_base01    .s:bg_none
616 | exe "hi! gitcommitBranch"       .s:fmt_bold     .s:fg_magenta   .s:bg_none
617 | hi! link gitcommitNoBranch gitcommitBranch
618 | exe "hi! gitcommitDiscardedType".s:fmt_none     .s:fg_red       .s:bg_none
619 | exe "hi! gitcommitSelectedType" .s:fmt_none     .s:fg_green     .s:bg_none
620 | "exe "hi! gitcommitUnmergedType"
621 | "exe "hi! gitcommitType"
622 | "exe "hi! gitcommitNoChanges"
623 | "exe "hi! gitcommitHeader"
624 | exe "hi! gitcommitHeader"       .s:fmt_none     .s:fg_base01    .s:bg_none
625 | exe "hi! gitcommitUntrackedFile".s:fmt_bold     .s:fg_cyan      .s:bg_none
626 | exe "hi! gitcommitDiscardedFile".s:fmt_bold     .s:fg_red       .s:bg_none
627 | exe "hi! gitcommitSelectedFile" .s:fmt_bold     .s:fg_green     .s:bg_none
628 | exe "hi! gitcommitUnmergedFile" .s:fmt_bold     .s:fg_yellow    .s:bg_none
629 | exe "hi! gitcommitFile"         .s:fmt_bold     .s:fg_base0     .s:bg_none
630 | hi! link gitcommitDiscardedArrow gitcommitDiscardedFile
631 | hi! link gitcommitSelectedArrow  gitcommitSelectedFile
632 | hi! link gitcommitUnmergedArrow  gitcommitUnmergedFile
633 | "exe "hi! gitcommitArrow"
634 | "exe "hi! gitcommitOverflow"
635 | "exe "hi! gitcommitBlank"
636 | " }}}
637 | " html highlighting "{{{
638 | " ---------------------------------------------------------------------
639 | exe "hi! htmlTag"           .s:fmt_none .s:fg_base01 .s:bg_none
640 | exe "hi! htmlEndTag"        .s:fmt_none .s:fg_base01 .s:bg_none
641 | exe "hi! htmlTagN"          .s:fmt_bold .s:fg_base1  .s:bg_none
642 | exe "hi! htmlTagName"       .s:fmt_bold .s:fg_blue   .s:bg_none
643 | exe "hi! htmlSpecialTagName".s:fmt_ital .s:fg_blue   .s:bg_none
644 | exe "hi! htmlArg"           .s:fmt_none .s:fg_base00 .s:bg_none
645 | exe "hi! javaScript"        .s:fmt_none .s:fg_yellow .s:bg_none
646 | "}}}
647 | " perl highlighting "{{{
648 | " ---------------------------------------------------------------------
649 | exe "hi! perlHereDoc"    . s:fg_base1  .s:bg_back   .s:fmt_none
650 | exe "hi! perlVarPlain"   . s:fg_yellow .s:bg_back   .s:fmt_none
651 | exe "hi! perlStatementFileDesc". s:fg_cyan.s:bg_back.s:fmt_none
652 | 
653 | "}}}
654 | " tex highlighting "{{{
655 | " ---------------------------------------------------------------------
656 | exe "hi! texStatement"   . s:fg_cyan   .s:bg_back   .s:fmt_none
657 | exe "hi! texMathZoneX"   . s:fg_yellow .s:bg_back   .s:fmt_none
658 | exe "hi! texMathMatcher" . s:fg_yellow .s:bg_back   .s:fmt_none
659 | exe "hi! texMathMatcher" . s:fg_yellow .s:bg_back   .s:fmt_none
660 | exe "hi! texRefLabel"    . s:fg_yellow .s:bg_back   .s:fmt_none
661 | "}}}
662 | " ruby highlighting "{{{
663 | " ---------------------------------------------------------------------
664 | exe "hi! rubyDefine"     . s:fg_base1  .s:bg_back   .s:fmt_bold
665 | "rubyInclude
666 | "rubySharpBang
667 | "rubyAccess
668 | "rubyPredefinedVariable
669 | "rubyBoolean
670 | "rubyClassVariable
671 | "rubyBeginEnd
672 | "rubyRepeatModifier
673 | "hi! link rubyArrayDelimiter    Special  " [ , , ]
674 | "rubyCurlyBlock  { , , }
675 | 
676 | "hi! link rubyClass             Keyword
677 | "hi! link rubyModule            Keyword
678 | "hi! link rubyKeyword           Keyword
679 | "hi! link rubyOperator          Operator
680 | "hi! link rubyIdentifier        Identifier
681 | "hi! link rubyInstanceVariable  Identifier
682 | "hi! link rubyGlobalVariable    Identifier
683 | "hi! link rubyClassVariable     Identifier
684 | "hi! link rubyConstant          Type
685 | "}}}
686 | " haskell syntax highlighting"{{{
687 | " ---------------------------------------------------------------------
688 | " For use with syntax/haskell.vim : Haskell Syntax File
689 | " http://www.vim.org/scripts/script.php?script_id=3034
690 | " See also Steffen Siering's github repository:
691 | " http://github.com/urso/dotrc/blob/master/vim/syntax/haskell.vim
692 | " ---------------------------------------------------------------------
693 | "
694 | " Treat True and False specially, see the plugin referenced above
695 | let hs_highlight_boolean=1
696 | " highlight delims, see the plugin referenced above
697 | let hs_highlight_delimiters=1
698 | 
699 | exe "hi! cPreCondit". s:fg_orange.s:bg_none   .s:fmt_none
700 | 
701 | exe "hi! VarId"    . s:fg_blue   .s:bg_none   .s:fmt_none
702 | exe "hi! ConId"    . s:fg_yellow .s:bg_none   .s:fmt_none
703 | exe "hi! hsImport" . s:fg_magenta.s:bg_none   .s:fmt_none
704 | exe "hi! hsString" . s:fg_base00 .s:bg_none   .s:fmt_none
705 | 
706 | exe "hi! hsStructure"        . s:fg_cyan   .s:bg_none   .s:fmt_none
707 | exe "hi! hs_hlFunctionName"  . s:fg_blue   .s:bg_none
708 | exe "hi! hsStatement"        . s:fg_cyan   .s:bg_none   .s:fmt_none
709 | exe "hi! hsImportLabel"      . s:fg_cyan   .s:bg_none   .s:fmt_none
710 | exe "hi! hs_OpFunctionName"  . s:fg_yellow .s:bg_none   .s:fmt_none
711 | exe "hi! hs_DeclareFunction" . s:fg_orange .s:bg_none   .s:fmt_none
712 | exe "hi! hsVarSym"           . s:fg_cyan   .s:bg_none   .s:fmt_none
713 | exe "hi! hsType"             . s:fg_yellow .s:bg_none   .s:fmt_none
714 | exe "hi! hsTypedef"          . s:fg_cyan   .s:bg_none   .s:fmt_none
715 | exe "hi! hsModuleName"       . s:fg_green  .s:bg_none   .s:fmt_undr
716 | exe "hi! hsModuleStartLabel" . s:fg_magenta.s:bg_none   .s:fmt_none
717 | hi! link hsImportParams      Delimiter
718 | hi! link hsDelimTypeExport   Delimiter
719 | hi! link hsModuleStartLabel  hsStructure
720 | hi! link hsModuleWhereLabel  hsModuleStartLabel
721 | 
722 | " following is for the haskell-conceal plugin
723 | " the first two items don't have an impact, but better safe
724 | exe "hi! hsNiceOperator"     . s:fg_cyan   .s:bg_none   .s:fmt_none
725 | exe "hi! hsniceoperator"     . s:fg_cyan   .s:bg_none   .s:fmt_none
726 | 
727 | "}}}
728 | " pandoc markdown syntax highlighting "{{{
729 | " ---------------------------------------------------------------------
730 | 
731 | "PandocHiLink pandocNormalBlock
732 | exe "hi! pandocTitleBlock"               .s:fg_blue   .s:bg_none   .s:fmt_none
733 | exe "hi! pandocTitleBlockTitle"          .s:fg_blue   .s:bg_none   .s:fmt_bold
734 | exe "hi! pandocTitleComment"             .s:fg_blue   .s:bg_none   .s:fmt_bold
735 | exe "hi! pandocComment"                  .s:fg_base01 .s:bg_none   .s:fmt_ital
736 | exe "hi! pandocVerbatimBlock"            .s:fg_yellow .s:bg_none   .s:fmt_none
737 | hi! link pandocVerbatimBlockDeep         pandocVerbatimBlock
738 | hi! link pandocCodeBlock                 pandocVerbatimBlock
739 | hi! link pandocCodeBlockDelim            pandocVerbatimBlock
740 | exe "hi! pandocBlockQuote"               .s:fg_blue   .s:bg_none   .s:fmt_none
741 | exe "hi! pandocBlockQuoteLeader1"        .s:fg_blue   .s:bg_none   .s:fmt_none
742 | exe "hi! pandocBlockQuoteLeader2"        .s:fg_cyan   .s:bg_none   .s:fmt_none
743 | exe "hi! pandocBlockQuoteLeader3"        .s:fg_yellow .s:bg_none   .s:fmt_none
744 | exe "hi! pandocBlockQuoteLeader4"        .s:fg_red    .s:bg_none   .s:fmt_none
745 | exe "hi! pandocBlockQuoteLeader5"        .s:fg_base0  .s:bg_none   .s:fmt_none
746 | exe "hi! pandocBlockQuoteLeader6"        .s:fg_base01 .s:bg_none   .s:fmt_none
747 | exe "hi! pandocListMarker"               .s:fg_magenta.s:bg_none   .s:fmt_none
748 | exe "hi! pandocListReference"            .s:fg_magenta.s:bg_none   .s:fmt_undr
749 | 
750 | " Definitions
751 | " ---------------------------------------------------------------------
752 | let s:fg_pdef = s:fg_violet
753 | exe "hi! pandocDefinitionBlock"              .s:fg_pdef  .s:bg_none  .s:fmt_none
754 | exe "hi! pandocDefinitionTerm"               .s:fg_pdef  .s:bg_none  .s:fmt_stnd
755 | exe "hi! pandocDefinitionIndctr"             .s:fg_pdef  .s:bg_none  .s:fmt_bold
756 | exe "hi! pandocEmphasisDefinition"           .s:fg_pdef  .s:bg_none  .s:fmt_ital
757 | exe "hi! pandocEmphasisNestedDefinition"     .s:fg_pdef  .s:bg_none  .s:fmt_bldi
758 | exe "hi! pandocStrongEmphasisDefinition"     .s:fg_pdef  .s:bg_none  .s:fmt_bold
759 | exe "hi! pandocStrongEmphasisNestedDefinition"   .s:fg_pdef.s:bg_none.s:fmt_bldi
760 | exe "hi! pandocStrongEmphasisEmphasisDefinition" .s:fg_pdef.s:bg_none.s:fmt_bldi
761 | exe "hi! pandocStrikeoutDefinition"          .s:fg_pdef  .s:bg_none  .s:fmt_revr
762 | exe "hi! pandocVerbatimInlineDefinition"     .s:fg_pdef  .s:bg_none  .s:fmt_none
763 | exe "hi! pandocSuperscriptDefinition"        .s:fg_pdef  .s:bg_none  .s:fmt_none
764 | exe "hi! pandocSubscriptDefinition"          .s:fg_pdef  .s:bg_none  .s:fmt_none
765 | 
766 | " Tables
767 | " ---------------------------------------------------------------------
768 | let s:fg_ptable = s:fg_blue
769 | exe "hi! pandocTable"                        .s:fg_ptable.s:bg_none  .s:fmt_none
770 | exe "hi! pandocTableStructure"               .s:fg_ptable.s:bg_none  .s:fmt_none
771 | hi! link pandocTableStructureTop             pandocTableStructre
772 | hi! link pandocTableStructureEnd             pandocTableStructre
773 | exe "hi! pandocTableZebraLight"              .s:fg_ptable.s:bg_base03.s:fmt_none
774 | exe "hi! pandocTableZebraDark"               .s:fg_ptable.s:bg_base02.s:fmt_none
775 | exe "hi! pandocEmphasisTable"                .s:fg_ptable.s:bg_none  .s:fmt_ital
776 | exe "hi! pandocEmphasisNestedTable"          .s:fg_ptable.s:bg_none  .s:fmt_bldi
777 | exe "hi! pandocStrongEmphasisTable"          .s:fg_ptable.s:bg_none  .s:fmt_bold
778 | exe "hi! pandocStrongEmphasisNestedTable"    .s:fg_ptable.s:bg_none  .s:fmt_bldi
779 | exe "hi! pandocStrongEmphasisEmphasisTable"  .s:fg_ptable.s:bg_none  .s:fmt_bldi
780 | exe "hi! pandocStrikeoutTable"               .s:fg_ptable.s:bg_none  .s:fmt_revr
781 | exe "hi! pandocVerbatimInlineTable"          .s:fg_ptable.s:bg_none  .s:fmt_none
782 | exe "hi! pandocSuperscriptTable"             .s:fg_ptable.s:bg_none  .s:fmt_none
783 | exe "hi! pandocSubscriptTable"               .s:fg_ptable.s:bg_none  .s:fmt_none
784 | 
785 | " Headings
786 | " ---------------------------------------------------------------------
787 | let s:fg_phead = s:fg_orange
788 | exe "hi! pandocHeading"                      .s:fg_phead .s:bg_none.s:fmt_bold
789 | exe "hi! pandocHeadingMarker"                .s:fg_yellow.s:bg_none.s:fmt_bold
790 | exe "hi! pandocEmphasisHeading"              .s:fg_phead .s:bg_none.s:fmt_bldi
791 | exe "hi! pandocEmphasisNestedHeading"        .s:fg_phead .s:bg_none.s:fmt_bldi
792 | exe "hi! pandocStrongEmphasisHeading"        .s:fg_phead .s:bg_none.s:fmt_bold
793 | exe "hi! pandocStrongEmphasisNestedHeading"  .s:fg_phead .s:bg_none.s:fmt_bldi
794 | exe "hi! pandocStrongEmphasisEmphasisHeading".s:fg_phead .s:bg_none.s:fmt_bldi
795 | exe "hi! pandocStrikeoutHeading"             .s:fg_phead .s:bg_none.s:fmt_revr
796 | exe "hi! pandocVerbatimInlineHeading"        .s:fg_phead .s:bg_none.s:fmt_bold
797 | exe "hi! pandocSuperscriptHeading"           .s:fg_phead .s:bg_none.s:fmt_bold
798 | exe "hi! pandocSubscriptHeading"             .s:fg_phead .s:bg_none.s:fmt_bold
799 | 
800 | " Links
801 | " ---------------------------------------------------------------------
802 | exe "hi! pandocLinkDelim"                .s:fg_base01 .s:bg_none   .s:fmt_none
803 | exe "hi! pandocLinkLabel"                .s:fg_blue   .s:bg_none   .s:fmt_undr
804 | exe "hi! pandocLinkText"                 .s:fg_blue   .s:bg_none   .s:fmt_undb
805 | exe "hi! pandocLinkURL"                  .s:fg_base00 .s:bg_none   .s:fmt_undr
806 | exe "hi! pandocLinkTitle"                .s:fg_base00 .s:bg_none   .s:fmt_undi
807 | exe "hi! pandocLinkTitleDelim"           .s:fg_base01 .s:bg_none   .s:fmt_undi   .s:sp_base00
808 | exe "hi! pandocLinkDefinition"           .s:fg_cyan   .s:bg_none   .s:fmt_undr   .s:sp_base00
809 | exe "hi! pandocLinkDefinitionID"         .s:fg_blue   .s:bg_none   .s:fmt_bold
810 | exe "hi! pandocImageCaption"             .s:fg_violet .s:bg_none   .s:fmt_undb
811 | exe "hi! pandocFootnoteLink"             .s:fg_green  .s:bg_none   .s:fmt_undr
812 | exe "hi! pandocFootnoteDefLink"          .s:fg_green  .s:bg_none   .s:fmt_bold
813 | exe "hi! pandocFootnoteInline"           .s:fg_green  .s:bg_none   .s:fmt_undb
814 | exe "hi! pandocFootnote"                 .s:fg_green  .s:bg_none   .s:fmt_none
815 | exe "hi! pandocCitationDelim"            .s:fg_magenta.s:bg_none   .s:fmt_none
816 | exe "hi! pandocCitation"                 .s:fg_magenta.s:bg_none   .s:fmt_none
817 | exe "hi! pandocCitationID"               .s:fg_magenta.s:bg_none   .s:fmt_undr
818 | exe "hi! pandocCitationRef"              .s:fg_magenta.s:bg_none   .s:fmt_none
819 | 
820 | " Main Styles
821 | " ---------------------------------------------------------------------
822 | exe "hi! pandocStyleDelim"               .s:fg_base01 .s:bg_none  .s:fmt_none
823 | exe "hi! pandocEmphasis"                 .s:fg_base0  .s:bg_none  .s:fmt_ital
824 | exe "hi! pandocEmphasisNested"           .s:fg_base0  .s:bg_none  .s:fmt_bldi
825 | exe "hi! pandocStrongEmphasis"           .s:fg_base0  .s:bg_none  .s:fmt_bold
826 | exe "hi! pandocStrongEmphasisNested"     .s:fg_base0  .s:bg_none  .s:fmt_bldi
827 | exe "hi! pandocStrongEmphasisEmphasis"   .s:fg_base0  .s:bg_none  .s:fmt_bldi
828 | exe "hi! pandocStrikeout"                .s:fg_base01 .s:bg_none  .s:fmt_revr
829 | exe "hi! pandocVerbatimInline"           .s:fg_yellow .s:bg_none  .s:fmt_none
830 | exe "hi! pandocSuperscript"              .s:fg_violet .s:bg_none  .s:fmt_none
831 | exe "hi! pandocSubscript"                .s:fg_violet .s:bg_none  .s:fmt_none
832 | 
833 | exe "hi! pandocRule"                     .s:fg_blue   .s:bg_none  .s:fmt_bold
834 | exe "hi! pandocRuleLine"                 .s:fg_blue   .s:bg_none  .s:fmt_bold
835 | exe "hi! pandocEscapePair"               .s:fg_red    .s:bg_none  .s:fmt_bold
836 | exe "hi! pandocCitationRef"              .s:fg_magenta.s:bg_none   .s:fmt_none
837 | exe "hi! pandocNonBreakingSpace"         . s:fg_red   .s:bg_none  .s:fmt_revr
838 | hi! link pandocEscapedCharacter          pandocEscapePair
839 | hi! link pandocLineBreak                 pandocEscapePair
840 | 
841 | " Embedded Code
842 | " ---------------------------------------------------------------------
843 | exe "hi! pandocMetadataDelim"            .s:fg_base01 .s:bg_none   .s:fmt_none
844 | exe "hi! pandocMetadata"                 .s:fg_blue   .s:bg_none   .s:fmt_none
845 | exe "hi! pandocMetadataKey"              .s:fg_blue   .s:bg_none   .s:fmt_none
846 | exe "hi! pandocMetadata"                 .s:fg_blue   .s:bg_none   .s:fmt_bold
847 | hi! link pandocMetadataTitle             pandocMetadata
848 | 
849 | "}}}
850 | " Utility autocommand "{{{
851 | " ---------------------------------------------------------------------
852 | " In cases where Solarized is initialized inside a terminal vim session and 
853 | " then transferred to a gui session via the command `:gui`, the gui vim process 
854 | " does not re-read the colorscheme (or .vimrc for that matter) so any `has_gui` 
855 | " related code that sets gui specific values isn't executed.
856 | "
857 | " Currently, Solarized sets only the cterm or gui values for the colorscheme 
858 | " depending on gui or terminal mode. It's possible that, if the following 
859 | " autocommand method is deemed excessively poor form, that approach will be 
860 | " used again and the autocommand below will be dropped.
861 | "
862 | " However it seems relatively benign in this case to include the autocommand 
863 | " here. It fires only in cases where vim is transferring from terminal to gui 
864 | " mode (detected with the script scope s:vmode variable). It also allows for 
865 | " other potential terminal customizations that might make gui mode suboptimal.
866 | "
867 | autocmd GUIEnter * if (s:vmode != "gui") | exe "colorscheme " . g:colors_name | endif
868 | "}}}
869 | " Highlight Trailing Space {{{
870 | " Experimental: Different highlight when on cursorline
871 | function! s:SolarizedHiTrail()
872 |     if g:solarized_hitrail==0
873 |         hi! clear solarizedTrailingSpace
874 |     else
875 |         syn match solarizedTrailingSpace "\s*$"
876 |         exe "hi! solarizedTrailingSpace " .s:fmt_undr .s:fg_red .s:bg_none .s:sp_red
877 |     endif
878 | endfunction  
879 | augroup SolarizedHiTrail
880 |     autocmd!
881 |     if g:solarized_hitrail==1
882 |         autocmd! Syntax * call s:SolarizedHiTrail()
883 |         autocmd! ColorScheme * if g:colors_name == "solarized" | call s:SolarizedHiTrail() | else | augroup! s:SolarizedHiTrail | endif
884 |     endif
885 | augroup END
886 | " }}}
887 | " Menus "{{{
888 | " ---------------------------------------------------------------------
889 | " Turn off Solarized menu by including the following assignment in your .vimrc:
890 | "
891 | "    let g:solarized_menu=0
892 | 
893 | function! s:SolarizedOptions()
894 |     new "new buffer
895 |     setf vim "vim filetype
896 |     let failed = append(0, s:defaults_list)
897 |     let failed = append(0, s:colorscheme_list)
898 |     let failed = append(0, s:options_list)
899 |     let failed = append(0, s:lazycat_list)
900 |     0 "jump back to the top
901 | endfunction
902 | if !exists(":SolarizedOptions")
903 |     command SolarizedOptions :call s:SolarizedOptions()
904 | endif
905 | 
906 | function! SolarizedMenu()
907 |     if exists("g:loaded_solarized_menu")
908 |         try
909 |             silent! aunmenu Solarized
910 |         endtry
911 |     endif
912 |     let g:loaded_solarized_menu = 1
913 | 
914 |     if g:colors_name == "solarized" && g:solarized_menu != 0
915 | 
916 |         amenu &Solarized.&Contrast.&Low\ Contrast        :let g:solarized_contrast="low"       \| colorscheme solarized<CR>
917 |         amenu &Solarized.&Contrast.&Normal\ Contrast     :let g:solarized_contrast="normal"    \| colorscheme solarized<CR>
918 |         amenu &Solarized.&Contrast.&High\ Contrast       :let g:solarized_contrast="high"      \| colorscheme solarized<CR>
919 |         an    &Solarized.&Contrast.-sep-                 <Nop>
920 |         amenu &Solarized.&Contrast.&Help:\ Contrast      :help 'solarized_contrast'<CR>
921 | 
922 |         amenu &Solarized.&Visibility.&Low\ Visibility    :let g:solarized_visibility="low"     \| colorscheme solarized<CR>
923 |         amenu &Solarized.&Visibility.&Normal\ Visibility :let g:solarized_visibility="normal"  \| colorscheme solarized<CR>
924 |         amenu &Solarized.&Visibility.&High\ Visibility   :let g:solarized_visibility="high"    \| colorscheme solarized<CR>
925 |         an    &Solarized.&Visibility.-sep-                 <Nop>
926 |         amenu &Solarized.&Visibility.&Help:\ Visibility    :help 'solarized_visibility'<CR>
927 | 
928 |         amenu &Solarized.&Background.&Toggle\ Background :ToggleBG<CR>
929 |         amenu &Solarized.&Background.&Dark\ Background   :set background=dark  \| colorscheme solarized<CR>
930 |         amenu &Solarized.&Background.&Light\ Background  :set background=light \| colorscheme solarized<CR>
931 |         an    &Solarized.&Background.-sep-               <Nop>
932 |         amenu &Solarized.&Background.&Help:\ ToggleBG     :help togglebg<CR>
933 | 
934 |         if g:solarized_bold==0 | let l:boldswitch="On" | else | let l:boldswitch="Off" | endif
935 |         exe "amenu &Solarized.&Styling.&Turn\\ Bold\\ ".l:boldswitch." :let g:solarized_bold=(abs(g:solarized_bold-1)) \\| colorscheme solarized<CR>"
936 |         if g:solarized_italic==0 | let l:italicswitch="On" | else | let l:italicswitch="Off" | endif
937 |         exe "amenu &Solarized.&Styling.&Turn\\ Italic\\ ".l:italicswitch." :let g:solarized_italic=(abs(g:solarized_italic-1)) \\| colorscheme solarized<CR>"
938 |         if g:solarized_underline==0 | let l:underlineswitch="On" | else | let l:underlineswitch="Off" | endif
939 |         exe "amenu &Solarized.&Styling.&Turn\\ Underline\\ ".l:underlineswitch." :let g:solarized_underline=(abs(g:solarized_underline-1)) \\| colorscheme solarized<CR>"
940 | 
941 |         amenu &Solarized.&Diff\ Mode.&Low\ Diff\ Mode    :let g:solarized_diffmode="low"     \| colorscheme solarized<CR>
942 |         amenu &Solarized.&Diff\ Mode.&Normal\ Diff\ Mode :let g:solarized_diffmode="normal"  \| colorscheme solarized<CR>
943 |         amenu &Solarized.&Diff\ Mode.&High\ Diff\ Mode   :let g:solarized_diffmode="high"    \| colorscheme solarized<CR>
944 | 
945 |         if g:solarized_hitrail==0 | let l:hitrailswitch="On" | else | let l:hitrailswitch="Off" | endif
946 |         exe "amenu &Solarized.&Experimental.&Turn\\ Highlight\\ Trailing\\ Spaces\\ ".l:hitrailswitch." :let g:solarized_hitrail=(abs(g:solarized_hitrail-1)) \\| colorscheme solarized<CR>"
947 |         an    &Solarized.&Experimental.-sep-               <Nop>
948 |         amenu &Solarized.&Experimental.&Help:\ HiTrail    :help 'solarized_hitrail'<CR>
949 | 
950 |         an    &Solarized.-sep1-                          <Nop>
951 | 
952 |         amenu &Solarized.&Autogenerate\ options          :SolarizedOptions<CR>
953 | 
954 |         an    &Solarized.-sep2-                          <Nop>
955 | 
956 |         amenu &Solarized.&Help.&Solarized\ Help          :help solarized<CR>
957 |         amenu &Solarized.&Help.&Toggle\ Background\ Help :help togglebg<CR>
958 |         amenu &Solarized.&Help.&Removing\ This\ Menu     :help solarized-menu<CR>
959 | 
960 |         an 9999.77 &Help.&Solarized\ Colorscheme         :help solarized<CR>
961 |         an 9999.78 &Help.&Toggle\ Background             :help togglebg<CR>
962 |         an 9999.79 &Help.-sep3-                          <Nop>
963 | 
964 |     endif
965 | endfunction
966 | 
967 | autocmd ColorScheme * if g:colors_name != "solarized" | silent! aunmenu Solarized | else | call SolarizedMenu() | endif
968 | 
969 | "}}}
970 | " License "{{{
971 | " ---------------------------------------------------------------------
972 | "
973 | " Copyright (c) 2011 Ethan Schoonover
974 | "
975 | " Permission is hereby granted, free of charge, to any person obtaining a copy
976 | " of this software and associated documentation files (the "Software"), to deal
977 | " in the Software without restriction, including without limitation the rights
978 | " to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
979 | " copies of the Software, and to permit persons to whom the Software is
980 | " furnished to do so, subject to the following conditions:
981 | "
982 | " The above copyright notice and this permission notice shall be included in
983 | " all copies or substantial portions of the Software.
984 | "
985 | " THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
986 | " IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
987 | " FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
988 | " AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
989 | " LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
990 | " OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
991 | " THE SOFTWARE.
992 | "
993 | " vim:foldmethod=marker:foldlevel=0
994 | "}}}
995 | 


--------------------------------------------------------------------------------