├── NEWS
├── README
├── TODO
└── plugin
    └── scmdiff.vim


/NEWS:
--------------------------------------------------------------------------------
 1 | 2008-09-20
 2 | * Changed the default diff key from C-d to <Leader>d (default would be \d)
 3 | 
 4 | 2008-09-03
 5 | * Add Enabled/Disabled messages when scmdiff is toggled
 6 | * Fix highlighting on error messages so subsequent messages aren't highlighted
 7 | 
 8 | 2008-08-25
 9 | * Move Highlight colors out of code so they can be customized by user in .vimrc
10 | 
11 | 2008-08-18
12 | * Initial support for mercurial auto-detection 
13 | 
14 | 2008-08-17
15 | * fix bug: Look for SCM directories based on path of file in current buffer, not on getcwd() 
16 | 
17 | 2008-08-15
18 | * Add auto-detection of svn, git, and cvs SCMs
19 | 
20 | 2008-08-10
21 | 
22 | * Make C-d a toggle to turn the diff on/off
23 | * Avoid deleting unrelated buffers when turning diff off
24 | * Autorefresh now works properly
25 | 


--------------------------------------------------------------------------------
/README:
--------------------------------------------------------------------------------
 1 | 
 2 | vim-scmdiff: A Vim script to show the differences from a base version in SCM.  
 3 | 
 4 | Supported SCMs:
 5 |   * CVS
 6 |   * SVN
 7 |   * GIT
 8 |   * Mercurial
 9 |   * Bitkeeper
10 | 
11 | Installation:
12 |   Copy the scmdiff.vim script to your vim plugin path ie: "~/.vim/plugin".   (system paths may vary)
13 | 
14 | Default commands:
15 |   \d Toggle diff view on/off
16 |   :D rev Difference between current and rev
17 | 
18 | This script is an evolution from the scripts posted at the following places:
19 |   http://tekrat.com/2008/02/21/vim-diff/
20 |   http://www.vim.org/scripts/script.php?script_id=2201
21 |   http://playground.audioscrobbler.com/jonty/scmdiff.vim
22 | 
23 | 


