├── README.md
├── dns-and-dhcp.tf
├── ec2-machines.tf
├── networks.tf
├── routing-and-network.tf
├── securitygroups.tf
├── subnets.tf
└── variables.tf


/README.md:
--------------------------------------------------------------------------------
1 | # A COMPLETE AWS ENVIRONMENT WITH TERRAFORM
2 | this repo is only to store the files of the article published on linuxacademy article
3 | 
4 | https://linuxacademy.com/howtoguides/posts/show/topic/13922-a-complete-aws-environment-with-terraform
5 | 
6 | You can find full instructions in the article :
7 | 


--------------------------------------------------------------------------------
/dns-and-dhcp.tf:
--------------------------------------------------------------------------------
 1 | resource "aws_vpc_dhcp_options" "mydhcp" {
 2 |     domain_name = "${var.DnsZoneName}"
 3 |     domain_name_servers = ["AmazonProvidedDNS"]
 4 |     tags {
 5 |       Name = "My internal name"
 6 |     }
 7 | }
 8 | 
 9 | resource "aws_vpc_dhcp_options_association" "dns_resolver" {
10 |     vpc_id = "${aws_vpc.terraformmain.id}"
11 |     dhcp_options_id = "${aws_vpc_dhcp_options.mydhcp.id}"
12 | }
13 | 
14 | /* DNS PART ZONE AND RECORDS */
15 | #resource "aws_route53_zone" "main" {
16 | #  name = "${var.DnsZoneName}"
17 | #  vpc_id = "${aws_vpc.terraformmain.id}"
18 | #  comment = "Managed by terraform"
19 | #}
20 | # This throws this error: 
21 | #   Error: aws_route53_zone.main: "vpc_id": [REMOVED] use 'vpc' configuration block instead
22 | # so change it accordingly: 
23 | resource "aws_route53_zone" "main" {
24 |   name = "${var.DnsZoneName}"
25 |   vpc {
26 |     vpc_id = "${aws_vpc.terraformmain.id}"
27 |   }
28 |   comment = "Managed by terraform"
29 | }
30 | 
31 | resource "aws_route53_record" "database" {
32 |    zone_id = "${aws_route53_zone.main.zone_id}"
33 |    name = "mydatabase.${var.DnsZoneName}"
34 |    type = "A"
35 |    ttl = "300"
36 |    records = ["${aws_instance.database.private_ip}"]
37 | }
38 | 


--------------------------------------------------------------------------------
/ec2-machines.tf:
--------------------------------------------------------------------------------
 1 | resource "aws_instance" "phpapp" {
 2 |   ami           = "${lookup(var.AmiLinux, var.region)}"
 3 |   instance_type = "t2.micro"
 4 |   associate_public_ip_address = "true"
 5 |   subnet_id = "${aws_subnet.PublicAZA.id}"
 6 |   vpc_security_group_ids = ["${aws_security_group.FrontEnd.id}"]
 7 |   key_name = "${var.key_name}"
 8 |   tags {
 9 |         Name = "phpapp"
10 |   }
11 |   user_data = <<HEREDOC
12 |   #!/bin/bash
13 |   yum update -y
14 |   yum install -y httpd24 php56 php56-mysqlnd
15 |   service httpd start
16 |   chkconfig httpd on
17 |   echo "<?php" >> /var/www/html/calldb.php
18 |   echo "\$conn = new mysqli('mydatabase.linuxacademy.internal', 'root', 'secret', 'test');" >> /var/www/html/calldb.php
19 |   echo "\$sql = 'SELECT * FROM mytable'; " >> /var/www/html/calldb.php
20 |   echo "\$result = \$conn->query(\$sql); " >>  /var/www/html/calldb.php
21 |   echo "while(\$row = \$result->fetch_assoc()) { echo 'the value is: ' . \$row['mycol'] ;} " >> /var/www/html/calldb.php
22 |   echo "\$conn->close(); " >> /var/www/html/calldb.php
23 |   echo "?>" >> /var/www/html/calldb.php
24 | HEREDOC
25 | }
26 | 
27 | resource "aws_instance" "database" {
28 |   ami           = "${lookup(var.AmiLinux, var.region)}"
29 |   instance_type = "t2.micro"
30 |   associate_public_ip_address = "false"
31 |   subnet_id = "${aws_subnet.PrivateAZA.id}"
32 |   vpc_security_group_ids = ["${aws_security_group.Database.id}"]
33 |   key_name = "${var.key_name}"
34 |   tags {
35 |         Name = "database"
36 |   }
37 |   user_data = <<HEREDOC
38 |   #!/bin/bash
39 |   sleep 180
40 |   yum update -y
41 |   yum install -y mysql55-server
42 |   service mysqld start
43 |   /usr/bin/mysqladmin -u root password 'secret'
44 |   mysql -u root -psecret -e "create user 'root'@'%' identified by 'secret';" mysql
45 |   mysql -u root -psecret -e 'CREATE TABLE mytable (mycol varchar(255));' test
46 |   mysql -u root -psecret -e "INSERT INTO mytable (mycol) values ('linuxacademythebest') ;" test
47 | HEREDOC
48 | }
49 | 


