├── Debounce.zip
├── ContactIDdecoderSch.png
├── Leonardo2ESP8266-01.png
├── List-of-Contact-ID-codes.PDF
├── At_firmware_bin1.54
    ├── AiThinker_ESP8266_DIO_8M_8M_20160615_V1.5.4.bin
    ├── AiThinker_ESP8266_DIO_32M_32M_20160615_V1.5.4.bin
    └── readme.txt
├── ThingHTTPSettings.txt
├── README.md
└── ThingSpeak3.1.ino


/Debounce.zip:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/hgshoemaker/Contact_ID2SMS/HEAD/Debounce.zip


--------------------------------------------------------------------------------
/ContactIDdecoderSch.png:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/hgshoemaker/Contact_ID2SMS/HEAD/ContactIDdecoderSch.png


--------------------------------------------------------------------------------
/Leonardo2ESP8266-01.png:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/hgshoemaker/Contact_ID2SMS/HEAD/Leonardo2ESP8266-01.png


--------------------------------------------------------------------------------
/List-of-Contact-ID-codes.PDF:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/hgshoemaker/Contact_ID2SMS/HEAD/List-of-Contact-ID-codes.PDF


--------------------------------------------------------------------------------
/At_firmware_bin1.54/AiThinker_ESP8266_DIO_8M_8M_20160615_V1.5.4.bin:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/hgshoemaker/Contact_ID2SMS/HEAD/At_firmware_bin1.54/AiThinker_ESP8266_DIO_8M_8M_20160615_V1.5.4.bin


--------------------------------------------------------------------------------
/At_firmware_bin1.54/AiThinker_ESP8266_DIO_32M_32M_20160615_V1.5.4.bin:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/hgshoemaker/Contact_ID2SMS/HEAD/At_firmware_bin1.54/AiThinker_ESP8266_DIO_32M_32M_20160615_V1.5.4.bin


--------------------------------------------------------------------------------
/ThingHTTPSettings.txt:
--------------------------------------------------------------------------------
 1 | ThingHTTP Settings
 2 | 
 3 | Name: Name your thing
 4 | 
 5 | API Key: Autogenerated
 6 | 
 7 | // This is the Twillio SMS API url Change the Accounts/ AccountSid
 8 | URL: https://api.twilio.com/2010-04-01/Accounts/ACXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX/Messages.json
 9 | 
10 | HTTP Auth Username: <Enter your AccountSid>
11 | 
12 | HTTP Auth Password: <Enter your Auth Token>
13 | 
14 | Method: POST
15 | 
16 | Content Type: <BLANK>
17 | 
18 | HTTP Version: 1.1
19 | 
20 | Host: <BLANK>
21 | 
22 | Headers: <Select remove headers>
23 | 
24 | // From is your Twillio account phone and To is your registered cell phone number
25 | Body: From=+1XXXXXXXXXX&To=+1XXXXXXXXXX&Body=%%message%%
26 | 
27 | Parse String: <BLANK>


--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
 1 | # Contact_ID2SMS
 2 | This decodes Alarm System Contact ID protocol using a Arduino Leonardo then sends SMS using an ESP8266 via ThingSpeak and Twillio 
 3 | 
 4 | This code is for a Arduino Leonardo board. It has more program space than a UNO
 5 |  and also a real UART pins 0 and 1. Not tested on UNO.
 6 |  
 7 |  The original idea li0r.wordpress.com Alarmino project, has great information on the contact id
 8 |  protocol and hardware to decode DTMF.
 9 |  
10 |  Contact ID decoding and SMS message buffering and great hardware information
11 |  Modified (very poorly I must admit) to use ESP8266-01 instead of SIM900 GSM board
12 |  NASCO Alarm Panel SMS Gateway (APSG)
13 |  For information please visit www.ndtech.com.au
14 |  Debounce library import as a zip 
15 |   
16 |  ESP8266 WiFi code
17 |  WiFiEsp Library
18 |  For more details see: http://yaab-arduino.blogspot.com/p/wifiesp-example-client.html
19 |  ESP8266 AT Firmware 1.5.4
20 |   
21 |  ThingSpeak.com ThingHTTP to Twillio SMS API
22 | 


