├── .gitignore
├── after
    ├── ftplugin
    │   ├── less
    │   │   └── rails.vim
    │   ├── sass
    │   │   └── rails.vim
    │   ├── scss
    │   │   └── rails.vim
    │   ├── coffee
    │   │   └── rails.vim
    │   ├── ruby
    │   │   └── rails.vim
    │   ├── css
    │   │   └── rails.vim
    │   └── javascript
    │   │   └── rails.vim
    └── syntax
    │   ├── less
    │       └── rails.vim
    │   ├── sass
    │       └── rails.vim
    │   ├── scss
    │       └── rails.vim
    │   ├── coffee
    │       └── rails.vim
    │   ├── eruby
    │       └── rails.vim
    │   ├── haml
    │       └── rails.vim
    │   ├── css
    │       └── rails.vim
    │   ├── javascript
    │       └── rails.vim
    │   └── ruby
    │       └── rails.vim
├── .github
    └── FUNDING.yml
├── CONTRIBUTING.markdown
├── ftplugin
    └── railslog.vim
├── compiler
    └── rails.vim
├── syntax
    └── railslog.vim
├── README.markdown
├── plugin
    └── rails.vim
└── doc
    └── rails.txt


/.gitignore:
--------------------------------------------------------------------------------
1 | /rails.zip
2 | /rails.vba
3 | /doc/tags
4 | 


--------------------------------------------------------------------------------
/after/ftplugin/less/rails.vim:
--------------------------------------------------------------------------------
1 | source <sfile>:h:h/css/rails.vim
2 | 


--------------------------------------------------------------------------------
/after/ftplugin/sass/rails.vim:
--------------------------------------------------------------------------------
1 | source <sfile>:h:h/scss/rails.vim
2 | 


--------------------------------------------------------------------------------
/after/ftplugin/scss/rails.vim:
--------------------------------------------------------------------------------
1 | source <sfile>:h:h/css/rails.vim
2 | 


--------------------------------------------------------------------------------
/after/syntax/less/rails.vim:
--------------------------------------------------------------------------------
1 | source <sfile>:h:h/css/rails.vim
2 | 


--------------------------------------------------------------------------------
/after/syntax/sass/rails.vim:
--------------------------------------------------------------------------------
1 | source <sfile>:h:h/scss/rails.vim
2 | 


--------------------------------------------------------------------------------
/after/syntax/scss/rails.vim:
--------------------------------------------------------------------------------
1 | source <sfile>:h:h/css/rails.vim
2 | 


--------------------------------------------------------------------------------
/after/syntax/coffee/rails.vim:
--------------------------------------------------------------------------------
1 | source <sfile>:h:h/javascript/rails.vim
2 | 


--------------------------------------------------------------------------------
/after/ftplugin/coffee/rails.vim:
--------------------------------------------------------------------------------
1 | source <sfile>:h:h/javascript/rails.vim
2 | 


--------------------------------------------------------------------------------
/.github/FUNDING.yml:
--------------------------------------------------------------------------------
1 | github: tpope
2 | custom: ["https://www.paypal.me/vimpope"]
3 | 


--------------------------------------------------------------------------------
/after/syntax/eruby/rails.vim:
--------------------------------------------------------------------------------
1 | syn include @rubyTop <sfile>:h:h/ruby/rails.vim
2 | 


--------------------------------------------------------------------------------
/after/syntax/haml/rails.vim:
--------------------------------------------------------------------------------
1 | syn include @hamlRubyTop <sfile>:h:h/ruby/rails.vim
2 | 


--------------------------------------------------------------------------------
/after/syntax/css/rails.vim:
--------------------------------------------------------------------------------
1 | if expand('%:p') !~# '[\/]\%(app\|lib\|vendor\)[\/]assets[\/]'
2 |   finish
3 | endif
4 | 
5 | call rails#sprockets_syntax()
6 | 


--------------------------------------------------------------------------------
/after/syntax/javascript/rails.vim:
--------------------------------------------------------------------------------
1 | if expand('%:p') !~# '[\/]\%(app\|lib\|vendor\)[\/]assets[\/]'
2 |   finish
3 | endif
4 | 
5 | call rails#sprockets_syntax()
6 | 


--------------------------------------------------------------------------------
/after/ftplugin/ruby/rails.vim:
--------------------------------------------------------------------------------
1 | if (!exists('*RailsDetect') || !RailsDetect()) && expand('%:p') !~# '.*\ze[\/]\%(app\|config\|lib\|test\|spec\)[\/]'
2 |   finish
3 | endif
4 | 
5 | try
6 |   call rails#ruby_setup()
7 | catch /^Vim\%((\a\+)\)\=:E117:.*rails#ruby_setup/
8 | endtry
9 | 


--------------------------------------------------------------------------------
/after/ftplugin/css/rails.vim:
--------------------------------------------------------------------------------
 1 | try
 2 |   if expand('%:p') =~# '[\/]assets[\/]'
 3 |     call rails#sprockets_setup('css')
 4 |   endif
 5 |   if expand('%:p') =~# '[\/]javascript[\/]packs[\/]'
 6 |     call rails#webpacker_setup('css')
 7 |   endif
 8 | catch /^Vim\%((\a\+)\)\=:E117:/
 9 | endtry
10 | 


--------------------------------------------------------------------------------
/after/ftplugin/javascript/rails.vim:
--------------------------------------------------------------------------------
 1 | try
 2 |   if expand('%:p') =~# '[\/]assets[\/]'
 3 |     call rails#sprockets_setup('js')
 4 |   endif
 5 |   if expand('%:p') =~# '[\/]javascript[\/]packs[\/]'
 6 |     call rails#webpacker_setup('js')
 7 |   endif
 8 | catch /^Vim\%((\a\+)\)\=:E117:/
 9 | endtry
10 | 


--------------------------------------------------------------------------------
/CONTRIBUTING.markdown:
--------------------------------------------------------------------------------
 1 | If your [commit message sucks][suck], I'm not going to accept your pull
 2 | request.  I've explained very politely dozens of times that [my general
 3 | guidelines][guidelines] are absolute rules on my own repositories, so I may
 4 | lack the energy to explain it to you yet another time.  And please, if I ask
 5 | you to change something, `git commit --amend` and `git push -f`.
 6 | 
 7 | If a feature idea is nontrivial, you should probably open an issue to [discuss
 8 | it][] before attempting a pull request.  One of the biggest challenges in
 9 | maintaining rails.vim has been beating back the bloat, so do not assume that
10 | your idea will make the cut.  And if I like your idea, I'm generally amenable
11 | to just knocking it out myself, rather than making you familiarize yourself
12 | with a 4 thousand line code base.
13 | 
14 | [suck]: http://stopwritingramblingcommitmessages.com/
15 | [guidelines]: http://tbaggery.com/2008/04/19/a-note-about-git-commit-messages.html
16 | [discuss it]: http://www.igvita.com/2011/12/19/dont-push-your-pull-requests/
17 | 


--------------------------------------------------------------------------------
/ftplugin/railslog.vim:
--------------------------------------------------------------------------------
 1 | if exists('b:did_ftplugin')
 2 |   finish
 3 | endif
 4 | let b:did_ftplugin = 1
 5 | 
 6 | function! s:reload_log() abort
 7 |   if &buftype == 'quickfix' && get(w:, 'quickfix_title') =~ '^:cgetfile'
 8 |     let cmd = 'cgetfile ' .
 9 |           \ (exists('*fnameescape') ? fnameescape(w:quickfix_title[10:-1]) : w:quickfix_title[10:-1]) .