--------------------------------------------------------------------------------
/networks.tf:
--------------------------------------------------------------------------------
 1 | provider "aws" {
 2 |   #access_key = "${var.aws_access_key}"
 3 |   #secret_key = "${var.aws_secret_key}"
 4 |   shared_credentials_file = "${var.credentialsfile}"
 5 |   region     = "${var.region}"
 6 | }
 7 | resource "aws_vpc" "terraformmain" {
 8 |     cidr_block = "${var.vpc-fullcidr}"
 9 |    #### this 2 true values are for use the internal vpc dns resolution
10 |     enable_dns_support = true
11 |     enable_dns_hostnames = true
12 |     tags {
13 |       Name = "My terraform vpc"
14 |     }
15 | }
16 | 


--------------------------------------------------------------------------------
/routing-and-network.tf:
--------------------------------------------------------------------------------
 1 | # Declare the data source
 2 | data "aws_availability_zones" "available" {}
 3 | 
 4 | /* EXTERNAL NETWORG , IG, ROUTE TABLE */
 5 | resource "aws_internet_gateway" "gw" {
 6 |    vpc_id = "${aws_vpc.terraformmain.id}"
 7 |     tags {
 8 |         Name = "internet gw terraform generated"
 9 |     }
10 | }
11 | resource "aws_network_acl" "all" {
12 |    vpc_id = "${aws_vpc.terraformmain.id}"
13 |     egress {
14 |         protocol = "-1"
15 |         rule_no = 2
16 |         action = "allow"
17 |         cidr_block =  "0.0.0.0/0"
18 |         from_port = 0
19 |         to_port = 0
20 |     }
21 |     ingress {
22 |         protocol = "-1"
23 |         rule_no = 1
24 |         action = "allow"
25 |         cidr_block =  "0.0.0.0/0"
26 |         from_port = 0
27 |         to_port = 0
28 |     }
29 |     tags {
30 |         Name = "open acl"
31 |     }
32 | }
33 | resource "aws_route_table" "public" {
34 |   vpc_id = "${aws_vpc.terraformmain.id}"
35 |   tags {
36 |       Name = "Public"
37 |   }
38 |   route {
39 |         cidr_block = "0.0.0.0/0"
40 |         gateway_id = "${aws_internet_gateway.gw.id}"
41 |     }
42 | }
43 | resource "aws_route_table" "private" {
44 |   vpc_id = "${aws_vpc.terraformmain.id}"
45 |   tags {
46 |       Name = "Private"
47 |   }
48 |   route {
49 |         cidr_block = "0.0.0.0/0"
50 |         nat_gateway_id = "${aws_nat_gateway.PublicAZA.id}"
51 |   }
52 | }
53 | resource "aws_eip" "forNat" {
54 |     vpc      = true
55 | }
56 | resource "aws_nat_gateway" "PublicAZA" {
57 |     allocation_id = "${aws_eip.forNat.id}"
58 |     subnet_id = "${aws_subnet.PublicAZA.id}"
59 |     depends_on = ["aws_internet_gateway.gw"]
60 | }
61 | 