--------------------------------------------------------------------------------
/TODO:
--------------------------------------------------------------------------------
 1 | Bugs
 2 | 
 3 | * After exiting (:q) a buffer that has diff enabled, subsequent diffs appear to fail.
 4 | * Should restore options like 'wrap' to their original state when turning diff off
 5 | * winsaveview() and winrestview() require Vim 7.x. Autodetect and degrade gracefully.
 6 | 
 7 | Features
 8 | 
 9 | * Option to show side-by-side diff (ie. don't hide original buffer)
10 | * Make it easier to customize colors and commands
11 | * Add a refresh or enable an auto-update feature so diff highlighting changes as changes are made.
12 | 


--------------------------------------------------------------------------------
/plugin/scmdiff.vim:
--------------------------------------------------------------------------------
  1 | " Vim script to show file differences from a base version in SCM.
  2 | " Home: http://github.com/ghewgill/vim-scmdiff
  3 | 
  4 | " Default commands:
  5 | "   \d      Toggle diff view on/off
  6 | "   :D rev  Difference between current and rev
  7 | "
  8 | " You can change the highlighting by adding the following to your 
  9 | " .vimrc file and customizing as necessary.  (or just uncomment them here):
 10 | "   highlight DiffAdd ctermbg=DarkBlue ctermfg=white cterm=NONE
 11 | "   highlight DiffChange ctermbg=DarkBlue ctermfg=white cterm=NONE
 12 | "   highlight DiffText ctermbg=DarkBlue ctermfg=white cterm=underline
 13 | "   highlight DiffDelete ctermbg=red ctermfg=white
 14 | 
 15 | if exists("loadedScmDiff") || &cp
 16 |     finish
 17 | endif
 18 | 
 19 | let loadedScmDiff = 1
 20 | 
 21 | map <silent> <Leader>d :call <SID>scmToggle()<CR>
 22 | noremap <unique> <script> <plug>Dh :call <SID>scmDiff("h")<CR>
 23 | com! -bar -nargs=? D :call s:scmDiff(<f-args>)
 24 | 
 25 | let g:scmDiffRev = ''
 26 | 
 27 | function! s:scmToggle()
 28 | 
 29 |     if exists('b:scmDiffOn') && b:scmDiffOn == 1
 30 |         let b:scmDiffOn = 0
 31 |         set nodiff
 32 |         exe 'bdelete ' . b:scmDiffTmpfile
 33 |         echohl DiffDelete | echon "scmdiff Disabled" | echohl None
 34 |     else
 35 |         call s:scmDiff()
 36 |         if exists('b:scmDiffOn') && b:scmDiffOn == 1
 37 |             echohl DiffAdd | echon "scmdiff Enabled" | echohl None
 38 |         endif
 39 |     endif
 40 | 
 41 | endfunction
 42 | 
 43 | function! s:scmRefresh()
 44 | 
 45 |     if exists('b:scmDiffOn') && b:scmDiffOn == 1
 46 |         call s:scmDiff()
 47 |     endif
 48 | 
 49 | endfunction
 50 | 
 51 | function! s:detectSCM()
 52 | 
 53 |     " Cache the results we find here to save time
 54 |     if exists("g:scmBufPath") && g:scmBufPath == expand("%:p:h") && exists("g:scmDiffCommand")
 55 |         return
 56 |     endif
 57 |     let g:scmBufPath = expand("%:p:h")
 58 | 
 59 |     " Detect CVS, SCCS(bitkeeper) or .svn directories in current path
 60 |     if !exists("g:scmDiffCommand") && isdirectory(g:scmBufPath."/.svn")
 61 |         let g:scmDiffCommand = "svn diff"
 62 |         return
 63 |     endif
 64 | 
 65 |     if !exists("g:scmDiffCommand") && isdirectory(g:scmBufPath."/CVS")
 66 |         let g:scmDiffCommand = "cvs diff"
 67 |         return
 68 |     endif
 69 | 
 70 |     if !exists("g:scmDiffCommand") && isdirectory(g:scmBufPath."/SCCS")
 71 |         let g:scmDiffCommand = "bk diffs"
 72 |         return
 73 |     endif
 74 | 
 75 |     " Detect .git, SCCS(bitkeeper), .hg(mercurial), _darcs(darcs) directories recursively in reverse
 76 |     let my_path = g:scmBufPath
 77 |     while my_path != "/"
 78 |         if !exists("g:scmDiffCommand") && isdirectory(my_path."/.git")
 79 |             let g:scmDiffCommand = "git diff --no-ext-diff"
 80 |             return
 81 |         endif
 82 |         if !exists("g:scmDiffCommand") && isdirectory(my_path."/.hg")
 83 |             let g:scmDiffCommand = "hg diff"
 84 |             return
 85 |         endif
 86 |         if !exists("g:scmDiffCommand") && isdirectory(my_path."/_darcs")
 87 |             let g:scmDiffCommand = "darcs diff -u"
 88 |             return
 89 |         endif
 90 |         let my_path = simplify(my_path."/../")
 91 |     endwhile
 92 | 
 93 |     " Detect if file is in clearcase
 94 |     let l:fullBufPath = resolve (expand("%:p"))
 95 |     let l:bufVer = system('cleartool des -s -cview "'.l:fullBufPath.'"')
 96 |     if l:bufVer =~ '@@'
 97 |         let g:scmDiffCommand = "cleartool diff -diff_format -pre"
 98 |     endif
 99 | 
100 | endfunction
101 | 
102 | function! s:scmDiff(...)
103 | 
104 |     call s:detectSCM()
105 |     if (!exists("g:scmDiffCommand"))
106 |         echohl WarningMsg | echon "Could not find .git, .svn, .hg, _darcs, SCCS, or CVS directories, are you under a supported SCM repository path?" | echohl None
107 |         return
108 |     endif
109 | 
110 |     if exists('b:scmDiffOn') && b:scmDiffOn == 1
111 |         let b:scmDiffOn = 0
112 |         set nodiff
113 |         exe 'bdelete ' . b:scmDiffTmpfile
114 |     endif
115 | 
116 |     let b:scmDiffOn = 1
117 |     let view = winsaveview()
118 | 
119 |     if a:0 == 1
120 |         if a:1 == 'none'
121 |             let g:scmDiffRev = ''
122 |         else
123 |             let g:scmDiffRev = a:1
124 |             if (match(g:scmDiffCommand, 'darcs'))
125 |                 g:scmDiffRev = '--from-patch=' . g:scmDiffRev
126 |             endif
127 |         endif
128 |     endif
129 | 
130 |     let ftype = &filetype
131 |     let b:scmDiffTmpfile = tempname()
132 |     let cmd = 'cat ' . bufname('%') . ' > ' . b:scmDiffTmpfile
133 |     let cmdOutput = system(cmd)
134 |     let tmpdiff = tempname()
135 |     let cmd = 'cd ' . g:scmBufPath . ' && ' . g:scmDiffCommand . ' ' . g:scmDiffRev . ' ' . expand('%:t') . ' > ' . tmpdiff
136 |     let cmdOutput = system(cmd)
137 |     let doWrap = &wrap  " Save the current state of wrap for later
138 | 
139 |     if v:shell_error && cmdOutput != ''
140 |         echohl WarningMsg | echon cmdOutput | echohl None
141 |         return
142 |     endif
143 | 
144 |     let cmd = 'patch -R -p0 ' . b:scmDiffTmpfile . ' ' . tmpdiff
145 |     let cmdOutput = system(cmd)
146 | 
147 |     if v:shell_error && cmdOutput != ''
148 |         echohl WarningMsg | echon cmdOutput | echohl None
149 |         return
150 |     endif
151 | 
152 |     if a:0 > 0 && a:1 == 'h'
153 |         exe 'diffsplit' . b:scmDiffTmpfile
154 |     else
155 |         exe 'vert diffsplit' . b:scmDiffTmpfile
156 |     endif
157 | 
158 |     exe 'set filetype=' . ftype
159 | 
160 |     hide
161 |     if doWrap == 1  
162 |         set wrap  "Restore the state of wrap
163 |     endif
164 | 
165 |     set foldcolumn=0
166 |     set foldlevel=100
167 |     set diffopt= " removed filler so we don't show deleted lines
168 |     set noscrollbind
169 | 
170 |     call winrestview(view)
171 | 
172 | endfunction
173 | 
174 | autocmd CursorHold * call s:scmRefresh()
175 | 
176 | 
177 | " vim>600: expandtab sw=4 ts=4 sts=4 fdm=marker
178 | " vim<600: expandtab sw=4 ts=4 sts=4
179 | 


--------------------------------------------------------------------------------