--------------------------------------------------------------------------------
/At_firmware_bin1.54/readme.txt:
--------------------------------------------------------------------------------
 1 | ******************************************************************
 2 | AiThinker_ESP8266_DIO_8M_8M_20160615_V1.5.4.bin
 3 | 
 4 | MD5: 8E9E9252317A9BCA67673C17B9E3E075
 5 | 
 6 | FirmWare Infomation:
 7 |     SPI MODE: DIO
 8 |     Flash Size: 8Mbit
 9 |     File Size: 8Mbit
10 |     SPI SPEED: 40MHz
11 |     SDK Version: V1.5.4
12 |     Release Date: 2016.6.15
13 |     
14 | ******************************************************************
15 | AiThinker_ESP8266_DIO_32M_32M_20160615_V1.5.4.bin
16 | 
17 | MD5: B561B49242DC88EA5CBFCAB0CF287BF5
18 | 
19 | FirmWare Infomation:
20 |     SPI MODE: DIO
21 |     Flash Size: 32Mbit
22 |     File Size: 32Mbit
23 |     SPI SPEED: 40MHz
24 |     SDK Version: V1.5.4
25 |     Release Date: 2016.6.15
26 |     
27 | ******************************************************************
28 | 
29 | How to download:
30 |     1. Please select the firmware in ESP_DOWNLOAD_TOOL_V2.4;
31 |     2. The address should write 0x00000;
32 |     3. If you don't know how to config your download panel, please checked the "DoNotChgBin". That will be download the bin as default setting.
33 | 
34 |     
35 |     More infomation please visit http://www.ai-thinker.com/ 
36 |     If you have any question, please send your mail to support@aithinker.com 