--------------------------------------------------------------------------------
/securitygroups.tf:
--------------------------------------------------------------------------------
 1 | resource "aws_security_group" "FrontEnd" {
 2 |   name = "FrontEnd"
 3 |   tags {
 4 |         Name = "FrontEnd"
 5 |   }
 6 |   description = "ONLY HTTP CONNECTION INBOUD"
 7 |   vpc_id = "${aws_vpc.terraformmain.id}"
 8 | 
 9 |   ingress {
10 |         from_port = 80
11 |         to_port = 80
12 |         protocol = "TCP"
13 |         cidr_blocks = ["0.0.0.0/0"]
14 |   }
15 |   ingress {
16 |     from_port   = "22"
17 |     to_port     = "22"
18 |     protocol    = "TCP"
19 |     cidr_blocks = ["0.0.0.0/0"]
20 |   }
21 |   egress {
22 |     from_port = 0
23 |     to_port = 0
24 |     protocol = "-1"
25 |     cidr_blocks = ["0.0.0.0/0"]
26 |   }
27 | }
28 | 
29 | resource "aws_security_group" "Database" {
30 |   name = "Database"
31 |   tags {
32 |         Name = "Database"
33 |   }
34 |   description = "ONLY tcp CONNECTION INBOUND"
35 |   vpc_id = "${aws_vpc.terraformmain.id}"
36 |   ingress {
37 |       from_port = 3306
38 |       to_port = 3306
39 |       protocol = "TCP"
40 |       security_groups = ["${aws_security_group.FrontEnd.id}"]
41 |   }
42 |   ingress {
43 |       from_port   = "22"
44 |       to_port     = "22"
45 |       protocol    = "TCP"
46 |       cidr_blocks = ["0.0.0.0/0"]
47 |   }
48 |   egress {
49 |     from_port = 0
50 |     to_port = 0
51 |     protocol = "-1"
52 |     cidr_blocks = ["0.0.0.0/0"]
53 |   }
54 | }
55 | 


--------------------------------------------------------------------------------
/subnets.tf:
--------------------------------------------------------------------------------
 1 | resource "aws_subnet" "PublicAZA" {
 2 |   vpc_id = "${aws_vpc.terraformmain.id}"
 3 |   cidr_block = "${var.Subnet-Public-AzA-CIDR}"
 4 |   tags {
 5 |         Name = "PublicAZA"
 6 |   }
 7 |  availability_zone = "${data.aws_availability_zones.available.names[0]}"
 8 | }
 9 | resource "aws_route_table_association" "PublicAZA" {
10 |     subnet_id = "${aws_subnet.PublicAZA.id}"
11 |     route_table_id = "${aws_route_table.public.id}"
12 | }
13 | resource "aws_subnet" "PrivateAZA" {
14 |   vpc_id = "${aws_vpc.terraformmain.id}"
15 |   cidr_block = "${var.Subnet-Private-AzA-CIDR}"
16 |   tags {
17 |         Name = "PublicAZB"
18 |   }
19 |   availability_zone = "${data.aws_availability_zones.available.names[1]}"
20 | }
21 | resource "aws_route_table_association" "PrivateAZA" {
22 |     subnet_id = "${aws_subnet.PrivateAZA.id}"
23 |     route_table_id = "${aws_route_table.private.id}"
24 | }
25 | 


--------------------------------------------------------------------------------
/variables.tf:
--------------------------------------------------------------------------------
 1 | variable "region" {
 2 |   default = "us-east-2"
 3 | }
 4 | variable "AmiLinux" {
 5 |   type = "map"
 6 |   default = {
 7 |     us-east-1 = "ami-b73b63a0" # Virginia
 8 |     us-west-2 = "ami-5ec1673e" # Oregon
 9 |     eu-west-1 = "ami-9398d3e0" # Ireland
10 |     us-east-2 = "ami-ea87a78f" # Ohio
11 |   }
12 |   description = "I add only 3 regions (Virginia, Oregon, Ireland) to show the map feature but you can add all the regions that you need"
13 | }
14 | /*
15 | variable "aws_access_key" {
16 |   default = "xxxxx"
17 |   description = "the user aws access key"
18 | }
19 | 
20 | variable "aws_secret_key" {
21 |   default = "xxxx"
22 |   description = "the user aws secret key"
23 | }
24 | */
25 | variable "credentialsfile" {
26 |   default = "/Users/giuseppe/.aws/credentials" #replace your home directory
27 |   description = "where your access and secret_key are stored, you create the file when you run the aws config"
28 | }
29 | 
30 | variable "vpc-fullcidr" {
31 |     default = "172.28.0.0/16"
32 |   description = "the vpc cdir"
33 | }
34 | variable "Subnet-Public-AzA-CIDR" {
35 |   default = "172.28.0.0/24"
36 |   description = "the cidr of the subnet"
37 | }
38 | variable "Subnet-Private-AzA-CIDR" {
39 |   default = "172.28.3.0/24"
40 |   description = "the cidr of the subnet"
41 | }
42 | variable "key_name" {
43 |   default = "demotmp"
44 |   description = "the ssh key to use in the EC2 machines"
45 | }
46 | variable "DnsZoneName" {
47 |   default = "linuxacademy.internal"
48 |   description = "the internal dns name"
49 | }
50 | 


--------------------------------------------------------------------------------