10 |           \ "|call setpos('.', " . string(getpos('.')) . ")"
11 |   else
12 |     let cmd = 'checktime'
13 |   endif
14 |   return cmd . "|if &l:filetype !=# 'railslog'|setfiletype railslog|endif"
15 | endfunction
16 | 
17 | if exists('w:quickfix_title')
18 |   runtime! ftplugin/qf.vim ftplugin/qf_*.vim ftplugin/qf/*.vim
19 | endif
20 | let b:undo_ftplugin = get(b:, 'undo_ftplugin', 'exe')
21 | nnoremap <buffer> <silent> R :<C-U>exe <SID>reload_log()<CR>
22 | nnoremap <buffer> <silent> G :<C-U>exe <SID>reload_log()<Bar>exe v:count ? v:count : '$'<CR>
23 | nnoremap <buffer> <silent> q :bwipe<CR>
24 | let b:undo_ftplugin .= '|sil! nunmap <buffer> R|sil! nunmap <buffer> G|sil! nunmap <buffer> q'
25 | setlocal noswapfile autoread
26 | let b:undo_ftplugin .= '|set swapfile< autoread<'
27 | if exists('+concealcursor')
28 |   setlocal concealcursor=nc conceallevel=2
29 |   let b:undo_ftplugin .= ' concealcursor< conceallevel<'
30 | else
31 |   let s:pos = getpos('.')
32 |   setlocal modifiable
33 |   silent exe '%s/\m\C\%(\e\[[0-9;]*m\|\r$\)//e' . (&gdefault ? '' : 'g')
34 |   call setpos('.', s:pos)
35 | endif
36 | setlocal readonly nomodifiable
37 | let b:undo_ftplugin .= ' noreadonly modifiable'
38 | 


--------------------------------------------------------------------------------
/compiler/rails.vim:
--------------------------------------------------------------------------------
 1 | " Vim compiler file
 2 | 
 3 | if exists("current_compiler")
 4 |   finish
 5 | endif
 6 | 
 7 | CompilerSet errorformat=%D(in\ %f),
 8 |       \%\\s%#from\ %f:%l:%m,
 9 |       \%\\s%#from\ %f:%l:,
10 |       \%\\s%##\ %f:%l:%m,
11 |       \%\\s%##\ %f:%l,
12 |       \%\\s%#[%f:%l:\ %#%m,
13 |       \%\\s%#%f:%l:\ %#%m,
14 |       \%\\s%#%f:%l:,
15 |       \%m\ [%f:%l]:,
16 |       \%+Erake\ aborted!,
17 |       \%+EDon't\ know\ how\ to\ build\ task\ %.%#,
18 |       \%+Einvalid\ option:%.%#,
19 |       \%+Irake\ %\\S%\\+%\\s%\\+#\ %.%#
20 | 
21 | runtime! compiler/rake.vim
22 | 
23 | let current_compiler = "rails"
24 | 
25 | CompilerSet makeprg=rails
26 | " CompilerSet makeprg=ruby\ bin/rails
27 | " CompilerSet makeprg=ruby\ script/rails
28 | 
29 | CompilerSet errorformat^=
30 |       \%\\S%\\+\ \ %#%[cefi]%[rxod]%[eir]%[a-z]%#%\\x1b[0m\ %\\+%\\S%\\+%$
31 |       \%\\&%\\x1b%\\S%\\+\ \ %#%m%\\>%\\x1b[0m\ \ %#%f,
32 |       \%\\s\ %#%[cefi]%[rxod]%[eir]%[a-z]%#\ %\\+%\\S%\\+%$
33 |       \%\\&%\\s\ %#%m%\\>\ \ %#%f,
34 |       \\ %#Overwrite%.%#%\\S%\\+\ \ %#%m%\\x1b[0m\ \ %#%f,
35 |       \%-G\ %#Overwrite%.%#\"h\"%.%#,
36 |       \%+GStarted\ %\\u%\\u%.%#,
37 |       \%+GCompleted\ %\\d%\\d%\\d%.%#,
38 |       \%+G[ActiveJob]%.%#]\ Perform%.%#,
39 |       \%.%#rails\ test\ %f:%l,
40 |       \%+GCurrent\ version:%.%#,
41 |       \%+G\ %#Status\ %#Migration\ ID%.%#,
42 |       \%+G\ The\ fixture\ ID\ for\ %.%#,
43 |       \%f:\ %s\ (%m)%$
44 |       \%\\&%.%#/fixtures/%.%#(%\\d%\\+),
45 |       \%+G\ %#Prefix\ %#Verb%.%#,
46 |       \%+G\ %#Code\ LOC:\ %.%#,
47 |       \%+GAbout\ your\ application's\ environment,
48 |       \%+Grun\ %\\S%#::Application.routes,
49 |       \%+Irails\ %\\S%\\+%\\s%\\+#\ %.%#,
50 |       \%+Eruby:%.%#(LoadError),
51 |       \%+EUsage:%.%#,
52 |       \%+ECould\ not\ find\ generator%.%#,
53 |       \%+EType\ 'rails'\ for\ help.,
54 |       \%\\&completion=rails#complete_rails,
55 |       \%\\&start=console,
56 |       \%\\&terminal=%\\C%\\%%(console%\\\|dbconsole%\\\|server%\\\|%[cs]%\\\|db%\\)%\\>:%\\@!%\\ze%.%#,
57 |       \%\\&force_start=%\\C%\\%%(console%\\\|dbconsole%\\\|server%\\\|%[cs]%\\\|db%\\)%\\>:%\\@!%\\ze%.%#,
58 |       \%\\&default=default
59 | 
60 | " -complete=customlist,rails#complete_rails
61 | 


--------------------------------------------------------------------------------
/syntax/railslog.vim:
--------------------------------------------------------------------------------
 1 | if exists('b:current_syntax')
 2 |   finish
 3 | endif
 4 | 
 5 | if has('conceal')
 6 |   syn match railslogEscape      '\e\[[0-9;]*m' conceal
 7 |   syn match railslogEscapeMN    '\e\[[0-9;]*m' conceal nextgroup=railslogModelNum,railslogEscapeMN skipwhite contained
 8 | else
 9 |   syn match railslogEscape      '\e\[[0-9;]*m'
10 |   syn match railslogEscapeMN    '\e\[[0-9;]*m' nextgroup=railslogModelNum,railslogEscapeMN skipwhite contained
11 | endif
12 | syn match   railslogQfFileName  "^[^()|]*|\@=" nextgroup=railslogQfSeparator
13 | syn match   railslogQfSeparator "|" nextgroup=railslogQfLineNr contained
14 | syn match   railslogQfLineNr    "[^|]*" contained contains=railslogQfError
15 | syn match   railslogQfError     "error" contained
16 | syn match   railslogRender      '\%(\%(^\||\)\s*\%(\e\[[0-9;]*m\)\=\)\@<=\%(Started\|Processing\|Rendering\|Rendered\|Redirected\|Completed\)\>'
17 | syn match   railslogComment     '\%(^\|[]|]\)\@<=\s*# .*'
18 | syn match   railslogModel       '\%(\%(^\|[]|]\)\s*\%(\e\[[0-9;]*m\)*\)\@<=\%(CACHE SQL\|CACHE\|SQL\)\>' skipwhite nextgroup=railslogModelNum,railslogEscapeMN
19 | syn match   railslogModel       '\%(\%(^\|[]|]\)\s*\%(\e\[[0-9;]*m\)*\)\@<=\%(CACHE \)\=\u\%(\w\|:\)* \%(Load\%( Including Associations\| IDs For Limited Eager Loading\)\=\|Columns\|Exists\|Count\|Create\|Update\|Destroy\|Delete all\)\>' skipwhite nextgroup=railslogModelNum,railslogEscapeMN
20 | syn region  railslogModelNum    start='(' end=')' contains=railslogNumber contained skipwhite
21 | syn match   railslogActiveJob   '\[ActiveJob\]'hs=s+1,he=e-1 nextgroup=railslogJobScope skipwhite
22 | syn match   railslogJobScope    '\[\u\%(\w\|:\)*\]' contains=railslogJobName contained
23 | syn match   railslogJob         '\%(\%(^\|[\]|]\)\s*\%(\e\[[0-9;]*m\)*\)\@<=\%(Enqueued\|Performing\|Performed\)\>' skipwhite nextgroup=railslogJobName
24 | syn match   railslogJobName     '\<\u\%(\w\|:\)*\>' contained
25 | syn match   railslogNumber      '\<\d\+%'
26 | syn match   railslogNumber      '[ (]\@<=\<\d\+\.\d\+\>\.\@!'
27 | syn match   railslogNumber      '[ (]\@<=\<\d\+\%(\.\d\+\)\=ms\>'
28 | syn region  railslogString      start='"' skip='\\"' end='"' oneline contained
29 | syn region  railslogHash        start='{' end='}' oneline contains=railslogHash,railslogString
30 | syn match   railslogIP          '\<\d\{1,3\}\%(\.\d\{1,3}\)\{3\}\>'
31 | syn match   railslogIP          '\<\%(\x\{1,4}:\)\+\%(:\x\{1,4}\)\+\>\|\S\@<!:\%(:\x\{1,4}\)\+\>\|\<\%(\x\{1,4}:\)\+\%(:\S\@!\|\x\{1,4}\>\)'
32 | syn match   railslogTimestamp   '\<\d\d\d\d-\d\d-\d\d \d\d:\d\d:\d\d\%( [+-]\d\d\d\d\| UTC\)\=\>'
33 | syn match   railslogSessionID   '\<\x\{32\}\>'
34 | syn match   railslogUUID        '\<\x\{8\}-\x\{4\}-\x\{4\}-\x\{4\}-\x\{12\}\>'
35 | syn match   railslogIdentifier  '\%(^\||\)\@<=\s*\%(Session ID\|Parameters\|Unpermitted parameters\)\ze:'
36 | syn match   railslogSuccess     '\<2\d\d\%( \u\w*\)\+\>'
37 | syn match   railslogRedirect    '\<3\d\d\%( \u\w*\)\+\>'
38 | syn match   railslogError       '\<[45]\d\d\%( \u\w*\)\+\>'
39 | syn match   railslogDeprecation '\<DEPRECATION WARNING\>'
40 | syn keyword railslogHTTP        OPTIONS GET HEAD POST PUT PATCH DELETE TRACE CONNECT
41 | 
42 | hi def link railslogQfFileName  Directory
43 | hi def link railslogQfLineNr    LineNr
44 | hi def link railslogQfError     Error
45 | hi def link railslogEscapeMN    railslogEscape
46 | hi def link railslogEscape      Ignore
47 | hi def link railslogComment     Comment
48 | hi def link railslogRender      Keyword
49 | hi def link railslogModel       Type
50 | hi def link railslogJob         Repeat
51 | hi def link railslogJobName     Structure
52 | hi def link railslogNumber      Float
53 | hi def link railslogString      String
54 | hi def link railslogSessionID   Constant
55 | hi def link railslogUUID        Constant
56 | hi def link railslogIdentifier  Identifier
57 | hi def link railslogRedirect    railslogSuccess
58 | hi def link railslogSuccess     Special
59 | hi def link railslogDeprecation railslogError
60 | hi def link railslogError       Error
61 | hi def link railslogHTTP        Special
62 | 


--------------------------------------------------------------------------------
/README.markdown:
--------------------------------------------------------------------------------
  1 | # rails.vim
  2 | 
  3 | This is a massive (in a good way) Vim plugin for editing Ruby on Rails
  4 | applications.
  5 | 
  6 | * Easy navigation of the Rails directory structure.  `gf` considers
  7 |   context and knows about partials, fixtures, and much more.  There are
  8 |   two commands, `:A` (alternate) and `:R` (related) for easy jumping
  9 |   between files, including favorites like model to schema, template to
 10 |   helper, and controller to functional test.  Commands like `:Emodel`,
 11 |   `:Eview`, `:Econtroller`, are provided to `:edit` files by type, along
 12 |   with `S`, `V`, and `T` variants for `:split`, `:vsplit`, and
 13 |   `:tabedit`.  Throw a bang on the end (`:Emodel foo!`) to automatically
 14 |   create the file with the standard boilerplate if it doesn't exist.
 15 |   `:help rails-navigation`
 16 | 
 17 | * Enhanced syntax highlighting.  From `has_and_belongs_to_many` to
 18 |   `distance_of_time_in_words`, it's here.
 19 | 
 20 | * Interface to the `rails` command.  Generally, use `:Rails console` to
 21 |   call `rails console`.  Many commands have wrappers with additional features:
 22 |   `:Generate controller Blog` generates a blog controller and loads the
 23 |   generated files into the quickfix list, and `:Runner` wraps `rails runner`
 24 |   and doubles as a direct test runner.  `:help rails-exec`
 25 | 
 26 | * Default task runner.  Use `:Rails` (with no arguments) to run the current
 27 |   test, spec, or feature.  Use `:.Rails` to do a focused run of just the
 28 |   method, example, or scenario on the current line.  `:Rails` can also run
 29 |   arbitrary migrations, load individual fixtures, and more.
 30 |   `:help rails-default-task`
 31 | 
 32 | * Partial and concern extraction.  In a view, `:Extract {file}`
 33 |   replaces the desired range (typically selected in visual line mode)
 34 |   with `render '{file}'`, which is automatically created with your
 35 |   content.  In a model or controller, a concern is created, with the
 36 |   appropriate `include` declaration left behind.
 37 |   `:help rails-:Extract`
 38 | 
 39 | * Fully customizable. Define "projections" at the global, app, or gem
 40 |   level to define navigation commands and override the alternate file,
 41 |   default rake task, syntax highlighting, and more.
 42 |   `:help rails-projections`.
 43 | 
 44 | * Integration with other plugins.  If [dispatch.vim][] is installed, `:Rails`
 45 |   and other command wrappers will use it for asynchronous execution.  Users of
 46 |   [dadbod.vim](https://github.com/tpope/vim-dadbod) and
 47 |   [dbext](http://www.vim.org/script.php?script_id=356) get easy access to
 48 |   their application's database.  Users of
 49 |   [abolish.vim](https://github.com/tpope/vim-abolish) get pluralize and
 50 |   tableize coercions, and users of [bundler.vim][] get a smattering of
 51 |   features.   `:help rails-integration`
 52 | 
 53 | ## Installation
 54 | 
 55 | If you don't have a preferred installation method, I recommend
 56 | installing [pathogen.vim](https://github.com/tpope/vim-pathogen), and
 57 | then simply copy and paste:
 58 | 
 59 |     cd ~/.vim/bundle
 60 |     git clone https://github.com/tpope/vim-rails.git
 61 |     vim -u NONE -c "helptags vim-rails/doc" -c q
 62 | 
 63 | While not strictly necessary, [bundler.vim][] and [dispatch.vim][] are highly
 64 | recommended.
 65 | 
 66 | [bundler.vim]: https://github.com/tpope/vim-bundler
 67 | [dispatch.vim]: https://github.com/tpope/vim-dispatch
 68 | 
 69 | ## FAQ
 70 | 
 71 | > I installed the plugin and started Vim.  Why does only the `:Rails`
 72 | > command exist?
 73 | 
 74 | This plugin cares about the current file, not the current working
 75 | directory.  Edit a file from a Rails application.
 76 | 
 77 | > I opened a new tab.  Why does only the `:Rails` command exist?
 78 | 
 79 | This plugin cares about the current file, not the current working directory.
 80 | Edit a file from a Rails application.  You can use `:AT` and the `:T` family
 81 | of commands to open a new tab and edit a file at the same time.
 82 | 
 83 | > Can I use rails.vim to edit Rails engines?
 84 | 
 85 | It's not supported, but if you `touch config/environment.rb` in the root
 86 | of the engine, things should mostly work.
 87 | 
 88 | > Can I use rails.vim to edit other Ruby projects?
 89 | 
 90 | I wrote [rake.vim](https://github.com/tpope/vim-rake) for exactly that
 91 | purpose.  It activates for any project with a `Rakefile` that's not a
 92 | Rails application.
 93 | 
 94 | > What Rails versions are supported?
 95 | 
 96 | All of them, although you may notice a few minor breakages if you dip below
 97 | 3.0.  A few features like syntax highlighting tend to reflect the latest
 98 | version only.
 99 | 
100 | > Didn't rails.vim used to handle indent settings?
101 | 
102 | It got yanked after increasing contention over JavaScript.  Check out
103 | [sleuth.vim](https://github.com/tpope/vim-sleuth).
104 | 
105 | ## Self-Promotion
106 | 
107 | Like rails.vim? Follow the repository on
108 | [GitHub](https://github.com/tpope/vim-rails) and vote for it on
109 | [vim.org](http://www.vim.org/scripts/script.php?script_id=1567).  And if
110 | you're feeling especially charitable, follow [tpope](http://tpo.pe/) on
111 | [Twitter](http://twitter.com/tpope) and
112 | [GitHub](https://github.com/tpope).
113 | 
114 | ## License
115 | 
116 | Copyright (c) Tim Pope.  Distributed under the same terms as Vim itself.
117 | See `:help license`.
118 | 


--------------------------------------------------------------------------------
/plugin/rails.vim:
--------------------------------------------------------------------------------
  1 | " rails.vim - Detect a rails application
  2 | " Author:       Tim Pope <http://tpo.pe/>
  3 | " GetLatestVimScripts: 1567 1 :AutoInstall: rails.vim
  4 | 
  5 | " Install this file as plugin/rails.vim.
  6 | 
  7 | if exists('g:loaded_rails') || &cp || v:version < 800
  8 |   finish
  9 | endif
 10 | let g:loaded_rails = 1
 11 | 
 12 | " Utility Functions {{{1
 13 | 
 14 | function! s:error(str)
 15 |   echohl ErrorMsg
 16 |   echomsg a:str
 17 |   echohl None
 18 |   let v:errmsg = a:str
 19 | endfunction
 20 | 
 21 | let s:slash = exists('+shellslash') ? '\' : '/'
 22 | function! s:IsAbs(path) abort
 23 |   return tr(a:path, s:slash, '/') =~# '^/\|^\a\+:'
 24 | endfunction
 25 | 
 26 | " }}}1
 27 | " Detection {{{1
 28 | 
 29 | function! RailsDetect(...) abort
 30 |   if exists('b:rails_root')
 31 |     return 1
 32 |   endif
 33 |   if a:0
 34 |     let path = a:1
 35 |   elseif &l:buftype =~# '^\%(nowrite\)\=$' && len(@%) || &l:buftype =~# '^\%(nofile\|acwrite\)' && s:IsAbs(@%)
 36 |     let path = @%
 37 |   else
 38 |     return
 39 |   endif
 40 |   if !s:IsAbs(path)
 41 |     let s = exists('+shellslash') && !&shellslash ? '\' : '/'
 42 |     let path = substitute(getcwd(), '\' . s . '\=$', s, '') . path
 43 |   endif
 44 |   let path = substitute(path, '[' . s:slash . '/]$', '', '')
 45 |   try
 46 |     if exists('*ExcludeBufferFromDiscovery') && ExcludeBufferFromDiscovery(file, 'projectionist')
 47 |       return
 48 |     endif
 49 |   catch
 50 |   endtry
 51 | 
 52 |   if exists('*ProjectionistHas')
 53 |     let previous = ''
 54 |     while path !=# previous && path !~# '^\.\=$\|^[\/][\/][^\/]*$'
 55 |       if ProjectionistHas('config/environment.rb&app/', path)
 56 |         let b:rails_root = path
 57 |         return 1
 58 |       endif
 59 |       let previous = path
 60 |       let path = fnamemodify(path, ':h')
 61 |     endwhile
 62 |     return 0
 63 |   endif
 64 |   let file = findfile('config/environment.rb', escape(path, ', ').';')
 65 |   if !empty(file) && isdirectory(fnamemodify(file, ':p:h:h') . '/app')
 66 |     let b:rails_root = fnamemodify(file, ':p:h:h')
 67 |     return 1
 68 |   endif
 69 | endfunction
 70 | 
 71 | function! s:LogDetect() abort
 72 |   let path = matchstr(get(w:, 'quickfix_title'), '\<cgetfile \zs.*\ze[\\/]log[\\/].*.log$')
 73 |   if !empty(path) && filereadable(path . '/config/environment.rb') && isdirectory(path . '/app')
 74 |     let b:rails_root = path
 75 |     setlocal filetype=railslog
 76 |   endif
 77 | endfunction
 78 | 
 79 | " }}}1
 80 | " Initialization {{{1
 81 | 
 82 | if !exists('g:did_load_ftplugin')
 83 |   filetype plugin on
 84 | endif
 85 | if !exists('g:loaded_projectionist')
 86 |   runtime! plugin/projectionist.vim
 87 | endif
 88 | 
 89 | function! s:doau_user(arg) abort
 90 |   if exists('#User#'.a:arg)
 91 |     try
 92 |       let [modelines, &modelines] = [&modelines, 0]
 93 |       exe 'doautocmd User' a:arg
 94 |     finally
 95 |       let &modelines = modelines
 96 |     endtry
 97 |   endif
 98 | endfunction
 99 | 
100 | augroup railsPluginDetect
101 |   autocmd!
102 | 
103 |   autocmd BufNewFile,BufReadPost *
104 |         \ if RailsDetect() && empty(&filetype) |
105 |         \   call rails#buffer_setup() |
106 |         \ endif
107 |   autocmd VimEnter *
108 |         \ if get(g:, 'rails_vim_enter', get(g:, 'projectionist_vim_enter', 1)) &&
109 |         \     empty(expand("<amatch>")) && RailsDetect(getcwd()) |
110 |         \   call rails#buffer_setup() |
111 |         \   call s:doau_user('BufEnterRails') |
112 |         \ endif
113 |   autocmd FileType netrw
114 |         \ if RailsDetect(get(b:, 'netrw_curdir', @%)) |
115 |         \   call s:doau_user('BufEnterRails') |
116 |         \ endif
117 |   autocmd FileType * if RailsDetect() | call rails#buffer_setup() | endif
118 | 
119 |   autocmd BufNewFile,BufReadPost */config/*.yml{,.example,.sample},*/{test,spec}/fixtures/*.yml
120 |         \ if &filetype !=# 'eruby.yaml' && RailsDetect() |
121 |         \   set filetype=eruby.yaml |
122 |         \ endif
123 |   autocmd BufNewFile,BufReadPost *.rjs,*.rxml,*.builder,*.jbuilder,*.ruby
124 |         \ if &filetype !=# 'ruby' | set filetype=ruby | endif
125 |   autocmd BufNewFile,BufReadPost *.turbo_stream.erb
126 |         \ if &filetype !=# 'eruby.html' | set filetype=eruby.html | endif
127 |   autocmd BufReadPost *.log if RailsDetect() | set filetype=railslog | endif
128 | 
129 |   autocmd FileType qf call s:LogDetect()
130 | 
131 |   autocmd User ProjectionistDetect
132 |         \ if RailsDetect(get(g:, 'projectionist_file', '')) |
133 |         \   call projectionist#append(b:rails_root,
134 |         \     {'*': {"console": rails#app().static_rails_command('console')}}) |
135 |         \ endif
136 | augroup END
137 | 
138 | command! -bang -bar -nargs=* -range=-1 -complete=customlist,rails#complete_rails Rails execute rails#command(<bang>0, '<mods>', <count>, <q-args>)
139 | 
140 | " }}}1
141 | " dadbod.vim support {{{1
142 | 
143 | call extend(g:, {'db_adapters': {}}, 'keep')
144 | call extend(g:db_adapters, {
145 |       \ 'oracle-enhanced': 'oracle',
146 |       \ 'mysql2': 'mysql',
147 |       \ 'sqlite3': 'sqlite'}, 'keep')
148 | 
149 | let g:db_adapter_rails = 'rails#db_'
150 | 
151 | " }}}1
152 | " abolish.vim support {{{1
153 | 
154 | function! s:function(name)
155 |     return function(substitute(a:name,'^s:',matchstr(expand('<sfile>'), '<SNR>\d\+_'),''))
156 | endfunction
157 | 
158 | augroup railsPluginAbolish
159 |   autocmd!
160 |   autocmd VimEnter * call s:abolish_setup()
161 | augroup END
162 | 
163 | function! s:abolish_setup()
164 |   if exists('g:Abolish') && has_key(g:Abolish,'Coercions')
165 |     if !has_key(g:Abolish.Coercions,'l')
166 |       let g:Abolish.Coercions.l = s:function('s:abolish_l')
167 |     endif
168 |     if !has_key(g:Abolish.Coercions,'t')
169 |       let g:Abolish.Coercions.t = s:function('s:abolish_t')
170 |     endif
171 |   endif
172 | endfunction
173 | 
174 | function! s:abolish_l(word)
175 |   let singular = rails#singularize(a:word)
176 |   return a:word ==? singular ? rails#pluralize(a:word) : singular
177 | endfunction
178 | 
179 | function! s:abolish_t(word)
180 |   if a:word =~# '\u'
181 |     return rails#pluralize(rails#underscore(a:word))
182 |   else
183 |     return rails#singularize(rails#camelize(a:word))
184 |   endif
185 | endfunction
186 | 
187 | " }}}1
188 | " vim:set sw=2 sts=2:
189 | 


--------------------------------------------------------------------------------
/after/syntax/ruby/rails.vim:
--------------------------------------------------------------------------------
  1 | hi def link rubyEntity                      rubyMacro
  2 | hi def link rubyEntities                    rubyMacro
  3 | hi def link rubyExceptionMacro              rubyMacro
  4 | hi def link rubyValidation                  rubyMacro
  5 | hi def link rubyCallback                    rubyMacro
  6 | hi def link rubyRakeMacro                   rubyMacro
  7 | hi def link rubyTestMacro                   rubyMacro
  8 | hi def link rubyMacro                       Macro
  9 | hi def link rubyRoute                       rubyControl
 10 | hi def link rubySchema                      rubyControl
 11 | hi def link rubyResponse                    rubyControl
 12 | hi def link rubyAction                      rubyControl
 13 | hi def link rubyUrlHelper                   rubyHelper
 14 | hi def link rubyViewHelper                  rubyHelper
 15 | hi def link rubyTestHelper                  rubyHelper
 16 | hi def link rubyUserAssertion               rubyAssertion
 17 | hi def link rubyAssertion                   rubyException
 18 | hi def link rubyTestAction                  rubyControl
 19 | hi def link rubyHelper                      Function
 20 | hi def link rubyDebug                       Debug
 21 | 
 22 | let s:has_app = exists('*RailsDetect') && RailsDetect()
 23 | if s:has_app
 24 |   let s:path = '/' . rails#buffer().relative()
 25 | else
 26 |   let s:path = tr(expand('%:p'), '\', '/')
 27 | endif
 28 | 
 29 | if s:path =~# '\v/app/%(channels|controllers|helpers|jobs|mailers|models)/.*\.rb$|/app/views/'
 30 |   syn match rubyHelper '\v<%(logger)>[!?:]@!'
 31 | endif
 32 | 
 33 | if s:path =~# '/app/models/.*_observer\.rb$'
 34 |   syn match rubyMacro '\v<%(observe)>[!?:]@!'
 35 | 
 36 | elseif s:path =~# '/app/models/.*\.rb$'
 37 |   syn match rubyMacro '\v<%(accepts_nested_attributes_for|attr_readonly|attribute|enum|serialize|store|store_accessor)>[!?:]@!'
 38 |   syn match rubyMacro '\v<%(default_scope|scope)>[!?:]@!'
 39 |   syn match rubyEntity '\v<%(belongs_to|has_one|composed_of)>[!?:]@!'
 40 |   syn match rubyEntities '\v<%(has_many|has_and_belongs_to_many)>[!?:]@!'
 41 |   syn match rubyCallback '\v<%(before_validation|after_validation)>[!?:]@!'
 42 |   syn match rubyCallback '\v<%(before_create|before_destroy|before_save|before_update)>[!?:]@!'
 43 |   syn match rubyCallback '\v<%(after_create|after_destroy|after_save|after_update)>[!?:]@!'
 44 |   syn match rubyCallback '\v<%(around_create|around_destroy|around_save|around_update)>[!?:]@!'
 45 |   syn match rubyCallback '\v<%(after_commit|after_create_commit|after_update_commit|after_save_commit|after_destroy_commit|after_rollback)>[!?:]@!'
 46 |   syn match rubyCallback '\v<%(after_find|after_initialize|after_touch)>[!?:]@!'
 47 |   syn match rubyValidation '\v<%(validates|validates_acceptance_of|validates_associated|validates_confirmation_of|validates_each|validates_exclusion_of|validates_format_of|validates_inclusion_of|validates_length_of|validates_numericality_of|validates_presence_of|validates_absence_of|validates_size_of|validates_with)>[!?:]@!'
 48 |   syn match rubyValidation '\v<%(validates_associated|validates_uniqueness_of)>[!?:]@!'
 49 |   syn match rubyMacro '\v<%(validate|has_rich_text|has_secure_password|has_secure_token|has_one_attached|has_many_attached|delegated_type)>[!?:]@!'
 50 | endif
 51 | 
 52 | if s:path =~# '/app/jobs/.*\.rb$'
 53 |   syn match rubyMacro '\v<%(queue_as)>[!?:]@!'
 54 |   syn match rubyExceptionMacro '\v<%(rescue_from|retry_on|discard_on)>[!?:]@!'
 55 |   syn match rubyCallback '\v<%(before_enqueue|around_enqueue|after_enqueue|before_perform|around_perform|after_perform)>[!?:]@!'
 56 | endif
 57 | 
 58 | if s:path =~# '/app/helpers/.*_helper\.rb$\|/app/views/'
 59 |   let s:autogenerated_helpers = '
 60 |         \ action_name asset_path asset_url atom_feed audio_path audio_tag audio_url auto_discovery_link_tag
 61 |         \ button_tag button_to
 62 |         \ cache cache_fragment_name cache_if cache_unless caching? capture cdata_section check_box check_box_tag class_names collection_check_boxes collection_radio_buttons collection_select color_field color_field_tag compute_asset_extname compute_asset_host compute_asset_path concat content_for content_for? content_tag controller controller_name controller_path convert_to_model cookies csp_meta_tag csrf_meta_tag csrf_meta_tags current_cycle current_page? cycle
 63 |         \ date_field date_field_tag date_select datetime_field datetime_field_tag datetime_local_field datetime_local_field_tag datetime_select debug distance_of_time_in_words distance_of_time_in_words_to_now dom_class dom_id
 64 |         \ email_field email_field_tag escape_javascript escape_once excerpt
 65 |         \ favicon_link_tag field_id field_name field_set_tag fields fields_for file_field file_field_tag flash font_path font_url form_for form_tag form_with
 66 |         \ grouped_collection_select grouped_options_for_select
 67 |         \ headers hidden_field hidden_field_tag highlight
 68 |         \ image_path image_submit_tag image_tag image_url
 69 |         \ j javascript_cdata_section javascript_include_tag javascript_path javascript_tag javascript_url
 70 |         \ l label label_tag link_to link_to_if link_to_unless link_to_unless_current localize
 71 |         \ mail_to month_field month_field_tag
 72 |         \ number_field number_field_tag number_to_currency number_to_human number_to_human_size number_to_percentage number_to_phone number_with_delimiter number_with_precision
 73 |         \ option_groups_from_collection_for_select options_for_select options_from_collection_for_select
 74 |         \ params password_field password_field_tag path_to_asset path_to_audio path_to_font path_to_image path_to_javascript path_to_stylesheet path_to_video phone_field phone_field_tag phone_to pluralize preload_link_tag provide public_compute_asset_path
 75 |         \ radio_button radio_button_tag range_field range_field_tag raw render request request_forgery_protection_token reset_cycle response
 76 |         \ safe_concat safe_join sanitize sanitize_css search_field search_field_tag select_date select_datetime select_day select_hour select_minute select_month select_second select_tag select_time select_year session simple_format sms_to strip_links strip_tags stylesheet_link_tag stylesheet_path stylesheet_url submit_tag
 77 |         \ t tag telephone_field telephone_field_tag text_area text_area_tag text_field text_field_tag time_ago_in_words time_field time_field_tag time_select time_tag time_zone_options_for_select time_zone_select to_sentence token_list translate truncate
 78 |         \ uncacheable! url_field url_field_tag url_for url_to_asset url_to_audio url_to_font url_to_image url_to_javascript url_to_stylesheet url_to_video utf8_enforcer_tag
 79 |         \ video_path video_tag video_url
 80 |         \ week_field week_field_tag weekday_options_for_select weekday_select word_wrap
 81 |         \'[1:-1]
 82 |   exe 'syn match rubyViewHelper "\v<%(' . escape(tr(s:autogenerated_helpers, ' ', '|'), '?') . ')[[:keyword:]!?:]@!"'
 83 |   syn match rubyViewHelper '\v<select>%([!?:]|\s*[{]|\s*do>|\s*[(]=\s*[&])@!'
 84 |   syn match rubyViewHelper '\v\.@<!<%(h|html_escape|u|url_encode)>[!?:]@!'
 85 |   syn match rubyViewHelper '\v<%(asset_pack_path|image_pack_tag|javascript_pack_tag|stylesheet_pack_tag)>[!?:]@!'
 86 |   syn match rubyViewHelper '\v<action_cable_meta_tag>[!?:]@!'
 87 |   if s:path =~# '_[^\/]*$'
 88 |     syn match rubyViewHelper '\v<local_assigns>[!?:]@!'
 89 |   endif
 90 | endif
 91 | 
 92 | if s:path =~# '/app/controllers/.*\.rb$'
 93 |   syn match rubyHelper '\v<%(params|request|response|session|headers|cookies|flash)>[!?:]@!'
 94 |   syn match rubyMacro '\v<%(protect_from_forgery|skip_forgery_protection|http_basic_authenticate_with)>[!?:]@!'
 95 |   syn match   rubyMacro '\v<respond_to>\ze[( ] *[:*]'
 96 |   syn match   rubyResponse '\v<respond_to>\ze +%([&{]|do>)'
 97 |   syn match rubyResponse '\v<%(render|head|redirect_to|redirect_back|redirect_back_or_to|respond_with|send_data|send_file)>[!?:]@!'
 98 |   syn match rubyResponse '\v<%(authenticate_or_request_with_http_basic|authenticate_with_http_basic|http_basic_authenticate_or_request_with|request_http_basic_authentication)>[!?:]@!'
 99 | endif
100 | 
101 | let b:rails_path = s:path
102 | if s:path =~# '/app/controllers/.*\.rb$\|/app/mailers/.*\.rb$\|/app/models/.*_mailer\.rb$'
103 |   syn match rubyHelper '\v<%(render_to_string)>[!?:]@!'
104 |   syn match rubyCallback '\v<%(before|append_before|prepend_before|after|append_after|prepend_after|around|append_around|prepend_around|skip_before|skip_after|skip)_action>[!?:]@!'
105 |   syn match rubyMacro '\v<%(helper|helper_attr|helper_method|layout)>[!?:]@!'
106 |   syn match rubyExceptionMacro '\v<%(rescue_from)>[!?:]@!'
107 | endif
108 | 
109 | if s:path =~# '/app/mailers/.*\.rb$\|/app/models/.*_mailer\.rb$'
110 |   syn match rubyResponse '\v<%(mail|render)>[!?:]@!'
111 |   syn match   rubyResponse '\v<headers>[!?:]@!'
112 |   syn match   rubyHelper '\v<headers\[@='
113 |   syn match rubyHelper '\v<%(params|attachments)>[!?:]@!'
114 |   syn match rubyMacro '\v<%(default)>[!?:]@!'
115 |   syn match rubyMacro '\v<%(register_interceptor|register_interceptors|register_observer|register_observers)>[!?:]@!'
116 | endif
117 | 
118 | if s:path =~# '/app/\w\+/concerns/.*\.rb$'
119 |   syn match rubyMacro '\v<%(included|class_methods)>[!?:]@!'
120 | endif
121 | 
122 | if s:path =~# '\v/app/%(controllers|helpers|mailers)/.*\.rb$|/app/views/|/test/(controllers|integration|system)/.*_test\.rb$|/spec/(features|requests)/.*_spec\.rb$'
123 |   syn match rubyUrlHelper '\v<%(url_for|polymorphic_path|polymorphic_url|edit_polymorphic_path|edit_polymorphic_url|new_polymorphic_path|new_polymorphic_url)>[!?:]@!'
124 | endif
125 | 
126 | if s:path =~# '/db/migrate/.*\.rb$\|/db/schema\.rb$'
127 |   syn match rubySchema '\v<%(create_table|change_table|drop_table|rename_table|create_join_table|drop_join_table)>[!?:]@!'
128 |   syn match rubySchema '\v<%(create_schema|drop_schema)>[!?:]@!'
129 |   syn match rubySchema '\v<%(add_column|rename_column|change_column|change_column_default|change_column_null|remove_column|remove_columns)>[!?:]@!'
130 |   syn match rubySchema '\v<%(add_foreign_key|remove_foreign_key)>[!?:]@!'
131 |   syn match rubySchema '\v<%(add_timestamps|remove_timestamps)>[!?:]@!'
132 |   syn match rubySchema '\v<%(add_reference|remove_reference|add_belongs_to|remove_belongs_to)>[!?:]@!'
133 |   syn match rubySchema '\v<%(add_index|remove_index|rename_index)>[!?:]@!'
134 |   syn match rubySchema '\v<%(enable_extension|reversible|revert)>[!?:]@!'
135 |   syn match rubySchema '\v<%(execute|transaction)>[!?:]@!'
136 | endif
137 | 
138 | if s:path =~# '\.rake$\|/Rakefile[^/]*$'
139 |   syn match rubyRakeMacro '\v^\s*\zs%(task|file|namespace|desc)>%([!?:]|\s*[=])@!'
140 | endif
141 | 
142 | if s:path =~# '/config/routes\>.*\.rb$'
143 |   syn match rubyRoute '\v<%(resource|resources|collection|member|new|nested|shallow)>[!?:]@!'
144 |   syn match rubyRoute '\v<%(match|get|put|patch|post|delete|root|mount)>[!?:]@!'
145 |   syn match rubyRoute '\v<%(scope|controller|namespace|constraints|defaults)>[!?:]@!'
146 |   syn match rubyRoute '\v<%(concern|concerns)>[!?:]@!'
147 |   syn match rubyRoute '\v<%(direct|resolve)>[!?:]@!'
148 |   syn match rubyHelper '\v<%(redirect)>[!?:]@!'
149 | endif
150 | 
151 | if s:path =~# '/test\%(/\|/.*/\)test_[^\/]*\.rb$\|/test/.*_test\.rb$\|/features/step_definitions/.*\.rb$'
152 |   syn match rubyAssertion '\v<%(refute|refute_empty|refute_equal|refute_in_delta|refute_in_epsilon|refute_includes|refute_instance_of|refute_kind_of|refute_match|refute_nil|refute_operator|refute_predicate|refute_respond_to|refute_same)>[!?:]@!'
153 |   syn match rubyAssertion '\v<%(assert|assert_empty|assert_equal|assert_in_delta|assert_in_epsilon|assert_includes|assert_instance_of|assert_kind_of|assert_match|assert_nil|assert_operator|assert_predicate|assert_respond_to|assert_same)>[!?:]@!'
154 |   syn match rubyAssertion '\v<%(assert_not|assert_not_empty|assert_not_equal|assert_not_in_delta|assert_not_in_epsilon|assert_not_includes|assert_not_instance_of|assert_not_kind_of|assert_no_match|assert_not_nil|assert_not_operator|assert_not_predicate|assert_not_respond_to|assert_not_same)>[!?:]@!'
155 |   syn match rubyAssertion '\v<%(assert_raises|assert_send|assert_throws)>[!?:]@!'
156 |   syn match rubyAssertion '\v<%(assert_nothing_raised|assert_not_send|assert_nothing_thrown)>[!?:]@!'
157 |   syn match rubyAssertion '\v<%(assert_raise|assert_block|assert_mock|assert_output|assert_raise_with_message|assert_silent)>[!?:]@!'
158 |   syn match rubyAssertion '\v<%(flunk)>[!?:]@!'
159 | endif
160 | 
161 | if s:path =~# '/spec/.*_spec\.rb$'
162 |   syn match rubyTestHelper '\v<subject>[!?:]@!'
163 |   syn match rubyTestMacro '\v<%(let|given)!=[[:keyword:]!?:]@!'
164 |   syn match rubyTestMacro '\v<subject>!=\ze%(\s*[(]|\s+[{&:]|\s+do\>)'
165 |   syn match rubyTestMacro '\v<%(before|after|around|background|setup|teardown)>[!?:]@!'
166 |   syn match rubyTestMacro '\v<%(context|describe|feature|shared_context|shared_examples|shared_examples_for)>[!?:]@!' containedin=rubyKeywordAsMethod
167 |   syn match rubyTestMacro '\v<%(it|example|specify|scenario|include_examples|include_context|it_should_behave_like|it_behaves_like)>[!?:]@!'
168 |   syn match rubyDebug '\v<%(fcontext|fdescribe)>[!?:]@!' containedin=rubyKeywordAsMethod
169 |   syn match rubyDebug '\v<%(fit|fexample|fspecify)>[!?:]@!'
170 |   syn match rubyComment '\v<%(xcontext|xdescribe|xfeature)>[!?:]@!' containedin=rubyKeywordAsMethod
171 |   syn match rubyComment '\v<%(xit|xexample|xspecify|xscenario)>[!?:]@!'
172 | endif
173 | if s:path =~# '/spec/.*_spec\.rb$\|/features/step_definitions/.*\.rb$'
174 |   syn match rubyAssertion '\v<%(pending|skip|expect|is_expected|expect_any_instance_of|allow|allow_any_instance_of)>[!?:]@!'
175 |   syn match rubyTestHelper '\v<%(described_class)>[!?:]@!'
176 |   syn match rubyTestHelper '\v<%(double|instance_double|class_double|object_double)>[!?:]@!'
177 |   syn match rubyTestHelper '\v<%(spy|instance_spy|class_spy|object_spy)>[!?:]@!'
178 |   syn match rubyTestAction '\v<%(stub_const|hide_const)>[!?:]@!'
179 | endif
180 | 
181 | if s:path =~# '\v/test/%(channels|controllers|helpers|integration|mailers|models|system)/.*_test\.rb$'
182 |   if s:has_app && !empty(rails#app().user_assertions())
183 |     exe "syn match rubyUserAssertion '\\v<%(" . escape(join(rails#app().user_assertions(), '|'), '?') . ")[[:keyword:]?!:]@!'"
184 |   endif
185 |   syn match rubyTestMacro '\v<%(test|setup|teardown)>[!?:]@!'
186 |   syn match rubyAssertion '\v<%(assert_difference|assert_no_difference)>[!?:]@!'
187 |   syn match rubyAssertion '\v<%(assert_changes|assert_no_changes)>[!?:]@!'
188 |   syn match rubyAssertion '\v<%(assert_emails|assert_enqueued_emails|assert_no_emails|assert_no_enqueued_emails)>[!?:]@!'
189 |   syn match rubyTestAction '\v<%(travel|travel_to|travel_back|freeze_time|unfreeze_time)>[!?:]@!'
190 | endif
191 | if s:path =~# '\v/test/%(controllers|integration|system)/.*_test\.rb$'
192 |   syn match rubyAssertion '\v<%(assert_response|assert_redirected_to|assert_template|assert_recognizes|assert_generates|assert_routing)>[!?:]@!'
193 | endif
194 | if s:path =~# '\v/test/%(controllers|helpers|integration|system)/.*_test\.rb$'
195 |   syn match rubyAssertion '\v<%(assert_dom_equal|assert_dom_not_equal|assert_select|assert_select_encoded|assert_select_email)>[!?:]@!'
196 |   syn match rubyTestHelper '\v<%(css_select)>[!?:]@!'
197 | endif
198 | if s:path =~# '/test/system/.*_test\.rb$' ||
199 |       \ s:has_app && rails#buffer().type_name('test-system')
200 |   syn match rubyAssertion     '\v<%(assert_matches_css|assert_matches_selector|assert_matches_xpath)>[!?:]@!'
201 |   syn match rubyAssertion     '\v<%(refute_matches_css|refute_matches_selector|refute_matches_xpath)>[!?:]@!'
202 |   syn match rubyAssertion '\v<%(assert_not_matches_css|assert_not_matches_selector|assert_not_matches_xpath)>[!?:]@!'
203 |   syn match rubyAssertion    '\v<%(assert_button|assert_checked_field|assert_content|assert_css|assert_current_path|assert_field|assert_link|assert_select|assert_selector|assert_table|assert_text|assert_title|assert_unchecked_field|assert_xpath)>[!?:]@!'
204 |   syn match rubyAssertion '\v<%(assert_no_button|assert_no_checked_field|assert_no_content|assert_no_css|assert_no_current_path|assert_no_field|assert_no_link|assert_no_select|assert_no_selector|assert_no_table|assert_no_text|assert_no_title|assert_no_unchecked_field|assert_no_xpath)>[!?:]@!'
205 |   syn match rubyAssertion    '\v<%(refute_button|refute_checked_field|refute_content|refute_css|refute_current_path|refute_field|refute_link|refute_select|refute_selector|refute_table|refute_text|refute_title|refute_unchecked_field|refute_xpath)>[!?:]@!'
206 | endif
207 | 
208 | if s:path =~# '/spec/controllers/.*_spec\.rb$'
209 |   syn match rubyTestMacro '\v<%(render_views)>[!?:]@!'
210 |   syn match rubyTestHelper '\v<%(assigns)>[!?:]@!'
211 | endif
212 | if s:path =~# '/spec/helpers/.*_spec\.rb$'
213 |   syn match rubyTestAction '\v<%(assign)>[!?:]@!'
214 |   syn match rubyTestHelper '\v<helper>[!?:]@!'
215 |   syn match rubyTestMacro '\v<helper>!=\ze%(\s*[(]|\s+[{&:]|\s+do\>)'
216 | endif
217 | if s:path =~# '/spec/views/.*_spec\.rb$'
218 |   syn match rubyTestAction '\v<%(assign|render)>[!?:]@!'
219 |   syn match rubyTestHelper '\v<%(rendered)>[!?:]@!'
220 | endif
221 | 
222 | if s:has_app && rails#buffer().type_name('test', 'spec')
223 |   syn match rubyTestMacro '\v<%(fixtures|use_transactional_tests|use_instantiated_fixtures)>[!?:]@!'
224 |   syn match rubyTestHelper '\v<%(file_fixture)>[!?:]@!'
225 | endif
226 | if s:path =~# '\v/test/%(controllers|integration)/.*_test\.rb$|/spec/%(controllers|requests)/.*_spec\.rb$'
227 |   syn match   rubyTestAction '\v\.@<!<%(get|post|put|patch|delete|head|process)>[?!:]@!'
228 |   syn match   rubyTestAction '\v<follow_redirect![[:keyword:]!?:]@!'
229 |   syn match rubyTestAction '\v<%(get_via_redirect|post_via_redirect)>[!?:]@!'
230 |   syn match rubyTestHelper '\v<%(request|response|flash|session|cookies|fixture_file_upload)>[!?:]@!'
231 | endif
232 | if s:path =~# '/test/system/.*_test\.rb$\|/spec/features/.*_spec\.rb$' ||
233 |       \ s:has_app && rails#buffer().type_name('cucumber')
234 |   syn match rubyTestHelper '\v<%(body|current_host|current_path|current_scope|current_url|current_window|html|response_headers|source|status_code|title|windows)>[!?:]@!'
235 |   syn match rubyTestHelper '\v<%(page|text)>[!?:]@!'
236 |   syn match rubyTestHelper '\v<%(all|field_labeled|find|find_all|find_button|find_by_id|find_field|find_link|first)>[!?:]@!'
237 |   syn match rubyTestAction '\v<%(evaluate_script|execute_script|go_back|go_forward|open_new_window|save_and_open_page|save_and_open_screenshot|save_page|save_screenshot|switch_to_frame|switch_to_window|visit|window_opened_by|within|within_element|within_fieldset|within_frame|within_table|within_window)>[!?:]@!'
238 |   syn match   rubyTestAction '\v<reset_session![[:keyword:]!?:]@!'
239 |   syn match rubyTestAction '\v<%(attach_file|check|choose|click_button|click_link|click_link_or_button|click_on|fill_in|select|uncheck|unselect)>[!?:]@!'
240 | endif
241 | 
242 | if !s:has_app
243 |   finish
244 | endif
245 | 
246 | syn match rubyAttribute '\v<%(class_attribute)>[!?:]@!'
247 | syn match rubyAttribute '\v<%(attr_internal|attr_internal_accessor|attr_internal_reader|attr_internal_writer)>[!?:]@!'
248 | syn match rubyAttribute '\v<%(cattr_accessor|cattr_reader|cattr_writer|mattr_accessor|mattr_reader|mattr_writer)>[!?:]@!'
249 | syn match rubyAttribute '\v<%(thread_cattr_accessor|thread_cattr_reader|thread_cattr_writer|thread_mattr_accessor|thread_mattr_reader|thread_mattr_writer)>[!?:]@!'
250 | syn match rubyMacro '\v<%(alias_attribute|concern|concerning|delegate|delegate_missing_to|with_options)>[!?:]@!'
251 | 
252 | let s:special = {
253 |       \ '[': '\[\@=',
254 |       \ ']': '[[.]\@!',
255 |       \ '{': '\%(\s*{\|\s\+do\>\)\@=',
256 |       \ '}': '\%(\s*{\|\s\+do\>\)\@!'}
257 | function! s:highlight(group, ...) abort
258 |   let value = rails#buffer().projected(a:0 ? a:1 : a:group)
259 |   let words = split(join(filter(value, 'type(v:val) == type("")'), ' '))
260 |   call filter(words, 'type(v:val) == type("") && v:val =~# ''^\h\k*[!?]\=[][{}]\=$''')
261 |   if !empty(words)
262 |     exe 'syn match' a:group '"\<\%(' . substitute(
263 |           \ join(words, '\|'),
264 |           \ '[][{}]', '\=get(s:special, submatch(0), submatch(0))', 'g') .
265 |           \ '\)[[:keyword:]!?:]\@!"'
266 |   endif
267 | endfunction
268 | 
269 | call s:highlight(
270 |       \ rails#buffer().type_name('helper', 'view') ? 'rubyHelper' : 'rubyMacro',
271 |       \ 'keywords')
272 | call s:highlight('rubyMacro')
273 | call s:highlight('rubyAction')
274 | call s:highlight('rubyHelper')
275 | call s:highlight('rubyEntity')
276 | call s:highlight('rubyEntities')
277 | 


--------------------------------------------------------------------------------
/doc/rails.txt:
--------------------------------------------------------------------------------
  1 | *rails.txt*	Plugin for working with Ruby on Rails applications
  2 | 
  3 | Author:  Tim Pope <http://tpo.pe/>
  4 | 
  5 | |rails-introduction|            Introduction and Feature Summary
  6 | |rails-navigation|              Navigation
  7 | |rails-gf|                          File Under Cursor - gf
  8 | |rails-alternate-related|           Alternate and Related Files
  9 | |rails-type-navigation|             File Type Commands
 10 | |rails-exec|                    Executable Wrappers
 11 | |rails-refactoring|             Refactoring Helpers
 12 | |rails-partials|                    Partial Extraction
 13 | |rails-migrations|                  Migration Inversion
 14 | |rails-misc|                    Miscellaneous Commands
 15 | |rails-integration|             Integration
 16 | |rails-vim-integration|             Integration with the Vim Universe
 17 | |rails-rails-integration|           Integration with the Rails Universe
 18 | |rails-syntax|                  Syntax Highlighting
 19 | |rails-projections|             Projections
 20 | |rails-configuration|           Configuration
 21 | |rails-global-settings|         Global Settings
 22 | |rails-about|                   About rails.vim
 23 | |rails-license|                     License
 24 | 
 25 | INTRODUCTION					*rails-introduction* *rails*
 26 | 
 27 | Whenever you edit a file in a Rails application, this plugin will be
 28 | automatically activated.  This sets various options and defines a few
 29 | buffer-specific commands.
 30 | 
 31 | If you are in a hurry to get started, with a minimal amount of reading, you
 32 | are encouraged to at least skim through the headings and command names in this
 33 | file, to get a better idea of what is offered.  If you only read one thing,
 34 | make sure it is the navigation section.
 35 | 
 36 | NAVIGATION					*rails-navigation*
 37 | 
 38 | Navigating the twisted file hierarchy of Rails projects is what initially
 39 | inspired the creation of this plugin.
 40 | 
 41 | The standard Rails load path is prepended to 'path', enabling |:find| to work:
 42 | >
 43 | 	:find application_controller
 44 | <
 45 | In asset files, 'path' is instead set to the asset load path, and
 46 | 'suffixesadd' is set to a long list of possible JavaScript or CSS suffixes.
 47 | 
 48 | File Under Cursor - gf ~
 49 | 						*rails-gf*
 50 | The |gf| command, which normally edits the current file under the cursor, has
 51 | been remapped to take context into account.  |CTRL-W_f| (open in new window),
 52 | |CTRL-W_gf| (open in new tab), and |c_CTRL-R_CTRL-F| (insert filename on
 53 | command line) are also remapped.
 54 | 
 55 | Example uses of |gf|, and where they might lead.
 56 | (* indicates cursor position)
 57 | >
 58 | 	Pos*t.first
 59 | <	app/models/post.rb ~
 60 | >
 61 | 	has_many :c*omments
 62 | <	app/models/comment.rb ~
 63 | >
 64 | 	link_to 'Home', :controller => 'bl*og'
 65 | <	app/controllers/blog_controller.rb ~
 66 | >
 67 | 	<%= render 'sh*ared/sidebar' %>
 68 | <	app/views/shared/_sidebar.html.erb ~
 69 | >
 70 | 	<%= stylesheet_link_tag 'appl*ication' %>
 71 | <	app/assets/stylesheets/application.css ~
 72 | >
 73 | 	class BlogController < Applica*tionController
 74 | <	app/controllers/application_controller.rb ~
 75 | >
 76 | 	class ApplicationController < ActionCont*roller::Base
 77 | <	.../action_controller/base.rb ~
 78 | >
 79 | 	fixtures :pos*ts
 80 | <	test/fixtures/posts.yml ~
 81 | >
 82 | 	layout :pri*nt
 83 | <	app/views/layouts/print.html.erb ~
 84 | >
 85 | 	<%= link_to "New", new_comme*nt_path %>
 86 | <	app/controllers/comments_controller.rb (jumps to def new) ~
 87 | 
 88 | In the last example, the controller and action for the named route are
 89 | determined by evaluating routes.rb as Ruby and doing some introspection.  This
 90 | means code from the application is executed.  Keep this in mind when
 91 | navigating unfamiliar applications.
 92 | 
 93 | Alternate and Related Files ~
 94 | 						*rails-alternate-related*
 95 | Two commands, :A and :R, are used to quickly jump to an "alternate" and a
 96 | "related" file, defined below.
 97 | 
 98 | 	*rails-:A* *rails-:AE* *rails-:AS* *rails-:AV* *rails-:AT* *rails-:AD*
 99 | :A			These commands were picked to mimic Michael Sharpe's
100 | :AE			a.vim.  Briefly, they edit the "alternate" file, in
101 | :AS			either the same window (:A and :AE), a new split
102 | :AV			window (:AS), a new vertically split window (:AV), a
103 | :AT			new tab (:AT), or read it into the current buffer
104 | :AD			(:AD).  With a range (:.A), they find the "related"
105 | 			file for the specified line.  With a filename
106 | 			argument, they edit a file relative to the application
107 | 			root (:A Rakefile), and with both a count and a
108 | 			filename (:1A post.rb), they find a file in 'path',
109 | 			similar to |:find| but with smarter tab completion.
110 | 
111 | 	*rails-:R* *rails-:RE* *rails-:RS* *rails-:RV* *rails-:RT* *rails-:RD*
112 | :R			These are similar |rails-:A| and friends above, only
113 | :RE			they default to the "related" file rather than the
114 | :RS			"alternate."  :R is equivalent to :.A and :0R is
115 | :RV			equivalent to :.A.  The filename and count version
116 | :RT			(:1R post.rb) is hard coded to use the application
117 | :RD			load path rather than 'path', so that one can access
118 | 			Ruby files regardless of 'filetype'.
119 | 
120 | 					*rails-alternate* *rails-related*
121 | The alternate file is most frequently the test file, though there are
122 | exceptions.  The related file varies, and is sometimes dependent on current
123 | location in the file.  For example, when editing a controller, the related
124 | file is template for the method currently being edited.
125 | 
126 | The easiest way to learn these commands is to experiment.  A few examples of
127 | alternate and related files for a Test::Unit application follow:
128 | 
129 | Current file		Alternate file		Related file ~
130 | model			unit test		schema definition
131 | controller (in method)	functional test		template (view)
132 | template (view)		functional test  	controller (jump to method)
133 | migration		previous migration	next migration
134 | database.yml		database.example.yml	environments/*.rb
135 | 
136 | Alternates can be tweaked with |rails-projections|.
137 | 
138 | File Type Navigation Commands ~
139 | 						*rails-type-navigation*
140 | For the less common cases, a more deliberate set of commands are provided.
141 | Each of the upcoming commands takes an optional argument (with tab completion)
142 | but defaults to a reasonable guess.  Commands that default to the current
143 | model or controller generally behave like you'd expect in other file types.
144 | For example, in app/helpers/posts_helper.rb, the current controller is
145 | "posts", and in test/fixtures/comments.yml, the current model is "comment".
146 | In model related files, the current controller is the pluralized model name,
147 | and in controller related files, the current model is the singularized
148 | controller name.
149 | 
150 | Each of the following commands has variants for splitting, vertical splitting,
151 | opening in a new tab, and reading the file into the current buffer.  For
152 | :Emodel, those variants would be :Smodel, :Vmodel, :Tmodel, and :Dmodel.
153 | They also allow for jumping to methods or line numbers using the same syntax
154 | as |:rails-R|, and file creation (with a bit of boilerplate) can be forced by
155 | adding a ! after the filename (not after the command itself!).
156 | 
157 | Additionally, for each unrecognized directory of the form app/{type}s/
158 | containing at least one file matching *_{type}.rb, a command of the form
159 | :E{type} is automatically defined.
160 | 
161 | :Econtroller					|rails-:Econtroller|
162 | :Eenvironment					|rails-:Eenvironment|
163 | :Efixtures					|rails-:Efixtures|
164 | :Efunctionaltest				|rails-:Efunctionaltest|
165 | :Ehelper					|rails-:Ehelper|
166 | :Einitializer					|rails-:Einitializer|
167 | :Eintegrationtest				|rails-:Eintegrationtest|
168 | :Ejavascript					|rails-:Ejavascript|
169 | :Elayout					|rails-:Elayout|
170 | :Elib						|rails-:Elib|
171 | :Elocale					|rails-:Elocale|
172 | :Emailer					|rails-:Emailer|
173 | :Emigration					|rails-:Emigration|
174 | :Emodel						|rails-:Emodel|
175 | :Eschema					|rails-:Eschema|
176 | :Espec						|rails-:Espec|
177 | :Estylesheet					|rails-:Estylesheet|
178 | :Etask						|rails-:Etask|
179 | :Eunittest					|rails-:Eunittest|
180 | :Eview						|rails-:Eview|
181 | 
182 | 				*rails-:Econtroller* *rails-:Rcontroller*
183 | :Econtroller [{name}]	Edit the specified or current controller.
184 | 
185 | 				*rails-:Eenvironment* *rails-:Renvironment*
186 | :Eenvironment [{name}]  Edit the config/environments file specified.  With no
187 | 			argument, defaults to editing config/application.rb
188 | 			or config/environment.rb.
189 | 
190 | 				*rails-:Efixtures* *rails-:Rfixtures*
191 | :Efixtures [{name}]	Edit the fixtures for the given or current model.  If
192 | 			an argument is given, it must be pluralized, like the
193 | 			final filename (this may change in the future).  If
194 | 			omitted, the current model is pluralized.  An optional
195 | 			extension can be given, to distinguish between YAML
196 | 			and CSV fixtures.
197 | 
198 | 			*rails-:Efunctionaltest* *rails-:Rfunctionaltest*
199 | :Efunctionaltest [{name}]
200 | 			Edit the functional test or controller spec for the
201 | 			specified or current controller.
202 | 
203 | 				*rails-:Ehelper* *rails-:Rhelper*
204 | :Ehelper [{name}]	Edit the helper for the specified name or current
205 | 			controller.
206 | 
207 | 				*rails-:Einitializer* *rails-:Rinitializer*
208 | :Einitializer [{name}]  Edit the config/initializers file specified.  With no
209 | 			argument, defaults to editing config/routes.rb.
210 | 
211 | 			*rails-:Eintegrationtest* *rails-:Rintegrationtest*
212 | :Eintegrationtest [{name}]
213 | 			Edit the integration test, integration spec, or
214 | 			cucumber feature specified.  With no argument,
215 | 			defaults to editing test/test_helper.rb.
216 | 
217 | 				*rails-:Ejavascript* *rails-:Rjavascript*
218 | :Ejavascript [{name}]	Edit the JavaScript for the specified name or current
219 | 			controller.  Also supports CoffeeScript in
220 | 			app/scripts/.
221 | 
222 | 				*rails-:Elayout* *rails-:Rlayout*
223 | :Elayout [{name}]	Edit the specified layout.  Defaults to the layout for
224 | 			the current controller, or the application layout if
225 | 			that cannot be found.  A new layout will be created if
226 | 			an extension is given.
227 | 
228 | 				*rails-:Elib* *rails-:Rlib*
229 | :Elib [{name}]		Edit the library from the lib directory for the
230 | 			specified name.  With no argument, defaults to editing
231 | 			the application Gemfile (a task formally handled by
232 | 			the defunct :Rplugin).
233 | 
234 | 				*rails-:Elocale* *rails-:Rlocale*
235 | :Elocale [{name}]	Edit the config/locale file specified, optionally
236 | 			adding a yml or rb extension if none is given.  With
237 | 			no argument, checks config/environment.rb for the
238 | 			default locale.
239 | 
240 | 				*rails-:Emailer* *rails-:Rmailer*
241 | :Emailer [{name}]	Edit the specified mailer.
242 | 
243 | 				*rails-:Emigration* *rails-:Rmigration*
244 | :Emigration [{pattern}]	If {pattern} is a number, find the migration for that
245 | 			particular set of digits, zero-padding if necessary.
246 | 			Otherwise, find the newest migration containing the
247 | 			given pattern.  Omitting the pattern selects the
248 | 			latest migration.  Give a numeric argument of 0 to edit
249 | 			db/seeds.rb.
250 | 
251 | 				*rails-:Emodel* *rails-:Rmodel*
252 | :Emodel [{name}]	Edit the specified or current model.
253 | 
254 | 				*rails-:Espec* *rails-:Rspec*
255 | :Espec [{name}]		Edit the given spec.  With no argument, defaults to
256 | 			editing spec/spec_helper.rb (If you want to jump to
257 | 			the spec for the given file, use |rails-:A| instead).
258 | 			This command is only defined if there is a spec folder
259 | 			in the root of the application.
260 | 
261 | 				*rails-:Eschema* *rails-:Rschema*
262 | :Eschema [{table}]	Edit the schema and optionally jump to the specified
263 | 			table.
264 | 
265 | 				*rails-:Estylesheet* *rails-:Rstylesheet*
266 | :Estylesheet [{name}]	Edit the stylesheet for the specified name or current
267 | 			controller.  Also supports Sass and SCSS.
268 | 
269 | 				*rails-:Etask* *rails-:Rtask*
270 | :Etask [{name}]		Edit the .rake file from lib/tasks for the specified
271 | 			name.  If no argument is given, the application
272 | 			Rakefile is edited.
273 | 
274 | 				*rails-:Eunittest* *rails-:Runittest*
275 | :Eunittest [{name}]	Edit the unit test or model spec for the specified
276 | 			name or current model.
277 | 
278 | 				*rails-:Eview* *rails-:Rview*
279 | :Eview [[{controller}/]{view}]
280 | 			Edit the specified view.  The controller will default
281 | 			sensibly, and the view name can be omitted when
282 | 			editing a method of a controller.  If a view name is
283 | 			given with an extension, a new file will be created.
284 | 			This is a quick way to create a new view.
285 | 
286 | Finally, one Vim feature that proves helpful in conjunction with all of the
287 | above is |CTRL-^|.  This keystroke edits the previous file, and is helpful to
288 | back out of any of the above commands.
289 | 
290 | EXECUTABLE WRAPPERS				*rails-exec*
291 | 
292 | Several commands are provided that wrap the `rails` and `rake` executables.
293 | Additionally, `rails` (or `rake` on Rails versions older than 5) can be
294 | invoked directly with |:make| or dispatch.vim's :Make.
295 | 
296 | 						*rails-:Rails*
297 | :Rails {command} [options]
298 | 			Invoke "rails {command}".  On older versions of Rails,
299 | 			it will conditionally invoke "rake {command}" and
300 | 			"script/{command}" when appropriate.  Uses |:!| or
301 | 			dispatch.vim's :Start if the command is "console",
302 | 			"dbconsole", or "server".  Otherwise, the "rails"
303 | 			|:compiler| plugin included with the plugin is
304 | 			temporarily enabled, and |:make|  or dispatch.vim's
305 | 			:Make is used to load the output into the quickfix
306 | 			list.
307 | 			Unlike other commands, :Rails is available globally,
308 | 			for use with the "new" subcommand.
309 | 
310 | :Rails			With no command, runs a default task based on the
311 | 			current file.  See |rails-default-task|.
312 | 
313 | 						*rails-:Rscript*
314 | :Rscript {command} [options]
315 | 			Deprecated alias for |:Rails| {command}.
316 | 
317 | 						*rails-:Console*
318 | :Console {options}	Launch rails console {options}. If dispatch.vim's
319 | 			:Start is available, that is used.  Otherwise,
320 | 			executes directly in the foreground.
321 | 
322 | 					*rails-:Generate* *rails-:Rgenerate*
323 | :Generate {options}	Invoke rails generate {options} and loads the
324 | 			generated files into the quickfix list.  Use ! to
325 | 			suppress jumping to the first file.
326 | 
327 | 					*rails-:Destroy* *rails-:Rdestroy*
328 | :Destroy {options}	Invoke rails destroy {options} and loads the destroyed
329 | 			files into the quickfix list.
330 | 
331 | 					*rails-:Server* *rails-:Rserver*
332 | :Server {options}	Launch rails server {options} in the background.  If
333 | 			dispatch.vim's :Start is available, that is used.
334 | 			Otherwise, the --daemon option is passed in.
335 | 
336 | 					*rails-:Server!* *rails-:Rserver!*
337 | :Server! {options}	Kill the pid found in tmp/pids/server.pid and then
338 | 			invoke :Server.
339 | 
340 | 					*rails-:Runner* *rails-:Rrunner*
341 | :[range]Runner [file]	Run the given file or code with rails runner and load
342 | :Runner {code}		the results in to the quickfix list, using the error
343 | 			parser from the "ruby" |:compiler|.  If the file looks
344 | 			like a test, spec, or cucumber feature, the
345 | 			"rubyunit", "rspec", or "cucumber" |:compiler| will be
346 | 			used instead.  If provided, [range] is passed to the
347 | 			test runner to restrict execution to a particular
348 | 			line.  With no argument, defaults to running the test
349 | 			for the current file.
350 | 
351 | 						*rails-:Rp*
352 | :[range]Rp {code}	Use rails runner to execute "p begin {code} end" and
353 | 			echo the result.
354 | 
355 | 						*rails-:Rpp*
356 | :[range]Rpp {code}	Like :Rp, but with pp (pretty print).
357 | 
358 | 						*rails-:Rake*
359 | :[range]Rake {task}	Invoke `rake`.  Generally, you are encouraged to use
360 | 			|:Rails| or directly invoke |:make| instead.
361 | 
362 | 						*rails-default-task*
363 | 
364 | Invoking |:Rails| with no arguments runs a default task.  This is typically
365 | the associated test task, but can also be a closely related utility task.
366 | 
367 | File                            Task ~
368 | test/*_test.rb                  test TEST=test/*_test.rb
369 | spec/*_spec.rb                  spec SPEC=spec/*_spec.rb
370 | features/*.feature              cucumber FEATURE=features/*.feature
371 | app/*.rb                        test TEST=... | spec SPEC=...
372 | test/fixtures/*.yml             db:fixtures:load FIXTURES=*
373 | config.ru                       middleware
374 | config/routes.rb                routes
375 | db/migrate/*_*.rb               db:migrate:redo VERSION=*
376 | db/schema.rb                    db:migrate:status
377 | db/seeds.rb                     db:seed
378 | README                          about
379 | 
380 | For some files, giving the command a range (e.g., :.Rails) triggers a variant
381 | of the task to be performed.
382 | 
383 | File                            Task when given range ~
384 | test/*_test.rb                  test TEST=test/*_test.rb TESTOPTS=-n<method>
385 | spec/*_spec.rb                  spec SPEC=spec/*_spec.rb:<line>
386 | features/*.feature              cucumber FEATURE=features/*.feature:<line>
387 | test/fixtures/*.yml             db:fixtures:identify LABEL=<label>
388 | db/migrate/*_*.rb               db:migrate:down VERSION=*
389 | lib/tasks/*.rake                <try to guess currently edited task>
390 | 
391 | You can override the default task with a comment like "# rails <task>" either
392 | at the top of the file or before the method referenced by the given line
393 | number.
394 | 
395 | If dispatch.vim is installed, you can also run the default task by calling
396 | |:Dispatch| with no arguments.  Use :.FocusDispatch and :0FocusDispatch to see
397 | the default task with and without a range given.
398 | 
399 | REFACTORING HELPERS				*rails-refactoring*
400 | 
401 | A few features are dedicated to helping you refactor your code.
402 | 
403 | Partial Extraction ~
404 | 						*rails-partials*
405 | 
406 | The :Extract command can be used to extract part of a view to a partial, part
407 | of a helper to another helper, or part of a model or controller to a concern.
408 | 
409 | 					*rails-:Extract* *rails-:Rextract*
410 | :[range]Extract [{controller}/]{name}
411 | 			Create a {name} partial from [range] lines (default:
412 | 			current line).  Only available in views.
413 | 
414 | :[range]Extract {helper}
415 | 			Create a {name} helper from [range] lines (default:
416 | 			current line).  Only available in helpers.
417 | 
418 | :[range]Extract {concern}
419 | 			Create a {name} concern from [range] lines (default:
420 | 			current line).  Only available in models and
421 | 			controllers.
422 | 
423 | If this is your file, in app/views/blog/show.html.erb: >
424 | 
425 |  1	<div>
426 |  2	  <h2><%= @post.title %></h2>
427 |  3	  <p><%= @post.body %></p>
428 |  4	</div>
429 | 
430 | And you issue this command: >
431 | 
432 | 	:2,3Extract post
433 | 
434 | Your file will change to this: >
435 | 
436 |  1	<div>
437 |  2	  <%= render "post" %>
438 |  3	</div>
439 | 
440 | And app/views/blog/_post.html.erb will now contain: >
441 | 
442 |  1	<h2><%= @post.title %></h2>
443 |  2	<p><%= @post.body %></p>
444 | <
445 | The easiest way to choose what to extract is to use |linewise-visual| mode.
446 | Then, a simple >
447 | 	:'<,'>Extract blog/post
448 | will suffice. (Note the use of a controller name in this example.)
449 | 
450 | Migration Inversion ~
451 | 					*rails-migrations* *rails-:Rinvert*
452 | :Rinvert		In a migration, rewrite the self.up method into a
453 | 			self.down method.  If self.up is empty, the process is
454 | 			reversed.  This chokes on more complicated
455 | 			instructions, but works reasonably well for simple
456 | 			calls to create_table, add_column, and the like.
457 | 			Newer versions of Rails provide increasingly good
458 | 			support for reversible migration definitions, so this
459 | 			command is deprecated and no longer maintained.
460 | 
461 | MISCELLANEOUS COMMANDS				*rails-misc*
462 | 
463 | 						*rails-:Clog*
464 | :Clog [environment]	Load the log file for the given environment using
465 | 			|:cgetfile|, open the quickfix window, and jump to the
466 | 			last line.  |R| is remapped to reload the list, and
467 | 			|G| remapped to do the same before it's usual behavior
468 | 			of jumping to the last line.  If the delay in loading
469 | 			is too long, you might consider :Rails log:clear.
470 | 
471 | 						*rails-:Rlog*
472 | :Rlog [environment]	Open the log file in the preview window using
473 | 			|:pedit|.  Deprecated in favor if |rails-:Clog|.
474 | 
475 | 					*rails-:Preview* *rails-:Rpreview*
476 | :Preview [path]		Open the given path for the current app in a browser.
477 | 			The host and port are determined by applying some
478 | 			netstat/lsof trickery to the current server pid.  If
479 | 			no server is running, Pow is consulted, and if all
480 | 			else fails, a default of localhost:3000 is used.  If
481 | 			no path is given, a default is used based on the
482 | 			current file and the application's routes.  The
483 | 			default is overridden by comments like the following
484 | 			that are either before the current method call or at
485 | 			the top of the file: >
486 | 
487 | 		# GET /users
488 | 		# PUT /users/1
489 | <
490 | 			If it's not using the right browser, define an OpenURL
491 | 			command:
492 | >
493 | 		:command -bar -nargs=1 OpenURL :!open <args>
494 | <
495 | 					*rails-:Preview!* *rails-:Rpreview!*
496 | :Preview! [path]	Like :Preview, but open the path inside Vim using
497 | 			|netrw| instead.
498 | 
499 | 						*rails-:Rrefresh*
500 | :Rrefresh		Refreshes cached settings.
501 | 
502 | 						*rails-:Rrefresh!*
503 | :Rrefresh!		As above, and also reloads rails.vim.
504 | 
505 | 						*rails-:Cd* *rails-:Rcd*
506 | 						*rails-:Lcd* *rails-:Rlcd*
507 | :Cd [{directory}]	These have been removed.  Install projectionist.vim
508 | :Lcd [{directory}]	for a replacement.
509 | 
510 | 						*rails-:Ctags* *rails-:Rtags*
511 | :Ctags			Calls ctags -R on the current application root.
512 | 			Exuberant ctags must be installed.  Additional
513 | 			arguments can be passed to ctags with
514 | 			|g:rails_ctags_arguments|.
515 | 
516 | INTEGRATION					*rails-integration*
517 | 
518 | Having one foot in Rails and one in Vim, rails.vim has two worlds with which
519 | to interact.
520 | 
521 | Integration with the Vim Universe ~
522 | 						*rails-vim-integration*
523 | 
524 | A handful of Vim plugins are enhanced by rails.vim.  All plugins mentioned can
525 | be found at http://www.vim.org/.
526 | 
527 | 						*rails-dadbod*
528 | Created by yours truly, dadbod.vim is a modern take on a Vim database plugin.
529 | This plugin sets the dadbod.vim default to the application's development
530 | database, and also provides an interface for accessing any environment of any
531 | Rails app:
532 | >
533 |   :DB rails:#production
534 |   :DB rails:/path/to/app
535 |   :DB rails:/path/to/app#production
536 | <
537 | 						*rails-:Rdbext* *rails-dbext*
538 | Native support for dbext has been removed.  Install dadbod.vim and enable
539 | |g:dadbod_manage_dbext| to achieve the same effect.
540 | 
541 | 						*rails-surround*
542 | The |surround| plugin available from vim.org enables adding and removing
543 | "surroundings" like parentheses, quotes, and HTML tags.  Even by itself, it is
544 | quite useful for Rails development, particularly eRuby editing.  When coupled
545 | with this plugin, a few additional replacement surroundings are available in
546 | eRuby files.  See the |surround| documentation for details on how to use them.
547 | The table below uses ^ to represent the position of the surrounded text.
548 | 
549 | Key	Surrounding ~
550 | =	<%= ^ %>
551 | -	<% ^ -%>
552 | #	<%# ^ %>
553 | <C-E>	<% ^ -%>\n<% end -%>
554 | 
555 | The last surrounding is particularly useful in insert mode with the following
556 | map in one's vimrc.  Use Alt+o to open a new line below the current one.  This
557 | works nicely even in a terminal (where most alt/meta maps will fail) because
558 | most terminals send <M-o> as <Esc>o anyways.
559 | >
560 | 	imap <M-o> <Esc>o
561 | <
562 | One can also use the <C-E> surrounding in a plain Ruby file to append a bare
563 | "end" on the following line.
564 | 
565 | 						*rails-abolish*
566 | Among the many features of |abolish| on vim.org is the ability to change the
567 | inflection of the word under the cursor.  For example, one can hit crs to
568 | change from MixedCase to snake_case.  This plugin adds two additional
569 | inflections: crl for alternating between the singular and plural, and crt for
570 | altering between tableize and classify.  The latter is useful in changing
571 | constructs like BlogPost.all to current_user.blog_posts.all and vice versa.
572 | 
573 | 						*rails-rspec*
574 | The presence of a spec directory causes several additional behaviors to
575 | activate.  :A knows about specs and will jump to them (but Test::Unit files
576 | still get priority).  The associated controller or model of a spec is
577 | detected, so all navigation commands should work as expected inside a spec
578 | file.  :Rails in a spec runs just that spec, and in a model, controller, or
579 | helper, runs the associated spec.
580 | 
581 | :Eunittest and :Efunctionaltest lead double lives, handling model/helper and
582 | controller/mailer specs respectively.  For everything else, you can use
583 | :Espec.
584 | 
585 | ABBREVIATIONS				*rails-abbreviations* *rails-snippets*
586 | 
587 | Abbreviations have been removed without replacement.
588 | 
589 | SYNTAX HIGHLIGHTING				*rails-syntax*
590 | 
591 | Syntax highlighting is by and large a transparent process.  For the full
592 | effect, however, you need a colorscheme which accentuates rails.vim
593 | extensions.  One such colorscheme is vividchalk, available from vim.org.
594 | 
595 | The following is a summary of the changes made by rails.vim to the standard
596 | syntax highlighting.
597 | 
598 | 						*rails-syntax-keywords*
599 | Rails specific keywords are highlighted in a filetype specific manner.  For
600 | example, in a model, has_many is highlighted, whereas in a controller,
601 | before_filter is highlighted.  A wide variety of syntax groups are used but
602 | they all link by default to railsMethod.
603 | 
604 | 						*rails-syntax-assertions*
605 | If you define custom assertions in test_helper.rb, these will be highlighted
606 | in your tests.  These are found by scanning test_helper.rb for lines of the
607 | form "  def assert_..." and extracting the method name.  The railsUserMethod
608 | syntax group is used.  The list of assertions can be refreshed with
609 | |rails-:Rrefresh|.
610 | 
611 | PROJECTIONS		*rails-config/projections.json* *rails-projections*
612 | 
613 | The bulk of rails.vim features support core Rails conventions and a just a
614 | handful of popular additions (such as RSpec).  Projections let you teach
615 | rails.vim about app specific and gem specific behavior.
616 | 
617 | There are four primary ways to define projections:
618 | 
619 | 1. Globally, in |g:rails_projections|.
620 | 2. Per app, in config/projections.json.
621 | 3. Per bundled gem, in |g:rails_gem_projections| (requires bundler.vim).
622 | 4. Inside a bundled gem, in lib/rails/projections.json (requires bundler.vim).
623 | 
624 | Vim syntax looks a lot like JSON, but with funky |line-continuation|:
625 | >
626 | 	let g:rails_projections = {
627 | 	      \ "app/uploaders/*_uploader.rb": {
628 | 	      \   "command": "uploader",
629 | 	      \   "template":
630 | 	      \     ["class {camelcase|capitalize|colons}Uploader < "
631 | 	      \      . "CarrierWave::Uploader::Base", "end"],
632 | 	      \   "test": [
633 | 	      \     "test/unit/{}_uploader_test.rb",
634 | 	      \     "spec/models/{}_uploader_spec.rb"
635 | 	      \   ],
636 | 	      \   "rubyMacro": ["process", "version"]
637 | 	      \ },
638 | 	      \ "features/support/*.rb": {"command": "support"},
639 | 	      \ "features/support/env.rb": {"command": "support"}}
640 | 
641 | Keys can be either literal file names or globs containing a single asterisk.
642 | In the latter case, you can use {} placeholders in the values to plug in some
643 | transformation of the variable portion, based on those available in
644 | projectionist.vim.  See projectionist.vim's documentation for a comprehensive
645 | explanation, but you can probably get the gist from the list below.
646 | 
647 | Older versions of rails.vim used the following unsupported % expansions, shown
648 | here with their {} equivalents:
649 | 
650 | `%s`: `{}` (Original)
651 | `%S`: `{camelcase|capitalize|colons}` (Ruby class name)
652 | `%S`: `{camelcase|capitalize|dot}` (JavaScript class name)
653 | `%p`: `{plural}`
654 | `%i`: `{singular}`
655 | `%h`: `{underscore|capitalize|blank}`
656 | 
657 | The full list of available options is as follows:
658 | 
659 | 						*rails-projection-alternate*
660 | "alternate" ~
661 | 	Determines the destination of the |rails-:A| command.  If this is a
662 | 	list, the first readable file will be used.  For a related file, as
663 | 	with :.A and :R, {lnum} and {define} expand to the current line number
664 | 	or 'define' match.
665 | 						*rails-projection-related*
666 | "related" ~
667 | 	Deprecated in favor of "alternate" with either a {lnum} or {define}.
668 | 	Use {lnum|nothing} to force a file not to match a plain :A without
669 | 	interpolating anything.
670 | 						*rails-projection-test*
671 | "test" ~
672 | 	Determines the default test file to run with |:Rails| and
673 | 	|rails-:Runner|.  Also serves as a default for "alternate".
674 | 						*rails-projection-task*
675 | "task" ~
676 | 	Determines the default rake task to run.  Provide {lnum} or {define}
677 | 	to substitute the current line number or 'define' match (typically a
678 | 	method), or just a bare % (like |:_%|) to substitute the current file
679 | 	name.
680 | "keywords" ~
681 | 	Obsolete: see rubyMacro, rubyAction, and rubyHelper below.
682 | 						*rails-projection-command*
683 | "command" ~
684 | 	Names a navigation command to be created.  Use the same name on
685 | 	multiple projections to combine them into a single command.  Glob
686 | 	keys are used when the command is given an argument, and literal file
687 | 	keys are used when no argument is given.  See the "features/support"
688 | 	entries above for an example :Esupport that defaults to env.
689 | 						*rails-projection-affinity*
690 | "affinity" ~
691 | 	Provide this if the root of your file name corresponds to either
692 | 	a model or controller.  The root of a helper generally corresponds to
693 | 	a controller, for example, so a "helper" projection would have an
694 | 	"affinity" of "controller".  You can also provide "collection" if it
695 | 	corresponds to a plural model (e.g., fixtures), or "resource" if it
696 | 	corresponds to a singular controller.  Providing this lets you use
697 | 	other affiliated commands without an argument, and determines the
698 | 	default if a command has no literal file name.
699 | 						*rails-projection-template*
700 | "template" ~
701 | 	If you provide a ! after the argument to the navigation command (that
702 | 	is, :Euploader foo!, NOT :Euploader! foo), and a new file is created,
703 | 	this will be used as an array of lines to populate the body.
704 | 						*rails-projection-railsParams*
705 | "railsParams" ~
706 | 	Provides a dictionary of defaults for URL parameters for
707 | 	|rails-:Preview|, for example {"user_id": "2"}.  The fallback for
708 | 	unspecified parameters is "1".
709 | 						*rails-projection-compiler*
710 | 						*rails-projection-railsRunner*
711 | "railsRunner" ~
712 | 	Determines the command (and |:compiler| plugin) to use with
713 | 	|rails-:Runner| in lieu of a literal `rails runner`.  Can be
714 | 	"minitest", "rspec", or "cucumber".
715 | 						*rails-projection-rubyMacro*
716 | "rubyMacro" ~
717 | 	List of keywords to highlight as class declarations (like
718 | 	before_action or validates_presence_of).
719 | 						*rails-projection-rubyAction*
720 | "rubyAction" ~
721 | 	List of keywords to highlight as imperative methods (like
722 | 	redirect_to or create_table).
723 | 						*rails-projection-rubyHelper*
724 | "rubyHelper" ~
725 | 	List of keywords to highlight as functional methods (like
726 | 	params or any view helper).
727 | 
728 | CONFIGURATION					*rails-configuration*
729 | 
730 | In addition to projections (described above) and the crude hammer of global
731 | settings (described below), rails.vim provides a few different mechanisms for
732 | configuration.
733 | 
734 | 					*rails-:autocmd* *rails-autocommands*
735 | If you would like to set your own custom Vim settings whenever a Rails file is
736 | loaded, you can use an autocommand like the following in your vimrc: >
737 | 
738 | 	autocmd User Rails		map <buffer> <F9> :Rails<CR>
739 | 
740 | There used to be autocommands that fire based on the "type" or file name of
741 | the buffer, but they have been removed.  If you still need to execute code for
742 | certain file types only, use the bare User Rails event above and check
743 | rails#buffer().relative() for the path relative to the Rails root.
744 | 
745 | 						*macros/rails.vim*
746 | If you have several commands to run on initialization for all file types, they
747 | can be placed in a "macros/rails.vim" file in the 'runtimepath' (for example,
748 | "~/.vim/macros/rails.vim").  This file is sourced by rails.vim each time a
749 | Rails file is loaded.
750 | 
751 | GLOBAL SETTINGS					*rails-global-settings*
752 | 
753 | When all else fails, set a global.
754 | 
755 | 						*g:rails_ctags_arguments*
756 | Additional arguments to pass to ctags from |:rails-Ctags|.  Defaults to
757 | limiting to Ruby files.
758 | >
759 | 	let g:rails_ctags_arguments = ['--languages=Ruby']
760 | <
761 | This option is ignored if a ctags configuration file named .ctags is found in
762 | the root of the project.
763 | 
764 | 						*g:rails_projections*  >
765 | Defines the set of globally available projections.  See |rails-projections|.
766 | Where possible, it is generally advisable to use |g:rails_gem_projections| or
767 | |config/projections.json| instead.
768 | 
769 | 						*g:rails_gem_projections*
770 | This is a dictionary where the keys are gem names and the values are
771 | projection dictionaries.  Projections are only used if the given gem is
772 | bundled (requires bundler.vim).
773 | >
774 | 	let g:rails_gem_projections = {
775 | 	      \ "active_model_serializers": {
776 | 	      \   "app/serializers/*_serializer.rb": {
777 | 	      \     "command": "serializer",
778 | 	      \     "affinity": "model"}},
779 | 	      \ "fabrication": {
780 | 	      \   "spec/fabricators/*_fabricator.rb": {
781 | 	      \     "command": "fabricator",
782 | 	      \     "affinity": "model",
783 | 	      \     "alternate": [
784 | 	      \       "db/schema.rb#{plural}{lnum|nothing}",
785 | 	      \       "app/models/{}.rb"],
786 | 	      \     "test": "spec/models/{}_spec.rb",
787 | 	      \     "template": "Fabricator :{} do\nend"}}}
788 | <
789 | See |rails-projections|.  Generally, you should prefer these gem projections
790 | over global projections to avoid getting a bunch of useless commands in every
791 | single project.
792 | 
793 | Gem maintainers may also provide custom projections by placing them in
794 | lib/rails/projections.json.
795 | 
796 | ABOUT					*rails-about* *rails-plugin-author*
797 | 
798 | The latest stable version can be found at
799 | 	http://www.vim.org/scripts/script.php?script_id=1567
800 | 
801 | Bugs can be reported and the very latest development version can be retrieved
802 | from GitHub:
803 | 	https://github.com/tpope/vim-rails >
804 | 	git clone https://github.com/tpope/vim-rails.git
805 | <
806 | 						*rails-license*
807 | Copyright (c) Tim Pope.  Distributed under the same terms as Vim itself.
808 | See |license|.
809 | 
810 |  vim:tw=78:ts=8:ft=help:norl:
811 | 


--------------------------------------------------------------------------------