** IT DOES NOT WORKING AS A LOCAL FILE! (FLASH SECURITY POLICY)
35 |
36 |
37 |
38 |
39 |
40 |
70 |
71 |
72 |
73 |
74 |
101 |
102 |
103 |
104 |
105 |
117 |
118 |
119 |
120 |
121 |
122 |
123 |
124 |
--------------------------------------------------------------------------------
/player.swf:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/gokerDEV/f4player/ddc7cb650bfa585ace30256695ad299acfaf49ae/player.swf
--------------------------------------------------------------------------------
/skins/mySkin.swf:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/gokerDEV/f4player/ddc7cb650bfa585ace30256695ad299acfaf49ae/skins/mySkin.swf
--------------------------------------------------------------------------------
/source/f4/Player.as:
--------------------------------------------------------------------------------
1 | /*
2 | ═ f4.Player ═════════════════════════════════════════════════════════════
3 | Software: f4.Player - flash video player
4 | Version: 1.3.5
5 | Support: http://gokercebeci.com/dev/f4player
6 | Author: goker.cebeci
7 | Contact: http://gokercebeci.com
8 | -------------------------------------------------------------------------
9 | License: Distributed under the GNU General Public License (GPLv3)
10 | http://www.gnu.org/copyleft/gpl.html
11 | This program is distributed in the hope that it will be useful - WITHOUT
12 | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 | FITNESS FOR A PARTICULAR PURPOSE.
14 | ═══════════════════════════════════════════════════════════════════════════ */
15 | package f4
16 | {
17 |
18 | import flash.display.MovieClip;
19 | import flash.display.Loader;
20 | import flash.display.Stage;
21 | import flash.display.StageDisplayState;
22 | import flash.display.Bitmap;
23 | import flash.display.BitmapData;
24 |
25 | import flash.net.NetConnection;
26 | import f4.PlayerNetStream;
27 | import flash.net.URLLoader;
28 | import flash.net.URLRequest;
29 | import flash.media.Video;
30 | import flash.media.SoundTransform
31 | import flash.events.NetStatusEvent;
32 | import flash.events.TimerEvent;
33 | import flash.events.Event;
34 | import flash.events.SecurityErrorEvent;
35 | import flash.events.AsyncErrorEvent;
36 | import flash.geom.Matrix;
37 | import flash.utils.Timer;
38 |
39 | import flash.external.ExternalInterface;
40 | import flashx.textLayout.formats.Float;
41 |
42 | public class Player extends MovieClip implements PlayerInterface
43 | {
44 |
45 | public var body:MovieClip;
46 | private var nc:NetConnection;
47 | private var ns:PlayerNetStream;
48 | private var v:Video;
49 | private var st:SoundTransform;
50 | private var togglepause:Boolean = false;
51 | private var volcache:Number = 0;
52 | private var duration:int;
53 | private var videoWidth:int;
54 | private var videoHeight:int;
55 | private var status:String;
56 | public var callback:Function;
57 |
58 | public var stream:String;
59 | public var streamname:String;
60 | public var live:Boolean;
61 | public var subscribe:Boolean;
62 | public var autoplay:String;
63 |
64 | public function Player(stream:String = null, name:String = null, live:Boolean = false, subscribe:Boolean = false)
65 | {
66 |
67 | this.stream = stream;
68 | this.streamname = name;
69 | this.live = live;
70 | this.subscribe = subscribe;
71 |
72 | body = new MovieClip();
73 | body.graphics.drawRoundRect(0, 0, 160, 90, 0, 0);
74 |
75 | nc = new NetConnection();
76 | nc.addEventListener(NetStatusEvent.NET_STATUS, nsEvent);
77 | nc.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityError);
78 | nc.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncEvent);
79 | this.Log('Stream URL: ' + stream);
80 | //nc.call("checkBandwidth", null);
81 | //nc.connect(stream);
82 | //nc.client = this;
83 |
84 | }
85 |
86 | // EVENTS
87 | // =============================================================
88 | public function nsEvent(e:NetStatusEvent):void
89 | {
90 | Log("NetStatusEvent: " + e.info.code);
91 | if (status != e.info.code)
92 | {
93 | switch (e.info.code)
94 | {
95 | case "NetConnection.Connect.Success":
96 | Log('NetConnection connected to ' + stream);
97 | if (subscribe)
98 | {
99 | nc.call("FCSubscribe", null, streamname);
100 | }
101 | ns = new PlayerNetStream(nc);
102 | ns.addEventListener(NetStatusEvent.NET_STATUS, nsEvent);
103 | ns.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncEvent);
104 | ns.bufferTime = 5; // buffer time 5 sec.
105 | ns.onMetaData = metaDataEvent;
106 | ns.onCuePoint = cuePointEvent;
107 | st = new SoundTransform();
108 | if (autoplay)
109 | {
110 | Play(autoplay);
111 | }
112 | break;
113 | case "NetStream.Play.StreamNotFound":
114 | trace("Stream not found: " + stream);
115 | break;
116 | }
117 | status = e.info.code;
118 | if (callback != null)
119 | callback(Info());
120 | }
121 | }
122 |
123 | public function securityError(e:SecurityErrorEvent):void
124 | {
125 | this.Log("NetStatusEvent: " + e.text);
126 | }
127 |
128 | public function asyncEvent(e:AsyncErrorEvent):void
129 | {
130 | this.Log("AsyncErrorEvent: " + e.text);
131 | }
132 |
133 | public function metaDataEvent(i:Object):void
134 | {
135 | this.Log('MetaData');
136 | duration = i.duration;
137 | videoWidth = i.width;
138 | videoHeight = i.height;
139 | }
140 |
141 | public function cuePointEvent(i:Object):void
142 | {
143 | this.Log('Cuepoint');
144 | }
145 |
146 | public function onBWDone():void
147 | {
148 | this.Log("BWDone");
149 | }
150 |
151 | public function onFCSubscribe(i:Object):void
152 | {
153 | if (i.code == "NetStream.Play.Start")
154 | {
155 | this.Log("Subscribe: " + i.code);
156 | }
157 | }
158 |
159 | public function onFCUnsubscribe(i:Object):void
160 | {
161 | trace("UnSubscribe", i);
162 | }
163 |
164 | // =============================================================
165 | // =============================================================
166 | public function Callback(callback:Function):void
167 | {
168 | this.callback = callback;
169 | var timer:Timer = new Timer(100);
170 | var timerEvent = function(e:TimerEvent):void
171 | {
172 | var info:Object = Info();
173 | if (info.progress >= 100)
174 | timer.stop();
175 | if (nc.connected)
176 | callback(info);
177 | }
178 | timer.addEventListener(TimerEvent.TIMER, timerEvent);
179 | timer.start();
180 | }
181 |
182 | private function Info():Object
183 | {
184 | var playing:Number = ns ? (ns.time / duration).toFixed(2) : 0;
185 | return {'width': videoWidth, 'height': videoHeight, 'total': ns ? ns.bytesTotal : 0, 'loaded': ns ? ns.bytesLoaded : 0, 'progress': ns ? (ns.bytesLoaded / ns.bytesTotal).toFixed(2) : 0, 'duration': duration, 'time': ns ? ns.time : 0, 'playing': (playing > 1 ? 1 : playing), 'status': status};
186 | }
187 |
188 | public function Movie(w:int, h:int):Video
189 | {
190 | this.Log('Video dimensions: ' + w.toString() + 'x' + h.toString());
191 | v = new Video(w, h);
192 | v.smoothing = true;
193 | this.Log('NetConnection is: ' + nc.connected);
194 | v.attachNetStream(ns);
195 | return v;
196 | }
197 |
198 | public function Play(file:String):Boolean
199 | {
200 | if (nc.connected)
201 | {
202 | if (stream)
203 | {
204 | this.Log("Play stream: " + streamname);
205 | ns.play(streamname, live ? -1 : 1);
206 | }
207 | else
208 | {
209 | this.Log("Play file: " + file);
210 | ns.play(file);
211 | }
212 | }
213 | else
214 | {
215 | autoplay = file || streamname;
216 | nc.connect(stream);
217 | nc.client = this;
218 | this.Log('Autoplay: ' + autoplay);
219 | }
220 | return true;
221 | }
222 |
223 | public function Pause():Boolean
224 | {
225 | this.Log('Pause');
226 | if (togglepause)
227 | {
228 | togglepause = false;
229 | ns.resume();
230 | }
231 | else
232 | {
233 | togglepause = true;
234 | ns.pause();
235 | }
236 | return togglepause;
237 | }
238 |
239 | public function Stop():void
240 | {
241 | this.Log('Stop');
242 | ns.close();
243 | }
244 |
245 | public function Volume(vol:Number)
246 | {
247 | this.Log('Volume: ' + vol.toString());
248 | st.volume = vol;
249 | ns.soundTransform = st;
250 | }
251 |
252 | public function Mute():Number
253 | {
254 | if (volcache)
255 | {
256 | this.Log('VolumeCache: ' + volcache.toString());
257 | st.volume = volcache;
258 | ns.soundTransform = st;
259 | volcache = 0;
260 | }
261 | else
262 | {
263 | this.Log('Mute');
264 | volcache = st.volume;
265 | st.volume = 0;
266 | ns.soundTransform = st;
267 | }
268 | return st.volume;
269 | }
270 |
271 | public function Fullscreen(stage:Stage):Boolean
272 | {
273 | this.Log('Fullscreen: ' + !(stage.displayState == StageDisplayState.FULL_SCREEN));
274 | if (stage.displayState == StageDisplayState.FULL_SCREEN)
275 | {
276 | stage.displayState = StageDisplayState.NORMAL;
277 | return false;
278 | }
279 | else
280 | {
281 | stage.displayState = StageDisplayState.FULL_SCREEN;
282 | return true;
283 | }
284 | }
285 |
286 | public function Seek(point:int):int
287 | {
288 | this.Log('Seek: ' + point.toString());
289 | ns.seek(point);
290 | }
291 |
292 | public function Thumbnail(image:String, w:int, h:int):MovieClip
293 | {
294 | this.Log('Thumbnail: ' + image);
295 | var mc:MovieClip = new MovieClip();
296 | var bmp:BitmapData = new BitmapData(w, h, false, 0x000000);
297 | mc.addChild(new Bitmap(bmp));
298 | if (image)
299 | {
300 | var l = new Loader();
301 | var lEvent:Function = function(event:Event):void
302 | {
303 | var image:Bitmap = l.content;
304 | var m:Matrix = new Matrix();
305 | m.scale(w / image.width, h / image.height);
306 | bmp.draw(image, m, null, null, null, true);
307 | image = new Bitmap(bmp);
308 | mc.addChild(image);
309 | }
310 | l.contentLoaderInfo.addEventListener(Event.COMPLETE, lEvent);
311 | l.load(new URLRequest(image));
312 | }
313 | return mc;
314 | }
315 |
316 | public function Next():void
317 | {
318 | this.Log('Next');
319 | }
320 |
321 | public function Prev():void
322 | {
323 | this.Log('Prev');
324 | }
325 |
326 | public function Subtitle(sub:String):void
327 | {
328 | this.Log('Subtitle: ' + sub);
329 | }
330 |
331 | public function Log(log:String):void
332 | {
333 | trace(log);
334 | ExternalInterface.call("console.log", log);
335 | }
336 | }
337 | }
338 |
--------------------------------------------------------------------------------
/source/f4/PlayerInterface.as:
--------------------------------------------------------------------------------
1 | /*
2 | ═ f4.PlayerInterface ════════════════════════════════════════════════════
3 | Software: f4.PlayerInterface - flash video player interfece
4 | Version: 1.3.5
5 | Support: http://gokercebeci.com/dev/f4player
6 | Author: goker.cebeci
7 | Contact: http://gokercebeci.com
8 | -------------------------------------------------------------------------
9 | License: Distributed under the GNU General Public License (GPLv3)
10 | http://www.gnu.org/copyleft/gpl.html
11 | This program is distributed in the hope that it will be useful - WITHOUT
12 | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 | FITNESS FOR A PARTICULAR PURPOSE.
14 | ═══════════════════════════════════════════════════════════════════════════ */
15 | package f4
16 | {
17 | import flash.display.MovieClip;
18 | import flash.display.Stage;
19 | import flash.display.Bitmap;
20 | import flash.media.Video;
21 |
22 | public interface PlayerInterface
23 | {
24 | function Callback(callback:Function):void;
25 | function Movie(w:int, h:int):Video;
26 | function Play(file:String):Boolean;
27 | function Pause():Boolean;
28 | function Stop():void;
29 | function Volume(vol:Number);
30 | function Mute():Number;
31 | function Fullscreen(stage:Stage):Boolean;
32 | function Seek(point:int):int;
33 | function Thumbnail(image:String, w:int, h:int):MovieClip;
34 | function Next():void;
35 | function Prev():void;
36 | function Subtitle(sub:String):void;
37 | function Log(log:String):void;
38 | }
39 | }
40 |
--------------------------------------------------------------------------------
/source/f4/PlayerNetStream.as:
--------------------------------------------------------------------------------
1 | /*
2 | ═ f4.PlayerNetStream ════════════════════════════════════════════════════
3 | Software: f4.PlayerNetStream - flash video player custom netstream class
4 | Version: 1.3.5
5 | Support: http://gokercebeci.com/dev/f4player
6 | Author: goker.cebeci
7 | Contact: http://gokercebeci.com
8 | -------------------------------------------------------------------------
9 | License: Distributed under the GNU General Public License (GPLv3)
10 | http://www.gnu.org/copyleft/gpl.html
11 | This program is distributed in the hope that it will be useful - WITHOUT
12 | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 | FITNESS FOR A PARTICULAR PURPOSE.
14 | ═══════════════════════════════════════════════════════════════════════════ */
15 | package f4
16 | {
17 | import flash.net.NetConnection;
18 | import flash.net.NetStream;
19 |
20 | public dynamic class PlayerNetStream extends NetStream
21 | {
22 | public function PlayerNetStream(nc:NetConnection)
23 | {
24 | super(nc);
25 | }
26 | }
27 | }
--------------------------------------------------------------------------------
/source/myPlayer.as:
--------------------------------------------------------------------------------
1 | /*
2 | ═ f4.Player Sample ══════════════════════════════════════════════════════
3 | Software: f4.Player - flash video player sample
4 | Version: 1.3.5
5 | Support: http://gokercebeci.com/dev/f4player
6 | Author: goker.cebeci
7 | Contact: http://gokercebeci.com
8 | -------------------------------------------------------------------------
9 | License: Distributed under the GNU General Public License (GPLv3)
10 | http://www.gnu.org/copyleft/gpl.html
11 | This program is distributed in the hope that it will be useful - WITHOUT
12 | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 | FITNESS FOR A PARTICULAR PURPOSE.
14 | ═══════════════════════════════════════════════════════════════════════════ */
15 | package
16 | {
17 | import f4.Player;
18 | import flash.display.MovieClip;
19 | import flash.display.StageAlign;
20 | import flash.display.StageScaleMode;
21 | import flash.display.Loader;
22 | import flash.events.Event;
23 | import flash.events.KeyboardEvent;
24 | import flash.events.ContextMenuEvent;
25 | import flash.net.URLRequest;
26 | import flash.net.navigateToURL;
27 | import flash.ui.ContextMenu;
28 | import flash.ui.ContextMenuItem;
29 | import flash.external.ExternalInterface;
30 |
31 | public class myPlayer extends MovieClip
32 | {
33 | public function myPlayer()
34 | {
35 | stage.scaleMode = StageScaleMode.NO_SCALE;
36 | stage.align = StageAlign.TOP_LEFT;
37 | var stream = this.loaderInfo.parameters.stream;
38 | var streamname = this.loaderInfo.parameters.streamname;
39 | var live = this.loaderInfo.parameters.live == 1;
40 | var subscribe = this.loaderInfo.parameters.subscribe == 1;
41 | var video = this.loaderInfo.parameters.video;
42 | var thumbnail = this.loaderInfo.parameters.thumbnail;
43 | var skinfile = this.loaderInfo.parameters.skin;
44 | var autoplay = this.loaderInfo.parameters.autoplay == 1;
45 | var fullscreen = this.loaderInfo.parameters.fullscreen;
46 | var skin;
47 | var skinEvent:Function = function(e:Event):void
48 | {
49 | skin = e.currentTarget.content;
50 | stage.addChild(skin);
51 | ExternalInterface.call("console.log", 'initializating ...');
52 | ExternalInterface.call("stream", stream);
53 | var player = new Player(stream, streamname, live, subscribe);
54 |
55 | skin.initialization(player, stage.stageWidth, stage.stageHeight, video
56 | //,'data/video.flv'
57 | , thumbnail ? thumbnail : null
58 | //,'data/thumbnail.jpg'
59 | , autoplay, fullscreen);
60 | }
61 | var sl = new Loader();
62 | sl.contentLoaderInfo.addEventListener(Event.COMPLETE, skinEvent);
63 | sl.load(new URLRequest(skinfile ? skinfile : 'skins/mySkin.swf'));
64 | // Resize Event
65 | var resizeEvent:Function = function(e:Event):void
66 | {
67 | skin.pose(stage.stageWidth, stage.stageHeight);
68 | ExternalInterface.call("console.log", (stage.stageWidth.toString() + 'x' + stage.stageHeight.toString()));
69 | }
70 | stage.addEventListener(Event.RESIZE, resizeEvent);
71 | stage.addEventListener(Event.FULLSCREEN, resizeEvent);
72 | // CUSTOMIZE RIGHT CLICK CONTEXT MENU
73 | var menu:ContextMenu = new ContextMenu();
74 | menu.hideBuiltInItems();
75 | var signature = new ContextMenuItem("f4Player");
76 | function openLink(e:ContextMenuEvent):void
77 | {
78 | navigateToURL(new URLRequest("http://gokercebeci.com/dev/f4player/?feature=player"));
79 | }
80 | signature.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT, openLink);
81 | menu.customItems.push(signature);
82 | contextMenu = menu;
83 | }
84 | }
85 | }
--------------------------------------------------------------------------------
/source/myPlayer.fla:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/gokerDEV/f4player/ddc7cb650bfa585ace30256695ad299acfaf49ae/source/myPlayer.fla
--------------------------------------------------------------------------------
/source/myPlayer_CC.fla:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/gokerDEV/f4player/ddc7cb650bfa585ace30256695ad299acfaf49ae/source/myPlayer_CC.fla
--------------------------------------------------------------------------------
/source/mySkin.as:
--------------------------------------------------------------------------------
1 | /*
2 | ═ f4.Skin ═══════════════════════════════════════════════════════════════
3 | Software: f4.Skin - flash video player skin class
4 | Version: 1.3.5
5 | Support: http://gokercebeci.com/dev/f4player
6 | Author: goker.cebeci
7 | Contact: http://gokercebeci.com
8 | -------------------------------------------------------------------------
9 | License: Distributed under the GNU General Public License (GPLv3)
10 | http://www.gnu.org/copyleft/gpl.html
11 | This program is distributed in the hope that it will be useful - WITHOUT
12 | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 | FITNESS FOR A PARTICULAR PURPOSE.
14 | ═══════════════════════════════════════════════════════════════════════════ */
15 | package
16 | {
17 | import f4.PlayerInterface;
18 | import flash.display.MovieClip;
19 | import flash.events.Event;
20 | import flash.events.MouseEvent;
21 | import flash.media.Video;
22 |
23 | public class mySkin extends MovieClip
24 | {
25 | var player:PlayerInterface;
26 | var info:Object = new Object();
27 | var fullscreen:Boolean = true;
28 | var playing:Boolean = false;
29 | var volumeCache:Number;
30 | var status:String;
31 | var W:int = 480;
32 | var H:int = 270;
33 | var video:String;
34 | var image:MovieClip = new MovieClip();
35 | var seeking:Boolean = false;
36 |
37 | public function mySkin()
38 | {
39 | trace("mySkin loaded!");
40 | pose(W, H);
41 | }
42 |
43 | public function initialization(player:PlayerInterface, W:Number, H:Number, video:String, thumbnail:String, autoplay:Boolean = false, fullscreen:Boolean = true):void
44 | {
45 | fullscreen = fullscreen;
46 | this.W = info.width = W;
47 | this.H = info.height = H;
48 | info.progress = 0;
49 | pose(W, H);
50 | nav.pauseButton.visible = false;
51 | nav.seeker.visible = false;
52 | buffering.visible = false;
53 |
54 | //thumbnail [
55 | if (thumbnail)
56 | {
57 | image = player.Thumbnail(thumbnail, W, H);
58 | screen.addChildAt(image, 1);
59 | screen.width = W;
60 | screen.height = H;
61 | }
62 | // ] thumbnail
63 |
64 | var callback:Function = function(i:Object)
65 | {
66 | if ((i.width && i.height) && i.width != info.width && i.height != info.height)
67 | {
68 | info = i;
69 | pose(W, H);
70 | }
71 | info = i;
72 | nav.progressBar.width = (info.progress * nav.bar.width);
73 | nav.playingBar.width = (info.playing * nav.bar.width);
74 | nav.notify.text = formatTime(info.time) + " / " + formatTime(info.duration);
75 |
76 | if (status != info.status)
77 | {
78 | switch (info.status)
79 | {
80 | case "NetConnection.Connect.Success":
81 | //movie [
82 | var movie:Video = player.Movie(W, H);
83 | screen.addChildAt(movie, 1);
84 | // ] movie
85 | // repose
86 | pose(W, H);
87 | break;
88 | case "NetConnection.Connect.Closed":
89 | stopEvent(new MouseEvent(MouseEvent.CLICK));
90 | break;
91 | case "NetStream.Play.Start":
92 | image.visible = false;
93 | buffering.visible = false;
94 | break;
95 | case "NetStream.Unpause.Notify":
96 | case "NetStream.Buffer.Empty":
97 | case "NetStream.Seek.Notify":
98 | buffering.visible = true;
99 | break;
100 | case "NetStream.Buffer.Full":
101 | buffering.visible = false;
102 | break;
103 | case "NetStream.Play.Stop":
104 | stopEvent(new MouseEvent(MouseEvent.CLICK));
105 | break;
106 | case "NetStream.Failed":
107 | stopEvent(new MouseEvent(MouseEvent.CLICK));
108 | default:
109 | nav.notify.text = info.status;
110 | break;
111 | }
112 | status = info.status;
113 | }
114 | };
115 | // Callback Function
116 | player.Callback(callback);
117 | //═ PLAY ══════════════════════════════════════════════════════════════════════
118 | var playEvent:Function = function(e:Event):void
119 | {
120 | trace('playEvent');
121 | if (playing)
122 | {
123 | player.Pause();
124 | }
125 | else
126 | {
127 | playing = player.Play(video);
128 | overButton.visible = !playing;
129 | image.visible = !playing;
130 | }
131 | nav.playButton.visible = !playing;
132 | nav.pauseButton.visible = playing;
133 | };
134 | overButton.addEventListener(MouseEvent.CLICK, playEvent);
135 | nav.playButton.addEventListener(MouseEvent.CLICK, playEvent);
136 |
137 | // AUTOPLAY;
138 | if (autoplay)
139 | {
140 | playEvent(new MouseEvent(MouseEvent.CLICK));
141 | }
142 |
143 | //═ PAUSE ══════════════════════════════════════════════════════════════════════
144 | var pauseEvent:Function = function(e:Event):void
145 | {
146 | var isPause:Boolean;
147 | if (playing)
148 | {
149 | isPause = player.Pause();
150 | nav.playButton.visible = isPause;
151 | nav.pauseButton.visible = !isPause;
152 | }
153 | else
154 | {
155 | playEvent(e);
156 | }
157 | };
158 | overlay.addEventListener(MouseEvent.CLICK, pauseEvent);
159 | nav.pauseButton.addEventListener(MouseEvent.CLICK, pauseEvent);
160 | //═ STOP ══════════════════════════════════════════════════════════════════════;
161 | var stopEvent:Function = function(e:Event):void
162 | {
163 | trace('stopEvent');
164 | playing = false;
165 | nav.playButton.visible = !playing;
166 | nav.pauseButton.visible = playing;
167 | buffering.visible = playing;
168 | player.Stop();
169 | };
170 | //═ HIDE CONTROLS ═════════════════════════════════════════════════════════════
171 | var controlDisplayEvent:Function = function(e:Event):void
172 | {
173 | nav.y = e.type == 'mouseOver' || !playing ? overlay.height - 26 : overlay.height + 8;
174 | };
175 | overlay.addEventListener(MouseEvent.MOUSE_OVER, controlDisplayEvent);
176 | overlay.addEventListener(MouseEvent.MOUSE_OUT, controlDisplayEvent);
177 | nav.addEventListener(MouseEvent.MOUSE_OVER, controlDisplayEvent);
178 | nav.addEventListener(MouseEvent.MOUSE_OUT, controlDisplayEvent);
179 | //═ SEEK ══════════════════════════════════════════════════════════════════════
180 | var playingBarEvent:Function = function(e:MouseEvent):void
181 | {
182 | if(e.type == "click" || e.buttonDown == true){
183 | var point:Number = e.localX * info.playing;
184 | var seekpoint:Number = (point / 100) * info.duration;
185 | player.Seek(seekpoint);
186 | }
187 | };
188 | nav.playingBar.buttonMode = true;
189 | nav.playingBar.addEventListener(MouseEvent.CLICK, playingBarEvent);
190 | nav.playingBar.addEventListener(MouseEvent.MOUSE_MOVE, playingBarEvent);
191 | var progressBarEvent:Function = function(e:MouseEvent):void
192 | {
193 | if(e.type == "click" || e.buttonDown == true){
194 | var point:Number = e.localX * info.progress;
195 | var seekpoint:Number = (point / 100) * info.duration;
196 | player.Seek(seekpoint);
197 | }
198 | };
199 | nav.progressBar.buttonMode = true;
200 | nav.progressBar.addEventListener(MouseEvent.CLICK, progressBarEvent);
201 | nav.progressBar.addEventListener(MouseEvent.MOUSE_MOVE, progressBarEvent);
202 |
203 | //═ VOLUME ══════════════════════════════════════════════════════════════════════
204 | var setVolume:Function = function(newVolume:Number):void
205 | {
206 | player.Volume(newVolume);
207 | nav.volumeBar.mute.gotoAndStop((newVolume > 0) ? 1 : 2);
208 | nav.volumeBar.volumeOne.gotoAndStop((newVolume >= 0.2) ? 1 : 2);
209 | nav.volumeBar.volumeTwo.gotoAndStop((newVolume >= 0.4) ? 1 : 2);
210 | nav.volumeBar.volumeThree.gotoAndStop((newVolume >= 0.6) ? 1 : 2);
211 | nav.volumeBar.volumeFour.gotoAndStop((newVolume >= 0.8) ? 1 : 2);
212 | nav.volumeBar.volumeFive.gotoAndStop((newVolume == 1) ? 1 : 2);
213 | };
214 | var volumeEvent:Function = function(e:MouseEvent):void
215 | {
216 | if (e.buttonDown || e.type == 'click')
217 | switch (e.currentTarget)
218 | {
219 | case nav.volumeBar.mute:
220 | setVolume(player.Mute());
221 | break;
222 | case nav.volumeBar.volumeOne:
223 | setVolume(.2);
224 | break;
225 | case nav.volumeBar.volumeTwo:
226 | setVolume(.4);
227 | break;
228 | case nav.volumeBar.volumeThree:
229 | setVolume(.6);
230 | break;
231 | case nav.volumeBar.volumeFour:
232 | setVolume(.8);
233 | break;
234 | case nav.volumeBar.volumeFive:
235 | setVolume(1);
236 | break;
237 | }
238 | };
239 | nav.volumeBar.mute.addEventListener(MouseEvent.CLICK, volumeEvent);
240 | nav.volumeBar.mute.addEventListener(MouseEvent.ROLL_OVER, volumeEvent);
241 | nav.volumeBar.volumeOne.addEventListener(MouseEvent.CLICK, volumeEvent);
242 | nav.volumeBar.volumeOne.addEventListener(MouseEvent.ROLL_OVER, volumeEvent);
243 | nav.volumeBar.volumeTwo.addEventListener(MouseEvent.CLICK, volumeEvent);
244 | nav.volumeBar.volumeTwo.addEventListener(MouseEvent.ROLL_OVER, volumeEvent);
245 | nav.volumeBar.volumeThree.addEventListener(MouseEvent.CLICK, volumeEvent);
246 | nav.volumeBar.volumeThree.addEventListener(MouseEvent.ROLL_OVER, volumeEvent);
247 | nav.volumeBar.volumeFour.addEventListener(MouseEvent.CLICK, volumeEvent);
248 | nav.volumeBar.volumeFour.addEventListener(MouseEvent.ROLL_OVER, volumeEvent);
249 | nav.volumeBar.volumeFive.addEventListener(MouseEvent.CLICK, volumeEvent);
250 | nav.volumeBar.volumeFive.addEventListener(MouseEvent.ROLL_OVER, volumeEvent);
251 | //═ FULLSCREEN ══════════════════════════════════════════════════════════════════════;
252 | var fullscreenEvent:Function = function(e:Event):void
253 | {
254 | player.Fullscreen(stage);
255 | };
256 | nav.fullscreen.addEventListener(MouseEvent.CLICK, fullscreenEvent);
257 |
258 | }
259 |
260 | //═ POSE ══════════════════════════════════════════════════════════════════════;
261 | public function pose(W:Number, H:Number):void
262 | {
263 | trace('Pose: ' + W + 'x' + H);
264 | this.W = W;
265 | this.H = H;
266 | background.x = screen.x = overlay.x = 0;
267 | background.y = screen.y = overlay.y = 0;
268 | background.width = overlay.width = W;
269 | background.height = overlay.height = H;
270 | overlay.alpha = 0;
271 | var proportion:Number = W / H;
272 | var videoproportion:Number = info.width / info.height;
273 | if (videoproportion >= proportion)
274 | { //<= (H / W)
275 | screen.width = W;
276 | screen.height = W / videoproportion;
277 | }
278 | else
279 | {
280 | screen.width = H * videoproportion;
281 | screen.height = H;
282 | }
283 | screen.x = (W - screen.width) * .5;
284 | screen.y = (H - screen.height) * .5;
285 | overButton.x = (W - overButton.width) * .5;
286 | overButton.y = (H - overButton.height) * .5;
287 | buffering.x = (W - buffering.width) * .5;
288 | buffering.y = (H - buffering.height) * .5;
289 | //NAVIGATOR
290 | nav.y = H - 26;
291 | nav.bar.width = W;
292 | nav.pauseButton.y = nav.playButton.y;
293 | nav.progressBar.x = 0;
294 | nav.progressBar.y = nav.playingBar.y = nav.bar.y - 10;
295 | if (fullscreen)
296 | {
297 | nav.fullscreen.x = nav.bar.width - nav.fullscreen.width - 10;
298 | }
299 | else
300 | {
301 | nav.fullscreen.visible = false;
302 | }
303 | nav.volumeBar.x = nav.playButton.width + 10;
304 | nav.notify.x = nav.volumeBar.x + nav.volumeBar.width + 10;
305 | nav.progressBar.width = nav.playingBar.width = W;
306 | nav.progressBar.width = ((info.progress * W * .01) >> 0);
307 | }
308 |
309 | private function formatTime(time:Number):String
310 | {
311 | if (time > 0)
312 | {
313 | var integer:String = String((time / 60) >> 0);
314 | var decimal:String = String((time % 60) >> 0);
315 | return ((integer.length < 2) ? "0" + integer : integer) + ":" + ((decimal.length < 2) ? "0" + decimal : decimal);
316 | }
317 | else
318 | {
319 | return String("00:00");
320 | }
321 |
322 | }
323 | }
324 | }
--------------------------------------------------------------------------------
/source/mySkin.fla:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/gokerDEV/f4player/ddc7cb650bfa585ace30256695ad299acfaf49ae/source/mySkin.fla
--------------------------------------------------------------------------------
/source/mySkin_CC.fla:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/gokerDEV/f4player/ddc7cb650bfa585ace30256695ad299acfaf49ae/source/mySkin_CC.fla
--------------------------------------------------------------------------------
/thumbnail.jpg:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/gokerDEV/f4player/ddc7cb650bfa585ace30256695ad299acfaf49ae/thumbnail.jpg
--------------------------------------------------------------------------------
SAMPLE
41 | 42 |
43 |
54 |
55 |
56 | f4Player v1.3.5
44 | Free, Small, Quick, Customizable and the Bestest FLV Player on Internet! 45 |46 | f4Player is an open source flash (AS3) video/stream player and library project. It is so small that it is only 10kb (with skin file) and totally free under GPL license.
47 |A few years ago I wanted to play a video (flv) on my webpage and I developed a realy small, simple flv player and I'm still developing it for HTML5 support and JS interface.
48 |I've only tested it with flv, f4v, mp4, stream, live stream, subscribed CDN and it works enough for me for now!
49 |It is under GPLv3 License.
50 | 53 |
57 |
68 |
69 | f4Player
58 |
59 |
60 |
61 | You need Adobe Flash Player to watch this video. <br>
62 | <a href="http://get.adobe.com/flashplayer/">Download it from Adobe.</a>
63 | <a href="http://gokercebeci.com/dev/f4player" title="flv player">flv player</a>
64 |
65 |
66 | * f4Player write own log on browser's "console".
67 |USAGE
75 |
76 | <object id="f4Player" width="480" height="270" type="application/x-shockwave-flash" data="player.swf?v1.3.5">
77 | <param name="movie" value="player.swf?v1.3.5" />
78 | <param name="quality" value="high" />
79 | <param name="menu" value="false" />
80 | <param name="scale" value="noscale" />
81 | <param name="allowfullscreen" value="true">
82 | <param name="allowscriptaccess" value="always">
83 | <param name="swlivevonnect" value="true" />
84 | <param name="cachebusting" value="false">
85 | <param name="flashvars"
86 | value="skin=[SKIN_FILE]&video=[VIDEO_FILE]"/>
87 | <a href="http://www.adobe.com/go/flashplayer/">Download it from Adobe.</a>
88 | <a href="http://gokercebeci.com/dev/f4player" title="flv player">flv player</a>
89 | </object>
90 |
91 | or
92 |
93 | <embed type="application/x-shockwave-flash" src="player.swf?v1.3.5" id="f4Player" width="480" height="270" flashvars="skin=[SKIN_FILE]&video=[VIDEO_FILE]" allowscriptaccess="always" allowfullscreen="true" bgcolor="#000000"/>
94 | <noembed>
95 | You need Adobe Flash Player to watch this video.
96 | <a href="http://get.adobe.com/flashplayer/">Download it from Adobe.</a>
97 | <a href="http://gokercebeci.com/dev/f4player" title="flv player">flv player</a>
98 | </noembed>
99 |
100 | OPTIONS
106 |107 | skin= => skin file (swf) 108 | stream=rtmp:// => stream url 109 | streamname=livestream => stream name 110 | live=1 => default value 0 111 | subscribe=1 => default value 0 112 | thumbnail=null => thumbnail image 113 | video=myvideo.mp4 => video file 114 | autoplay=1 => default value 0 115 |116 |