--------------------------------------------------------------------------------
/ThingSpeak3.1.ino:
--------------------------------------------------------------------------------
  1 | /*
  2 |  * This code is for a Arduino Leonardo board. It has more program space than a UNO
  3 |  * and also a real UART pins 0 and 1. Not tested on UNO.
  4 |  *
  5 |  * The original idea li0r.wordpress.com Alarmino project, has great information on the contact id
  6 |  * protocol and hardware to decode DTMF.
  7 |  *
  8 |  * Contact ID decoding and SMS message buffering and great hardware information
  9 |  * Modified to use ESP8266-01 instead of SIM900 GSM board
 10 |  * NASCO Alarm Panel SMS Gateway (APSG)
 11 |  * For information please visit www.ndtech.com.au
 12 |  * Debounce library import as a zip 
 13 |  * 
 14 |  * ESP8266 WiFi code
 15 |  * WiFiEsp Library
 16 |  * For more details see: http://yaab-arduino.blogspot.com/p/wifiesp-example-client.html
 17 |  * ESP8266 AT Firmware 1.5.4
 18 |  * 
 19 |  * ThingSpeak.com HTTPThing to Twillio SMS API
 20 |  */
 21 | 
 22 | 
 23 | // --------------------------------------------------------------
 24 | // Libraries
 25 | #include <Debounce.h>
 26 | #include "WiFiEsp.h"
 27 | //----------------------------------------------------------------
 28 | 
 29 | #define FIRMWARE_VERSION           6
 30 | #define MAX_DTMF_DATA             20
 31 | #define CONTACT_ID_LENGTH         16
 32 | #define MAX_ALARM_EVENTS          16
 33 | #define DTMF_TO_HANDSHAKE_TIME  2000 // Time between last DTMF tone of phone number and sending the handshake tone
 34 | #define DTMF_TO_KISSOFF_TIME    1000 // Time between last DTMF tone of contact ID and sending the kissoff tone
 35 | 
 36 | #define STATE_INIT_GSM             0
 37 | #define STATE_ON_HOOK              1
 38 | #define STATE_WAIT_PHONE_NUMBER    2
 39 | #define STATE_WAIT_CONTACT_ID      3
 40 | #define SMS_CHECK              15000 // Time between SMS checks
 41 | #define SMS_SMS_DELAY          15000 // Time before sending a partially empty SMS message
 42 | #define SMS_CHECK_TIME_GOOD    10000 // Time between checking ESP module
 43 | #define SMS_CHECK_TIME_BAD     20000 // Time between checking ESP module
 44 | 
 45 | #define MAX_ZONES                   8
 46 | #define MAX_PHONES                  2
 47 | #define MAX_ZONE_NAME_LENGTH       15
 48 | #define MAX_SMS_MESSAGE           180
 49 | #define MAX_SMS_LENGTH            160
 50 | #define MAX_SMS_NUMBER             15
 51 | 
 52 | const int dtmf8870[]       = { 'D', '1', '2', '3', '4', '5', '6', '7', '8', '9', '0', '*', '#', 'A', 'B', 'C' };
 53 | const int dtmfContactID[]  = { 'X', '1', '2', '3', '4', '5', '6', '7', '8', '9', '0', '*', '#', 'D', 'E', 'F' };
 54 | const int dtmfValue[]      = {   0,   1,   2,   3,   4,   5,   6,   7,   8,   9,  10,  11,  12,  13,  14,  15 };
 55 | const int intValue[]       = {   0,   1,   2,   3,   4,   5,   6,   7,   8,   9,   0,   0,   0,   0,   0,   0 };
 56 | 
 57 | //API key for the Thingspeak ThingHTTP already configured
 58 | const String apiKey = "your thingspeak thingHTTP apiKey";
 59 | 
 60 | // Emulate Serial1 on pins 0/1 if not present
 61 | #ifndef HAVE_HWSERIAL1
 62 | #include "SoftwareSerial.h"
 63 | SoftwareSerial Serial1(0, 1); // RX, TX
 64 | #endif
 65 | 
 66 | char ssid[] = "your network SSID";            // your network SSID (name)
 67 | char pass[] = "your wifi password";        // your network password
 68 | int status = WL_IDLE_STATUS;     // the Wifi radio's status
 69 | char server[] = "api.thingspeak.com";
 70 | 
 71 | // Initialize the Ethernet client object
 72 | WiFiEspClient client;
 73 | 
 74 | 
 75 | 
 76 | // Pin Mapping (Leonardo)
 77 | // http://www.instructables.com/id/Step-by-Step-Guide-to-the-Arduino-Leonardo/step3/More-Analog-Pins/
 78 | #define PIN_DTMF_DECODE      2
 79 | #define PIN_DTMF_3           4
 80 | #define PIN_DTMF_1           6
 81 | #define PIN_OFF_HOOK         7
 82 | #define PIN_DTMF_0           8
 83 | #define PIN_DTMF_2          12
 84 | #define PIN_TONE            13
 85 | 
 86 | // --------------------------------------------------------------
 87 | // Ademco Contact ID Protocol
 88 | #define EVENT_QUALIFIER_OPENING                      1
 89 | #define EVENT_QUALIFIER_CLOSING                      3
 90 | #define EVENT_QUALIFIER_STATUS                       6
 91 | 
 92 | #define EVENT_CODE_BURGLAR_BURGLARY                  130
 93 | #define EVENT_CODE_BURGLAR_PERIMETER                 131
 94 | #define EVENT_CODE_BURGLAR_INTERIOR                  132
 95 | #define EVENT_CODE_BURGLAR_24_HOUR_SAFE              133
 96 | #define EVENT_CODE_BURGLAR_ENTRY_EXIT                134
 97 | #define EVENT_CODE_BURGLAR_DAY_NIGHT                 135
 98 | #define EVENT_CODE_BURGLAR_OUTDOOR                   136
 99 | #define EVENT_CODE_BURGLAR_TAMPER                    137
100 | #define EVENT_CODE_BURGLAR_NEAR_ALARM                138
101 | #define EVENT_CODE_BURGLAR_INTRUSION_VERIFIER        139
102 | #define EVENT_CODE_GENERAL_ALARM                     140
103 | #define EVENT_CODE_SYSTEM_AC_FAIL                    301
104 | #define EVENT_CODE_OCRA_OPEN_CLOSE                   402
105 | #define EVENT_CODE_OCRA_CANCEL                       406
106 | #define EVENT_CODE_RECENT_CLOSE                      459
107 | 
108 | #define IN_CANCEL                                    0
109 | #define IN_ALARM                                     1
110 | 
111 | // --------------------------------------------------------------
112 | // Types
113 | struct AlarmEvent {
114 |   byte type;
115 |   word code;
116 |   word zone;
117 | };
118 | 
119 | struct ZoneData {
120 |   boolean enabled;
121 |   char    name[MAX_ZONE_NAME_LENGTH + 1];
122 |   boolean alarm;
123 |   boolean cancel;
124 | };
125 | 
126 | struct PhoneData {
127 |   boolean enabled;
128 |   char    number[MAX_SMS_NUMBER + 1];
129 | };
130 | 
131 | // --------------------------------------------------------------
132 | // Global variables
133 | Debounce   offHook = Debounce(50, PIN_OFF_HOOK);
134 | int        state;
135 | int        dtmfBit;
136 | int        dtmfDigit;
137 | int        dtmfOffset;
138 | int        dtmfChecksum;
139 | boolean    dtmfDecoded;
140 | boolean    dtmfAvailable;
141 | int        dtmfData[MAX_DTMF_DATA];
142 | AlarmEvent alarmEvents[MAX_ALARM_EVENTS];
143 | byte       alarmEventsHead;
144 | byte       alarmEventsTail;
145 | byte       alarmEventsAvl;
146 | byte       alarmEventsLength;
147 | byte       alarmType;
148 | word       alarmCode;
149 | word       alarmZone;
150 | byte       eventQualifier;
151 | word       eventCode;
152 | word       eventZone;
153 | int        t;
154 | unsigned long smsSendSms;
155 | unsigned long espCheck;
156 | unsigned long smsCheck;
157 | char          smsBuffer[MAX_SMS_MESSAGE];
158 | char          smsNumber[MAX_SMS_NUMBER];
159 | char          smsMessage[MAX_SMS_MESSAGE];
160 | unsigned long now;
161 | unsigned long dtmfTime;
162 | 
163 | 
164 | // --------------------------------------------------------------
165 | // Configuration
166 | // true = enabled, Zone description, true = report alarms, true = report restorals
167 | ZoneData zones[MAX_ZONES] = {
168 |   { true, "ZONE ONE",    true, true },
169 |   { true, "ZONE TWO",    true, true },
170 |   { true, "ZONE THREE",  true, true },
171 |   { true, "ZONE FOUR",   true, true },
172 |   { true, "ZONE FIVE",   true, true },
173 |   { true, "ZONE SIX",    true, true },
174 |   { false, "ZONE SEVEN",  false, false },
175 |   { false, "ZONE EIGHT",  false, false }
176 | };
177 | 
178 | // PhoneData true = use the following number... the phone number is your Twillio registered cell phone #
179 | PhoneData phones[MAX_PHONES] = {
180 |   { true, "+1319xxxxxxx" },
181 |   { false, "+xxxxxxxxxxx" }
182 | };
183 | 
184 | void handleAlarmEvents(void);
185 | void sendSmsMessage(void);
186 | 
187 | // --------------------------------------------------------------
188 | // Setup
189 | 
190 | void setup()
191 | {
192 |   pinMode(PIN_OFF_HOOK, INPUT);
193 |   pinMode(PIN_DTMF_DECODE, INPUT);
194 |   pinMode(PIN_DTMF_0, INPUT);
195 |   pinMode(PIN_DTMF_1, INPUT);
196 |   pinMode(PIN_DTMF_2, INPUT);
197 |   pinMode(PIN_DTMF_3, INPUT);
198 |   pinMode(PIN_TONE, OUTPUT);
199 | 
200 |   delay(1000);
201 |   Serial.begin(9600);
202 |   delay(1000);
203 |   // initialize serial for ESP module
204 |   Serial1.begin(115200);
205 | 
206 |   dtmfBit = 0;
207 |   dtmfDigit = 0;
208 |   dtmfDecoded = false;
209 |   dtmfAvailable = false;
210 |   alarmEventsInit(MAX_ALARM_EVENTS);
211 |   state = STATE_ON_HOOK;
212 |   espCheck =0;
213 |   smsSendSms = 0;
214 |   smsCheck = 0;
215 | 
216 |   Serial.println("Alarm Panel SMS Gateway (APSG)");
217 |   delay(2000);
218 |   WiFi.init(&Serial1);
219 |   // check for the presence of the shield
220 |   if (WiFi.status() == WL_NO_SHIELD) {
221 |     Serial.println("WiFi shield not present");
222 |     // don't continue
223 |     while (true);
224 |   }
225 |   // attempt to connect to WiFi network
226 |   while ( status != WL_CONNECTED) {
227 |     Serial.print("Attempting to connect to WPA SSID: ");
228 |     Serial.println(ssid);
229 |     // Connect to WPA/WPA2 network
230 |     status = WiFi.begin(ssid, pass);
231 |   }
232 | }
233 | 
234 | void loop()
235 | {
236 |   
237 |   now = millis();
238 |   offHook.update();
239 |   espCheck = now;
240 | 
241 |   if (state == STATE_WAIT_PHONE_NUMBER || state == STATE_WAIT_CONTACT_ID) {
242 |     if (offHook.read() == 1) {
243 |       // Global reset - hungup detected
244 |       state = STATE_ON_HOOK;
245 |       //Serial.println("STATE_ON_HOOK");
246 |       //Serial.flush();
247 |     } else {
248 |       // Global decode - DTMF if available
249 |       dtmfHandler();
250 |     }
251 |   }
252 | 
253 |     // Check the ESP8266 buffer every now and then if we arent inside a call from the alarm
254 |   if (state == STATE_ON_HOOK) {
255 |     if (now > smsCheck) {
256 |       smsCheck = now + SMS_CHECK_TIME_GOOD;
257 |     }
258 |   }
259 |   if (status == WL_CONNECTED) {
260 |     // Send SMS messages if the timer has expired
261 |      if ((smsSendSms != 0) && (now > smsSendSms)) {
262 |         sendSmsMessage();
263 |         smsCheck = millis() + SMS_CHECK;
264 |       }
265 |     }
266 | 
267 |   switch (state) {
268 |     case STATE_ON_HOOK:
269 |       if (offHook.read() == 0) {
270 |         state = STATE_WAIT_PHONE_NUMBER;
271 |         dtmfOffset = 0;
272 |         dtmfChecksum = 0;
273 |         //Serial.println("STATE_WAIT_PHONE_NUMBER");Serial.flush();
274 |       } else {
275 |         handleAlarmEvents();
276 |       }
277 |       break;
278 | 
279 |     case STATE_WAIT_PHONE_NUMBER:
280 |       if (dtmfAvailable == true) {
281 |         dtmfAvailable = false;
282 |         dtmfTime = now;
283 |         if (dtmfOffset < MAX_DTMF_DATA) {
284 |           dtmfData[dtmfOffset] = dtmfDigit;
285 |           dtmfOffset++;
286 |           //Serial.print((char)(dtmf8870[dtmfDigit]));
287 |         }
288 |       } else {
289 |         if (dtmfOffset > 1) {
290 |           if (now > (dtmfTime + DTMF_TO_HANDSHAKE_TIME)) {
291 |             state = STATE_WAIT_CONTACT_ID;
292 |             dtmfOffset = 0;
293 |             dtmfChecksum = 0;
294 |             //Serial.println("");Serial.flush();
295 |             //Serial.println("STATE_WAIT_CONTACT_ID");Serial.flush();
296 |             tone(PIN_TONE, 1400); delay(100); noTone(PIN_TONE);
297 |             delay(100);
298 |             tone(PIN_TONE, 2300); delay(100); noTone(PIN_TONE);
299 |           }
300 |         }
301 |       }
302 |       break;
303 | 
304 |     case STATE_WAIT_CONTACT_ID:
305 |       if (dtmfAvailable == true) {
306 |         dtmfAvailable = false;
307 |         dtmfTime = now;
308 |         if (dtmfOffset < MAX_DTMF_DATA) {
309 |           dtmfData[dtmfOffset] = dtmfDigit;
310 |           dtmfOffset++;
311 |           dtmfChecksum = dtmfChecksum + dtmfValue[dtmfDigit];
312 |           //Serial.print((char)dtmfContactID[dtmfDigit]);
313 |           //Serial.print(dtmfDigit);
314 |           //Serial.flush();
315 |         }
316 |       } else {
317 |         if (dtmfOffset > 1) {
318 |           if (now > (dtmfTime + DTMF_TO_KISSOFF_TIME)) {
319 |             if (dtmfOffset == CONTACT_ID_LENGTH) {
320 |               dtmfChecksum = dtmfChecksum - dtmfValue[dtmfDigit];
321 |               for (t = 0; t < dtmfChecksum; t += 15);
322 |               dtmfChecksum = t - dtmfChecksum;
323 |               if (dtmfChecksum == 0) {
324 |                 dtmfChecksum = 15;
325 |               }
326 |               if (dtmfChecksum == dtmfValue[dtmfDigit]) {
327 |                 alarmType = intValue[dtmfData[6]];
328 |                 alarmCode = (((intValue[dtmfData[7]] * 10) + intValue[dtmfData[8]]) * 10) + intValue[dtmfData[9]];
329 |                 alarmZone = (((intValue[dtmfData[12]] * 10) + intValue[dtmfData[13]]) * 10) + intValue[dtmfData[14]];
330 |                 alarmEventsPut(alarmType, alarmCode, alarmZone);
331 |                 //Serial.println(" = OK");
332 |                 //Serial.flush();
333 |                 tone(PIN_TONE, 1400); delay(800); noTone(PIN_TONE);
334 |               } else {
335 |                 //Serial.println(" = CHECKSUM ERROR");
336 |                 //Serial.flush();
337 |               }
338 |             } else {
339 |               //Serial.println(" = LENGTH ERROR");
340 |               //Serial.flush();
341 |             }
342 |             dtmfOffset = 0;
343 |             dtmfChecksum = 0;
344 |           }
345 |         }
346 |       }
347 |       break;
348 |   }
349 | }
350 | 
351 | 
352 | void sendSMS(String number, String message)
353 | {
354 |   // attempt to connect to WiFi network
355 |   while ( status != WL_CONNECTED) {
356 |     //Serial.print("Attempting to connect to WPA SSID: ");
357 |     Serial.println(ssid);
358 |     // Connect to WPA/WPA2 network
359 |     status = WiFi.begin(ssid, pass);
360 |   }
361 |   // Make a TCP connection to remote host
362 |   if (client.connect(server, 80)){
363 |     Serial.println("Connected to ThingSpeak!");
364 |   
365 | 
366 |     //should look like this...
367 |     //api.thingspeak.com/apps/thinghttp/send_request?api_key={api key}&number={send to number}&message={text body}
368 | 
369 |     client.print("GET /apps/thinghttp/send_request?api_key=");
370 |     client.print(apiKey);
371 |     //Serial.println(apiKey);
372 |     client.print("&number=");
373 |     client.print(number);
374 |     client.print("&message=");
375 |     client.print(message);
376 |     client.println(" HTTP/1.1");
377 |     client.print("Host: ");
378 |     client.println(server);
379 |     client.println("Connection: close");
380 |     //Serial.println("Connection: closed");
381 |     client.println();
382 |   }
383 |   else
384 |   {
385 |     Serial.println(F("Connection failed"));
386 |   }
387 | 
388 |   // Check for a response from the server, and route it
389 |   // out the serial port.
390 |   while (client.connected())
391 |   {
392 |     if ( client.available() )
393 |     {
394 |       char c = client.read();
395 |       Serial.print(c);
396 |     }
397 |   }
398 |   //Serial.println();
399 |   client.stop();
400 | }
401 | 
402 | String URLEncode(const char* msg)
403 | {
404 |   const char *hex = "0123456789abcdef";
405 |   String encodedMsg = "";
406 | 
407 |   while (*msg != '\0') {
408 |     if ( ('a' <= *msg && *msg <= 'z')
409 |          || ('A' <= *msg && *msg <= 'Z')
410 |          || ('0' <= *msg && *msg <= '9') ) {
411 |       encodedMsg += *msg;
412 |     }
413 |     else {
414 |       encodedMsg += '%';
415 |       encodedMsg += hex[*msg >> 4];
416 |       encodedMsg += hex[*msg & 15];
417 |     }
418 |     msg++;
419 |   }
420 |   return encodedMsg;
421 | }
422 | 
423 | 
424 | void handleAlarmEvents(void) {
425 |   word tempZone;
426 | 
427 |   while (alarmEventsEmpty() == false) {
428 |     alarmEventsGet(eventQualifier, eventCode, eventZone);
429 |     smsBuffer[0] = 0;
430 |     // NOTE: Only add messages to smsBuffer if you want to send it via SMS
431 |     switch (eventQualifier) {
432 |       case EVENT_QUALIFIER_OPENING:
433 |         switch (eventCode) {
434 |           case EVENT_CODE_BURGLAR_BURGLARY:
435 |             if (eventZone <= MAX_ZONES) {
436 |               tempZone = eventZone - 1;
437 |               if (zones[tempZone].enabled == true && zones[tempZone].alarm == true) {
438 |                 sprintf(smsBuffer, "ALARM %s ", zones[tempZone].name);
439 |                 //Serial.print(smsBuffer);
440 |               }
441 |             }
442 |             sprintf(smsBuffer, "ALARM BURGLARY ZONE: %d ", eventZone);
443 |             break;
444 | 
445 |           case EVENT_CODE_BURGLAR_TAMPER:
446 |             sprintf(smsBuffer, "TAMPER %d ", eventZone);
447 |             //Serial.print(smsBuffer);
448 |             break;
449 | 
450 |           case EVENT_CODE_SYSTEM_AC_FAIL:
451 |             sprintf(smsBuffer, "AC FAIL %d ", eventZone);
452 |             //Serial.print(smsBuffer);
453 |             break;
454 | 
455 |           case EVENT_CODE_OCRA_OPEN_CLOSE:
456 |             sprintf(smsBuffer, "DISARM SYSTEM USER: %d ", eventZone);
457 |             //Serial.print(smsBuffer);
458 |             break;
459 | 
460 |           case EVENT_CODE_RECENT_CLOSE:
461 |             sprintf(smsBuffer, "RECENT CLOSE: %d ", eventZone);
462 |             //Serial.print(smsBuffer);
463 |             break;
464 | 
465 |           case EVENT_CODE_OCRA_CANCEL:
466 |             sprintf(smsBuffer, "CANCEL USER: %d ", eventZone);
467 |             //Serial.print(smsBuffer);
468 |             break;
469 | 
470 |           case EVENT_CODE_GENERAL_ALARM:
471 |             sprintf(smsBuffer, "General Alarm: %d ", eventZone);
472 |             //Serial.print(smsBuffer);
473 |             break;
474 | 
475 |           default:
476 |             sprintf(smsBuffer, "ALARM UNKNOWN ET: %d EZ: %d ", eventCode, eventZone);
477 |             //Serial.print(smsBuffer);
478 |             break;
479 |         }
480 |         break;
481 | 
482 |       case EVENT_QUALIFIER_CLOSING:
483 |         switch (eventCode) {
484 |           case EVENT_CODE_BURGLAR_BURGLARY:
485 |             if (eventZone <= MAX_ZONES) {
486 |               tempZone = eventZone - 1;
487 |               if (zones[tempZone].enabled == true && zones[tempZone].cancel == true) {
488 |                 sprintf(smsBuffer, " RESTORAL %s", zones[tempZone].name);
489 |                 // Serial.print(smsBuffer);
490 |               }
491 |             }
492 |             sprintf(smsBuffer, "RESTORAL ZONE: %d ", eventZone);
493 |             // Serial.print(smsBuffer);
494 |             break;
495 | 
496 |           case EVENT_CODE_BURGLAR_TAMPER:
497 |             sprintf(smsBuffer, "RESTORAL TAMPER %d ", eventZone);
498 |             //Serial.print(smsBuffer);
499 |             break;
500 | 
501 |           case EVENT_CODE_SYSTEM_AC_FAIL:
502 |             sprintf(smsBuffer, "RESTORAL AC FAIL %d ", eventZone);
503 |             //Serial.print(smsBuffer);
504 |             break;
505 | 
506 |           case EVENT_CODE_OCRA_OPEN_CLOSE:
507 |             sprintf(smsBuffer, "ARM SYSTEM USER: %d ", eventZone);
508 |             //Serial.print(smsBuffer);
509 |             break;
510 | 
511 |           case EVENT_CODE_RECENT_CLOSE:
512 |             sprintf(smsBuffer, "RECENT CLOSE: %d ", eventZone);
513 |             // Serial.print(smsBuffer);
514 |             break;
515 | 
516 |           default:
517 |             sprintf(smsBuffer, "CANCEL UNKNOWN ET: %d ZONE: %d ", eventCode, eventZone);
518 |             //Serial.print(smsBuffer);
519 |             break;
520 |         }
521 |         break;
522 | 
523 |       default:
524 |         sprintf(smsBuffer, "UNKNOWN EQ: %d ET: %d ZONE: %d ", eventQualifier, eventCode, eventZone);
525 |         //Serial.print(smsBuffer);
526 |         break;
527 |     }
528 | 
529 |     // CHECK If we have a new message to append to existing message
530 |     if (strlen(smsBuffer) > 0) {
531 |       int nml = strlen(smsBuffer);
532 |       int eml = strlen(smsMessage);
533 |       // CHECK If existing message does not have space for new message
534 |       if ((eml + 2 + nml) < MAX_SMS_LENGTH) {
535 |       //if ((eml + nml) > 0) {
536 |         strcat(smsMessage, smsBuffer);
537 |         eml = 0;
538 |       }
539 |       // Add the new message to the existing message
540 |       //strcat(smsMessage, smsBuffer);
541 |       //smsSendSms = millis() + SMS_SMS_DELAY;
542 |       smsSendSms = millis() + SMS_SMS_DELAY;
543 |     }
544 |   }
545 | }
546 | 
547 | void sendSmsMessage(void) {
548 |   byte p;
549 |   if (strlen(smsMessage) > 0) {
550 |     for (p = 0; p < MAX_PHONES; p++) {
551 |       if (phones[p].enabled == true) {
552 |        //Serial.println("------------------------------");
553 |        Serial.print("SMS TO: "); Serial.println(phones[p].number);
554 |        Serial.println(smsMessage);
555 |        //Serial.println("------------------------------");
556 |        sendSMS(phones[p].number, URLEncode(smsMessage));
557 |        
558 |       }
559 |     }
560 |   }
561 |   smsMessage[0] = 0;
562 |   smsSendSms = 0;
563 | 
564 | }
565 | 
566 | // ---------------------------------------------------------------------------
567 | // Read and decode a DTMF tone if available, dont read the same tone twice
568 | void dtmfHandler() {
569 |   int dtmfState = digitalRead(PIN_DTMF_DECODE);
570 |   if (dtmfState == LOW) {
571 |     if (dtmfDecoded == false) {
572 |       dtmfDecoded = true;
573 |       dtmfDigit = 0;
574 |       bitWrite(dtmfDigit, 0, digitalRead(PIN_DTMF_0));
575 |       bitWrite(dtmfDigit, 1, digitalRead(PIN_DTMF_1));
576 |       bitWrite(dtmfDigit, 2, digitalRead(PIN_DTMF_2));
577 |       bitWrite(dtmfDigit, 3, digitalRead(PIN_DTMF_3));
578 |       dtmfAvailable = true;
579 |     }
580 |   } else {
581 |     if (dtmfDecoded == true) {
582 |       dtmfDecoded = false;
583 |     }
584 |   }
585 | }
586 | 
587 | // ---------------------------------------------------------------------------
588 | // Alarm event buffer
589 | void alarmEventsInit(byte length) {
590 |   alarmEventsHead = 0;
591 |   alarmEventsTail = 0;
592 |   alarmEventsAvl = 0;
593 |   alarmEventsLength = length;
594 | }
595 | 
596 | boolean alarmEventsEmpty() {
597 |   if (alarmEventsAvl == 0) {
598 |     return true;
599 |   }
600 |   return false;
601 | }
602 | 
603 | boolean alarmEventsFull() {
604 |   if (alarmEventsAvl == alarmEventsLength) {
605 |     return true;
606 |   }
607 |   return false;
608 | }
609 | 
610 | boolean alarmEventsPut(byte a, word b, word c) {
611 |   if (alarmEventsAvl == alarmEventsLength) {
612 |     return false;
613 |   }
614 |   alarmEvents[alarmEventsHead].type = a;
615 |   alarmEvents[alarmEventsHead].code = b;
616 |   alarmEvents[alarmEventsHead].zone = c;
617 |   alarmEventsAvl = alarmEventsAvl + 1;
618 |   alarmEventsHead = (alarmEventsHead + 1) & (alarmEventsLength - 1);
619 |   return true;
620 | }
621 | 
622 | boolean alarmEventsGet(byte &a, word &b, word &c) {
623 |   if (alarmEventsAvl == 0) {
624 |     return false;
625 |   }
626 |   a = alarmEvents[alarmEventsTail].type;
627 |   b = alarmEvents[alarmEventsTail].code;
628 |   c = alarmEvents[alarmEventsTail].zone;
629 |   alarmEventsTail = (alarmEventsTail + 1) & (alarmEventsLength - 1);
630 |   alarmEventsAvl = alarmEventsAvl - 1;
631 |   return true;
632 | }
633 | 


--------------------------------------------------------------------------------