├── j2.serial
├── j2.zip
├── nj2.zip
├── COMPILED
    ├── j2.z3
    └── nj2.z3
├── j2.xzap
├── j2.chart
├── j2.zil
├── z0.zil
├── wishbringer.zil
├── j2.errors
├── README.md
├── rmode.init
├── north.zil
├── j2.txt
├── originalj2.txt
├── fog.zil
├── island.zil
├── misc.zil
├── under.zil
├── magick.zil
├── boxes.zil
├── bridge.zil
├── west.zil
├── globals.zil
└── cemetery.zil


/j2.serial:
--------------------------------------------------------------------------------
1 | 10
2 | 


--------------------------------------------------------------------------------
/j2.zip:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/historicalsource/wishbringer/HEAD/j2.zip


--------------------------------------------------------------------------------
/nj2.zip:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/historicalsource/wishbringer/HEAD/nj2.zip


--------------------------------------------------------------------------------
/COMPILED/j2.z3:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/historicalsource/wishbringer/HEAD/COMPILED/j2.z3


--------------------------------------------------------------------------------
/COMPILED/nj2.z3:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/historicalsource/wishbringer/HEAD/COMPILED/nj2.z3


--------------------------------------------------------------------------------
/j2.xzap:
--------------------------------------------------------------------------------
 1 | 	.TIME
 2 | 	.INSERT "J2FREQ"
 3 | 	.INSERT "J2DAT"
 4 | 	.INSERT "MISC"
 5 | 	.INSERT "PARSER"
 6 | 	.INSERT "GLOBALS"
 7 | 	.INSERT "SYNTAX"
 8 | 	.INSERT "VERBS"
 9 | 	.INSERT "PEOPLE"
10 | 	.INSERT "SOUTH"
11 | 	.INSERT "CENTER"
12 | 	.INSERT "WEST"
13 | 	.INSERT "EAST"
14 | 	.INSERT "NORTH"
15 | 	.INSERT "BRIDGE"
16 | 	.INSERT "FOG"
17 | 	.INSERT "SHOPPE"
18 | 	.INSERT "CEMETERY"
19 | 	.INSERT "UNDER"
20 | 	.INSERT "TOWER"
21 | 	.INSERT "ISLAND"
22 | 	.INSERT "BOXES"
23 | 	.INSERT "MAGICK"
24 |         .INSERT "J2STR"
25 | 	.END
26 | 


--------------------------------------------------------------------------------
/j2.chart:
--------------------------------------------------------------------------------
 1 | -date-  -rel-	-size-	-pre-	-obj-	-glo-	-voc-
 2 |  7/22     69	129104	22604	253	235	1043
 3 |  7/22     69	128928	22600	253	233	1043
 4 |  7/22     69	128932	22600	253	233	1043
 5 |  7/22     69	128932	22600	253	233	1043
 6 |  7/22     69	128872	22598	253	232	1043
 7 |  7/22     69	128876	22598	253	232	1043
 8 |  7/22     69	128878	22598	253	232	1043
 9 |  8/27     70	128884	22601	253	232	1043
10 |  9/17     -1	128904	22601	253	232	1043
11 |  9/17     69	128904	22601	253	232	1043
12 |  9/20     69	128904	22601	253	232	1043
13 |  9/20     70	128816	22601	253	232	1043
14 |  9/20     69	128816	22601	253	232	1043
15 |  5/23     70	139040	22043	253	231	1045
16 |  5/24     70	139040	22043	253	231	1045
17 |  6/09     70	127980	22555	253	231	1045
18 | 


--------------------------------------------------------------------------------
/j2.zil:
--------------------------------------------------------------------------------
 1 | "J2 for WISHBRINGER: (C)1985 Infocom, Inc. All Rights Reserved."
 2 | 
 3 | <PRINC "
 4 | WISHBRINGER: The Magick Stone of Dreams
 5 | 
 6 | ">
 7 | 
 8 | ON!-INITIAL
 9 | OFF!-INITIAL
10 | ENABLE!-INITIAL
11 | DISABLE!-INITIAL
12 | 
13 | <VERSION ZIP>
14 | 
15 | <SET REDEFINE T>
16 | 
17 | ; <GLOBAL BIGFIX 10000>
18 | 
19 | <OR <GASSIGNED? ZILCH>
20 |     <SETG WBREAKS <STRING !\" !,WBREAKS>>>
21 | 
22 | <COND (<GASSIGNED? PREDGEN>
23 |        <SETG ZSTR-ON <SETG ZSTR-OFF ,TIME>>
24 |        <ID 0>)>
25 | 
26 | <INSERT-FILE "MISC" T>
27 | <INSERT-FILE "PARSER" T>
28 | <INSERT-FILE "GLOBALS" T>
29 | <INSERT-FILE "SYNTAX" T>
30 | <INSERT-FILE "VERBS" T>
31 | <INSERT-FILE "PEOPLE" T>
32 | <INSERT-FILE "SOUTH" T>
33 | <INSERT-FILE "CENTER" T>
34 | <INSERT-FILE "WEST" T>
35 | <INSERT-FILE "EAST" T>
36 | <INSERT-FILE "NORTH" T>
37 | <INSERT-FILE "BRIDGE" T>
38 | <INSERT-FILE "FOG" T>
39 | <INSERT-FILE "SHOPPE" T>
40 | <INSERT-FILE "CEMETERY" T>
41 | <INSERT-FILE "UNDER" T>
42 | <INSERT-FILE "TOWER" T>
43 | <INSERT-FILE "ISLAND" T>
44 | <INSERT-FILE "BOXES" T>
45 | <INSERT-FILE "MAGICK" T>
46 | 
47 | <PROPDEF SIZE 5>
48 | <PROPDEF CAPACITY 0>
49 | 
50 | 


--------------------------------------------------------------------------------
/z0.zil:
--------------------------------------------------------------------------------
 1 | "J2 for WISHBRINGER: (C)1985 Infocom, Inc. All Rights Reserved."
 2 | 
 3 | <PRINC "
 4 | WISHBRINGER: The Magick Stone of Dreams
 5 | 
 6 | ">
 7 | 
 8 | ON!-INITIAL
 9 | OFF!-INITIAL
10 | ENABLE!-INITIAL
11 | DISABLE!-INITIAL
12 | 
13 | <COND (<GASSIGNED? MUDDLE>
14 |        <BLOAT 90000 0 0 3300 0 0 0 0 0 256>)>
15 | 
16 | <SET REDEFINE T>
17 | 
18 | ; <GLOBAL BIGFIX 10000>
19 | 
20 | <OR <GASSIGNED? ZILCH>
21 |     <SETG WBREAKS <STRING !\" !,WBREAKS>>>
22 | 
23 | <COND (<GASSIGNED? PREDGEN>
24 |        <SETG ZSTR-ON <SETG ZSTR-OFF ,TIME>>
25 |        <ID 0>)>
26 | 
27 | <INSERT-FILE "MISC" T>
28 | <INSERT-FILE "PARSER" T>
29 | <INSERT-FILE "GLOBALS" T>
30 | <INSERT-FILE "SYNTAX" T>
31 | <INSERT-FILE "VERBS" T>
32 | <INSERT-FILE "PEOPLE" T>
33 | <INSERT-FILE "SOUTH" T>
34 | <INSERT-FILE "CENTER" T>
35 | <INSERT-FILE "WEST" T>
36 | <INSERT-FILE "EAST" T>
37 | <INSERT-FILE "NORTH" T>
38 | <INSERT-FILE "BRIDGE" T>
39 | <INSERT-FILE "FOG" T>
40 | <INSERT-FILE "SHOPPE" T>
41 | <INSERT-FILE "CEMETERY" T>
42 | <INSERT-FILE "UNDER" T>
43 | <INSERT-FILE "TOWER" T>
44 | <INSERT-FILE "ISLAND" T>
45 | <INSERT-FILE "BOXES" T>
46 | <INSERT-FILE "MAGICK" T>
47 | 
48 | <PROPDEF SIZE 5>
49 | <PROPDEF CAPACITY 0>


--------------------------------------------------------------------------------
/wishbringer.zil:
--------------------------------------------------------------------------------
 1 | "J2 for WISHBRINGER: (C)1985 Infocom, Inc. All Rights Reserved."
 2 | 
 3 | <PRINC "
 4 | WISHBRINGER: The Magick Stone of Dreams
 5 | 
 6 | ">
 7 | 
 8 | ON!-INITIAL
 9 | OFF!-INITIAL
10 | ENABLE!-INITIAL
11 | DISABLE!-INITIAL
12 | 
13 | <COND (<GASSIGNED? MUDDLE>
14 |        <BLOAT 90000 0 0 3300 0 0 0 0 0 256>)>
15 | 
16 | <SET REDEFINE T>
17 | 
18 | ; <GLOBAL BIGFIX 10000>
19 | 
20 | <OR <GASSIGNED? ZILCH>
21 |     <SETG WBREAKS <STRING !\" !,WBREAKS>>>
22 | 
23 | <COND (<GASSIGNED? PREDGEN>
24 |        <SETG ZSTR-ON <SETG ZSTR-OFF ,TIME>>
25 |        <ID 0>)>
26 | 
27 | <INSERT-FILE "MISC" T>
28 | <INSERT-FILE "PARSER" T>
29 | <INSERT-FILE "GLOBALS" T>
30 | <INSERT-FILE "SYNTAX" T>
31 | <INSERT-FILE "VERBS" T>
32 | <INSERT-FILE "PEOPLE" T>
33 | <INSERT-FILE "SOUTH" T>
34 | <INSERT-FILE "CENTER" T>
35 | <INSERT-FILE "WEST" T>
36 | <INSERT-FILE "EAST" T>
37 | <INSERT-FILE "NORTH" T>
38 | <INSERT-FILE "BRIDGE" T>
39 | <INSERT-FILE "FOG" T>
40 | <INSERT-FILE "SHOPPE" T>
41 | <INSERT-FILE "CEMETERY" T>
42 | <INSERT-FILE "UNDER" T>
43 | <INSERT-FILE "TOWER" T>
44 | <INSERT-FILE "ISLAND" T>
45 | <INSERT-FILE "BOXES" T>
46 | <INSERT-FILE "MAGICK" T>
47 | 
48 | <PROPDEF SIZE 5>
49 | <PROPDEF CAPACITY 0>


--------------------------------------------------------------------------------
/j2.errors:
--------------------------------------------------------------------------------
 1 | Assembling J2.XZAP.1 on Thursday, June 9, 1988 16:10:47
 2 | Release(last was 70): 70
 3 | 
 4 |      0	Inserting J2FREQ.ZAP.4	   (554 bytes)
 5 |    618	Inserting J2DAT.ZAP.1	 (21937 bytes)
 6 |  22555	Inserting MISC.ZAP.3	  (1626 bytes)
 7 |  24181	Inserting PARSER.ZAP.3	 (11820 bytes)
 8 |  36001	Inserting GLOBALS.ZAP.3	  (4087 bytes)
 9 |  40088	Inserting SYNTAX.ZAP.1	     (0 bytes)
10 |  40088	Inserting VERBS.ZAP.3	  (8871 bytes)
11 |  48959	Inserting PEOPLE.ZAP.4	 (10770 bytes)
12 |  59729	Inserting SOUTH.ZAP.3	  (4495 bytes)
13 |  64224	Inserting CENTER.ZAP.3	 (14636 bytes)
14 |  78860	Inserting WEST.ZAP.3	  (3848 bytes)
15 |  82708	Inserting EAST.ZAP.3	  (4497 bytes)
16 |  87205	Inserting NORTH.ZAP.3	   (897 bytes)
17 |  88102	Inserting BRIDGE.ZAP.3	  (3739 bytes)
18 |  91841	Inserting FOG.ZAP.3	   (964 bytes)
19 |  92805	Inserting SHOPPE.ZAP.3	  (5546 bytes)
20 |  98351	Inserting CEMETERY.ZAP.3	  (3773 bytes)
21 | 102124	Inserting UNDER.ZAP.3	  (3046 bytes)
22 | 105170	Inserting TOWER.ZAP.3	  (7163 bytes)
23 | 112333	Inserting ISLAND.ZAP.3	  (3262 bytes)
24 | 115595	Inserting BOXES.ZAP.3	  (4159 bytes)
25 | 119754	Inserting MAGICK.ZAP.2	  (3581 bytes)
26 | 123335	Inserting J2STR.ZAP.1	  (4645 bytes)
27 | 
28 | QUEUED? global undefined:  121906
29 | GVAL global undefined:  120247
30 | PT?402 global undefined:  10802
31 | PT?302 global undefined:  10800
32 | PT?202 global undefined:  10798
33 | PT?102 global undefined:  10796
34 | PT?106 global undefined:  1068
35 | PT?113 global undefined:  1044
36 | PT?2602 global undefined:  966
37 | PT?502 global undefined:  892
38 | PT?110 global undefined:  726
39 | PT?619 global undefined:  710
40 | PT?210 global undefined:  684
41 | PT?2502 global undefined:  644
42 | 
43 | 
44 | Symbols unused:
45 | ZORKID
46 | FLAGS
47 | STR?255
48 | STR?254
49 | STR?253
50 | STR?252
51 | STR?251
52 | STR?250
53 | STR?229
54 | STR?228
55 | STR?227
56 | STR?226
57 | STR?225
58 | STR?224
59 | STR?223
60 | STR?213
61 | STR?212
62 | STR?211
63 | STR?210
64 | STR?209
65 | STR?146
66 | STR?145
67 | STR?144
68 | STR?27
69 | STR?26
70 | STR?25
71 | STR?24
72 | STR?23
73 | STR?22
74 | STR?21
75 | STR?14
76 | STR?13
77 | STR?12
78 | STR?11
79 | STR?10
80 | STR?9
81 | STR?8
82 | 
83 | 253 objects.
84 | 231 globals.
85 | 1045 word vocabulary.
86 | 
87 | 127980 bytes (125K).
88 |  22555 bytes of preload.
89 |  11712 bytes of impure.
90 | 
91 | Outputting symbol tables
92 | 


--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
 1 | # Wishbringer Source Code Collection
 2 | 
 3 | Wishbringer is a 1985 interactive fiction game written by Brian Moriarty and published by Infocom.
 4 | 
 5 | Further information on Wishbringer:
 6 | 
 7 | * [Wikipedia](https://en.wikipedia.org/wiki/Wishbringer)
 8 | * [The Digital Antiquarian](https://www.filfre.net/2014/04/wishbringer/)
 9 | * [The Interactive Fiction Database](https://ifdb.tads.org/viewgame?id=z02joykzh66wfhcl)
10 | * [The Infocom Gallery](http://infocom.elsewhere.org/gallery/wishbringer/)
11 | * [IFWiki](http://www.ifwiki.org/index.php/Wishbringer)
12 | 
13 | __What is this Repository?__
14 | 
15 | This repository is a directory of source code for the Infocom game "Wishbringer", including a variety of files both used and discarded in the production of the game. It is written in ZIL (Zork Implementation Language), a refactoring of MDL (Muddle), itself a dialect of LISP created by MIT students and staff.
16 | 
17 | The source code was contributed anonymously and represents a snapshot of the Infocom development system at time of shutdown - there is no remaining way to compare it against any official version as of this writing, and so it should be considered canonical, but not necessarily the exact source code arrangement for production.
18 | 
19 | __Basic Information on the Contents of This Repository__
20 | 
21 | It is mostly important to note that there is currently no known way to compile the source code in this repository into a final "Z-machine Interpreter Program" (ZIP) file. There are .ZIP files in some of the Infocom Source Code repositories but they were there as of final spin-down of the Infocom Drive and the means to create them is currently lost.
22 | 
23 | Throughout its history, Infocom used a TOPS20 mainframe with a compiler (ZILCH) to create and edit language files - this repository is a mirror of the source code directory archive of Infocom but could represent years of difference from what was originally released.
24 | 
25 | In general, Infocom games were created by taking previous Infocom source code, copying the directory, and making changes until the game worked the way the current Implementor needed. Structure, therefore, tended to follow from game to game and may or may not accurately reflect the actual function of the code.
26 | 
27 | There are also multiple versions of the "Z-Machine" and code did change notably between the first years of Infocom and a decade later. Addition of graphics, sound and memory expansion are all slowly implemented over time.
28 | 
29 | __What is the Purpose of this Repository__
30 | 
31 | This collection is meant for education, discussion, and historical work, allowing researchers and students to study how code was made for these interactive fiction games and how the system dealt with input and processing. It is not considered to be under an open license.
32 | 
33 | Researchers are encouraged to share their discoveries about the information in this source code and the history of Infocom and its many innovative employees.
34 | 
35 | 


--------------------------------------------------------------------------------
/rmode.init:
--------------------------------------------------------------------------------
  1 | Z!COMPILED!
  2 | !do not modify this file unless you know what you are doing
  3 | 	and do not forget to re-compile it!
  4 | [7[6[5[4[3[2[1 [..o 1:<q.fu..o>"lfsbcreatew' u1 fq1++4u1 zj .u2
  5 | iname:
  6 | 217*857,820	.Y
  7 | 336*2133,2095	..P
  8 | 345*1859,1827	..Y
  9 | 394*2450,2372	...J
 10 | 397*196,125	...M
 11 | -3*2133,2095	pprint
 12 | -1*9,0	execute     9
 13 | -1*774,726	execute   774
 14 | :^i6|[..o :fo..o2u5  q5"g f~:..o(q5)2"n -q5u5''
 15 |  q5"l-5*q5j .(0fsword*5,0i)j q2,.fswordw'"#q5*5j' 
 16 | q3,.+5fswordw q7,.+10fsword ]..o|
 17 | q2j :l .(eg -4:k)j 3k:l 9i q1\ z+6u4 6,q4\ "n zj' :<l .-q4;
 18 | :\u2 c\+q1u3
 19 | q2+1"g q3,q2^fs^rcmacw'"#
 20 |  q2+1"e .u5[5[4[1[..o fsbcreatew :1<m3>w wfsbkillw]1]4]5q5j'"#
 21 |   q2(c\+q1u7c:x2)2"eq3u2'"#q..qm6'''>
 22 |   !COMPILED!
 23 | <=>s
 24 | 10044041.U.MM.D
 25 | 0FS^RMORE
 26 | fsosteco"n 36.fs:etmode '
 27 | FS RGETTY"N (FSHEIGHT-(FSECHOLINES)-1)FSLINES' @
 28 | 
 29 | *MINI TECO* Feature (Using Self-contained Quoted Mode)
 30 | ...M<=1:<
 31 |   [2 0U2 [1 .U1 8<1:<>:;  [1.U1 %2W> [1[2
 32 |      [..O FSBCREATE 2F[LINESW
 33 |      [.M [..J Q.MU2 Q2&(-1000.)#(10000000.)U.M 1M.DMINI TECO H^V
 34 |      :<!S! FIU1 Q1-127"E ."N -D.,.^V' OS'
 35 |        Q1-3"E Q2&(-1000.)#(10000003.)M.CMINI TECO ZJ .^V OS'
 36 |        Q1-27"E 0,0A-27"E 0;'' Q1I Q1-15."E 12.FSREREAD ' .-1,.^V>
 37 |      HFX...N ]..J ].M M.D
 38 |      F]LINESW FSBKILLW ]2]1 Q2<Q1:W ]1> Q1J ]1]2
 39 |      Q.M&40000."N -1FSNOQUITW'
 40 |      1:<M...N>U.R Q.RF"L-^FEQIT"E <FIF;>' Q.R,2M.ZW'
 41 |      1FSNOQUITW H^V>,3M.Z -
 42 | 
 43 | Indentation without Inquiries, etc.
 44 | <=>-
 45 | MINTERNINDENT MAX
 46 | -1UINDENT MAX
 47 |  
 48 | New Line without asking.
 49 | .Y<=I
 50 | 1:< .U.B  -1U.Q
 51 |   Q.M&176."N
 52 |     Q.M&1000."N I
 53 |    (FQ.H"L Q.H/8,11.I Q.H-(8*(Q.H/8)),40.I 73.I'"# G.H') 0;'
 54 | ([.0 [.1 [.2 [.3 
 55 | <0,0A-12."N 0;' 0,-1A-15."N 0;' 2R>
 56 |  0FU.1U.0  Q.M&64."E ONOMUD'
 57 |  :1<:-^FLR>"N ONOMUD' .-Q.0"L ONOMUD'
 58 |  :1<:-FUU.2U.2>"N -1U.2'
 59 |  :<-^FLR 1A-;"N 0;'>"N ONOMUD' .-Q.2"L ONOMUD'
 60 |  0,(Q.2-.)A-60"N Q.2-1U.2'
 61 |  0FU.3U.3  Q.2,Q.3FU.3W
 62 |   :<.U.2 -^FLRW Q.3-.;>W Q.2J
 63 | qIndent Maxu.0
 64 | q.0"L Q.3,Q.3+8F=FUNCTION"E (Q.3+4)U.2 oagain ''
 65 | q.0u.0
 66 | (Q.0-1)"g (Q.2-Q.3-Q.0)U.3 Q.3"G Q.3R .U.2 ''
 67 | "#'
 68 | !AGAIN! Q.2"L ONORM'
 69 |  Q.2J Q.1U.B OFINIS'
 70 | !NORM! Q.0J
 71 |      !**!  <1A-40."N1A-11."N0;''C> .-Q.2"E ONEXT'   .^V
 72 |   :FI-127"E FIW Q.BJ 3U.Q OOUT' :FI-"N OFINIS'"#FIW'
 73 | !NEXT!  .,Q.1:FB 	"E OAGAIN' O**
 74 | !NOMUD! -1U.2 ONORM
 75 | !FINIS!  FSHPOSU.0 Q.1J Q.1-Q.B"E 15.I 12.I' Q.1U.B
 76 |      FQ.T"G 0U.1'"# WQ.0/8U.1 Q.0-(8*Q.1)U.0' Q.1,11.I Q.0,40.I
 77 | !OUT! ].3].2].1].0  )   0;' 
 78 |   Q.M&400."N 1M.Y<IY>  0;'
 79 |  >,Q.QM.Z  
 80 | 
 81 | Adjust Next Line
 82 | ..Y<=k

 83 |  [1[2[3 .U1
 84 |  :<:L .U2 Q1J
 85 |    (1000,Q2F&4000000.)"N Q..0F"G-1J W^FLL !<!@> ''
 86 |    .U.B [.B M.Y M...F ].B
 87 |    1A-42."E .U2 :L .U3 0L
 88 |    (1000,Q3F&4000000.)"N 0L [.B M...F ].B ''
 89 |    Q.B,.@V
 90 |    :FI-27"N .U.B 0;'FIW>,3M.Z  
 91 | 
 92 | Pprint Object
 93 | ..P,*pprint*<=n

 94 |  [0[1[2[3 1:<.U.B W:^FLL W^FLU0U1W
 95 |  < .U2 Q1J ^FLU0W Q2J
 96 |    :L .-Z;W .-Q0:"L 0;' .U2 Q1J
 97 |    (0,Q2F&4000000.)"N Q..0F"G-1J' W^FLL !<!@> '
 98 |    M.Y M...F
 99 |    1A-42."E .U2 :L .U3 Q2J
100 |      (0,Q3F&4000000.)"N 0L M...F '' >>,3M.Z G
101 | 
102 | Adjust a Paragraph (Looks for @ so as not to screw up Scribe)
103 | ...J<=
104 | 1:<.u.b
105 | [0[1[2[3[4[5 <.-Z; .-1,.+1F=
106 | 
"N 0,1AF@"N 0;''L>
107 | L 0,1A-15."E-L' .-Z"E0L'
108 | .U1 <0,1AF ;	"L0;'C> .U2 FSHPOSU5 Q1,Q2X3
109 | F=.T-"E 1M.X Old Prefix:   FQ.S"L' .,(G.S FSHPOSU5 .)FX3'
110 | FQ3U4 .U0
111 |      <-L B-.; 1AF
.@+1"GL0;' Q4F=3"N 0;'
112 |         0,Q4+1AF ;	;>
113 |   .U.B Q0(.U0)J
114 |      <L .-Z; 1AF
.@+1"G0;' Q4F=3"N 0;'
115 |         0,Q4+1AF ;	;> "N>W Q.B,.'
116 |   .-ZU1 Q0J  <L.-Z-Q1; Q4D> 1U2 <Q0J Q2-5; %2@FA -L Q0-.:;> 
117 |   Q0J F=.T-&(F=.T:)"N L .U0'"# Q4D'
118 | 
119 |  F=.T-"E 1M.X New Prefix:   FQ.S+1"G .,(G.S FSHPOSU5 .)FX3''
120 |  FSADLINEF(-Q5FSADLINEW F=.T:"E Q0,Z+Q1FA'"# Q0,Z+Q1@FA' 
121 |  )FSADLINEW
122 | .-ZU2 Q0J <G3 L .-Z-Q2;> Z+Q2J >,1M.Z  000
123 | 


--------------------------------------------------------------------------------
/north.zil:
--------------------------------------------------------------------------------
  1 | "NORTH for WISHBRINGER: (C)1985 Infocom, Inc. All rights reserved."
  2 | 
  3 | "*** WEST OF HOUSE ***"
  4 | 
  5 | <OBJECT WEST-OF-HOUSE
  6 | 	(IN ROOMS)
  7 | 	(DESC "West of House")
  8 | 	(LDESC
  9 | "You are standing in an open field west of a white house, with a boarded front door.")
 10 | 	(FLAGS ONBIT RLANDBIT)
 11 | 	(GLOBAL TREE TRAIL)
 12 | 	(NORTH PER BACK-TO-ROCKY-PATH)
 13 | 	(SOUTH PER UNWILLING-TO-MOVE)
 14 | 	(EAST PER BOARDS-ARE-SECURE)
 15 |       	(WEST PER UNWILLING-TO-MOVE)
 16 | 	(IN PER BOARDS-ARE-SECURE)>
 17 | 
 18 | <ROUTINE BACK-TO-ROCKY-PATH ()
 19 | 	 <COND (<ENABLED? ,I-WAKE-SMALL-BOX>
 20 | 		<TELL "The spectacle of the " D ,SMALL-BOX
 21 | 		      " has you frozen in your tracks." CR>
 22 | 		<RFALSE>)
 23 | 	       (T
 24 | 		<TELL "As the house disappears into the distance, you get the distinct feeling that, someday, you will pass this way again.">
 25 | 	        <CARRIAGE-RETURNS>
 26 | 	        <RETURN ,ROCKY-PATH>)>>
 27 | 
 28 | <ROUTINE BOARDS-ARE-SECURE ()
 29 | 	 <SAY-THE ,HOUSE-DOOR>
 30 | 	 <TELL " is securely closed." CR>
 31 | 	 <RFALSE>>
 32 | 
 33 | <OBJECT WHITE-HOUSE
 34 | 	(IN WEST-OF-HOUSE)
 35 | 	(DESC "house")
 36 | 	(SYNONYM HOUSE)
 37 | 	(ADJECTIVE WHITE)
 38 | 	(FLAGS NDESCBIT)
 39 | 	(ACTION WHITE-HOUSE-F)>
 40 | 
 41 | <ROUTINE WHITE-HOUSE-F ()
 42 | 	 <COND (<VERB? EXAMINE>
 43 | 		<TELL
 44 | "This place has seen better days. Its stately colonial architecture reflects the taste and wealth of its builders. But eons of trespassing by thoughtless adventurers have left the once noble edifice in ruins." CR>
 45 | 		<RTRUE>)
 46 | 	       (<VERB? LOOK-INSIDE OPEN MUNG THROUGH ENTER>
 47 | 		<BOARDS-ARE-SECURE>
 48 | 	        <RTRUE>)
 49 | 	       (T
 50 | 		<RFALSE>)>>
 51 | 
 52 | <OBJECT HOUSE-DOOR
 53 | 	(IN WEST-OF-HOUSE)
 54 | 	(DESC "front door")
 55 | 	(SYNONYM DOOR ENTRANCE ENTRY BOARDS)
 56 | 	(ADJECTIVE FRONT BOARDED)
 57 | 	(FLAGS NDESCBIT DOORBIT)
 58 | 	(ACTION HOUSE-DOOR-F)>
 59 | 
 60 | <ROUTINE HOUSE-DOOR-F ()
 61 | 	 <COND (<OR <HURT? ,HOUSE-DOOR>
 62 | 		    <VERB? OPEN>>
 63 | 		<BOARDS-ARE-SECURE>
 64 | 		<RTRUE>)
 65 | 	       (<USE-DOOR? ,WEST-OF-HOUSE>
 66 | 		<RTRUE>)
 67 | 	       (T
 68 | 		<RFALSE>)>>
 69 | 
 70 | <OBJECT LEAFLET
 71 | 	(IN SMALL-BOX)
 72 | 	(DESC "leaflet")
 73 | 	(SYNONYM LEAFLET MAIL ADVERT AD)
 74 | 	(ADJECTIVE JUNK-MAIL CANCEL JUNK STAMPED STAMP)
 75 | 	(FLAGS TAKEBIT READBIT)
 76 | 	(ACTION LEAFLET-F)
 77 | 	(VALUE 0)
 78 | 	(SIZE 1)>
 79 | 
 80 | <ROUTINE LEAFLET-F ()
 81 | 	 <COND (<VERB? READ LOOK-ON EXAMINE>
 82 | 		<COND (<IN? ,LEAFLET ,PROTAGONIST>
 83 | 		       <TELL "It seems to be a junk-mail ad for a primitive computer game. The cancelled stamp on the " D ,LEAFLET>
 84 | 		       <TOO-FADED>)
 85 | 		      (T
 86 | 		       <YOUD-HAVE-TO "be holding" ,LEAFLET>)>
 87 | 		<RTRUE>)
 88 | 	       (<HURT? ,LEAFLET>
 89 | 		<RUIN ,LEAFLET>
 90 | 		<RTRUE>)
 91 | 	       (T
 92 | 		<RFALSE>)>>
 93 | 	       
 94 | "*** ROCKY PATH ***"
 95 | 
 96 | <OBJECT ROCKY-PATH
 97 | 	(IN ROOMS)
 98 | 	(DESC "Rocky Path")
 99 | 	(FLAGS ONBIT RLANDBIT WETBIT)
100 | 	(GLOBAL RIVER TREE TRAIL)
101 | 	(NORTH PER PROBABLY-DROWN)
102 | 	(EAST TO FESTERON-POINT)
103 | 	(SOUTH PER ENTER-HOUSE?)
104 | 	(WEST TO SOUTH-OF-BRIDGE)
105 | 	(ACTION ROCKY-PATH-F)
106 | 	(PSEUDO "FOREST" FOREST-PSEUDO "WOODS" FOREST-PSEUDO)>
107 | 
108 | <ROUTINE FOREST-PSEUDO ()
109 | 	 <COND (<VERB? EXAMINE LOOK-INSIDE>
110 | 		<TELL "It's ">
111 | 		<COND (<NOT ,HOUSE-VISITED?>
112 | 		       <TELL "almost ">)>
113 | 		<TELL "impenetrable." CR>
114 | 		<RTRUE>)
115 | 	       (<VERB? ENTER THROUGH WALK-TO>
116 | 		<DO-WALK ,P?SOUTH>
117 | 		<RTRUE>)
118 | 	       (T
119 | 		<YOU-DONT-NEED "forest" T>
120 | 		<RFATAL>)>>
121 | 		
122 | <GLOBAL HOUSE-VISITED? <>>
123 | 
124 | <ROUTINE ROCKY-PATH-F (CONTEXT)
125 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
126 | 		<TELL "You're on a rocky path that runs east and west along the banks of the">
127 | 		<WHICH-TOWN "River">
128 | 		<TELL ". A ">
129 | 		<COND (<AND ,SKEWED?
130 | 		       	    <NOT ,HOUSE-VISITED?>>
131 | 		       <TELL
132 | "shimmering " D ,TRAIL " leads south into a dense forest">)
133 | 		      (T
134 | 		       <TELL
135 | "dense, impenetrable forest borders the south edge of the path">)>
136 | 		<TELL "." CR>)>>
137 | 
138 | <ROUTINE ENTER-HOUSE? ()
139 | 	 <COND (<AND ,SKEWED?
140 | 		     <NOT ,HOUSE-VISITED?>>
141 | 		<TELL
142 | "As you walk along the shimmering " D ,TRAIL " you feel a vague sense of disorientation, then a shock of recognition...">
143 | 		<CARRIAGE-RETURNS>
144 | 		<RETURN ,WEST-OF-HOUSE>)
145 | 	       (T
146 | 	        <TELL ,CANT " enter an impenetrable forest." CR>
147 | 		<RFALSE>)>>
148 | 
149 | "*** SOUTH OF BRIDGE ***"
150 | 
151 | <OBJECT RIVER
152 | 	(IN LOCAL-GLOBALS)
153 | 	(DESC "river")
154 | 	(SYNONYM RIVER WATER)
155 | 	(ADJECTIVE FESTERON WITCHVILLE)
156 | 	(FLAGS NDESCBIT TRYTAKEBIT CONTBIT OPENBIT)
157 | 	(ACTION RIVER-F)>
158 | 
159 | <ROUTINE RIVER-F ()
160 | 	 <COND (<VERB? EXAMINE>
161 | 		<TELL "The current looks swift and ">
162 | 		<COND (,SKEWED?
163 | 		       <TELL "murky">)
164 | 		      (T
165 | 		       <TELL "clean">)>
166 | 		<TELL "." CR>
167 | 		<RTRUE>)
168 | 	       (<VERB? CROSS>
169 | 		<COND (<EQUAL? ,HERE ,SOUTH-OF-BRIDGE>
170 | 		       <DO-WALK ,P?NORTH>)
171 | 		      (<EQUAL? ,HERE ,NORTH-OF-BRIDGE>
172 | 		       <DO-WALK ,P?SOUTH>)
173 | 		      (T
174 | 		       <V-WALK-AROUND>)>
175 | 		<RTRUE>)
176 | 	       (<HANDLE-WATER?>
177 | 		<RTRUE>)
178 | 	       (T
179 | 		<RFALSE>)>>
180 | 
181 | <OBJECT SOUTH-OF-BRIDGE
182 | 	(IN ROOMS)
183 | 	(DESC "South of Bridge")
184 | 	(FLAGS ONBIT RLANDBIT WETBIT)
185 | 	(GLOBAL RIVER BRIDGE)
186 | 	(NORTH PER GO-ON-BRIDGE)
187 | 	(EAST TO ROCKY-PATH)
188 | 	(SOUTH TO ROTARY-NORTH)
189 | 	(WEST TO RIVER-OUTLET)
190 | 	(ACTION SOUTH-OF-BRIDGE-F)>
191 | 		       
192 | <ROUTINE SOUTH-OF-BRIDGE-F (CONTEXT)
193 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
194 | 		<TELL
195 | "This is the south side of a " D ,BRIDGE " that spans the">
196 | 		<WHICH-TOWN "River">
197 | 		<TELL ". Paths lead off " <TO-E> " and west, and a road leads south to the " D ,FESTERON "." CR>)>>
198 | 
199 | <ROUTINE GO-ON-BRIDGE ()
200 | 	 <SETG WHERE-FROM ,SOUTH-OF-BRIDGE>
201 | 	 <RETURN ,ON-BRIDGE>>


--------------------------------------------------------------------------------
/j2.txt:
--------------------------------------------------------------------------------
  1 | Junior-Level Adventure #2
  2 | 
  3 | Working Title: DEVILSTONE
  4 | 
  5 | Market and Audience
  6 | 
  7 | DEVILSTONE is an easy-to-play introduction to interactive fantasies like
  8 | ZORK.  Its goal is to familiarize novices with the conventions and
  9 | traditions of the genre.  Text, plot and puzzles will be geared to the
 10 | comprehension of a bright sixth-grader.
 11 | 
 12 | Plot Synopsis
 13 | 
 14 | You're an apprentice postal clerk in the sleepy village of Frobton.  As
 15 | another eventless afternoon draws to an end, your boss Mr. Blather hands
 16 | you a special delivery envelope addressed to Ye Olde Magick Shoppe, a
 17 | little-visited establishment on the far side of town.  You obediently
 18 | hop onto your bicycle and pedal through the friendly streets, where you
 19 | are greeted by old neighbors and ritually chased by a poodle.  After
 20 | passing Hoople's Drug Store, the Palace Theater, the Park and other
 21 | familiar landmarks, you cross the little creek at the edge of town and
 22 | climb the steep hill up to the Magick Shoppe.
 23 | 
 24 | The Shoppe is a fascinating place full of strange machines, forbidden
 25 | books and fake ice cubes, all presided over by a sad old woman.  She's
 26 | mourning the loss of her beloved pet cat, which disappeared under
 27 | mysterious circumstances a few nights ago.  The letter you are
 28 | delivering turns out to be a ransom note:
 29 | 
 30 | "Bring the one true Devilstone to me before the moon sets, or you will
 31 | never see your cat again!"
 32 | 
 33 | or words of similar ilk, signed by a dangerous-sounding witch.
 34 | 
 35 | The bereaved woman vows never to surrender the Devilstone to anyone, cat
 36 | or no cat, and somehow manages to recruit you for a rescue mission. Your
 37 | only defense against the Evil Witch is to be the Devilstone itself, an
 38 | ordinary-looking pebble said to possess considerable Magick power when
 39 | used according to the instructions provided.
 40 | 
 41 | Upon leaving the Shoppe, you discover that the entire town of Frobton
 42 | has been skewed into some kind of alternative reality.  All the
 43 | landmarks and faces have taken on a sinister, larger-than-life aspect:
 44 | 
 45 | -- The little creek that used to run around the outskirts is now a dark,
 46 | raging river.  There's only one bridge, and that is guarded by a
 47 | creature which less original scenarios would refer to as a Troll.
 48 | 
 49 | -- The poodle that used to chase your bicycle has evolved into a
 50 | Hellhound.  Its appetite for bicylists is unaffected.  Good thing your
 51 | bike changed into a broomstick.
 52 | 
 53 | -- The little park in the center of town has become a dense forest full
 54 | of wild beasts, quicksand and other inconveniences.  But it's better
 55 | than walking the streets, which are patrolled by the Witch's Goon Squad.
 56 | 
 57 | -- Mr. Hoople's Drug Store and Ice Cream Parlor is now a swarmy tavern
 58 | full of ne'er-do-wells, misfits and troublemakers like yourself.  You
 59 | can buy supplies here that may prove useful in your quest.  But don't
 60 | expect much sympathy from Mr. Hoople, who is a spy for the Evil Witch.
 61 | 
 62 | -- The Palace Theater appears to be running a propaganda film called THE
 63 | WITCH IS WATCHING.  A better title might be WATCHING THE WITCH, because
 64 | what you see on the screen corresponds to what the Witch is actually
 65 | doing at that moment -- a good thing to know if you're trying to avoid
 66 | her.
 67 | 
 68 | -- The Post Office you used to work in is now the fortresslike lair of
 69 | the Witch.  Those unfortunate enough to visit the witch's Dungeon will
 70 | notice that the Chief Torturer bears a remarkable resemblance to Mr.
 71 | Blather.
 72 | 
 73 | Your mission, should you choose to accept it, is to rescue the poor
 74 | little kitty cat without being turned into a furry toilet seat cover or
 75 | a Commodore 64.
 76 | 
 77 | Spellcrafting
 78 | 
 79 | Unlike ZORK IV and V, it takes more than a magic word to make the
 80 | Devilstone do its thing.  Each of the dozen or so available spells
 81 | requires the player to locate some object or solve a puzzle before the
 82 | miracle can be invoked.  Some silly examples:
 83 | 
 84 | -- To "Fly," you must find a feather and wear it in your hair.
 85 | 
 86 | -- To "Walk Across Water," you must put white sand in your shoes.
 87 | 
 88 | -- To "See Through Walls," you must be holding a lighted candle.
 89 | 
 90 | The props you need for each spell are "spelled out" in the Devilstone
 91 | instruction card provided with the game (see below).
 92 | 
 93 | Other possibilities include:
 94 | 
 95 | -- Spells can be used only a few times, or once.
 96 | 
 97 | -- Using the Devilstone helps the Evil Witch find out where you are (a
 98 | "lighthouse" effect a la Tolkien).  This implies that it should be
 99 | possible to solve any problem without using the Stone, thereby rewarding
100 | clever players with less interference from the Witch.
101 | 
102 | -- A "panic button" spell that works like an on-line hint service.
103 | 
104 | Characters
105 | 
106 | -- Mr. Blather.  He has two cameos, first as your boss at the post
107 | office and later as a torturer in the witch's Dungeon.
108 | 
109 | -- The Woman in the Magick Shoppe.  She sounds and acts like a feeble
110 | old lady, but is sharp enough to get you to do her dirty work.  Like the
111 | other characters in DEVILSTONE, she talks a lot but doesn't move around
112 | much, if at all.
113 | 
114 | -- Various Townspeople.  Amiable enough in Frobton, their New Frobton
115 | counterparts greet you with warnings, sneers and sharp farming tools.
116 | Some of them are employed by the Evil Witch as spies and/or goons.
117 | 
118 | -- The Evil Witch (to be named later).  Impervious to water and falling
119 | houses.
120 | 
121 | Package Ideas
122 | 
123 | -- A small white pebble.
124 | 
125 | -- Instructions for using the Devilstone.  Instead of a booklet, it
126 | might be more fun to design a cardboard slide-rule device that lets you
127 | "dial up" the combination of objects you need to invoke a spell.
128 | 
129 | -- A sealed special-delivery letter containing the ransom note.
130 | 
131 | -- Two maps, one for each "version" of Frobton.  It might be possible to
132 | use a single map with a clever transparent overlay or something.
133 | 
134 | 
135 | 


--------------------------------------------------------------------------------
/originalj2.txt:
--------------------------------------------------------------------------------
  1 | Junior-Level Adventure #2
  2 | 
  3 | Working Title: DEVILSTONE
  4 | 
  5 | Market and Audience
  6 | 
  7 | DEVILSTONE is an easy-to-play introduction to interactive fantasies like
  8 | ZORK.  Its goal is to familiarize novices with the conventions and
  9 | traditions of the genre.  Text, plot and puzzles will be geared to the
 10 | comprehension of a bright sixth-grader.
 11 | 
 12 | Plot Synopsis
 13 | 
 14 | You're an apprentice postal clerk in the sleepy village of Frobton.  As
 15 | another eventless afternoon draws to an end, your boss Mr. Blather hands
 16 | you a special delivery envelope addressed to Ye Olde Magick Shoppe, a
 17 | little-visited establishment on the far side of town.  You obediently
 18 | hop onto your bicycle and pedal through the friendly streets, where you
 19 | are greeted by old neighbors and ritually chased by a poodle.  After
 20 | passing Hoople's Drug Store, the Palace Theater, the Park and other
 21 | familiar landmarks, you cross the little creek at the edge of town and
 22 | climb the steep hill up to the Magick Shoppe.
 23 | 
 24 | The Shoppe is a fascinating place full of strange machines, forbidden
 25 | books and fake ice cubes, all presided over by a sad old woman.  She's
 26 | mourning the loss of her beloved pet cat, which disappeared under
 27 | mysterious circumstances a few nights ago.  The letter you are
 28 | delivering turns out to be a ransom note:
 29 | 
 30 | "Bring the one true Devilstone to me before the moon sets, or you will
 31 | never see your cat again!"
 32 | 
 33 | or words of similar ilk, signed by a dangerous-sounding witch.
 34 | 
 35 | The bereaved woman vows never to surrender the Devilstone to anyone, cat
 36 | or no cat, and somehow manages to recruit you for a rescue mission. Your
 37 | only defense against the Evil Witch is to be the Devilstone itself, an
 38 | ordinary-looking pebble said to possess considerable Magick power when
 39 | used according to the instructions provided.
 40 | 
 41 | Upon leaving the Shoppe, you discover that the entire town of Frobton
 42 | has been skewed into some kind of alternative reality.  All the
 43 | landmarks and faces have taken on a sinister, larger-than-life aspect:
 44 | 
 45 | -- The little creek that used to run around the outskirts is now a dark,
 46 | raging river.  There's only one bridge, and that is guarded by a
 47 | creature which less original scenarios would refer to as a Troll.
 48 | 
 49 | -- The poodle that used to chase your bicycle has evolved into a
 50 | Hellhound.  Its appetite for bicylists is unaffected.  Good thing your
 51 | bike changed into a broomstick.
 52 | 
 53 | -- The little park in the center of town has become a dense forest full
 54 | of wild beasts, quicksand and other inconveniences.  But it's better
 55 | than walking the streets, which are patrolled by the Witch's Goon Squad.
 56 | 
 57 | -- Mr. Hoople's Drug Store and Ice Cream Parlor is now a swarmy tavern
 58 | full of ne'er-do-wells, misfits and troublemakers like yourself.  You
 59 | can buy supplies here that may prove useful in your quest.  But don't
 60 | expect much sympathy from Mr. Hoople, who is a spy for the Evil Witch.
 61 | 
 62 | -- The Palace Theater appears to be running a propaganda film called THE
 63 | WITCH IS WATCHING.  A better title might be WATCHING THE WITCH, because
 64 | what you see on the screen corresponds to what the Witch is actually
 65 | doing at that moment -- a good thing to know if you're trying to avoid
 66 | her.
 67 | 
 68 | -- The Post Office you used to work in is now the fortresslike lair of
 69 | the Witch.  Those unfortunate enough to visit the witch's Dungeon will
 70 | notice that the Chief Torturer bears a remarkable resemblance to Mr.
 71 | Blather.
 72 | 
 73 | Your mission, should you choose to accept it, is to rescue the poor
 74 | little kitty cat without being turned into a furry toilet seat cover or
 75 | a Commodore 64.
 76 | 
 77 | Spellcrafting
 78 | 
 79 | Unlike ZORK IV and V, it takes more than a magic word to make the
 80 | Devilstone do its thing.  Each of the dozen or so available spells
 81 | requires the player to locate some object or solve a puzzle before the
 82 | miracle can be invoked.  Some silly examples:
 83 | 
 84 | -- To "Fly," you must find a feather and wear it in your hair.
 85 | 
 86 | -- To "Walk Across Water," you must put white sand in your shoes.
 87 | 
 88 | -- To "See Through Walls," you must be holding a lighted candle.
 89 | 
 90 | The props you need for each spell are "spelled out" in the Devilstone
 91 | instruction card provided with the game (see below).
 92 | 
 93 | Other possibilities include:
 94 | 
 95 | -- Spells can be used only a few times, or once.
 96 | 
 97 | -- Using the Devilstone helps the Evil Witch find out where you are (a
 98 | "lighthouse" effect a la Tolkien).  This implies that it should be
 99 | possible to solve any problem without using the Stone, thereby rewarding
100 | clever players with less interference from the Witch.
101 | 
102 | -- A "panic button" spell that works like an on-line hint service.
103 | 
104 | Characters
105 | 
106 | -- Mr. Blather.  He has two cameos, first as your boss at the post
107 | office and later as a torturer in the witch's Dungeon.
108 | 
109 | -- The Woman in the Magick Shoppe.  She sounds and acts like a feeble
110 | old lady, but is sharp enough to get you to do her dirty work.  Like the
111 | other characters in DEVILSTONE, she talks a lot but doesn't move around
112 | much, if at all.
113 | 
114 | -- Various Townspeople.  Amiable enough in Frobton, their New Frobton
115 | counterparts greet you with warnings, sneers and sharp farming tools.
116 | Some of them are employed by the Evil Witch as spies and/or goons.
117 | 
118 | -- The Evil Witch (to be named later).  Impervious to water and falling
119 | houses.
120 | 
121 | Package Ideas
122 | 
123 | -- A small white pebble.
124 | 
125 | -- Instructions for using the Devilstone.  Instead of a booklet, it
126 | might be more fun to design a cardboard slide-rule device that lets you
127 | "dial up" the combination of objects you need to invoke a spell.
128 | 
129 | -- A sealed special-delivery letter containing the ransom note.
130 | 
131 | -- Two maps, one for each "version" of Frobton.  It might be possible to
132 | use a single map with a clever transparent overlay or something.
133 | 
134 | 
135 | 


--------------------------------------------------------------------------------
/fog.zil:
--------------------------------------------------------------------------------
  1 | "FOG for WISHBRINGER: Copyright (C)1985 Infocom, Inc."
  2 | 
  3 | "*** STEEP TRAIL & FOG ***"
  4 | 
  5 | <OBJECT FOG
  6 | 	(IN ROOMS)
  7 | 	(DESC "Fog")
  8 | 	(LDESC "You're lost in a thick cloud of fog.")
  9 | 	(GLOBAL TRAIL CLIFF)
 10 | 	(FLAGS ONBIT RLANDBIT)
 11 | 	(NORTH PER N-TRAIL)
 12 | 	(EAST PER E-TRAIL)
 13 | 	(SOUTH PER S-TRAIL)
 14 | 	(WEST PER W-TRAIL)
 15 | 	(UP PER U-TRAIL)
 16 | 	(DOWN PER D-TRAIL)
 17 |       ; (IN "You're \"in\" this fog far enough already.")
 18 |       ; (OUT "You won't get \"out\" of this fog that easily.")
 19 | 	(PSEUDO "FOG" FOG-PSEUDO "CLOUD" FOG-PSEUDO)>
 20 | 
 21 | <GLOBAL TLOC <>>
 22 | 
 23 | <ROUTINE I-FOG-RISING ()
 24 | 	 <COND (<OR ,ECLIPSE?
 25 | 		    <NOT <EQUAL? ,HERE ,CLIFF-EDGE>>>
 26 | 		<DISABLE <INT I-FOG-RISING>>
 27 | 		<RTRUE>)>
 28 | 	 <SETG WOMAN-SCRIPT <+ ,WOMAN-SCRIPT 1>>
 29 | 	 <COND (<ZERO? ,WOMAN-SCRIPT>
 30 | 		<RTRUE>)>
 31 | 	 <CRLF>
 32 | 	 <COND (<EQUAL? ,WOMAN-SCRIPT 1>
 33 | 		<TELL "The fog in the valley is rising towards you!">)
 34 | 
 35 | 	       (<EQUAL? ,WOMAN-SCRIPT 2>
 36 | 		<TELL "Fog is spilling over the edge of the cliff.">)
 37 | 	       
 38 | 	       (<EQUAL? ,WOMAN-SCRIPT 3>
 39 | 		<TELL "Fingers of fog are swirling around your feet.">)
 40 | 
 41 | 	       (T 
 42 | 		<DISABLE <INT I-FOG-RISING>>
 43 | 		<MOVE ,PROTAGONIST ,FOG>
 44 | 		<SETG HERE ,FOG>
 45 | 		<SETG TLOC 7>
 46 | 		<START-BUZZ 1>
 47 | 		<TELL 
 48 | "The rising mist envelops the cliff in a thick layer of..." CR CR>
 49 | 		<V-LOOK>
 50 | 		<RTRUE>)>
 51 | 	 <CRLF>>
 52 | 
 53 | <ROUTINE ENTER-FOG? ()
 54 | 	 <COND (,ENDING?
 55 | 		<SETG WOMAN-SCRIPT 5>
 56 | 		<TELL "A sudden noise from the " D ,MAGICK-SHOPPE
 57 | 		      " changes your mind." CR>
 58 | 		<RFALSE>)>
 59 | 	 <SETG TLOC 6>
 60 | 	 <START-BUZZ 1>
 61 | 	 <COND (,SKEWED?
 62 | 		<TELL
 63 | "As you descend the " D ,TRAIL " you are immediately engulfed in..." CR CR>
 64 | 		<RETURN ,FOG>)
 65 | 	       (T
 66 | 		<RETURN ,STEEP-TRAIL>)>>
 67 | 
 68 | <ROUTINE FOG-PSEUDO ()
 69 | 	 <COND (<VERB? EXAMINE LOOK-THRU LOOK-INSIDE>
 70 | 		<TELL "It's so thick you can barely see your own feet!" CR>
 71 | 		<RTRUE>)
 72 | 	       (<VERB? TAKE WALK-TO ENTER THROUGH>
 73 | 		<TELL "There's more than enough right here." CR>
 74 | 		<RTRUE>)
 75 | 	       (T
 76 | 		<YOU-DONT-NEED "fog" T>
 77 | 		<RFATAL>)>>
 78 | 
 79 | <OBJECT STEEP-TRAIL
 80 | 	(IN ROOMS)
 81 | 	(DESC "Steep Trail")
 82 | 	(FLAGS ONBIT RLANDBIT RMUNGBIT)
 83 | 	(GLOBAL TRAIL CLIFF)
 84 | 	(NORTH PER N-TRAIL)
 85 | 	(EAST PER E-TRAIL)
 86 | 	(SOUTH PER S-TRAIL)
 87 | 	(WEST PER W-TRAIL)
 88 | 	(UP PER U-TRAIL)
 89 | 	(DOWN PER D-TRAIL)
 90 | 	(ACTION STEEP-TRAIL-F)>
 91 | 
 92 | ; "RMUNGBIT = No map warning given"
 93 | 
 94 | <ROUTINE STEEP-TRAIL-F (CONTEXT)
 95 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
 96 | 		<TELL "A steep, rocky " D ,TRAIL " winds "
 97 | 		      <GET ,TRAILS ,TLOC> "." CR>)>>
 98 | 		
 99 | <GLOBAL TRAILS
100 | 	<PLTABLE 
101 | 	 "west and downward"
102 | 	 "north and east"
103 | 	 "south and upward"
104 | 	 "east and downward"
105 | 	 "south and west"
106 | 	 "north and upward">>
107 | 
108 | <ROUTINE N-TRAIL ()
109 | 	 <COND (<EQUAL? ,TLOC 1 3 7>
110 | 		<BUMP-CLIFF>
111 | 		<RFALSE>)
112 | 	       (<EQUAL? ,TLOC 4 5>
113 | 		<PROB-TUMBLE>
114 | 		<RFALSE>)
115 | 	       (<EQUAL? ,TLOC 2>
116 | 		<NEW-TRAIL 3>)
117 | 	       (T ; "6"
118 | 		<NEW-TRAIL 5>)>
119 | 	 <RETURN <NEXT-CELL>>>
120 | 
121 | <ROUTINE E-TRAIL ()
122 | 	 <COND (<EQUAL? ,TLOC 5 6 7>
123 | 		<PROB-TUMBLE>
124 | 		<RFALSE>)
125 | 	       (<EQUAL? ,TLOC 1 3>
126 | 		<BUMP-CLIFF>
127 | 		<RFALSE>)
128 | 	       (<EQUAL? ,TLOC 2>
129 | 		<NEW-TRAIL 1>)
130 | 	       (T ; "4"
131 | 		<NEW-TRAIL 5>)>
132 | 	 <RETURN <NEXT-CELL>>>
133 | 
134 | <ROUTINE S-TRAIL ()
135 | 	 <COND (<EQUAL? ,TLOC 1 2 7>
136 | 		<PROB-TUMBLE>
137 | 		<RFALSE>)
138 | 	       (<EQUAL? ,TLOC 4 6>
139 | 		<BUMP-CLIFF>
140 | 		<RFALSE>)
141 | 	       (<EQUAL? ,TLOC 3>
142 | 		<NEW-TRAIL 2>)
143 | 	       (T ; "5"
144 | 		<NEW-TRAIL 6>)>
145 | 	 <RETURN <NEXT-CELL>>>
146 | 
147 | <ROUTINE W-TRAIL ()
148 | 	 <COND (<EQUAL? ,TLOC 2 3 4>
149 | 		<PROB-TUMBLE>
150 | 		<RFALSE>)
151 | 	       (<EQUAL? ,TLOC 6>
152 | 		<BUMP-CLIFF>
153 | 		<RFALSE>)
154 | 	       (<EQUAL? ,TLOC 1>
155 | 		<NEW-TRAIL 2>)
156 | 	       (<EQUAL? ,TLOC 5>
157 | 		<NEW-TRAIL 4>)
158 | 	       (T ; "7"
159 | 		<TELL "Crash! ">
160 | 		<BELL-TINKLES>
161 | 		<RFALSE>)>
162 | 	 <RETURN <NEXT-CELL>>>
163 | 
164 | <ROUTINE U-TRAIL ()
165 | 	 <COND (<OR <EQUAL? ,TLOC 1 2 4>
166 | 		    <EQUAL? ,TLOC 5 7>>
167 | 		<CANT-SEE-ANY "any upward trails" T>
168 | 		<RFALSE>)
169 | 	       (<EQUAL? ,TLOC 3>
170 | 		<NEW-TRAIL 4>)
171 | 	       (T ; "6"
172 | 		<COND (,SKEWED?
173 | 		       <SETG TLOC 7>)
174 | 		      (T
175 | 		       <SETG TLOC <>>
176 | 		       <COND (<FSET? ,CLIFF-EDGE ,RMUNGBIT>
177 | 			      <FCLEAR ,CLIFF-EDGE ,RMUNGBIT>
178 | 			      <UPDATE-SCORE 1>
179 | 			      <CRLF>)>
180 | 		       <RETURN ,CLIFF-EDGE>)>)>
181 | 	 <RETURN <NEXT-CELL>>>
182 | 
183 | <ROUTINE D-TRAIL ()
184 | 	 <COND (<OR <EQUAL? ,TLOC 2 3 5>
185 | 		    <EQUAL? ,TLOC 6>>
186 | 		<CANT-SEE-ANY "any downward trails" T>
187 | 		<RFALSE>)
188 | 	       (<EQUAL? ,TLOC 1>
189 | 		<COND (,SKEWED?
190 | 		       <WALK-OUT-OF-FOG>)>
191 | 		<SETG TLOC <>>
192 | 		<RETURN ,CLIFF-BOTTOM>)
193 | 	       (<EQUAL? ,TLOC 4>
194 | 		<NEW-TRAIL 3>)
195 | 	       (T ; "7"
196 | 		<NEW-TRAIL 6>)>
197 | 	 <RETURN <NEXT-CELL>>>
198 | 
199 | <ROUTINE NEXT-CELL ()
200 | 	 <COND (,SKEWED?
201 | 		<FCLEAR ,FOG ,TOUCHBIT>
202 | 		<RETURN ,FOG>)
203 | 	       (T
204 | 		<RETURN ,STEEP-TRAIL>)>>
205 | 
206 | <ROUTINE WALK-OUT-OF-FOG ()
207 | 	 <START-BUZZ 2>
208 | 	 <SUDDEN-GUST>
209 | 	 <TELL "dissolves the fog and clears your vision." CR CR>>
210 | 
211 | <ROUTINE SUDDEN-GUST ()
212 | 	 <TELL "A sudden gust of wind ">>
213 | 
214 | <ROUTINE NEW-TRAIL (NEW-LOC)
215 | 	 <FCLEAR ,FOG ,TOUCHBIT>
216 | 	 <FCLEAR ,STEEP-TRAIL ,TOUCHBIT>
217 | 	 <SETG TLOC .NEW-LOC>>
218 | 
219 | <ROUTINE BUMP-CLIFF ()
220 | 	 <TELL <PICK-ONE ,BUMPS> "." CR>
221 | 	 <RFALSE>>
222 | 
223 | <GLOBAL BUMPS
224 | 	<LTABLE 0
225 | 	 "A cliff wall blocks your path"
226 | 	 "You just walked into a solid wall of stone"
227 | 	 "Your path is blocked by a cliff wall">>
228 | 
229 | <GLOBAL T-PROB 0>
230 | 
231 | <ROUTINE PROB-TUMBLE ()
232 | 	 <SETG T-PROB <+ ,T-PROB 10>>
233 | 	 <COND (<OR <EQUAL? ,T-PROB 100>
234 | 		    <PROB ,T-PROB>>
235 | 		<TELL 
236 | "Oh, no! You lost your footing and tumbled off the cliff!">
237 | 		<BAD-ENDING>)
238 | 	       (T
239 | 		<TUMBLE>)>>
240 | 
241 | <ROUTINE TUMBLE ()
242 | 	 <TELL "You'd " <PICK-ONE ,FALLS>>
243 | 	 <COND (<EQUAL? ,HERE ,HILLTOP ,LOOKOUT-HILL>
244 | 		<TELL " down the hill">)
245 | 	       (T
246 | 		<TELL " off the " D ,CLIFF>)>
247 | 	 <WENT-THAT-WAY>
248 | 	 <RFALSE>>
249 | 
250 | <GLOBAL FALLS
251 | 	<LTABLE 0 "tumble" "fall" "plummet">>
252 | 	 
253 | 
254 | 
255 | 
256 | 
257 | 


--------------------------------------------------------------------------------
/island.zil:
--------------------------------------------------------------------------------
  1 | "ISLAND for WISHBRINGER: (C)1985 Infocom, Inc. All rights reserved."
  2 | 
  3 | <OBJECT WHISTLE
  4 | 	(DESC "silver whistle")
  5 | 	(SYNONYM WHISTLE)
  6 | 	(ADJECTIVE SILVER)
  7 | 	(FLAGS TAKEBIT)
  8 | 	(ACTION WHISTLE-F)
  9 | 	(VALUE 3)
 10 | 	(SIZE 1)>
 11 | 
 12 | <GLOBAL BEEN-TO-ISLAND? <>>
 13 | <GLOBAL RETURN-FROM-ISLAND? <>>
 14 | 
 15 | <ROUTINE WHISTLE-F ()
 16 | 	 <COND (<VERB? EXAMINE>
 17 | 		<SAY-THE ,WHISTLE>
 18 | 		<TELL " is shaped like a " D ,PLATYPUS>
 19 | 		<COND (<OR <EQUAL? ,HERE ,EDGE-OF-LAKE>
 20 | 			   <AND <EQUAL? ,HERE ,ISLAND ,THRONE-ROOM>
 21 | 				,RETURN-FROM-ISLAND?>>
 22 | 		       <TELL ", and twinkles with gentle Magick">)>
 23 | 		<TELL "." CR>
 24 | 		<RTRUE>)
 25 | 	       (<VERB? BLOW-INTO>
 26 | 		<COND (<DONT-HAVE? ,WHISTLE>
 27 | 		       <RTRUE>)>
 28 | 		<WHISTLE-SOUND>
 29 | 		<COND (<AND <NOT ,BEEN-TO-ISLAND?>
 30 | 			    <EQUAL? ,HERE ,EDGE-OF-LAKE>>
 31 | 		       <SETG BEEN-TO-ISLAND? T>
 32 | 		       <CRLF>
 33 | 		       <SAY-THE ,WHISTLE>
 34 | 		       <TELL
 35 | "'s music echoes over the lake, rippling the water with gentle Magick. ">
 36 | 		       <SUDDEN-GUST>
 37 | 		       <TELL "blows through your hair. " ,YOU-SEE 
 38 | "the soft outline of " D ,ISLAND " drawing closer as you streak across the waves...">
 39 | 		       <CARRIAGE-RETURNS>
 40 | 		       <MOVE ,PROTAGONIST ,ISLAND>
 41 | 		       <SETG HERE ,ISLAND>
 42 | 		       <V-LOOK>)
 43 | 		      (<AND ,RETURN-FROM-ISLAND?
 44 | 			    <EQUAL? ,HERE ,ISLAND ,THRONE-ROOM>>
 45 | 		       <REMOVE ,WHISTLE>
 46 | 		       <COND (<NOT <IN? ,BOOTS ,FESTERON-POINT>>
 47 | 			      <SETG BOOT-LOC 0>
 48 | 			      <MOVE ,BOOTS ,FESTERON-POINT>)>
 49 | 		       <MOVE ,PROTAGONIST ,EDGE-OF-LAKE>
 50 | 		       <SETG HERE ,EDGE-OF-LAKE>
 51 | 		       <CRLF>
 52 | 		       <SUDDEN-GUST>
 53 | 		       <TELL "rises out of nowhere, and " D ,ISLAND>
 54 | 		       <BENEATH-FEET>
 55 | 		       <TELL ". You feel the " D ,WHISTLE " slip from "
 56 | 			     D ,HANDS " as you streak across the lake...">
 57 | 		       <CARRIAGE-RETURNS> 
 58 | 		       <V-LOOK>)>
 59 | 		<RTRUE>)
 60 | 	       (T
 61 | 		<RFALSE>)>>
 62 | 
 63 | <ROUTINE WHISTLE-SOUND ()
 64 | 	 <TELL
 65 | "A clear, sweet note stills the night with its beauty." CR>>
 66 | 
 67 | <OBJECT ISLAND
 68 | 	(IN ROOMS)
 69 | 	(DESC "Misty Island")
 70 | 	(FLAGS ONBIT WETBIT RLANDBIT NARTICLEBIT)
 71 | 	(GLOBAL CASTLE CLIFF LAKE ISLE)
 72 | 	(NORTH PER BUMP-CLIFF)
 73 | 	(EAST PER PROBABLY-DROWN)
 74 | 	(SOUTH PER BUMP-CLIFF)
 75 | 	(WEST PER ENTER-THRONE-ROOM)
 76 | 	(IN PER ENTER-THRONE-ROOM)
 77 | 	(PSEUDO "BEACH" HERE-F)
 78 | 	(ACTION ISLAND-F)>
 79 | 	
 80 | <ROUTINE ISLAND-F (CONTEXT)
 81 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
 82 | 		<STANDING>
 83 | 		<TELL 
 84 | "on a fog-shrouded beach. Sheer cliff walls rise " <TO-N> " and south, and the dark waters of the lake stretch eastward.|
 85 | |
 86 | To the west stands a magnificent " D ,CASTLE ", its parapets rising high into the mist. Golden light streams invitingly through the open " D ,ENTRANCE ". "
 87 | ,YOU-HEAR "friendly voices and music inside." CR>)>>
 88 | 
 89 | <ROUTINE ENTER-THRONE-ROOM ()
 90 | 	 <COND (<ZERO? ,KING-SCRIPT>
 91 | 		<SETG ANGER 4>
 92 | 		<ENABLE <QUEUE I-KING-BLAB -1>>)>
 93 | 	 <RETURN ,THRONE-ROOM>>
 94 | 
 95 | "*** THRONE ROOM ***"
 96 | 
 97 | <OBJECT THRONE-ROOM
 98 | 	(IN ROOMS)
 99 | 	(DESC "Throne Room")
100 | 	(FLAGS ONBIT RLANDBIT INDOORSBIT NARTICLEBIT)
101 | 	(GLOBAL CASTLE ISLE)
102 | 	(NORTH PER PLATS-BLOCK)
103 | 	(EAST PER EXIT-THRONE-ROOM)
104 | 	(SOUTH PER PLATS-BLOCK)
105 | 	(WEST PER PLATS-BLOCK)
106 | 	(OUT PER EXIT-THRONE-ROOM)
107 | 	(ACTION THRONE-ROOM-F)>
108 | 
109 | <ROUTINE PLATS-BLOCK ()
110 | 	 <THIS-IS-IT ,CROWD>
111 | 	 <SAY-THE ,CROWD>
112 | 	 <TELL " blocks your path." CR>
113 | 	 <RFALSE>>
114 | 
115 | <ROUTINE EXIT-THRONE-ROOM ()
116 | 	 <COND (<AND <ENABLED? ,I-KING-BLAB>
117 | 		     <L? ,KING-SCRIPT 4>>
118 | 		<TELL "\"Wait!\" cries the white " D ,PLATYPUS ". \"">
119 | 		<COND (<EQUAL? <LOC ,HAT> ,KING ,THRONE-ROOM>
120 | 		       <TELL "You forgot the " D ,HAT>)
121 | 		      (T
122 | 		       <TELL "I wish to speak with you">)>
123 | 	       <TELL "!\"" CR CR>)>
124 | 	 <RETURN ,ISLAND>>
125 | 
126 | <ROUTINE THRONE-ROOM-F (CONTEXT)
127 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
128 | 		<THIS-IS-IT ,CROWD>
129 | 	        <THIS-IS-IT ,KING>
130 | 	        <THIS-IS-IT ,PRINCESS>
131 | 		<STANDING>
132 | 		<TELL  
133 | "in a long, high-ceilinged chamber. Hundreds of " D ,PLATYPUS "es are ">
134 | 		<COND (<G? ,KING-SCRIPT 1>
135 | 		       <TELL "watching you respectfully">)
136 | 		      (T
137 | 		       <TELL "milling about with teacups in their paws">)>
138 | 		<TELL
139 | ", their faces illuminated by a roaring fireplace.|
140 | |
141 | At the far end of the chamber stands a mighty throne. It's occupied by a snow-white " D ,PLATYPUS " with a gold crown on its head and a jeweled scepter in its paw. On the floor near the throne is another crowned " D ,PLATYPUS 
142 | "... the same one you rescued from the pit." CR>)>>
143 | 
144 | <GLOBAL ADVENTURER ", brave Adventurer">
145 | 
146 | <GLOBAL KING-SCRIPT 0>
147 | 
148 | <ROUTINE I-KING-BLAB ()
149 | 	 <COND (<OR ,FUZZY? ,ECLIPSE?>
150 | 		<RTRUE>)
151 | 	       (<EQUAL? ,HERE ,THRONE-ROOM>
152 | 		<CRLF>
153 | 		<COND (<IN? ,HAT ,KING>
154 | 		       <SETG ANGER <- ,ANGER 1>>
155 | 		       <COND (<ZERO? ,ANGER>
156 | 			      <KING-ANNOYED>)
157 | 			     (T
158 | 			      <TELL "\"" <PICK-ONE ,KING-OFFERS>
159 | ",\" says " D ,KING ", holding it out to you." CR>)>
160 | 		       <RTRUE>)>
161 | 		<SETG KING-SCRIPT <+ ,KING-SCRIPT 1>>
162 | 		<COND (<EQUAL? ,KING-SCRIPT 1>
163 | 		       <SAY-THE ,CROWD>
164 | 		       <TELL " falls silent as you enter.|
165 | |
166 | \"Welcome" ,ADVENTURER ",\" says the white " D ,PLATYPUS ", rising from its throne to greet you. \"I am Anatinus, King of " D ,ISLAND ". My court thanks you most humbly for rescuing the life of my daughter, " D ,PRINCESS ". Great would our sorrow have been if not for your cunning.\"|
167 | |
168 | The " D ,CROWD " applauds politely, and " D ,PRINCESS " blushes." CR>)
169 | 		      
170 | 		      (<EQUAL? ,KING-SCRIPT 2>
171 | 		       <THIS-IS-IT ,HAT>
172 | 		       <MOVE ,HAT ,KING>
173 | 		       <TELL
174 | "\"My messengers have told me of your quest,\" continues " D ,KING ". \"Allow me to repay your kindness with words of advice.\"|
175 | |
176 | The old " D ,PLATYPUS " motions you to his side. \"The Tower of" ,EONE 
177 | " is formidable,\" he begins in a low, serious voice. \"You will never get inside unaided. Legends speak of a Magick Word that can open the gates of the Tower. But what Word it is, none can say.\"|
178 | |
179 | The king reaches beneath his throne and takes out a small " D ,HAT ". \"Take this,\" he says, holding it out to you." CR>) 
180 | 		      
181 | 		      (<EQUAL? ,KING-SCRIPT 3>
182 | 		       <TELL 
183 | "\"Take it to the sea,\" " D ,KING " whispers as you turn the hat in " 
184 | D ,HANDS "s. \"There you will find a creature learned in the lore of Magick. Heed him well! In his wisdom lies your only hope.\"" CR>)
185 | 		      
186 | 		      (<EQUAL? ,KING-SCRIPT 4>
187 | 		       <SETG ANGER 4>
188 | 		       <SETG RETURN-FROM-ISLAND? T>
189 | 		       <THIS-IS-IT ,WHISTLE>
190 | 		       <TELL 
191 | "A fanfare of trumpets breaks the silence, and the " D ,CROWD 
192 | " falls to its knees." CR CR>
193 | 		       <REAPPEARS>
194 | 		       <TELL "\"Good luck to you" ,ADVENTURER "!\" cries "
195 | D ,KING ", bowing deeply. \"Now blow into the " D ,WHISTLE " one more time, and deliver us from the horror of" ,EONE ".\"|
196 | |
197 | The " D ,PLATYPUS "es look at you expectantly." CR>)
198 | 		      (T
199 | 		       <REAPPEARS>
200 | 		       <SETG ANGER <- ,ANGER 1>>
201 | 		       <COND (<ZERO? ,ANGER>
202 | 			      <KING-ANNOYED T>)
203 | 			     (T
204 | 			      <TELL "\"" <PICK-ONE ,SCRAMS>
205 | 				    ",\" says " D ,KING "." CR>)>)>)>>
206 | 
207 | <GLOBAL KING-OFFERS 
208 | 	<LTABLE 0
209 | 	 "Take this Hat"
210 | 	 "This Hat is for you. Take it"
211 | 	 "I offer you this Hat">>
212 | 
213 | <GLOBAL SCRAMS
214 | 	<LTABLE 0
215 | 	 "Blow into the whistle, and your quest will continue"
216 | 	 "You need only blow into the whistle"
217 | 	 "The merest blow into the whistle will speed you on your quest">>
218 | 
219 | <ROUTINE REAPPEARS ("AUX" (THING <>))
220 | 	 <COND (<NOT <HELD? ,WHISTLE>>
221 | 		<SET THING ,WHISTLE>)
222 | 	       (<NOT <HELD? ,HAT>>
223 | 		<SET THING ,HAT>)>
224 | 	 <COND (.THING
225 | 		<MOVE .THING ,PROTAGONIST>
226 | 	        <SAY-THE .THING>
227 | 	        <TELL " magically reappears in " D ,HANDS "." CR CR>)>>
228 | 
229 | <ROUTINE KING-ANNOYED ("OPTIONAL" (BLOW? <>))
230 | 	 <SAY-THE ,KING>
231 | 	 <TELL " glares at you with annoyance.|
232 | |
233 | \"You dare to ignore a royal ">
234 | 	 <COND (.BLOW?
235 | 		<TELL "command">)
236 | 	       (T
237 | 		<TELL "gift">)>
238 | 	 <TELL "?\" he cries, deeply offended. \"I see. Perhaps a short visit to the granola mines will teach you some respect!\"|
239 | |
240 | The King turns you into a " D ,PLATYPUS " with an angry wave of his scepter, and the guards lead you away to twenty years of backbreaking labor.">
241 | 	 <BAD-ENDING>>
242 | 
243 | <OBJECT HAT
244 | 	(DESC "wizard's hat")
245 | 	(SYNONYM HAT)
246 | 	(ADJECTIVE WIZARD)
247 | 	(FLAGS TAKEBIT ; CONTBIT WEARBIT RMUNGBIT READBIT)
248 | 	(SIZE 5)
249 | 	(CAPACITY 5)
250 | 	(VALUE 1)
251 | 	(ACTION HAT-F)>
252 | 
253 | ; "RMUNGBIT = player has not yet looked inside hat"
254 | 
255 | <ROUTINE HAT-F ("AUX" TEMP)
256 | 	 <COND (<VERB? EXAMINE LOOK-ON READ>
257 | 		<SAY-THE ,HAT>
258 | 		<TELL " is decorated with foil stars and cheap glitter." CR>
259 | 		<RTRUE>)
260 | 	       (<VERB? LOOK-INSIDE LOOK-DOWN>
261 | 		<COND (<DONT-HAVE? ,HAT>
262 | 		       <RTRUE>)>
263 | 		<FCLEAR ,HAT ,RMUNGBIT>
264 | 		<TELL "Weird! It's like peering into an endless well." CR>
265 | 		<RTRUE>)
266 | 	       (<AND <VERB? TAKE>
267 | 		     <IN? ,HAT ,PELICAN>>
268 | 		<SAY-THE ,PELICAN>
269 | 		<TELL " would rather you didn't." CR>
270 | 		<RTRUE>)
271 | 	       (<VERB? WEAR>
272 | 		<TOO-LARGE ,HAT T>
273 | 		<RTRUE>)
274 | 	       (<AND <VERB? PUT THROW>
275 | 		     <EQUAL? ,PRSI ,HAT>>
276 | 		<COND (<DONT-HAVE? ,HAT>
277 | 		       <RTRUE>)
278 | 		      (<EQUAL? ,PRSO ,HAT>
279 | 		       <WHAT-A-CONCEPT>
280 | 		       <RTRUE>)
281 | 		      (<EQUAL? ,PRSO ,HANDS>
282 | 		       <TELL "You feel " D ,HANDS " tingling." CR>
283 | 		       <RTRUE>)>
284 | 		<SET TEMP <GETP ,PRSO ,P?SIZE>>
285 | 		<COND (<G? .TEMP 5>
286 | 		       <TOO-LARGE ,PRSO>)
287 | 		      (<FSET? ,HAT ,RMUNGBIT>
288 | 		       <TELL
289 | "Maybe you should look inside the " D ,HAT " first." CR>)
290 | 		      (T
291 | 		       <SAY-SURE>
292 | 		       <TELL "put ">
293 | 		       <ARTICLE ,PRSO T>
294 | 		       <TELL D ,PRSO " into the " D ,HAT "?">
295 | 		       <COND (<YES?>
296 | 			      <SET TEMP <+ .TEMP <GETP ,DCASE ,P?CAPACITY>>>
297 | 			      <PUTP ,DCASE ,P?CAPACITY .TEMP>
298 | 			      <MOVE ,PRSO ,DCASE>
299 | 		              <SAY-THE ,PRSO>
300 | 			      <TELL " disappears into the " D ,HAT>
301 | 			      <NO-TRACE>)
302 | 			      
303 | 			     (T
304 | 			      <TELL ,OKAY "you're still holding ">
305 | 			      <ARTICLE ,PRSO T>
306 | 			      <TELL D ,PRSO "." CR>)>)>
307 | 		<RTRUE>)
308 | 	       (<VERB? REACH-IN>
309 | 		<PERFORM ,V?PUT ,HANDS ,HAT>
310 | 		<RTRUE>)
311 | 	       (T
312 | 		<RFALSE>)>>
313 | 		         
314 | <OBJECT PRINCESS
315 | 	(IN THRONE-ROOM)
316 | 	(DESC "Princess Tasmania")
317 | 	(SYNONYM TASMANIA PLATYPUS)
318 | 	(ADJECTIVE PRINCESS)
319 | 	(FLAGS NDESCBIT NARTICLEBIT ACTORBIT TRYTAKEBIT)
320 | 	(ACTION PRINCESS-F)>
321 | 
322 | <GLOBAL CLAMPED? <>>
323 | 
324 | <ROUTINE PRINCESS-F ("OPTIONAL" (CONTEXT <>))
325 | 	 <THIS-IS-IT ,PRINCESS>
326 | 	 <COND (<EQUAL? ,HERE ,VESTIBULE>
327 | 		<TAKE-MIND-OFF ,PRINCESS>
328 | 		<RTRUE>)
329 | 	       (<EQUAL? ,HERE ,TORTURE-CHAMBER>
330 | 		<COND (<VERB? TAKE PUSH MOVE>
331 | 		       <COND (,CLAMPED?
332 | 			      <STILL-CLAMPED>)
333 | 			     (T
334 | 			      <TELL D ,PRINCESS
335 | " probably wouldn't enjoy being manhandled." CR>)>)
336 | 		      (<ASKING? ,PRINCESS>
337 | 		       <COND (,COAT-WORN?
338 | 			      <NO-TALKING>)
339 | 			     (T
340 | 			      <HAD-TIME "questions">)>
341 | 		       <RFATAL>)
342 | 		      (<VERB? TELL REPLY HELLO WAVE-AT ; GOODBYE>
343 | 		       <COND (,COAT-WORN?
344 | 			      <NO-TALKING>)
345 | 			     (T
346 | 			      <HAD-TIME "conversation">)>
347 | 		       <RFATAL>)
348 | 		      (<VERB? RESCUE UNLOCK RELEASE>
349 | 		       <HOW?>)
350 | 		      (<OR <HURT? ,PRINCESS>
351 | 			   <VERB? YELL KISS RUB SQUEEZE>>
352 | 		       <PRINTD ,PRINCESS>
353 | 		       <MIGHT-NOT-LIKE>)
354 | 		      (<AND <VERB? GIVE>
355 | 			    <EQUAL? ,PRSI ,PRINCESS>>
356 | 		       <COND (,COAT-WORN?
357 | 			      <NO-TALKING>)
358 | 			     (T
359 | 			      <TELL D ,PRINCESS
360 | " gracefully declines your offer." CR>)>
361 | 		       <RTRUE>)
362 | 		      (<PRINCESS-SPECIFIC?>
363 | 		       <RTRUE>)
364 | 		      (T
365 | 		       <RFALSE>)>
366 | 		<RTRUE>)
367 | 	       (<CROWD-F>
368 | 		<RTRUE>)
369 | 	       (T
370 | 		<RFALSE>)>>
371 | 
372 | <ROUTINE STILL-CLAMPED ()
373 | 	 <BUT-THE ,PRINCESS>
374 | 	 <TELL "is still clamped into the " D ,TMACHINE "!" CR>>
375 | 
376 | <ROUTINE HAD-TIME (STR)
377 | 	 <TELL
378 | "\"Would that we had time for " .STR ",\" sighs " D ,PRINCESS "." CR>>
379 | 
380 | <ROUTINE NO-TALKING ()
381 | 	 <TELL "\"No communication between prisoners!\" barks "
382 | 	       D ,CRISP "." CR>>
383 | 
384 | <ROUTINE TAKE-MIND-OFF (OBJ)
385 | 	 <TELL "A rumbling noise calls your attention away from ">
386 | 	 <ARTICLE .OBJ T>
387 | 	 <TELL D .OBJ "." CR>>
388 | 
389 | <ROUTINE PRINCESS-SPECIFIC? ()
390 | 	 <COND (<VERB? EXAMINE>
391 | 	        <TELL "Not unexpectedly, ">
392 | 		<COND (<AND <EQUAL? ,PRSO ,PRINCESS>
393 | 			    ,CLAMPED?>
394 | 		       <TELL "the Princess clamped into the " D ,TMACHINE>)
395 | 		      (T
396 | 		       <ARTICLE ,PRSO T>
397 | 		       <PRINTD ,PRSO>)>
398 | 		<TELL " is arrayed in high " D ,PLATYPUS
399 | 		      " fashion." CR>
400 | 	        <RTRUE>)
401 | 	       (<VERB? LISTEN BOW>
402 | 	        <TELL "Graciously, ">
403 | 		<ARTICLE ,PRSO T>
404 | 		<TELL D ,PRSO " acknowledges your respectful attention." CR>
405 | 	        <RTRUE>)
406 | 	       (T
407 | 		<RFALSE>)>>
408 | 
409 | <OBJECT KING
410 | 	(IN THRONE-ROOM)
411 | 	(DESC "King Anatinus")
412 | 	(SYNONYM ANATINUS PLATYPUS)
413 | 	(ADJECTIVE KING OLD WHITE)
414 | 	(FLAGS NDESCBIT NARTICLEBIT ACTORBIT)
415 | 	(ACTION CROWD-F)>
416 | 
417 | <OBJECT CROWD
418 | 	(IN THRONE-ROOM)
419 | 	(DESC "crowd")
420 | 	(SYNONYM CROWD ; PLATYPUS)
421 | 	(FLAGS NDESCBIT ACTORBIT)
422 | 	(ACTION CROWD-F)>
423 | 
424 | <ROUTINE CROWD-F ("OPTIONAL" (CONTEXT <>))
425 | 	 <COND (<PRINCESS-SPECIFIC?>
426 | 		<RTRUE>)
427 | 	       (<TALKING-TO? ,PRSO>
428 | 	        <TELL D ,KING " interrupts you gently. \"There's little time for chit-chat.\"" CR>
429 | 	        <RFATAL>)
430 | 	       (<OR <HURT? ,PRSO>
431 | 		    <VERB? YELL KISS>>
432 | 	        <NOT-LIKELY ,KING "would approve">
433 | 	        <RTRUE>)
434 | 	       (<AND <VERB? GIVE>
435 | 		     <EQUAL? ,PRSI ,PRINCESS ,KING ,CROWD>>
436 | 	        <TELL "With reluctant dignity, ">
437 | 	        <ARTICLE ,PRSI T>
438 | 	        <TELL  D ,PRSI " refuses your offer." CR>
439 | 	        <RTRUE>)
440 | 	       (T
441 | 	        <RFALSE>)>>
442 | 		      
443 | <OBJECT CASTLE
444 | 	(IN LOCAL-GLOBALS)
445 | 	(DESC "castle")
446 | 	(SYNONYM CASTLE PALACE BUILDING ENTRANCE)
447 | 	(FLAGS NDESCBIT)
448 | 	(ACTION CASTLE-F)>
449 | 
450 | <ROUTINE CASTLE-F ()
451 | 	 <COND (<ENTER-FROM? ,ISLAND ,THRONE-ROOM ,CASTLE>
452 | 		<RTRUE>)
453 | 	       (<VERB? EXAMINE LOOK-INSIDE>
454 | 		<COND (<EQUAL? ,HERE ,THRONE-ROOM>
455 | 		       <V-LOOK>)
456 | 		      (T
457 | 		       <GO-INSIDE>)>
458 | 		<RTRUE>)
459 | 	       (T
460 | 		<YOU-DONT-NEED ,CASTLE>
461 | 		<RFATAL>)>>
462 | 
463 | <OBJECT CASTLE-JUNK
464 | 	(IN THRONE-ROOM)
465 | 	(DESC "that")
466 | 	(SYNONYM THRONE CHEST SCEPTER FIREPLACE)
467 | 	(FLAGS NDESCBIT NARTICLEBIT)
468 | 	(ACTION CASTLE-JUNK-F)>
469 | 
470 | <ROUTINE CASTLE-JUNK-F ()
471 | 	 <COND (<SEE-VERB?>
472 | 		<TELL ,YOU-SEE "nothing " <PICK-ONE ,YAWNS>
473 | 		      " about it." CR>
474 | 		<RTRUE>)
475 | 	       (T
476 | 		<YOU-DONT-NEED "things in the castle" T>
477 | 	        <RFATAL>)>> 


--------------------------------------------------------------------------------
/misc.zil:
--------------------------------------------------------------------------------
  1 | "MISC for WISHBRINGER: (C)1985 Infocom, Inc. All Rights Reserved."
  2 | 
  3 | <SETG C-ENABLED? 0>
  4 | 
  5 | <SETG C-ENABLED 1>
  6 | 
  7 | <SETG C-DISABLED 0>
  8 | 
  9 | <DEFMAC TELL ("ARGS" A)
 10 | 	<FORM PROG ()
 11 | 	      !<MAPF ,LIST
 12 | 		     <FUNCTION ("AUX" E P O)
 13 | 			  <COND (<EMPTY? .A> <MAPSTOP>)
 14 | 				(<SET E <NTH .A 1>>
 15 | 				 <SET A <REST .A>>)>
 16 | 			  <COND (<TYPE? .E ATOM>
 17 | 				 <COND (<OR <=? <SET P <SPNAME .E>>
 18 | 						"CRLF">
 19 | 					    <=? .P "CR">>
 20 | 					<MAPRET '<CRLF>>)
 21 | 				       (<EMPTY? .A>
 22 | 					<ERROR INDICATOR-AT-END? .E>)
 23 | 				       (ELSE
 24 | 					<SET O <NTH .A 1>>
 25 | 					<SET A <REST .A>>
 26 | 					<COND (<OR <=? <SET P <SPNAME .E>>
 27 | 						       "DESC">
 28 | 						   <=? .P "D">
 29 | 						   <=? .P "OBJ">
 30 | 						   <=? .P "O">>
 31 | 					       <MAPRET <FORM PRINTD .O>>)
 32 | 					      (<OR <=? .P "NUM">
 33 | 						   <=? .P "N">>
 34 | 					       <MAPRET <FORM PRINTN .O>>)
 35 | 					      (<OR <=? .P "CHAR">
 36 | 						   <=? .P "CHR">
 37 | 						   <=? .P "C">>
 38 | 					       <MAPRET <FORM PRINTC .O>>)
 39 | 					      (ELSE
 40 | 					       <MAPRET
 41 | 						 <FORM PRINT
 42 | 						       <FORM GETP .O .E>>>)>)>)
 43 | 				(<TYPE? .E STRING ZSTRING>
 44 | 				 <MAPRET <FORM PRINTI .E>>)
 45 | 				(<TYPE? .E FORM LVAL GVAL>
 46 | 				 <MAPRET <FORM PRINT .E>>)
 47 | 				(ELSE <ERROR UNKNOWN-TYPE .E>)>>>>>
 48 | 
 49 | <DEFMAC VERB? ("ARGS" ATMS)
 50 | 	<MULTIFROB PRSA .ATMS>>
 51 | 
 52 | <DEFMAC PRSO? ("ARGS" ATMS)
 53 | 	<MULTIFROB PRSO .ATMS>>
 54 | 
 55 | <DEFMAC PRSI? ("ARGS" ATMS)
 56 | 	<MULTIFROB PRSI .ATMS>>
 57 | 
 58 | <DEFMAC ROOM? ("ARGS" ATMS)
 59 | 	<MULTIFROB HERE .ATMS>>
 60 | 
 61 | <DEFINE MULTIFROB (X ATMS "AUX" (OO (OR)) (O .OO) (L ()) ATM) 
 62 | 	<REPEAT ()
 63 | 		<COND (<EMPTY? .ATMS>
 64 | 		       <RETURN!- <COND (<LENGTH? .OO 1> <ERROR .X>)
 65 | 				       (<LENGTH? .OO 2> <NTH .OO 2>)
 66 | 				       (ELSE <CHTYPE .OO FORM>)>>)>
 67 | 		<REPEAT ()
 68 | 			<COND (<EMPTY? .ATMS> <RETURN!->)>
 69 | 			<SET ATM <NTH .ATMS 1>>
 70 | 			<SET L
 71 | 			     (<COND (<TYPE? .ATM ATOM>
 72 | 				     <CHTYPE <COND (<==? .X PRSA>
 73 | 						    <PARSE
 74 | 						     <STRING "V?"
 75 | 							     <SPNAME .ATM>>>)
 76 | 						   (ELSE .ATM)> GVAL>)
 77 | 				    (ELSE .ATM)>
 78 | 			      !.L)>
 79 | 			<SET ATMS <REST .ATMS>>
 80 | 			<COND (<==? <LENGTH .L> 3> <RETURN!->)>>
 81 | 		<SET O <REST <PUTREST .O
 82 | 				      (<FORM EQUAL? <CHTYPE .X GVAL> !.L>)>>>
 83 | 		<SET L ()>>>
 84 | 
 85 | <DEFMAC BSET ('OBJ "ARGS" BITS)
 86 | 	<MULTIBITS FSET .OBJ .BITS>>
 87 | 
 88 | <DEFMAC BCLEAR ('OBJ "ARGS" BITS)
 89 | 	<MULTIBITS FCLEAR .OBJ .BITS>>
 90 | 
 91 | <DEFMAC BSET? ('OBJ "ARGS" BITS)
 92 | 	<MULTIBITS FSET? .OBJ .BITS>>
 93 | 
 94 | <DEFINE MULTIBITS (X OBJ ATMS "AUX" (O ()) ATM) 
 95 | 	<REPEAT ()
 96 | 		<COND (<EMPTY? .ATMS>
 97 | 		       <RETURN!- <COND (<LENGTH? .O 1> <NTH .O 1>)
 98 | 				       (<==? .X FSET?> <FORM OR !.O>)
 99 | 				       (ELSE <FORM PROG () !.O>)>>)>
100 | 		<SET ATM <NTH .ATMS 1>>
101 | 		<SET ATMS <REST .ATMS>>
102 | 		<SET O
103 | 		     (<FORM .X
104 | 			    .OBJ
105 | 			    <COND (<TYPE? .ATM FORM> .ATM)
106 | 				  (ELSE <FORM GVAL .ATM>)>>
107 | 		      !.O)>>>
108 | 
109 | <DEFMAC RFATAL ()
110 | 	'<PROG () <PUSH 2> <RSTACK>>>
111 | 
112 | <DEFMAC PROB ('BASE?)
113 | 	<FORM NOT <FORM L? .BASE? '<RANDOM 100>>>>
114 | 
115 | ; <DEFMAC PROB ('BASE? "OPTIONAL" 'LOSER?)
116 | 	<COND (<ASSIGNED? LOSER?> <FORM ZPROB .BASE?>)
117 | 	      (ELSE <FORM G? .BASE? '<RANDOM 100>>)>>
118 | 
119 | <DEFMAC ENABLE ('INT) <FORM PUT .INT ,C-ENABLED? 1>>
120 | 
121 | <DEFMAC DISABLE ('INT) <FORM PUT .INT ,C-ENABLED? 0>>
122 | 
123 | <DEFMAC OPENABLE? ('OBJ)
124 | 	<FORM OR <FORM FSET? .OBJ ',DOORBIT>
125 | 	         <FORM FSET? .OBJ ',CONTBIT>>> 
126 | 
127 | <DEFMAC ABS ('NUM)
128 | 	<FORM COND (<FORM L? .NUM 0> <FORM - 0 .NUM>)
129 | 	           (T .NUM)>>
130 | 
131 | "*** ZCODE STARTS HERE ***"
132 | 
133 | "NOTE: This object MUST be the FIRST one defined (for MOBY-FIND)!"
134 | 
135 | <OBJECT DUMMY-OBJECT>
136 | 
137 | <ROUTINE GO () 
138 |          <SETG HERE ,HILLTOP>
139 | 	 <SETG WINNER ,PROTAGONIST>
140 | 	 <SETG SCORE 15>
141 | 	 <SETG MOVES 0>
142 | 	 <ENABLE <QUEUE I-PROMPT-1 1>>
143 | 	 <ENABLE <QUEUE I-PROMPT-2 10>>
144 | 	 <ENABLE <QUEUE I-CRISP-CALLING -1>>
145 | 	 <ENABLE <QUEUE I-VOSS-CALLING -1>>
146 | 	 <ENABLE <QUEUE I-BARKING -1>>
147 | 	 <ENABLE <QUEUE I-BEFORE-FIVE -1>>
148 | 	 <RESET-THEM>
149 | 	 <CRLF>
150 | 	 <INTRO>
151 | 	 <TELL " Thermofax.|
152 | |
153 | Only your Magick sword can save you now. You swing it high, speak the Word and stand unhurt as the blade absorbs the searing dragon-breath.|
154 | |
155 | The reptile bellows with rage and flaps its wings to fan the fire in its belly. You are advancing, sword poised to strike, when a familiar voice shatters the daydream and stays your mighty hand..." CR>
156 | 	 <V-VERSION>
157 | 	 <CRLF>
158 | 	 <V-LOOK>
159 | 	 <SOMEBODY-CALLING>
160 | 	 <DO-MAIN-LOOP>
161 | 	 <AGAIN>>
162 | 
163 | <ROUTINE DO-MAIN-LOOP ("AUX" X)
164 | 	 <REPEAT ()
165 | 		 <SET X <MAIN-LOOP>>>>
166 | 
167 | <ROUTINE MAIN-LOOP ("AUX" ICNT OCNT NUM CNT OBJ TBL V PTBL OBJ1 TMP X)
168 |    <REPEAT ()
169 |      <SET CNT 0>
170 |      <SET OBJ <>>
171 |      <SET PTBL T>
172 |      <SETG P-WON <PARSER>>
173 |      <COND (,P-WON
174 | 	    <SET ICNT <GET ,P-PRSI ,P-MATCHLEN>>
175 | 	    <SET OCNT <GET ,P-PRSO ,P-MATCHLEN>>
176 | 	    <COND (<AND ,P-IT-OBJECT
177 | 			<ACCESSIBLE? ,P-IT-OBJECT>>
178 | 		   <SET TMP <>>
179 | 		   <REPEAT ()
180 | 			   <COND (<G? <SET CNT <+ .CNT 1>> .ICNT>
181 | 				  <RETURN>)
182 | 				 (T
183 | 				  <COND (<EQUAL? <GET ,P-PRSI .CNT> ,IT>
184 | 					 <PUT ,P-PRSI .CNT ,P-IT-OBJECT>
185 | 					 <SET TMP T>
186 | 					 <RETURN>)>)>>
187 | 		   <COND (<NOT .TMP>
188 | 			  <SET CNT 0>
189 | 			  <REPEAT ()
190 | 			   <COND (<G? <SET CNT <+ .CNT 1>> .OCNT>
191 | 				  <RETURN>)
192 | 				 (T
193 | 				  <COND (<EQUAL? <GET ,P-PRSO .CNT> ,IT>
194 | 					 <PUT ,P-PRSO .CNT ,P-IT-OBJECT>
195 | 					 <RETURN>)>)>>)>
196 | 		   <SET CNT 0>)>
197 | 	    <SET NUM
198 | 		 <COND (<ZERO? .OCNT>
199 | 			.OCNT)
200 | 		       (<G? .OCNT 1>
201 | 			<SET TBL ,P-PRSO>
202 | 			<COND (<ZERO? .ICNT>
203 | 			       <SET OBJ <>>)
204 | 			      (T
205 | 			       <SET OBJ <GET ,P-PRSI 1>>)>
206 | 			.OCNT)
207 | 		       (<G? .ICNT 1>
208 | 			<SET PTBL <>>
209 | 			<SET TBL ,P-PRSI>
210 | 			<SET OBJ <GET ,P-PRSO 1>>
211 | 			.ICNT)
212 | 		       (T
213 | 			1)>>
214 | 	    <COND (<AND <NOT .OBJ>
215 | 			<1? .ICNT>>
216 | 		   <SET OBJ <GET ,P-PRSI 1>>)>
217 | 	    <COND (<EQUAL? ,PRSA ,V?WALK>
218 | 		   <SET V <PERFORM ,PRSA ,PRSO>>)
219 | 		  (<ZERO? .NUM>
220 | 		   <COND (<ZERO? <BAND <GETB ,P-SYNTAX ,P-SBITS> ,P-SONUMS>>
221 | 			  <SET V <PERFORM ,PRSA>>
222 | 			  <SETG PRSO <>>)
223 | 			 (<NOT ,LIT>
224 | 			  <PCLEAR>
225 | 			  <TOO-DARK>)
226 | 			 (T
227 | 			  <PCLEAR>
228 | 			  <TELL "(There isn't anything to ">
229 | 			  <SET TMP <GET ,P-ITBL ,P-VERBN>>
230 | 			  <COND (<VERB? TELL>
231 | 				 <TELL "talk to">)
232 | 				(<OR ,P-MERGED ,P-OFLAG>
233 | 				 <PRINTB <GET .TMP 0>>)
234 | 				(T
235 | 				 <SET V <WORD-PRINT <GETB .TMP 2>
236 | 						    <GETB .TMP 3>>>)>
237 | 			  <TELL "!)" CR>
238 | 			  <SET V <>>)>)
239 | 		; (<AND .PTBL <G? .NUM 1> <VERB? COMPARE>>
240 | 		   <SET V <PERFORM ,PRSA ,OBJECT-PAIR>>)
241 | 		  (T
242 | 		   <SET X 0>
243 | 		   ;"<SETG P-MULT <>>
244 | 		   <COND (<G? .NUM 1> <SETG P-MULT T>)>"
245 | 		   <SET TMP 0>
246 | 		   <REPEAT ()
247 | 		    <COND (<G? <SET CNT <+ .CNT 1>> .NUM>
248 | 			   <COND (<G? .X 0>
249 | 				  <TELL "(The ">
250 | 				  <COND (<NOT <EQUAL? .X .NUM>>
251 | 					 <TELL "other ">)>
252 | 				  <TELL "object">
253 | 				  <COND (<NOT <EQUAL? .X 1>>
254 | 					 <TELL "s">)>
255 | 				  <TELL " that you mentioned ">
256 | 				  <COND (<NOT <EQUAL? .X 1>>
257 | 					 <TELL "are">)
258 | 					(T <TELL "is">)>
259 | 				  <TELL "n't here!)" CR>)
260 | 				 (<NOT .TMP>
261 | 				  <REFERRING>)>
262 | 			   <RETURN>)
263 | 			  (T
264 | 			   <COND (.PTBL
265 | 				  <SET OBJ1 <GET ,P-PRSO .CNT>>)
266 | 				 (T
267 | 				  <SET OBJ1 <GET ,P-PRSI .CNT>>)>
268 | 	<COND (<OR <G? .NUM 1>
269 | 		   <EQUAL? <GET <GET ,P-ITBL ,P-NC1> 0> ,W?ALL ,W?EVERYTHING>>
270 | 	       <COND (<EQUAL? .OBJ1 ,NOT-HERE-OBJECT>
271 | 		      <SET X <+ .X 1>>
272 | 		      <AGAIN>)
273 | 		   
274 | 		     (<AND <EQUAL? ,P-GETFLAGS ,P-ALL>
275 | 			   <DONT-ALL? .OBJ1 .OBJ>>
276 | 		      <AGAIN>)
277 | 
278 | 		   ; (<AND <EQUAL? ,P-GETFLAGS ,P-ALL>
279 | 			   <VERB-ALL-TEST .OBJ1 .OBJ>>
280 | 		      <AGAIN>)
281 | 		   
282 | 		   ; (<AND <EQUAL? ,P-GETFLAGS ,P-ALL>
283 | 			   <VERB? TAKE>
284 | 		           <OR <AND <NOT <EQUAL? <LOC .OBJ1> ,WINNER ,HERE>>
285 | 				    <NOT <FSET? <LOC .OBJ1> ,SURFACEBIT>>>
286 | 			       <NOT <OR <FSET? .OBJ1 ,TAKEBIT>
287 | 				        <FSET? .OBJ1 ,TRYTAKEBIT>>>>>
288 | 		      <AGAIN>)
289 | 		   ; (<AND <EQUAL? ,P-GETFLAGS ,P-ALL>
290 | 			   <VERB? DROP PUT GIVE PUT-ON PUT-UNDER
291 | 				  PUT-BEHIND THROW>
292 | 			   <NOT <IN? .OBJ1 ,WINNER>>
293 | 			   <NOT <IN? ,P-IT-OBJECT ,WINNER>>>
294 | 		      <AGAIN>)
295 | 		     
296 | 		     (<NOT <ACCESSIBLE? .OBJ1>>
297 | 		      <AGAIN>)
298 | 		     (<EQUAL? .OBJ1 ,PROTAGONIST ; ,POCKET>
299 | 		      <AGAIN>)
300 | 		     (T
301 | 		      <COND (<EQUAL? .OBJ1 ,IT>
302 | 			     <COND (<NOT <FSET? ,P-IT-OBJECT ,NARTICLEBIT>>
303 | 				    <TELL "The ">)>
304 | 			     <PRINTD ,P-IT-OBJECT>)
305 | 			    (T
306 | 			     <COND (<NOT <FSET? .OBJ1 ,NARTICLEBIT>>
307 | 				    <TELL "The ">)>
308 | 			     <PRINTD .OBJ1>)>
309 | 		      <TELL ": ">)>)>
310 | 			   <SET TMP T>
311 | 			   <SETG PRSO <COND (.PTBL
312 | 					     .OBJ1)
313 | 					    (T
314 | 					     .OBJ)>>
315 | 			   <SETG PRSI <COND (.PTBL
316 | 					     .OBJ)
317 | 					    (T
318 | 					     .OBJ1)>>
319 | 		   <SET V <PERFORM ,PRSA ,PRSO ,PRSI>>
320 | 		   <COND (<EQUAL? .V ,M-FATAL>
321 | 			  <RETURN>)>)>>)>
322 | 	  ; <COND (<NOT <EQUAL? .V ,M-FATAL>>
323 | 		   <COND (<GAME-VERB?>
324 | 			  T)
325 | 			 (T
326 | 			  <SET V <APPLY <GETP <LOC ,WINNER> ,P?ACTION>
327 | 					,M-END>>)>)>
328 | 	    <COND (<GAME-VERB?>
329 | 		   T)
330 | 		  (<VERB? AGAIN>
331 | 		   T)
332 | 		  (,P-OFLAG
333 | 		   T)
334 | 		  (T
335 | 		   <SETG L-PRSA ,PRSA>
336 | 		   <SETG L-PRSO ,PRSO>
337 | 		   <SETG L-PRSI ,PRSI>)>
338 | 	    <COND (<EQUAL? .V ,M-FATAL>
339 | 		   <SETG P-CONT <>>)>)
340 | 	   (T
341 | 	    <SETG P-CONT <>>)>
342 |      <COND (,P-WON
343 | 	    <COND (<GAME-VERB?>
344 | 		   T)
345 | 		  (<AND <VERB? AGAIN>
346 | 			<GAME-VERB? ,L-PRSA>>
347 | 		   T)
348 | 		  (T
349 | 		   <SET V <CLOCKER>>)>)>
350 |      <SETG PRSA <>>
351 |      <SETG PRSO <>>
352 |      <SETG PRSI <>>>>
353 | 
354 | <ROUTINE DONT-ALL? (O I "AUX" L)
355 | 	 <SET L <LOC .O>>
356 | 	 <COND (<EQUAL? .O .I>
357 | 		<RTRUE>)
358 | 	       (<VERB? TAKE>
359 | 		<COND (<EQUAL? .L ,PROTAGONIST ; ,WINNER>
360 | 		       <RTRUE>)
361 | 		      (<AND <NOT <FSET? .O ,TAKEBIT>>
362 | 			    <NOT <FSET? .O ,TRYTAKEBIT>>>
363 | 		       <RTRUE>)
364 | 		      (<EQUAL? .O ,CAN-BOTTOM>
365 | 		       <RTRUE>)
366 | 		      (.I
367 | 		       <COND (<NOT <EQUAL? .L .I>>
368 | 			      <RTRUE>)
369 | 			     (<SEE-INSIDE? .I>
370 | 			      <RFALSE>)
371 | 			     (T
372 | 			      <RTRUE>)>)
373 | 		      (<EQUAL? .O ,MILK ,VULTURE>
374 | 		       <RTRUE>)
375 | 		      (<EQUAL? .L ,HERE>
376 | 		       <RFALSE>)
377 | 		      (<FSET? .L ,SURFACEBIT>
378 | 		       <RFALSE>)
379 | 		      (<FSET? .L ,ACTORBIT>
380 | 		       <RFALSE>)
381 | 		    ; (<SEE-INSIDE? .L>
382 | 		       <RFALSE>)
383 | 		      (T
384 | 		       <RTRUE>)>)
385 | 	       (<OR <EQUAL? ,PRSA ,V?DROP ,V?PUT ,V?PUT-ON>
386 | 		    <EQUAL? ,PRSA ; ,V?GIVE ; ,V?FEED ,V?THROW>>
387 | 		<COND (<EQUAL? .O ,MILK ,CAN-BOTTOM>
388 | 		       <RTRUE>)
389 | 		      (<EQUAL? .L ,PROTAGONIST ,WINNER>
390 | 		       <RFALSE>)
391 | 		      (T
392 | 		       <RTRUE>)>)
393 | 	       (T
394 | 		<RFALSE>)>>
395 | 
396 | <ROUTINE ENABLED? (RTN "AUX" C E)
397 | 	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
398 | 	 <SET C <REST ,C-TABLE ,C-INTS>>
399 | 	 <REPEAT ()
400 | 		 <COND (<EQUAL? .C .E> <RFALSE>)
401 | 		       (<EQUAL? <GET .C ,C-RTN> .RTN>
402 | 			<COND (<ZERO? <GET .C ,C-ENABLED?>> <RFALSE>)
403 | 			      (T <RTRUE>)>)>
404 | 		 <SET C <REST .C ,C-INTLEN>>>>
405 | 
406 | <ROUTINE GAME-VERB? ("OPTIONAL" (V <>))
407 | 	<COND (<NOT .V>
408 | 	       <SET V ,PRSA>)>
409 | 	<COND (<OR <EQUAL? .V ,V?BRIEF ,V?SCORE ,V?VERBOSE>
410 | 	           <EQUAL? .V ,V?QUIT ,V?RESTART ,V?RESTORE>
411 | 	           <EQUAL? .V ,V?SAVE ,V?SCRIPT ,V?SUPER-BRIEF>
412 | 	           <EQUAL? .V ,V?TELL ,V?UNSCRIPT ,V?VERSION>
413 | 		   <EQUAL? .V ,V?TIME ; ,V?INVENTORY>>
414 | 	       <RTRUE>)
415 | 	      (T
416 | 	       <RFALSE>)>>
417 | 
418 | <ROUTINE SPOKEN-TO (WHO)
419 |          <PCLEAR>
420 | 	 <TELL "(spoken to ">
421 | 	 <ARTICLE .WHO T>
422 | 	 <TELL D .WHO ")" CR>>
423 | 
424 | <ROUTINE ACCESSIBLE? (OBJ)
425 |          <COND (<FSET? .OBJ ,INVISIBLE>
426 | 		<RFALSE>)
427 | 	       (<EQUAL? <META-LOC .OBJ> ,WINNER ,HERE ,GLOBAL-OBJECTS>
428 | 	        <RTRUE>)
429 | 	       (<VISIBLE? .OBJ>
430 | 	        <RTRUE>)
431 | 	       (T 
432 | 		<RFALSE>)>>
433 | 
434 | <ROUTINE VISIBLE? (OBJ "AUX" L)
435 |          <SET L <LOC .OBJ>>
436 | 	 <COND (<NOT .L> 
437 | 		<RFALSE>)
438 |                (<FSET? .OBJ ,INVISIBLE>
439 | 	        <RFALSE>)
440 |                (<EQUAL? .L ,GLOBAL-OBJECTS>
441 | 	        <RFALSE>)
442 |                (<EQUAL? .L ,PROTAGONIST ,HERE ,WINNER>
443 | 	        <RTRUE>)
444 |                (<AND <EQUAL? .L ,LOCAL-GLOBALS>
445 | 		     <GLOBAL-IN? .OBJ ,HERE>>
446 | 		<RTRUE>)
447 |                (<AND <SEE-INSIDE? .L>
448 | 		     <VISIBLE? .L>>
449 | 	        <RTRUE>)
450 |                (T
451 | 	        <RFALSE>)>>
452 | 
453 | <ROUTINE SEE-INSIDE? (CONTAINER)
454 | 	 <COND (<FSET? .CONTAINER ,SURFACEBIT>
455 | 		<RTRUE>)
456 | 	       (<FSET? .CONTAINER ,CONTBIT>
457 | 		<COND (<OR <FSET? .CONTAINER ,OPENBIT>
458 | 		           <FSET? .CONTAINER ,TRANSBIT>>
459 | 		       <RTRUE>)
460 | 		      (T
461 | 		       <RFALSE>)>)
462 | 	       (<AND <FSET? .CONTAINER ,ACTORBIT>
463 | 		     <NOT <EQUAL? .CONTAINER ,PROTAGONIST>>>
464 | 		<RTRUE>)
465 | 	       (T
466 | 	    	<RFALSE>)>>
467 | 
468 | <ROUTINE META-LOC (OBJ)
469 | 	 <REPEAT ()
470 | 		 <COND (<NOT .OBJ>
471 | 			<RFALSE>)
472 | 		       (<IN? .OBJ ,GLOBAL-OBJECTS>
473 | 			<RETURN ,GLOBAL-OBJECTS>)
474 | 		       (<IN? .OBJ ,ROOMS>
475 | 			<RETURN .OBJ>)
476 | 		       (<FSET? .OBJ ,INVISIBLE>
477 | 			<RFALSE>)
478 | 		       (T
479 | 			<SET OBJ <LOC .OBJ>>)>>>
480 | 
481 | <CONSTANT C-TABLELEN 330>
482 | <GLOBAL C-TABLE <ITABLE NONE 330>>
483 | 
484 | <GLOBAL C-DEMONS 330>
485 | <GLOBAL C-INTS 330>
486 | 
487 | <CONSTANT C-INTLEN 6>
488 | <CONSTANT C-ENABLED? 0>
489 | <CONSTANT C-TICK 1>
490 | <CONSTANT C-RTN 2>
491 | 
492 | <ROUTINE QUEUE (RTN TICK "AUX" CINT)
493 | 	 <PUT <SET CINT <INT .RTN>> ,C-TICK .TICK>
494 | 	 .CINT>
495 | 
496 | <ROUTINE INT (RTN "OPTIONAL" (DEMON <>) E C INT)
497 | 	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
498 | 	 <SET C <REST ,C-TABLE ,C-INTS>>
499 | 	 <REPEAT ()
500 | 		 <COND (<EQUAL? .C .E>
501 | 			<SETG C-INTS <- ,C-INTS ,C-INTLEN>>
502 | 			<AND .DEMON <SETG C-DEMONS <- ,C-DEMONS ,C-INTLEN>>>
503 | 			<SET INT <REST ,C-TABLE ,C-INTS>>
504 | 			<PUT .INT ,C-RTN .RTN>
505 | 			<RETURN .INT>)
506 | 		       (<EQUAL? <GET .C ,C-RTN> .RTN> <RETURN .C>)>
507 | 		 <SET C <REST .C ,C-INTLEN>>>>
508 | 
509 | <GLOBAL CLOCK-WAIT <>>
510 | 
511 | <ROUTINE CLOCKER ("AUX" C E I TICK (FLG <>))
512 | 	 <COND (,CLOCK-WAIT
513 | 		<SETG CLOCK-WAIT <>>
514 | 		<RFALSE>)>
515 | 	 <SET C <REST ,C-TABLE <COND (,P-WON ,C-INTS) (T ,C-DEMONS)>>>
516 | 	 <SET E <REST ,C-TABLE ,C-TABLELEN>>
517 | 	 
518 |        ; "The following clause forces I-ECLIPSE to be
519 | 	  executed before any other pending interrupts"
520 | 
521 | 	 <COND (,ECLIPSE?
522 | 		<SET I <INT I-ECLIPSE>>
523 | 		<COND (<AND <NOT <ZERO? <GET .I ,C-ENABLED?>>>
524 | 			    <L? <GET .I ,C-TICK> 2>>
525 | 		       <APPLY <GET .I ,C-RTN>>)>)>
526 | 	 
527 | 	 <REPEAT ()
528 | 		 <COND (<EQUAL? .C .E>
529 | 			<COND (<OR <NOT <EQUAL? ,HERE ,INSIDE-SHOPPE>>
530 | 				   <FSET? ,CLOCK ,RMUNGBIT>>
531 | 			       <SETG GMOVES <+ ,GMOVES 1>>
532 | 			       <SETG MOVES <+ ,MOVES 1>>
533 | 	                       <COND (<G? ,MOVES 59>
534 | 		                      <SETG MOVES 0>
535 | 		                      <SETG SCORE <+ ,SCORE 1>>
536 | 		                      <COND (<G? ,SCORE 23>
537 | 		                             <SETG SCORE 0>)>)>)>
538 | 			<RETURN .FLG>)
539 | 		       (<NOT <ZERO? <GET .C ,C-ENABLED?>>>
540 | 			<SET TICK <GET .C ,C-TICK>>
541 | 			<COND (<ZERO? .TICK>)
542 | 			      (T
543 | 			       <PUT .C ,C-TICK <- .TICK 1>>
544 | 			       <COND (<AND <NOT <G? .TICK 1>>
545 | 					   <APPLY <GET .C ,C-RTN>>>
546 | 				      <SET FLG T>)>)>)>
547 | 		 <SET C <REST .C ,C-INTLEN>>>>
548 | 
549 | 
550 | <ROUTINE CARRIAGE-RETURNS ("AUX" (CNT 22))
551 | 	 <RESET-THEM>
552 | 	 <REPEAT ()
553 | 		 <CRLF>
554 | 	         <SET CNT <- .CNT 1>>
555 | 		 <COND (<ZERO? .CNT>
556 | 			<RTRUE>)>>>
557 | 
558 | <ROUTINE RESET-THEM ()
559 | 	 <PCLEAR>
560 |          <SETG P-IT-OBJECT ,NOT-HERE-OBJECT>
561 | 	 <SETG P-HIM-OBJECT ,NOT-HERE-OBJECT>
562 |          <SETG P-HER-OBJECT ,NOT-HERE-OBJECT>
563 |          <SETG P-THEM-OBJECT ,NOT-HERE-OBJECT>>
564 | 
565 | <ROUTINE PCLEAR ()
566 | 	 <SETG P-CONT <>>
567 | 	 <SETG QUOTE-FLAG <>>>


--------------------------------------------------------------------------------
/under.zil:
--------------------------------------------------------------------------------
  1 | "UNDER for WISHBRINGER: (C)1985 Infocom, Inc. All rights reserved."
  2 | 
  3 | <OBJECT TUNNEL-FORK
  4 | 	(IN ROOMS)
  5 | 	(DESC "Underground")
  6 | 	(FLAGS RLANDBIT INDOORSBIT)
  7 | 	(GLOBAL HOLE)
  8 | 	(NORTH TO UNDER-HILL)
  9 | 	(EAST TO UNDER-CELL)
 10 | 	(SOUTH PER INTO-GRAVE)
 11 | 	(IN "Which way do you want to go in?")
 12 | 	(OUT "Which way do you want to go out?")
 13 | 	(PSEUDO "TUNNEL" HERE-F)
 14 | 	(ACTION TUNNEL-FORK-F)>
 15 | 
 16 | <ROUTINE TUNNEL-FORK-F (CONTEXT)
 17 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
 18 | 		<SAY-CHAMBER>
 19 | 		<TELL <TO-N> 
 20 | " and east, and there's a dark hole in the south wall." CR>)>>
 21 | 
 22 | <ROUTINE SAY-CHAMBER ()
 23 | 	 <TELL "You're in a " <PICK-ONE ,CRAMPS> 
 24 | 	       " under" D ,GROUND " chamber. ">
 25 | 	 <COND (<PROB 50>
 26 | 		<TELL "Long">)
 27 | 	       (T
 28 | 		<TELL "Cold">)>
 29 | 	 <COND (<PROB 50>
 30 | 	        <TELL ", " <PICK-ONE ,CRAMPS>>)>
 31 | 	 <TELL " tunnels wander away ">>
 32 | 
 33 | <GLOBAL CRAMPS <LTABLE 0 "damp" "dark" "smelly" "dirty">>
 34 | 
 35 | <ROUTINE INTO-GRAVE ()
 36 | 	 <COND (<CANT-FIT-INTO? "hole">
 37 | 		<RFALSE>)
 38 | 	       (T
 39 | 		<MOVE-ALL ,OPEN-GRAVE ,INSIDE-GRAVE>
 40 | 	        <RETURN ,INSIDE-GRAVE>)>>
 41 | 
 42 | <OBJECT TUNNEL-CORNER
 43 | 	(IN ROOMS)
 44 | 	(DESC "Underground")
 45 | 	(FLAGS RLANDBIT INDOORSBIT)
 46 | 	(EAST PER ENTER-GRUE-NEST)
 47 | 	(SOUTH TO UNDER-CELL)
 48 | 	(WEST TO UNDER-HILL)
 49 | 	(OUT "Which way do you want to go out?")
 50 | 	(PSEUDO "TUNNEL" HERE-F)
 51 | 	(ACTION TUNNEL-CORNER-F)>
 52 | 
 53 | <ROUTINE TUNNEL-CORNER-F (CONTEXT)
 54 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
 55 | 		<SAY-CHAMBER>
 56 | 		<TELL <TO-S> ", east and west." CR>)>>
 57 | 
 58 | <ROUTINE ENTER-GRUE-NEST ()
 59 | 	 <COND (<AND <NOT ,GRUE-COVERED?>
 60 | 		     <NOT <ENABLED? I-GRUE-SLEEP>>>
 61 | 		<SETG SLEEP-SCRIPT 0>
 62 | 	        <ENABLE <QUEUE I-GRUE-SLEEP -1>>)>
 63 | 	 <RETURN ,GRUE-NEST>>
 64 | 
 65 | <OBJECT UNDER-HILL
 66 | 	(IN ROOMS)
 67 | 	(DESC "Underground")
 68 | 	(FLAGS RLANDBIT INDOORSBIT)
 69 | 	(GLOBAL STUMP)
 70 | 	(EAST TO TUNNEL-CORNER)
 71 | 	(SOUTH TO TUNNEL-FORK)
 72 | 	(UP TO LOOKOUT-HILL IF STUMP IS OPEN)
 73 | 	(OUT "Which way do you want to go out?")
 74 | 	(PSEUDO "TUNNEL" HERE-F)
 75 | 	(ACTION UNDER-HILL-F)>
 76 | 
 77 | <ROUTINE UNDER-HILL-F ("OPTIONAL" (CONTEXT <>))
 78 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
 79 | 		<SAY-CHAMBER>
 80 | 		<TELL <TO-S> " and east.|
 81 | |
 82 | The surrounding walls are almost obscured by the roots of a mighty tree. ">
 83 | 		<COND (<FSET? ,STUMP ,OPENBIT>
 84 | 		       <TELL 
 85 | "Feeble light streams in from an opening overhead">)
 86 | 		      (T
 87 | 		       <TELL
 88 | "Overhead you can see the underside of a large " D ,STUMP ". It appears to be hinged">)>
 89 | 		<TELL "." CR>)>>
 90 | 
 91 | "*** GRUE'S NEST ***"
 92 | 
 93 | <OBJECT GRUE-NEST
 94 | 	(IN ROOMS)
 95 | 	(DESC "Grue's Nest")
 96 | 	(FLAGS RLANDBIT INDOORSBIT)
 97 | 	(GLOBAL SIGN CORNER)
 98 | 	(WEST PER EXIT-NEST)
 99 | 	(OUT PER EXIT-NEST)
100 | 	(PSEUDO "TUNNEL" HERE-F "NEST" HERE-F)
101 | 	(ACTION GRUE-NEST-F)>
102 | 
103 | <ROUTINE EXIT-NEST ()
104 | 	 <SETG SLEEP-SCRIPT <- ,SLEEP-SCRIPT 1>>
105 | 	 <RETURN ,TUNNEL-CORNER>>
106 | 
107 | <ROUTINE GRUE-NEST-F (CONTEXT)
108 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
109 | 		<TELL
110 | "You have stumbled into the nesting place of a family of grues. Congratulations. Few indeed are the adventurers who have entered a grue's nest and lived as long as you have.|
111 | |
112 | Everything is littered with rusty swords of elvish workmanship, piles of bones and other debris. A">
113 | 		<OPEN-CLOSED ,REFRIGERATOR T>
114 | 	        <TELL D ,REFRIGERATOR 
115 | " stands in one " D ,CORNER " of the nest, and something">
116 | 		<COND (<IN? ,BLANKET ,BABY>
117 | 		       <TELL " is curled up under a " D ,BLANKET>)
118 | 		      (T
119 | 		       <TELL
120 | "... a small, dangerous-looking " D ,BABY "... is curled up">)>
121 | 		<TELL " in the other " D ,CORNER ".|
122 | |
123 | The only exit is to the west. Hope you survive long enough to use it."
124 | CR>)>>
125 | 
126 | <OBJECT BABY
127 | 	(IN GRUE-NEST)
128 | 	(DESC "little beast")
129 | 	(SYNONYM BEAST ANIMAL GRUE GRUB)
130 | 	(ADJECTIVE LITTLE BABY SLEEPING SMALL)
131 | 	(FLAGS NDESCBIT ACTORBIT SURFACEBIT)
132 | 	(CAPACITY 10)
133 | 	(SIZE 10)
134 | 	(ACTION BABY-F)>
135 | 
136 | <GLOBAL GRUE-COVERED? <>>
137 | 
138 | <ROUTINE BABY-F ("OPTIONAL" (CONTEXT <>)) 
139 |      	 <COND (<VERB? EXAMINE>
140 | 		<SAY-THE ,BABY>
141 | 		<TELL " is ">
142 | 		<COND (<IN? ,BLANKET ,BABY>
143 | 		       <TELL "covered with a " D ,BLANKET>)
144 | 		      (T
145 | 		       <TELL 
146 | "dressed in swaddling clothes with a pink baby bonnet, has long, slavering fangs and appears to be sleeping">)>
147 | 		<TELL "." CR>
148 | 		<RTRUE>) 
149 | 	       
150 | 	       (<AND <VERB? TELL HELLO REPLY ALARM YELL
151 | 			    ASK-ABOUT ASK-FOR QUESTION>
152 | 		     <EQUAL? ,PRSO ,BABY>>
153 | 		<WAKE-BABY "The sound of your voice">
154 | 		<RFATAL>)
155 | 	       	       
156 | 	       (<AND <VERB? PUT PUT-ON THROW THROW-OFF>
157 | 		     <EQUAL? ,PRSI ,BABY>>
158 | 		<COND (<EQUAL? ,PRSO ,BLANKET>
159 | 		       <COVER-GRUE>)
160 | 		      (T
161 | 		       <WAKE-BABY>)>
162 | 		<RTRUE>)
163 | 	       (<AND <VERB? HIDE>
164 | 		     <EQUAL? ,PRSO ,BABY>
165 | 		     ,PRSI>
166 | 		<COND (<EQUAL? ,PRSI ,BLANKET>
167 | 		       <COVER-GRUE>)
168 | 		      (T
169 | 		       <PERFORM ,V?PUT-ON ,PRSI ,BABY>)>
170 | 		<RTRUE>)
171 | 	       (<VERB? KISS> 
172 | 		<SAY-THE ,BABY>
173 | 		<TELL " smiles in its sleep." CR>
174 | 		<RTRUE>)
175 | 	       (<VERB? FEED GIVE>
176 | 		<YOUD-HAVE-TO "wake" ,BABY>
177 | 		<RTRUE>)
178 | 	       (<TOUCHING? ,BABY>
179 | 		<WAKE-BABY>
180 | 		<RFATAL>)
181 | 	       (<VERB? LISTEN>
182 | 		<SAY-THE ,BABY>
183 | 		<TELL " snores gently." CR>
184 | 		<RTRUE>)
185 | 	       (T
186 | 		<RFALSE>)>>
187 | 
188 | <ROUTINE WAKE-BABY ("OPTIONAL" REASON)
189 | 	 <TELL "Oh, no! ">
190 | 	 <COND (.REASON
191 | 		<TELL .REASON>)
192 | 	       (T
193 | 		<TELL "Your reckless fumbling">)>
194 | 	 <TELL " woke up the " D ,BABY "!|
195 | |
196 | The little creature ">
197 | 	 <COND (,LIT
198 | 		<TELL "blinks helplessly in the glow of">
199 | 	        <CANDLE-OR-STONE>)
200 | 	       (T
201 | 		<TELL "gurgles angrily in the " D ,DARKNESS>)>
202 | 	 <TELL ".">
203 | 	 <MOTHER-COMES>>
204 | 
205 | <ROUTINE MOTHER-COMES ()
206 | 	 <TELL " It opens its slavering jaws and">
207 | 	 <SUBWAY>
208 | 	 <CRLF>
209 | 	 <CRLF>
210 | 	 <COND (,LIT
211 | 		<TELL "A very large creature, equipped with slavering fangs and wearing a calico apron,">)
212 | 	       (T
213 | 		<TELL "Something very large">)>
214 | 	 <TELL " lurks into the nest">
215 | 	 <COND (,LIT
216 | 		<TELL ". Its mother-instinct overcomes its overwhelming fear of light long enough to devour">)
217 | 	       (T
218 | 		<TELL " and devours">)>
219 | 	 <TELL " you.">
220 | 	 <BAD-ENDING>>
221 | 
222 | <ROUTINE SUBWAY ()
223 | 	 <TELL " emits a hideous, plaintive wail that reminds you of a subway screeching to a halt.">>
224 | 
225 | <ROUTINE COVER-GRUE ()
226 | 	 <SETG GRUE-COVERED? T>
227 | 	 <DISABLE <INT I-GRUE-SLEEP>>
228 | 	 <MOVE ,BLANKET ,BABY>
229 | 	 <TELL ,OKAY "the " D ,BABY " is now covered with the " D ,BLANKET ".|
230 | |
231 | The creature stirs restlessly for an anxious moment. Then it settles into the comfortable " D ,DARKNESS " of the " D ,BLANKET 
232 | ", sighs gently and lies still." CR CR>
233 | 	 <UPDATE-SCORE 3>>
234 | 
235 | <ROUTINE CANDLE-OR-STONE ("AUX" OBJ)
236 | 	 <COND (<OR <IN? ,CANDLE ,PROTAGONIST>
237 | 		    <IN? ,CANDLE ,HERE>>
238 | 		<SET OBJ ,CANDLE>)
239 | 	       (T
240 | 		<SET OBJ ,WISHBRINGER>)>
241 | 	 <TELL " ">
242 | 	 <ARTICLE .OBJ T>
243 | 	 <TELL D .OBJ>>
244 | 
245 | <GLOBAL SLEEP-SCRIPT 0>
246 | 
247 | <ROUTINE I-GRUE-SLEEP ()
248 | 	 <COND (<OR ,FUZZY? ,ECLIPSE?>
249 | 		<RTRUE>)
250 | 	       (<EQUAL? ,HERE ,GRUE-NEST>
251 | 		<COND (<NOT ,LIT>
252 | 		       <SETG SLEEP-SCRIPT 0>
253 | 		       <RTRUE>)
254 | 		      (T
255 | 		       <SETG SLEEP-SCRIPT <+ ,SLEEP-SCRIPT 1>>
256 | 		       <CRLF>
257 | 		       <COND (<EQUAL? ,SLEEP-SCRIPT 1>
258 | 			      <TELL "Snoring fitfully, the " D ,BABY
259 | " turns away from the light of">
260 | 			      <CANDLE-OR-STONE>
261 | 			      <TELL " and faces the wall." CR>)
262 | 			     (<EQUAL? ,SLEEP-SCRIPT 2>
263 | 			      <SAY-THE ,BABY>
264 | 			      <TELL
265 | " is stirring restlessly. It looks as if it's about to wake up!" CR>)
266 | 			     (T
267 | 			      <TELL
268 | "With a toothy yawn, the " D ,BABY " opens its big red eyes and blinks at you with surprise and fear.">
269 | 			      <MOTHER-COMES>)>)>)>>  
270 | 
271 | <OBJECT REFRIGERATOR
272 | 	(IN GRUE-NEST)
273 | 	(DESC "refrigerator")
274 | 	(SYNONYM REFRIGERATOR FRIGE FRIDGE)
275 | 	(ADJECTIVE GRUE)
276 | 	(FLAGS CONTBIT NDESCBIT TRYTAKEBIT READBIT)
277 | 	(CAPACITY 10)
278 | 	(ACTION REFRIGERATOR-F)>
279 | 
280 | <ROUTINE REFRIGERATOR-F ()
281 | 	 <COND (<VERB? EXAMINE LOOK-ON READ> 
282 | 		<TELL "A label on the " D ,REFRIGERATOR " reads, \"">
283 | 		<FROBOZZ "Grue Refrigerator">
284 | 		<TELL ".\"" CR>
285 | 		<RTRUE>)
286 | 	       (<AND <VERB? OPEN>
287 | 		     <NOT <FSET? ,REFRIGERATOR ,OPENBIT>>>
288 | 		<HANDLE-FRIDGE " goes out as you open">
289 | 		<RFALSE>)
290 | 	       (<AND <VERB? CLOSE>
291 | 		     <FSET? ,REFRIGERATOR ,OPENBIT>>
292 | 		<HANDLE-FRIDGE " comes on as you close">
293 | 		<RFALSE>)
294 | 	       (<AND <VERB? PUT-ON>
295 | 		     <EQUAL? ,PRSI ,REFRIGERATOR>>
296 | 		<NO-ROOM>
297 | 		<TELL "It's covered with debris." CR>
298 | 		<RTRUE>)
299 | 	       (<MOVING? ,REFRIGERATOR>
300 | 		<TOO-LARGE ,REFRIGERATOR>
301 | 		<RTRUE>)
302 | 	       (<HURT? ,REFRIGERATOR>
303 | 		<TELL "The owners">
304 | 		<MIGHT-NOT-LIKE>
305 | 		<RTRUE>)
306 | 	       (T
307 | 		<RFALSE>)>>
308 | 
309 | <ROUTINE HANDLE-FRIDGE (STR)
310 | 	 <TELL "A light inside the " D ,REFRIGERATOR .STR " it." CR CR>>
311 | 
312 | <OBJECT BOTTLE
313 | 	(IN REFRIGERATOR)
314 | 	(DESC "bottle")
315 | 	(SYNONYM BOTTLE)
316 | 	(ADJECTIVE MILK)
317 | 	(FLAGS CONTBIT TAKEBIT TRANSBIT READBIT)
318 | 	(VALUE 0)
319 | 	(CAPACITY 1)
320 | 	(SIZE 5)
321 | 	(ACTION BOTTLE-F)>
322 | 
323 | <ROUTINE BOTTLE-F ("AUX" (FULL? <>))
324 | 	 <THIS-IS-IT ,BOTTLE>
325 | 	 <SET FULL? <IN? ,MILK ,BOTTLE>>
326 | 	 <COND (<VERB? EXAMINE LOOK-ON READ>
327 | 		<TELL "The words \"">
328 | 		<FROBOZZ "Unbreakable Milk Bottle">
329 | 		<TELL "\" are etched on the">
330 | 		<OPEN-CLOSED ,BOTTLE>
331 | 		<TELL D ,BOTTLE "." CR>
332 | 		<RTRUE>)
333 | 	       (<VERB? LOOK-INSIDE LOOK-DOWN SEARCH>
334 | 		<COND (<NOT <EQUAL? <LOC ,BOTTLE> ,HERE ,PROTAGONIST>>
335 | 		       <YOUD-HAVE-TO "take out" ,BOTTLE>
336 | 		       <RTRUE>)>
337 | 		<TELL "There's ">
338 | 		<COND (.FULL?
339 | 		       <TELL "a bit of " D ,MILK>)
340 | 		      (T
341 | 		       <PRINT-CONTENTS ,BOTTLE>)>
342 | 		<TELL " in the " D ,BOTTLE "." CR>
343 | 		<RTRUE>)
344 | 	       (<VERB? DRINK DRINK-FROM>
345 | 		<COND (.FULL?
346 | 		       <PERFORM ,V?DRINK ,MILK>)
347 | 		      (T
348 | 		       <BOTTLE-EMPTY>)>
349 | 		<RTRUE>)
350 | 	       (<VERB? POUR EMPTY>
351 | 		<COND (.FULL?
352 | 		       <PERFORM ,V?POUR ,MILK>)
353 | 		      (T
354 | 		       <BOTTLE-EMPTY>)>
355 | 		<RTRUE>)
356 | 	       (<VERB? SHAKE>
357 | 		<COND (.FULL?
358 | 		       <COND (<FSET? ,BOTTLE ,OPENBIT>
359 | 			      <PERFORM ,V?POUR ,MILK>)
360 | 			     (T
361 | 			      <SAY-THE ,MILK>
362 | 			      <TELL " doesn't look any better." CR>)>)
363 | 		      (T
364 | 		       <BOTTLE-EMPTY>)>
365 | 		<RTRUE>)
366 | 	       (<AND <VERB? PUT>
367 | 		     <EQUAL? ,PRSI ,BOTTLE>>
368 | 		<TELL "The mouth of the " D ,BOTTLE
369 | 		      " is too narrow." CR>
370 | 		<RTRUE>)
371 | 	       (<AND <VERB? OPEN CLOSE>
372 | 		     <DONT-HAVE? ,BOTTLE>>
373 | 		<RTRUE>)
374 | 	       (<HURT? ,BOTTLE>
375 | 		<TELL 
376 | "Maybe you should read the " D ,BOTTLE " first." CR>
377 | 		<RTRUE>)
378 | 	       (T
379 | 		<RFALSE>)>>
380 | 
381 | <ROUTINE BOTTLE-EMPTY ()
382 | 	 <SAY-THE ,BOTTLE>
383 | 	 <TELL " is empty." CR>>
384 | 
385 | <OBJECT MILK
386 | 	(IN BOTTLE)
387 | 	(DESC "grue milk")
388 | 	(SYNONYM MILK LIQUID)
389 | 	(ADJECTIVE GRUE LITTLE ICKY)
390 | 	(FLAGS NDESCBIT NARTICLEBIT TAKEBIT)
391 | 	(ACTION MILK-F)
392 | 	(SIZE 0)>
393 | 
394 | <ROUTINE ACCESS-MILK? ()
395 | 	 <COND (<NOT <IN? ,MILK ,BOTTLE>>
396 | 		<BOTTLE-EMPTY>
397 | 		<RFALSE>)
398 | 	       (<FSET? ,BOTTLE ,OPENBIT>
399 | 		<RTRUE>)
400 | 	       (T
401 | 		<YOUD-HAVE-TO "open" ,BOTTLE>
402 | 		<RFALSE>)>>
403 | 
404 | <ROUTINE MILK-F ()
405 | 	 <COND (<VERB? EXAMINE LOOK-INSIDE>
406 | 		<SAY-THE ,MILK>
407 | 		<TELL 
408 | " is dark brown, with little icky things lurking in it." CR>
409 | 		<RTRUE>)
410 | 	       (<NOT <IN? ,BOTTLE ,PROTAGONIST>>
411 | 		<YOUD-HAVE-TO "be holding" ,BOTTLE>
412 | 		<RTRUE>)
413 | 	       (<VERB? DRINK DRINK-FROM TASTE>
414 | 		<COND (<ACCESS-MILK?>
415 | 		       <REMOVE ,MILK>
416 | 		       <SETG MILK-SCRIPT 4>
417 | 		       <ENABLE <QUEUE I-DRINK -1>>
418 | 		       <TELL "Slurp! All gone." CR>)>
419 | 		<RTRUE>)
420 | 	       (<AND <VERB? POUR EMPTY TAKE PUT PUT-ON THROW DROP>
421 | 		     <EQUAL? ,PRSO ,MILK>>
422 | 		<COND (<ACCESS-MILK?>
423 | 		       <REMOVE ,MILK>
424 | 		       <SAY-THE ,MILK>
425 | 		       <TELL " splashes all over the place." CR>
426 | 		       <COND (<AND <ACCESSIBLE? ,KITTY>
427 | 				   <NOT <FSET? ,KITTY ,RMUNGBIT>>>
428 | 			      <CRLF>
429 | 			      <GIVE-MILK-TO-CAT ,KITTY>)
430 | 			     (<ACCESSIBLE? ,CHAOS>
431 | 			      <CRLF>
432 | 			      <GIVE-MILK-TO-CAT ,CHAOS>)>)>
433 | 		<RTRUE>)
434 | 	       (<AND <VERB? FEED GIVE>
435 | 		     <EQUAL? ,PRSO ,MILK>
436 | 		     <FSET? ,PRSI ,ACTORBIT>>
437 | 		<PERFORM ,V?POUR ,MILK>
438 | 		<RTRUE>)
439 | 	       (<VERB? SMELL>
440 | 		<COND (<ACCESS-MILK?>
441 | 		       <TELL "The fumes make you queasy." CR>)>
442 | 		<RTRUE>)
443 | 	       (<VERB? SHAKE>
444 | 		<MEAN-BOTTLE>
445 | 		<PERFORM ,V?SHAKE ,BOTTLE>
446 | 		<RTRUE>)
447 | 	       (<VERB? EAT BITE>
448 | 		<NOT-SOLID>
449 | 		<RTRUE>)
450 | 	       (T
451 | 		<RFALSE>)>>
452 | 
453 | <ROUTINE MEAN-BOTTLE ()
454 | 	 <TELL ,I-ASSUME " the " D ,BOTTLE ".)" CR CR>>
455 | 
456 | <GLOBAL MILK-SCRIPT 0>
457 | 
458 | <ROUTINE I-DRINK ()
459 | 	 <SETG MILK-SCRIPT <- ,MILK-SCRIPT 1>>
460 | 	 <CRLF>
461 | 	 <COND (<EQUAL? ,MILK-SCRIPT 3>
462 | 		<TELL
463 | "You can feel little icky things sliding down your throat.">)
464 | 	       (<EQUAL? ,MILK-SCRIPT 2>
465 | 		<TELL 
466 | "(The " D ,MILK " is lurking in your stomach.">
467 | 		<MAKE-IT-SNAPPY>)
468 | 	       (<EQUAL? ,MILK-SCRIPT 1>
469 | 		<TELL
470 | "(The taste of the " D ,MILK " is starting to wear off.">
471 | 		<HOLD-YOUR-PEACE>)
472 | 	       (T
473 | 		<SETG MILK-SCRIPT 0>
474 | 		<DISABLE <INT I-DRINK>>
475 | 		<TELL
476 | "(Thankfully, the icky taste of " D ,MILK " is gone.)">)>
477 | 	 <CRLF>>
478 | 
479 | <OBJECT WORM
480 | 	(IN REFRIGERATOR)
481 | 	(DESC "earthworm")
482 | 	(SYNONYM WORM EARTHWORM)
483 | 	(ADJECTIVE EARTH WORMS)
484 | 	(FLAGS VOWELBIT TAKEBIT)
485 | 	(VALUE 3)
486 | 	(SIZE 1)
487 | 	(ACTION WORM-F)>
488 | 
489 | <ROUTINE WORM-F ()
490 | 	 <COND (<AND <VERB? TAKE>
491 | 		     <EQUAL? ,PRSO ,WORM>>
492 | 		<COND (<V-TAKE>
493 | 		       <CRLF>
494 | 		       <SAY-THE ,WORM>
495 | 	               <TELL " squirms with annoyance at your touch." CR>)>
496 | 		<RTRUE>)
497 | 	       (<VERB? EXAMINE>
498 | 		<SAY-THE ,WORM>
499 | 		<TELL " is covered with nasty little bits of dirt and slime. It wriggles nervously">
500 | 		<COND (<IN? ,WORM ,PROTAGONIST>
501 | 		       <TELL " in " D ,HANDS>)>
502 | 		<TELL " as you look at it." CR>
503 | 		<RTRUE>)
504 | 	       (<TALKING-TO? ,WORM>
505 | 		<IT-IGNORES-YOU ,WORM>
506 | 		<RFATAL>)
507 | 	       (<AND <VERB? EAT TASTE KISS>
508 | 		     <EQUAL? ,PRSO ,WORM>>
509 | 		<TELL "Yuck! You've got to be kidding." CR>
510 | 		<RTRUE>)
511 | 	       (T
512 | 		<RFALSE>)>> 
513 | 	       
514 | <OBJECT DEBRIS
515 | 	(IN GRUE-NEST)
516 | 	(DESC "debris")
517 | 	(SYNONYM DEBRIS BONE SWORDS BONES)
518 | 	(ADJECTIVE SWORD ELVISH)
519 | 	(FLAGS NDESCBIT)
520 | 	(ACTION DEBRIS-F)>
521 | 
522 | <ROUTINE DEBRIS-F ()
523 | 	 <COND (<NOT <EQUAL? ,HERE ,GRUE-NEST>>
524 | 		<CANT-SEE-ANY>
525 | 		<RFATAL>)
526 | 	       (<SEE-VERB?>
527 | 		<TELL "Aside from the ominous implications, you see nothing "
528 | <PICK-ONE ,YAWNS> " about the " D ,DEBRIS "." CR>
529 | 		<RTRUE>)
530 | 	       (T
531 | 		<YOU-DONT-NEED ,DEBRIS>
532 | 		<RFATAL>)>>
533 | 
534 | ; <OBJECT GENERIC-GRUE
535 | 	(IN GLOBAL-OBJECTS)
536 | 	(DESC "grue")
537 | 	(SYNONYM GRUE GRUES)
538 | 	(ADJECTIVE LURKING SINISTER)
539 | 	(ACTION GENERIC-GRUE-F)>
540 | 
541 | ; <ROUTINE GENERIC-GRUE-F ()
542 |           <COND (<AND <EQUAL? ,HERE ,GRUE-NEST>
543 | 		      <BABY-F>>
544 | 		 <RTRUE>)
545 |       		(<VERB? EXAMINE>
546 | 		 <TELL
547 | "No one has ever seen a grue... except, perhaps, from the inside." CR>
548 | 		 <RTRUE>)
549 | 	        (<VERB? WHAT>
550 | 	         <TELL
551 | "The grue is a sinister, lurking presence in the dark places of the earth. Its favorite diet is adventurers, but its insatiable appetite is tempered by its fear of light. No grue has ever been seen by the light of day, and few have survived its fearsome jaws to tell the tale." CR>
552 | 		<RTRUE>)
553 | 	       (<VERB? FIND WHERE>
554 | 	        <TELL "There aren't any grues here">
555 | 	        <COND (<FSET? ,HERE ,ONBIT>
556 | 		       <TELL "! There's too much light.">
557 | 		       <CRLF>)
558 | 		      (T
559 | 		       <TELL ", but there's probably one">
560 | 		       <LURKING-NEARBY>)>
561 | 		<RTRUE>)
562 | 	       (<VERB? LISTEN>
563 | 	        <TELL "They make no sound, but are always">
564 | 		<LURKING-NEARBY>
565 | 		<RTRUE>)
566 | 	       (T
567 | 		<RFALSE>)>>
568 | 
569 | ; <ROUTINE LURKING-NEARBY ()
570 | 	 <TELL " lurking in the " D ,DARKNESS " nearby." CR>>
571 | 
572 | "*** UNDER CELL ***"
573 | 
574 | <OBJECT UNDER-CELL
575 | 	(IN ROOMS)
576 | 	(DESC "Underground")
577 | 	(FLAGS RLANDBIT INDOORSBIT)
578 | 	(GLOBAL CELL HIDDEN-HATCH)
579 | 	(NORTH TO TUNNEL-CORNER)
580 | 	(WEST TO TUNNEL-FORK)
581 | 	(UP PER THROUGH-HATCH?)
582 | 	(OUT "Which way do you want to go out?")
583 | 	(PSEUDO "TUNNEL" HERE-F)
584 | 	(ACTION UNDER-CELL-F)>
585 | 
586 | <ROUTINE UNDER-CELL-F (CONTEXT)
587 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
588 | 		<SAY-CHAMBER>
589 | 		<TELL <TO-N> " and west." CR CR>
590 | 		<COND (<FSET? ,HIDDEN-HATCH ,RMUNGBIT>
591 | 		       <TELL "A patch of freshly-dried concrete is visible">)
592 | 		      (T
593 | 		       <COND (<FSET? ,UNDER-CELL ,ONBIT>
594 | 			      <TELL 
595 | "Faint light is streaming in from a narrow hole">)
596 | 			     (T
597 | 			      <TELL "A dark, narrow hole is visible">)>)>
598 | 		<TELL " overhead." CR>)>>
599 | 		
600 | 


--------------------------------------------------------------------------------
/magick.zil:
--------------------------------------------------------------------------------
  1 | "MAGICK for WISHBRINGER:
  2 |  Copyright (C)1985 Infocom, Inc. All rights reserved.
  3 |  Reconstructed from .ZAP files 5/23/88 by Prof."
  4 | 
  5 | <OBJECT WISHBRINGER
  6 | 	(DESC "small stone")
  7 | 	(FLAGS TOOLBIT RMUNGBIT TAKEBIT)
  8 | 	(SYNONYM STONE ROCK LIGHT WISHBRINGER)
  9 | 	(ADJECTIVE SMALL MAGIC MAGICK GLOWING VIOLET)
 10 | 	(SIZE 1)
 11 | 	(VALUE 5)
 12 | 	(ACTION WISHBRINGER-F)>
 13 | 
 14 | <ROUTINE WISHBRINGER-F ()
 15 | 	<COND (<VERB? EXAMINE>
 16 | 	       <SAY-THE ,WISHBRINGER>
 17 | 	       <COND (<FSET? ,WISHBRINGER ,ONBIT>
 18 | 		      <TELL " glows">
 19 | 		      <SAY-GLOW>
 20 | 		      <RTRUE>)>
 21 | 	       <TELL " is dark and cold." CR>
 22 | 	       <RTRUE>)
 23 | 	      (T
 24 | 	       <RFALSE>)>>
 25 | 
 26 | <ROUTINE SAY-GLOW ()
 27 | 	 <TELL " with an eerie violet-white radiance." CR>
 28 | 	 <RTRUE>>
 29 | 
 30 | <ROUTINE NOT-SATISFIED ("OPT" (CONDITIONS? <>))
 31 | 	 <REFER-TO-MANUAL>
 32 | 	 <TELL " for a summary of what you must ">
 33 | 	 <COND (.CONDITIONS?
 34 | 		<TELL "do ">)
 35 | 	       (T
 36 | 		<TELL "be holding ">)>
 37 | 	 <TELL "to make that Wish come true.)" CR>
 38 | 	 <RTRUE>>
 39 | 
 40 | <ROUTINE BEFORE-YOU-WISH (STR OBJ)
 41 | 	 <THIS-IS-IT .OBJ>
 42 | 	 <TELL "(You probably ought to " .STR " the " D .OBJ
 43 | 	       " before you make that Wish!)" CR>
 44 | 	 <RTRUE>>
 45 | 
 46 | <ROUTINE STONE-IGNORES (STR)
 47 | 	 <TELL "The Stone, sensing that " .STR 
 48 | 	       ", decides to ignore your Wish." CR>
 49 | 	 <RTRUE>>
 50 | 
 51 | <ROUTINE NOT-WISHING? (OBJ)
 52 | 	 <COND (<VERB? WISH>
 53 | 		<TELL "How can you do that ">
 54 | 		<COND (<EQUAL? .OBJ ,PRSO>
 55 | 		       <TELL "to">)
 56 | 		      (T
 57 | 		       <TELL "with">)>
 58 | 		<TELL " an abstract concept like \"" D .OBJ "\"?" CR>
 59 | 		<RTRUE>)
 60 | 	       (T
 61 | 		<RFALSE>)>>
 62 | 
 63 | <OBJECT FLIGHT
 64 | 	(LOC GLOBAL-OBJECTS)
 65 | 	(DESC "Flight")
 66 | 	(FLAGS WISHBIT NARTICLEBIT)
 67 | 	(SYNONYM FLIGHT)
 68 | 	(ACTION FLIGHT-F)>
 69 | 
 70 | <ROUTINE FLIGHT-F ()
 71 | 	 <COND (<NOT-WISHING? ,FLIGHT>
 72 | 		<RFATAL>)
 73 | 	       (<NOT <IN? ,BROOM ,PROTAGONIST>>
 74 | 		<NOT-SATISFIED>
 75 | 		<RFATAL>)
 76 | 	       (<ZERO? ,BROOM-SIT?>
 77 | 		<BEFORE-YOU-WISH "sit on" ,BROOM>
 78 | 		<RFATAL>)
 79 | 	       (<AND <FSET? ,HERE ,INDOORSBIT>
 80 | 		     <NOT <EQUAL? ,HERE ,LABORATORY>>>
 81 | 		<STONE-IGNORES "you're not outdoors">
 82 | 		<RFATAL>)>
 83 | 	 <FSET ,FLIGHT ,TOUCHBIT>
 84 | 	 <FSET ,VULTURE ,RMUNGBIT>
 85 | 	 <INC SPELLS>
 86 | 	 <TELL 
 87 | "The Stone begins to pulse with violet Magick. Translucent planes of energy coax the broomstick ">
 88 | 	 <COND (<EQUAL? ,HERE ,LABORATORY>
 89 | 		<TELL "out the window and ">)>
 90 | 	 <TELL "high into the moonlit sky.|
 91 | |
 92 | You feel a cool wind whip your face as you streak northward, guided by the steady glow of " ,GAME ".">
 93 | 	 <TO-FINISH>
 94 | 	 <MOVE ,BROOM ,CLIFF-EDGE>
 95 | 	 <SETG BROOM-SIT? <>>
 96 | 	 <CLATTERS ,BROOM>
 97 | 	 <CRLF>
 98 | 	 <V-LOOK>
 99 | 	 <RTRUE>>
100 | 
101 | <OBJECT FREEDOM
102 | 	(LOC GLOBAL-OBJECTS)
103 | 	(DESC "Freedom")
104 | 	(FLAGS WISHBIT NARTICLEBIT)
105 | 	(SYNONYM FREEDOM)
106 | 	(ACTION FREEDOM-F)>
107 | 
108 | <ROUTINE FREEDOM-F ("AUX" RM)
109 | 	 <COND (<NOT-WISHING? ,FREEDOM>
110 | 		<RFATAL>)
111 | 	       (<HELD? ,CHOCOLATE> ;"NOT removed - GTB"
112 | 		<BEFORE-YOU-WISH "eat" ,CHOCOLATE>
113 | 		<RFATAL>)
114 | 	       (<ZERO? ,CHOCOLATE-SCRIPT>
115 | 		<NOT-SATISFIED T>
116 | 		<RFATAL>)
117 | 	       (<AND ,CHAINED?
118 | 		     <EQUAL? ,HERE ,TORTURE-CHAMBER>>
119 | 		<SETG CHOCOLATE-SCRIPT 1>
120 | 		<FSET ,FREEDOM ,TOUCHBIT>
121 | 		<INC SPELLS>
122 | 		<COND (<IN? ,CRISP ,TORTURE-CHAMBER>
123 | 		       <FSET ,WISHBRINGER ,NDESCBIT>
124 | 		       <MOVE ,WISHBRINGER ,COAT>
125 | 		       <TELL D ,CRISP " watches with surprise as a">
126 | 		       <FINGER-OF-LIGHT>
127 | 		       <TELL CR "\"Good trick,\" " D ,CRISP
128 | " remarks as he relocks your chains, snatches " ,GAME
129 | " away from you and drops it into his coat pocket. \"You'll have to tell " 
130 | ,EONE " how you did it.\"" CR>
131 | 		       <RFATAL>)>
132 | 		<OPEN-TORTURE-CHAINS>
133 | 		<TELL "A">
134 | 		<FINGER-OF-LIGHT>
135 | 		<RFATAL>)
136 | 	       (<AND <EQUAL? ,HERE ,JAIL-CELL>
137 | 		     <FSET? ,HIDDEN-HATCH ,RMUNGBIT>>
138 | 		<SET RM ,LOOKOUT-HILL>
139 | 		<COND (<EQUAL? <LOC ,BOOTS> ,LOOKOUT-HILL ,RIVER-OUTLET>
140 | 		       <SET RM ,ROTARY-WEST>)>
141 | 		<FREE-TO .RM>
142 | 		<RFATAL>)
143 | 	       (T
144 | 		<SETG CHOCOLATE-SCRIPT 2>
145 | 		<STONE-IGNORES "you're not really confined">
146 | 		<RFATAL>)>>		     
147 | 		
148 | <ROUTINE FINGER-OF-LIGHT ()
149 | 	 <TELL 
150 | " wraithlike finger of light jumps out of the Magick Stone! It twists itself into the shape of a " D ,KEY ", unlocks your chains and fades away." CR>
151 | 	 <RTRUE>>
152 | 	       
153 | <ROUTINE FREE-TO (PLACE)
154 | 	 <FSET ,FREEDOM ,TOUCHBIT>
155 | 	 <FSET ,VULTURE ,RMUNGBIT>
156 | 	 <INC SPELLS>
157 | 	 <SETG CHOCOLATE-SCRIPT 1>
158 | 	 <MOVE ,PROTAGONIST .PLACE>
159 | 	 <SETG HERE .PLACE>
160 | 	 <FCLEAR .PLACE ,TOUCHBIT>
161 | 	 <TELL
162 | "The Magick Stone shines brightly as you speak the Wish. You feel a momentary dizziness, then a breath of fresh air...">
163 | 	 <CARRIAGE-RETURNS>
164 | 	 <V-LOOK>
165 | 	 <RTRUE>>
166 | 		
167 | <OBJECT RAIN
168 | 	(LOC GLOBAL-OBJECTS)
169 | 	(DESC "rain")
170 | 	(FLAGS WISHBIT NARTICLEBIT)
171 | 	(SYNONYM RAIN RAINWATER)
172 | 	(ACTION RAIN-F)>
173 | 
174 | <GLOBAL RAIN-ROOM <>>
175 | 
176 | <ROUTINE RAIN-F ("AUX" OBJ NXT)
177 | 	 <COND (<VERB? WISH>
178 | 		<COND (<NOT <IN? ,UMBRELLA ,PROTAGONIST>>
179 | 		       <NOT-SATISFIED>
180 | 		       <RFATAL>)
181 | 		      (<NOT <FSET? ,UMBRELLA ,OPENBIT>>
182 | 		       <BEFORE-YOU-WISH "open" ,UMBRELLA>
183 | 		       <RFATAL>)
184 | 		      (<FSET? ,HERE ,INDOORSBIT>
185 | 		       <STONE-IGNORES "you're not outdoors">
186 | 		       <RFATAL>)>
187 | 		<FSET ,RAIN ,TOUCHBIT>
188 | 		<FSET ,VULTURE ,RMUNGBIT>
189 | 		<INC SPELLS>
190 | 		<SETG RAIN-ROOM ,HERE>
191 | 		<TELL
192 | "A searing bolt of lightning shatters the night! It strikes the glowing Stone of Dreams, and fractures the sky into a billion raindrops.|
193 | |
194 | Everything around you is soaked in a brief but savage downpour.">
195 | 		<COND (<EQUAL? ,HERE ,FOG>
196 | 		       <SETG HERE ,CLIFF-BOTTOM>
197 | 		       <MOVE ,PROTAGONIST ,CLIFF-BOTTOM>
198 | 		       <SETG TLOC <>>
199 | 		       <START-BUZZ 2>
200 | 		       <TELL 
201 | " Your vision clears as the thick fog sinks away.||">
202 | 		       <V-LOOK>
203 | 		       <RTRUE>)
204 | 		      (<EQUAL? ,HERE ,EDGE-OF-LAKE>
205 | 		       <SETG PIT-FULL? T>
206 | 		       <TELL
207 | " A flood of rainwater cascades down Lookout Hill, quickly filling the narrow pit." CR>
208 | 		       <COND (<IN? ,PLATYPUS ,PIT>
209 | 			      <THIS-IS-IT ,PLATYPUS>
210 | 			      <TELL CR 
211 | "The platypus swims gracefully out and shakes herself off.||">
212 | 			      <DRAW-X>)>
213 | 		       <COND (<SET OBJ <FIRST? ,PIT>>
214 | 			      <REPEAT ()
215 | 				 <COND (<ZERO? .OBJ>
216 | 					<RETURN>)>
217 | 				 <SET NXT <NEXT? .OBJ>>
218 | 				 <COND (<NOT <EQUAL? .OBJ ,BRANCH>>
219 | 					<REMOVE .OBJ>)>
220 | 				 <SET OBJ .NXT>>)>
221 | 		       <RTRUE>)>
222 | 		<CRLF>
223 | 		<SET OBJ <REACTOR?>>
224 | 		<COND (<ZERO? .OBJ>
225 | 		       <RTRUE>)>
226 | 		<TELL CR "It's obvious that ">
227 | 		<ARTICLE .OBJ T>
228 | 		<TELL " did not enjoy the sudden bath." CR>
229 | 		<RTRUE>)
230 | 	       (<OR <NOT <FSET? ,RAIN ,TOUCHBIT>>
231 | 		    <NOT <EQUAL? ,HERE ,RAIN-ROOM>>>
232 | 		<TELL "No rain is expected">
233 | 		<COND (<FSET? ,HERE ,INDOORSBIT>
234 | 		       <TELL ", especially indoors." CR>
235 | 		       <RFATAL>)>
236 | 		<TELL " here." CR>
237 | 		<RFATAL>)
238 | 	       (<AND ,PIT-FULL?
239 | 		     <EQUAL? ,HERE ,EDGE-OF-LAKE>>
240 | 		<TELL "The only rain here is in the pit." CR>
241 | 		<RFATAL>)
242 | 	       (T
243 | 		<TELL "Alas. The rain is all gone." CR>
244 | 		<RFATAL>)>>
245 | 		
246 | <OBJECT FORESIGHT
247 | 	(LOC GLOBAL-OBJECTS)
248 | 	(DESC "Foresight")
249 | 	(FLAGS WISHBIT NARTICLEBIT)
250 | 	(SYNONYM FORESIGHT)
251 | 	(ACTION FORESIGHT-F)>
252 | 
253 | <ROUTINE FORESIGHT-F ("AUX" FROM)
254 | 	 <COND (<NOT-WISHING? ,FORESIGHT>
255 | 		<RFATAL>)
256 | 	       (<NOT <IN? ,GLASSES ,PROTAGONIST>>
257 | 		<NOT-SATISFIED>
258 | 		<RFATAL>)
259 | 	       (<NOT <FSET? ,GLASSES ,WORNBIT>>
260 | 		<BEFORE-YOU-WISH "wear" ,GLASSES>
261 | 		<RFATAL>)>
262 | 	 <FSET ,FORESIGHT ,TOUCHBIT>
263 | 	 <FSET ,VULTURE ,RMUNGBIT>
264 | 	 <INC SPELLS>
265 | 	 <TELL "The ">
266 | 	 <COND (,FUZZY?
267 | 	        <TELL <PICK-ONE ,BLURS> " ">)>
268 | 	 <COND (<FSET? ,HERE ,INDOORSBIT>
269 | 		<TELL "room around you">)
270 | 	       (T
271 | 		<TELL "moonlight">)>
272 | 	 <TELL " fades as you speak the Wish.">
273 | 	 <SET FROM ,HERE>
274 | 	 <SETG HERE ,MUSEUM>
275 | 	 <CARRIAGE-RETURNS>
276 | 	 <USL>
277 | 	 <TELL
278 | "A pinprick of brilliance pierces the gloom. It creeps closer, growing more powerful and unearthly as it approaches.|
279 | |
280 | The light is shining from the forehead of a " D ,KITTY
281 | "! It leaps into your arms and curls comfortably around your neck, purring like an old companion.|
282 | |
283 | Suddenly a pair of gnarled hands closes around the " D ,KITTY
284 | " and tears it away from you. The glowing spot on the cat's forehead drops into your open palm as the thief disappears with a cackle into the " D ,DARKNESS
285 | ".|
286 | |
287 | An aged voice in your mind chuckles, ">
288 | 	 <LIAR>
289 | 	 <TELL ".\"">
290 | 	 <CARRIAGE-RETURNS>
291 | 	 <SETG HERE .FROM>
292 | 	 <COND (<ZERO? ,FUZZY>
293 | 		<SET FROM <ANYONE-HERE?>>
294 | 		<COND (<NOT <EQUAL? .FROM <> ,KITTY ,BABY>>
295 | 		     ; <TELL " ">
296 | 		       <COND (<FSET? .FROM ,NARTICLEBIT>
297 | 			      <TELL "The ">)>
298 | 		       <STRANGE-LOOK .FROM>
299 | 		       <CRLF>)>)>
300 | 	 <RFATAL>>
301 | 	       
302 | <ROUTINE LIAR ()
303 | 	 <TELL "\"Now you know me for the old liar I am">
304 | 	 <RTRUE>>
305 | 
306 | <ROUTINE STRANGE-LOOK (WHO)
307 | 	 <TELL D .WHO " gives you a strange look." CR>
308 | 	 <RTRUE>>
309 | 
310 | <OBJECT LUCK
311 | 	(LOC GLOBAL-OBJECTS)
312 | 	(DESC "Luck")
313 | 	(FLAGS WISHBIT NARTICLEBIT)
314 | 	(SYNONYM LUCK)
315 | 	(ACTION LUCK-F)>
316 | 
317 | <GLOBAL LUCKY? <>>
318 | 
319 | <ROUTINE LUCK-F ()
320 | 	 <COND (<NOT-WISHING? ,LUCK>
321 | 		<RFATAL>)
322 | 	       (<NOT <IN? ,SHOE ,PROTAGONIST>>
323 | 		<NOT-SATISFIED>
324 | 		<RFATAL>)>
325 | 	 <FSET ,LUCK ,TOUCHBIT>
326 | 	 <FSET ,VULTURE ,RMUNGBIT>
327 | 	 <INC SPELLS>
328 | 	 <SETG LUCKY? T>
329 | 	 <FSET ,SHOE ,ONBIT>
330 | 	 <ENABLE <QUEUE I-LUCK -1>>
331 | 	 <THIS-IS-IT ,SHOE>
332 | 	 <TELL
333 | "The Stone of Dreams brightens as you speak the Wish, and the edges of the "
334 | D ,SHOE " begin to twinkle with Luck." CR>
335 | 	 <COND (<EQUAL? ,HERE ,FOG>
336 | 		<SETG TLOC <>>
337 | 		<SETG HERE ,CLIFF-BOTTOM>
338 | 		<MOVE ,PROTAGONIST ,CLIFF-BOTTOM>
339 | 		<WALK-OUT-OF-FOG>
340 | 		<V-LOOK>)>
341 | 	 <RFATAL>>
342 | 	       
343 | <ROUTINE BAD-LUCK (STR)
344 | 	 <TELL CR "(It's bad luck to " .STR ".">
345 | 	 <COND (<ENABLED? ,I-LUCK>
346 | 		<DISABLE <INT I-LUCK>>
347 | 		<TELL " You've neutralized the Luck Wish!)" CR>
348 | 		<I-LUCK T>
349 | 		<RTRUE>)>
350 | 	 <TELL ")" CR>
351 | 	 <RTRUE>>
352 | 
353 | <OBJECT ADVICE
354 | 	(LOC GLOBAL-OBJECTS)
355 | 	(DESC "Advice")
356 | 	(FLAGS WISHBIT NARTICLEBIT)
357 | 	(SYNONYM ADVICE)
358 | 	(ACTION ADVICE-F)>
359 | 
360 | <ROUTINE ADVICE-F ()
361 | 	 <COND (<NOT-WISHING? ,ADVICE>
362 | 		<RFATAL>)
363 | 	       (<NOT <IN? ,CONCH-SHELL, PROTAGONIST>>
364 | 		<NOT-SATISFIED>
365 | 		<RFATAL>)>
366 | 	 <FSET ,ADVICE ,TOUCHBIT>
367 | 	 <FSET ,VULTURE ,RMUNGBIT>
368 | 	 <INC SPELLS>
369 | 	 <ENABLE <QUEUE I-SHELL-TALK -1>>
370 | 	 <TELL ,GAME " emits a violet flash of Magick." CR>
371 | 	 <RFATAL>>
372 | 
373 | <OBJECT DARKNESS
374 | 	(LOC GLOBAL-OBJECTS)
375 | 	(DESC "darkness")
376 | 	(FLAGS WISHBIT NARTICLEBIT)
377 | 	(SYNONYM DARKNESS DARK)
378 | 	(ACTION DARKNESS-F)>
379 | 
380 | <GLOBAL DARK-PLACE <>>
381 | <GLOBAL ECLIPSE? <>>
382 | 
383 | <ROUTINE DARKNESS-F ("AUX" (INDOORS? <>) WHO)
384 | 	 <COND (<VERB? WISH>
385 | 		<COND (<AND <IN? ,BOTTLE ,PROTAGONIST>
386 | 			    <IN? ,MILK ,BOTTLE>>
387 | 		       <BEFORE-YOU-WISH "drink" ,MILK>
388 | 		       <RFATAL>)
389 | 		      (<ZERO? ,MILK-SCRIPT>
390 | 		       <NOT-SATISFIED T>
391 | 		       <RFATAL>)
392 | 		      (<NOT <FSET? ,HERE ,ONBIT>>
393 | 		       <STONE-IGNORES "dim enough in here already">
394 | 		       <RFATAL>)>
395 | 		<FSET ,DARKNESS ,TOUCHBIT>
396 | 		<FSET ,VULTURE ,RMUNGBIT>
397 | 		<INC SPELLS>
398 | 		<SETG DARK-PLACE ,HERE>
399 | 		<SETG MILK-SCRIPT 1>
400 | 		<ENABLE <QUEUE I-ECLIPSE 2>>
401 | 		<FCLEAR ,WISHBRINGER ,ONBIT>
402 | 		<FCLEAR ,SHOE ,ONBIT>
403 | 		<SETG ECLIPSE? T>
404 | 		<SETG MOVIE-STATUS ,NO-MOVIE?>
405 | 		<SETG NO-MOVIE? T>
406 | 		<COND (<FSET? ,HERE ,INDOORSBIT>
407 | 		       <SET INDOORS? T>)>
408 | 		<SET WHO <REACTOR?>>
409 | 		<TELL "The ">
410 | 		<COND (.INDOORS?
411 | 		       <TELL "air">)
412 | 		      (T
413 | 		       <TELL "night">)>
414 | 		<TELL " becomes very still as you speak the Wish. ">
415 | 		<COND (<EQUAL? .WHO ,HELLHOUND ,PELICAN>
416 | 		       <SAY-THE .WHO>
417 | 		       <COND (<EQUAL? .WHO ,HELLHOUND>
418 | 			      <TELL " stops ">
419 | 			      <COND (,HELLHOUND-HAPPY?
420 | 				     <TELL "thumping its tail,">)
421 | 				    (T
422 | 				     <TELL "in mid-roar,">)>)>
423 | 		       <TELL " cocks its head and sniffs the air nervously.">)
424 | 		      (<EQUAL? .WHO ,TROLL ,GRAVEDIGGER>
425 | 		       <SAY-THE .WHO>
426 | 		       <FROWNS>)
427 | 		      (<EQUAL? .WHO ,MACGUFFIN ,CRISP ,KING>
428 | 		       <TELL D .WHO>
429 | 		       <FROWNS>)
430 | 		      (<EQUAL? .WHO ,MISS-VOSS ,PRINCESS ,EVIL-ONE>
431 | 		       <TELL D .WHO>
432 | 		       <FROWNS T>)
433 | 		      (.WHO
434 | 		       <TELL "You notice ">
435 | 		       <ARTICLE .WHO T>
436 | 		       <TELL " looking">
437 | 		       <NERVOUSLY>)>
438 | 		<TELL
439 | "||All at once a terrifying shadow sweeps across the ">
440 | 		<COND (.INDOORS?
441 | 		       <TELL "surface of " ,GAME>)
442 | 		      (T
443 | 		       <TELL "face of the full moon">)>
444 | 		<COND (<FSET? ,CANDLE ,ONBIT>
445 | 		       <FCLEAR ,CANDLE ,ONBIT>
446 | 		       <COND (<VISIBLE? ,CANDLE>
447 | 			      <TELL ". The candle flame withers and dies">)>)>
448 | 		<TELL ", plunging the ">
449 | 		<COND (.INDOORS?
450 | 		       <TELL "room">)
451 | 		      (T
452 | 		       <TELL "landscape">)>
453 | 		<TELL " into total darkness.">
454 | 		<COND (<EQUAL? .WHO ,HELLHOUND>
455 | 		       <TELL CR CR>
456 | 		       <SAY-THE ,HELLHOUND>
457 | 		       <TELL 
458 | "'s eyes grow wide with terror. It flops itself down on the ground, covers its eyes with its forepaws and moans pitifully">
459 | 		       <IN-GLOOM>)
460 | 		      (<EQUAL? .WHO ,TROLL>
461 | 		       <CRLF>
462 | 		       <FRIGHTEN-TROLL>)
463 | 		      (<EQUAL? .WHO ,GRAVEDIGGER>
464 | 		       <TELL "|
465 | |
466 | \"Who turned out the lights?!\" cries the " D ,GRAVEDIGGER
467 | ", stumbling around the pitch-black lobby in terror." CR>)
468 | 		      (.WHO
469 | 		       <TELL CR CR ,YOU-HEAR>
470 | 		       <ARTICLE .WHO T>
471 | 		       <TELL "making fearful noises">
472 | 		       <IN-GLOOM>)
473 | 		      (T
474 | 		       <CRLF>)>
475 | 		<SETG LIT <LIT? ,HERE>>
476 | 		<RTRUE>)
477 | 	       (<AND <EQUAL? ,PRSO ,DARKNESS>
478 | 		     <SEE-VERB?>>
479 | 		<YOU-CANT-SEE>
480 | 		<TELL "anything in darkness!" CR>
481 | 		<RFATAL>)
482 | 	       (<OR <EQUAL? ,PRSA ,V?LISTEN ,V?YELL>
483 | 		    <TALKING-TO? ,DARKNESS>>
484 | 		<TELL "You hear nothing." CR>
485 | 		<RFATAL>)
486 | 	       (<NOT-WISHING? ,DARKNESS>
487 | 		<RFATAL>)
488 | 	       (T
489 | 		<RFALSE>)>>
490 | 		
491 | <ROUTINE IN-GLOOM ()
492 | 	 <TELL " in the sudden gloom." CR>
493 | 	 <RTRUE>>
494 | 
495 | <ROUTINE NERVOUSLY ()
496 | 	 <TELL " around nervously.">
497 | 	 <RTRUE>>
498 | 
499 | <ROUTINE FROWNS ("OPT" (FEMALE? <>))
500 | 	 <TELL " frowns, blinks ">
501 | 	 <COND (.FEMALE?
502 | 		<TELL "her">)
503 | 	       (T
504 | 		<TELL "his">)>
505 | 	 <TELL " eyes and looks">
506 | 	 <NERVOUSLY>
507 | 	 <RTRUE>>
508 | 
509 | <ROUTINE REACTOR? ("AUX" WHO)
510 | 	 <COND (<AND <EQUAL? ,HERE ,EDGE-OF-LAKE>
511 | 		     <IN? ,PLATYPUS ,PIT>>
512 | 		<RETURN ,PLATYPUS>)
513 | 	       (<EQUAL? ,HERE ,THRONE-ROOM>
514 | 		<RETURN ,CROWD>)>
515 | 	 <SET WHO <ANYONE-HERE?>>
516 | 	 <COND (<EQUAL? .WHO <> ,BABY>
517 | 		<RFALSE>)
518 | 	       (<AND <EQUAL? .WHO ,KITTY>
519 | 		     <FSET? ,KITTY ,RMUNGBIT>>
520 | 		<RFALSE>)>
521 | 	 <RETURN .WHO>>
522 | 	       
523 | <ROUTINE I-ECLIPSE ("AUX" WHO)
524 | 	 <COND (,LUCKY?
525 | 		<FSET ,SHOE ,ONBIT>)>
526 | 	 <DISABLE <INT I-ECLIPSE>>
527 | 	 <SETG ECLIPSE? <>>
528 | 	 <SETG NO-MOVIE? ,MOVIE-STATUS>
529 | 	 <FSET ,VULTURE ,RMUNGBIT>
530 | 	 <FSET ,WISHBRINGER ,ONBIT>
531 | 	 <TELL CR "As suddenly as it faded, the light ">
532 | 	 <COND (<FSET? ,HERE ,INDOORSBIT>
533 | 		<COND (<VISIBLE? ,WISHBRINGER>
534 | 		       <TELL "from " ,GAME>)
535 | 		      (T
536 | 		       <TELL "around you">)>)
537 | 	       (T
538 | 		<TELL "of the moon">)>
539 | 	 <TELL " returns">
540 | 	 <COND (<AND <NOT <FSET? ,CANDLE ,RMUNGBIT>>
541 | 		     <NOT <FSET? ,CANDLE ,ONBIT>>>
542 | 		<FSET ,CANDLE ,ONBIT>
543 | 		<COND (<VISIBLE? ,CANDLE>
544 | 		       <TELL ", and the candle flares back to life">)>)>
545 | 	 <TELL ".">
546 | 	 <SET WHO <REACTOR?>>
547 | 	 <COND (<EQUAL? .WHO ,HELLHOUND>
548 | 		<SETG DOG-SCRIPT 0>
549 | 		<TELL CR CR>
550 | 		<SAY-THE ,HELLHOUND>
551 | 		<TELL
552 | " recovers from its embarrassing fear of darkness, and ">
553 | 		<COND (,HELLHOUND-HAPPY?
554 | 		       <TELL "thumps its tail">)
555 | 		      (T
556 | 		       <TELL "snarls at you">)>
557 | 		<TELL " with renewed enthusiasm.">)
558 | 	       (.WHO
559 | 		<TELL "||With a ">
560 | 		<COND (<EQUAL? .WHO ,CROWD ,HUMANOIDS>
561 | 		       <TELL "collective ">)>
562 | 		<TELL "sigh of relief, ">
563 | 		<ARTICLE .WHO T>
564 | 		<TELL D .WHO " turn">
565 | 		<COND (<NOT <EQUAL? .WHO ,HUMANOIDS ,BOOTS>>
566 | 		       <TELL "s">)>
567 | 		<TELL " to look at you.">)>
568 | 	 <CRLF>
569 | 	 <SETG LIT <LIT? ,HERE>>
570 | 	 <COND (<NOT <EQUAL? ,HERE ,DARK-PLACE>>
571 | 		<CRLF>
572 | 		<V-LOOK>)>
573 | 	 <SETG DARK-PLACE <>>
574 | 	 <RTRUE>>
575 | 
576 | <OBJECT MOON
577 | 	(LOC GLOBAL-OBJECTS)
578 | 	(DESC "moon")
579 | 	(FLAGS NDESCBIT)
580 | 	(SYNONYM MOON)
581 | 	(ACTION MOON-F)>
582 | 
583 | <ROUTINE MOON-F ()
584 | 	 <COND (<OR <ZERO? ,SKEWED?>
585 | 		    <FSET? ,HERE ,INDOORSBIT>>
586 | 		<YOU-CANT-SEE>
587 | 		<TELL "the moon right now." CR>
588 | 		<RFATAL>)
589 | 	       (<VERB? LOOK-ON EXAMINE>
590 | 		<SAY-THE ,MOON>
591 | 		<COND (,ECLIPSE?
592 | 		       <TELL " has disappeared!" CR>
593 | 		       <RFATAL>)>
594 | 		<TELL "'s cold light makes you shiver." CR>
595 | 		<RTRUE>)
596 | 	       (T
597 | 		<YOU-DONT-NEED ,MOON>
598 | 		<RFATAL>)>>
599 | 
600 | 


--------------------------------------------------------------------------------
/boxes.zil:
--------------------------------------------------------------------------------
  1 | "BOXES for WISHBRINGER: (C)1985 Infocom, Inc. All rights reserved."
  2 | 
  3 | "*** BAD MAILBOX ***"
  4 | 
  5 | <GLOBAL BOX-SEEN? <>>
  6 | <GLOBAL BOX-DANGEROUS? <>>
  7 | 
  8 | <OBJECT MAILBOX
  9 | 	(IN PLEASURE-WHARF)
 10 | 	(DESC "big mailbox")
 11 | 	(SYNONYM MAILBOX BOX LID)
 12 | 	(ADJECTIVE MAIL BIG LARGE)
 13 | 	(FLAGS CONTBIT)
 14 | 	(ACTION MAILBOX-F)
 15 | 	(DESCFCN DESCRIBE-MAILBOX)
 16 | 	(CAPACITY 15)
 17 | 	(CONTFCN IN-MAILBOX)>
 18 | 
 19 | <ROUTINE IN-MAILBOX (CONTEXT)
 20 | 	 <COND (<AND <EQUAL? .CONTEXT ,M-CONT>
 21 | 		     <TOUCHING? ,PRSO>>
 22 | 		<TELL ,CANT " reach into the " D ,MAILBOX "." CR>
 23 | 		<RFATAL>)
 24 | 	       (T
 25 | 		<RFALSE>)>>
 26 | 
 27 | <ROUTINE DESCRIBE-MAILBOX (CONTEXT)
 28 | 	 <COND (<EQUAL? .CONTEXT ,M-OBJDESC>
 29 | 		<TELL "A big">
 30 | 		<COND (,BOX-DANGEROUS?
 31 | 		       <TELL ", hungry">)>
 32 | 		<TELL " mailbox is ">
 33 | 		<COND (,BOX-DANGEROUS?
 34 | 		       <TELL "threatening you ">)>
 35 | 		<TELL "nearby.">)>>
 36 | 
 37 | <ROUTINE BY-ITSELF ()
 38 | 	 <SAY-THE ,MAILBOX>
 39 | 	 <TELL " is opening and closing all by itself!" CR>>
 40 | 
 41 | <ROUTINE MAILBOX-F ()
 42 | 	 <THIS-IS-IT ,MAILBOX>
 43 | 	 <COND (<VERB? EXAMINE>
 44 | 		<COND (,BOX-DANGEROUS?
 45 |  		       <BY-ITSELF>)
 46 | 		      (T
 47 |                        <SAY-THE ,MAILBOX>
 48 | 		       <TELL " seems ordinary enough.">
 49 | 		       <COND (,SKEWED?
 50 | 			      <TELL " Or does it?">)>
 51 | 		       <CRLF>)>
 52 | 		<RTRUE>)
 53 | 	       (<VERB? OPEN>
 54 | 		<COND (,BOX-DANGEROUS?
 55 | 		       <BY-ITSELF>)
 56 | 		      (<FSET? ,MAILBOX ,OPENBIT>
 57 | 		       <ALREADY-OPEN>)
 58 | 		      (,SKEWED?
 59 | 		       <TELL "It immediately snaps shut. Bang!" CR>
 60 | 		       <RFATAL>)
 61 | 		      (T
 62 | 		       <ENABLE <QUEUE I-BOX-LID 2>>
 63 | 		     ; <FSET ,MAILBOX ,OPENBIT>
 64 | 		     ; <OPENED>
 65 | 		     ; <CRLF>
 66 | 		       <NOW-CLOSED-OR-OPEN ,MAILBOX T>)>
 67 | 		<RTRUE>)
 68 | 	       (<VERB? CLOSE>
 69 | 		<COND (,BOX-DANGEROUS?
 70 | 		       <BY-ITSELF>)
 71 | 		      (<NOT <FSET? ,MAILBOX ,OPENBIT>>
 72 | 		       <ALREADY-CLOSED>)
 73 | 		      (T
 74 | 		       <DISABLE <INT I-BOX-LID>>
 75 | 		     ; <FCLEAR ,MAILBOX ,OPENBIT>
 76 | 		     ; <TELL "Closed." CR>
 77 | 		       <NOW-CLOSED-OR-OPEN ,MAILBOX>)>
 78 | 		<RTRUE>)
 79 | 	       (<HURT? ,MAILBOX>
 80 | 		<COND (,BOX-DANGEROUS?
 81 | 		       <BOX-MOOD>)
 82 | 		      (T
 83 | 		       <TELL "You shouldn't">
 84 | 		       <DO-TO>
 85 | 		       <TELL "government property." CR>)>
 86 | 	        <RTRUE>)
 87 | 	       (<AND <VERB? LOOK-INSIDE LOOK-DOWN REACH-IN>
 88 | 		      ,BOX-DANGEROUS?>
 89 | 		<BOX-MOOD>
 90 | 		<RTRUE>)
 91 | 	       (<AND <VERB? GIVE PUT FEED THROW>
 92 | 		     <EQUAL? ,PRSI ,MAILBOX>>
 93 | 		<COND (<EQUAL? ,PRSO ,LEAFLET>
 94 | 		       <COND (<ENABLED? ,I-WAKE-BOX>
 95 | 			      <DISABLE <INT I-WAKE-BOX>>)
 96 | 			     (T
 97 | 			      <DISABLE <INT I-BAD-BOX>>)>
 98 | 		       <MOVE ,LEAFLET ,MAILBOX>		       
 99 | 		       <TELL "Done." CR>
100 | 		       <COND (,BOX-DANGEROUS?
101 | 			      <SETG BOX-DANGEROUS? <>>
102 | 			      <MOVE ,MAILBOX ,STEEP-TRAIL>      
103 | 			      <CRLF>
104 | 			      <SAY-THE ,MAILBOX>
105 | 			      <TELL " gobbles the " D ,LEAFLET 
106 | " down, smacks its lid and belches. \"Mmmm! Good!\"|
107 | |
108 | The satisfied box scrapes slowly out of sight." CR>)>
109 | 		       <RTRUE>)
110 | 		      (<NOT ,BOX-DANGEROUS?>
111 | 		       <RFALSE>)
112 | 		      (<EQUAL? ,PRSO ,VIOLET-NOTE>
113 | 		       <BOX-SPITS "STAMPED">
114 | 		       <RTRUE>)
115 | 		      (T
116 | 		       <BOX-SPITS "MAIL">
117 | 		       <RTRUE>)>) 
118 | 	       (T
119 | 		<RFALSE>)>>
120 | 
121 | <ROUTINE BOX-MOOD ()
122 | 	 <TELL "Better not. ">
123 | 	 <SAY-THE ,MAILBOX>
124 | 	 <TELL " isn't in a very good mood." CR>>
125 | 
126 | <ROUTINE BOX-SPITS (STR)
127 | 	 <MOVE ,PRSO ,HERE>
128 | 	 <SAY-THE ,MAILBOX>
129 | 	 <TELL " spits out ">
130 | 	 <ARTICLE ,PRSO T>
131 | 	 <TELL D ,PRSO " on the " D ,GROUND ". \"Not " .STR "!\"" CR>>
132 | 
133 | <ROUTINE I-BOX-LID ()
134 | 	 <COND (<IN? ,MAILBOX ,HERE>
135 | 		<TELL CR "The ">
136 | 		<BIG-LID>
137 | 		<TELL "squeaks and">
138 | 		<BANGS>)>
139 |        ; <DISABLE <INT I-BOX-LID>>
140 | 	 <FCLEAR ,MAILBOX ,OPENBIT>>
141 | 
142 | <ROUTINE BIG-LID ()
143 | 	 <TELL "lid of the " D ,MAILBOX " ">>
144 | 
145 | <ROUTINE BANGS ()
146 | 	 <TELL " snaps shut with a clang." CR>>
147 | 
148 | <GLOBAL BOX-YELLS
149 | 	<LTABLE 0  
150 | 	 "Feed me"
151 | 	 "I'm hungry"
152 | 	 "I want MAIL"
153 | 	 "Feed me. I'm HUNGRY"
154 | 	 "Mail"
155 | 	 "Hungry"
156 | 	 "Eat">>
157 | 
158 | <ROUTINE HUNGRY ()
159 | 	 <TELL "\"" <PICK-ONE ,BOX-YELLS> "!\"">>
160 | 
161 | <GLOBAL BOX-SCRIPT 0>
162 | 		       
163 | <ROUTINE I-WAKE-BOX ()
164 | 	 <COND (<OR ,FUZZY? ,ECLIPSE?>
165 | 		<RTRUE>)
166 | 	       (<EQUAL? ,HERE ,PLEASURE-WHARF>
167 | 	        <SETG BOX-SCRIPT <+ ,BOX-SCRIPT 1>>
168 | 		<THIS-IS-IT ,MAILBOX>
169 | 		<CRLF>
170 | 		<COND (<EQUAL? ,BOX-SCRIPT 1>
171 | 		       <TELL "A voice behind you growls, ">
172 | 		       <HUNGRY>
173 | 		       <TELL 
174 | " You turn to face the sound, but there's nobody here except you." CR>)
175 | 		      
176 | 		      (<EQUAL? ,BOX-SCRIPT 2>
177 | 		       <TELL "You watch with astonishment as the ">
178 | 		       <BIG-LID>
179 | 		       <TELL
180 | "slowly opens by itself, then">
181 | 		       <BANGS>)
182 | 		      
183 | 		      (<EQUAL? ,BOX-SCRIPT 3>
184 | 		       <SETG BOX-DANGEROUS? T>
185 | 		       <TELL "The ">
186 | 		       <BIG-LID>
187 | 		       <TELL "opens again. ">
188 | 		       <HUNGRY>
189 | 		       <CRLF>)
190 | 		      
191 | 		      (<EQUAL? ,BOX-SCRIPT 4>
192 | 		       <DISABLE <INT I-WAKE-BOX>>
193 | 		       <ENABLE <QUEUE I-BAD-BOX -1>>
194 | 		       <SAY-THE ,MAILBOX>
195 | 		       <TELL
196 | " begins to clatter like a rusty machine. Your astonishment turns to horror as the mindless thing begins to MOVE! Slowly at first, but with increasing confidence, it scrapes across the planks of the "
197 | D ,PLEASURE-WHARF ", heading straight in your direction!" CR CR "The ">
198 | 		       <BIG-LID>
199 | 		       <TELL "snaps open with a menacing clang. ">
200 | 		       <HUNGRY>
201 | 		       <CRLF>)>)>>
202 | 
203 | <GLOBAL BOX-COMING 0>
204 | <GLOBAL EAT-SCRIPT 0>
205 | <GLOBAL PREVIOUS-LOC <>>
206 | 
207 | <ROUTINE NO-MAILBOX-ALLOWED? ()
208 | 	 <COND (<OR <EQUAL? ,HERE ,WHARF ,PLEASURE-WHARF ,FESTERON-POINT>
209 | 		    <EQUAL? ,HERE ,ROTARY-NORTH ,ROTARY-SOUTH ,ROTARY-EAST>
210 | 		    <EQUAL? ,HERE ,ROTARY-WEST ,EDGE-OF-LAKE ,RIVER-OUTLET>
211 | 		    <EQUAL? ,HERE ,PARK ,LOOKOUT-HILL ,SOUTH-OF-BRIDGE>
212 | 		    <EQUAL? ,HERE ,WEST-OF-HOUSE ,ROCKY-PATH>>
213 | 		<RFALSE>)
214 | 	       (T
215 | 		<RTRUE>)>>
216 | 
217 | ; <ROUTINE NO-MAILBOX-ALLOWED? ("AUX" TEMP)
218 | 	 <SET TEMP <GET ,BOXES-ALLOWED 0>>
219 | 	 <REPEAT ()
220 | 		 <COND (<EQUAL? ,HERE <GET ,BOXES-ALLOWED .TEMP>>
221 | 			<RFALSE>)
222 | 		       (<ZERO? .TEMP>
223 | 			<RTRUE>)
224 | 		       (T
225 | 			<SET TEMP <- .TEMP 1>>)>>>
226 | 
227 | ; <GLOBAL BOXES-ALLOWED
228 | 	<PLTABLE
229 | 	 WHARF PLEASURE-WHARF PARK ROTARY-NORTH ROTARY-SOUTH ROTARY-EAST
230 | 	 ROTARY-WEST EDGE-OF-LAKE RIVER-OUTLET LOOKOUT-HILL SOUTH-OF-BRIDGE
231 | 	 WEST-OF-HOUSE FESTERON-POINT>>
232 | 
233 | <ROUTINE I-BAD-BOX ("AUX" TEMP)
234 | 	 <COND (<OR ,FUZZY? ,ECLIPSE?>
235 | 		<RTRUE>)
236 | 	       (<IN? ,MAILBOX ,HERE>
237 | 		<SETG BOX-COMING 0>
238 | 		<SETG EAT-SCRIPT <+ ,EAT-SCRIPT 1>>
239 | 		<COND (<FIGHT? ,SMALL-BOX>
240 | 		       <RTRUE>)
241 | 		      (<EQUAL? ,EAT-SCRIPT 1>
242 | 		       <SAY-BOX-CLOSER ,BOX-CLOSERS>)
243 | 		      (<EQUAL? ,EAT-SCRIPT 2>
244 | 		       <SAY-BOX-CLOSER ,BOX-EVEN-CLOSERS>)
245 | 		      (T
246 | 		       <SETG EAT-SCRIPT 0>
247 | 		       <SET TEMP <FIRST? ,PROTAGONIST>>
248 | 		       <COND (.TEMP
249 | 			      <FCLEAR .TEMP ,WORNBIT>
250 | 			      <MOVE .TEMP ,FOSSIL>
251 | 			      <CRLF>
252 | 			      <SAY-THE ,MAILBOX>
253 | 			      <TELL " " <PICK-ONE ,SWIPES> " ">
254 | 			      <ARTICLE .TEMP T>
255 | 			      <TELL D .TEMP " away from you and swallows it! ">
256 | 			      <COND (<PROB 50>
257 | 			             <HUNGRY>)>
258 | 			      <CRLF>
259 | 			      <COND (<EQUAL? .TEMP ,WISHBRINGER ,SHOE>
260 | 				     <I-LUCK>
261 | 				     <I-GLOW>)>)
262 | 			     (T
263 | 			      <HUNGRY> <CRLF> <CRLF>
264 | 			      <TELL
265 | "With a triumphant roar, the " D ,MAILBOX " trips your feet and sends you sprawling to the " D ,GROUND ". Its snapping lid closes in, and you are Sent.">
266 | 			      <BAD-ENDING>)>)>)
267 | 	       (T
268 | 		<SETG EAT-SCRIPT 0>
269 | 		<COND (<EQUAL? ,HERE ,WEST-OF-HOUSE>
270 | 		       <RTRUE>)
271 | 		      (<NO-MAILBOX-ALLOWED?>
272 | 		       <RTRUE>)>
273 | 		<COND (<NOT <EQUAL? ,HERE ,PREVIOUS-LOC>>
274 | 		       <SETG PREVIOUS-LOC ,HERE>
275 | 		       <SETG BOX-COMING 0>)>
276 | 		<SETG BOX-COMING <+ ,BOX-COMING 1>>
277 | 		<COND ; (<EQUAL? ,BOX-COMING 1>
278 | 		         <RTRUE>)
279 | 		      (<EQUAL? ,BOX-COMING 2>
280 | 		       <TELL CR <PICK-ONE ,BAD-BOX-COMINGS> CR>)
281 | 		      (T
282 | 		       <MOVE ,MAILBOX ,HERE>
283 | 		       <SAY-BOX-CLOSER ,BAD-BOX-ARRIVALS T>
284 | 		       <FIGHT? ,SMALL-BOX>)>)>>
285 | 
286 | <ROUTINE SAY-BOX-CLOSER (LIST "OPTIONAL" (HUNGRY? <>))
287 | 	 <CRLF>
288 | 	 <SAY-THE ,MAILBOX>
289 | 	 <TELL <PICK-ONE .LIST> ".">
290 | 	 <COND (<OR .HUNGRY?
291 | 		    <PROB 50>>
292 | 		<TELL " ">
293 | 		<HUNGRY>)>
294 | 	 <CRLF>>
295 | 
296 | <GLOBAL BOX-CLOSERS
297 | 	<LTABLE 0
298 | 	 " is getting closer"
299 | 	 " shouts \"MAIL!\" as it edges closer"
300 | 	 "'s lid snaps open and shut with hunger">>
301 | 
302 | <GLOBAL BOX-EVEN-CLOSERS
303 | 	<LTABLE 0
304 | 	 " cries, \"Feed me MAIL!\" It's getting very close"
305 | 	 " is almost close enough to touch you"
306 | 	 " scrapes even closer and snaps its lid">>
307 | 
308 | <GLOBAL BAD-BOX-COMINGS
309 | 	<LTABLE 0 
310 | "You hear a scraping noise nearby. It's getting closer!"
311 | "Something is scraping across the ground nearby. It's coming this way!"
312 | "A distant scraping noise is getting louder.">>
313 | 
314 | <GLOBAL BAD-BOX-ARRIVALS
315 | 	<LTABLE 0 
316 |          " has found you again"
317 |          " scrapes into view"
318 |          " appears nearby">>  
319 | 
320 | "*** SMALL MAILBOX ***"
321 | 
322 | <OBJECT SMALL-BOX
323 | 	(IN INSIDE-POST-OFFICE)
324 | 	(DESC "little mailbox")
325 | 	(SYNONYM MAILBOX BOX BOXES LID)
326 | 	(ADJECTIVE MAIL SMALL LITTLE PRIVATE)
327 | 	(FLAGS CONTBIT NDESCBIT)
328 | 	(CAPACITY 10)
329 | 	(ACTION SMALL-BOX-F)>
330 | 
331 | <ROUTINE SMALL-BOX-F ()
332 | 	 <THIS-IS-IT ,SMALL-BOX>
333 | 	 <COND (<EQUAL? ,HERE ,INSIDE-POST-OFFICE>
334 | 		<COND (<PRIVATE-BOXES?>
335 | 		       <RTRUE>)
336 | 		      (T
337 | 		       <RFALSE>)>)
338 | 	       (<AND <VERB? OPEN>
339 | 		     <NOT ,HOUSE-VISITED?>>
340 | 		<SETG HOUSE-VISITED? T>
341 | 		<ENABLE <QUEUE I-WAKE-SMALL-BOX -1>>
342 | 		<RFALSE>)
343 | 	       (<VERB? EXAMINE>
344 | 		<COND (<OR ,BOX-ALIVE?
345 | 			   <ENABLED? ,I-WAKE-SMALL-BOX>>
346 | 		       <TELL "It's the strangest " D ,SMALL-BOX
347 | 		             " you've ever seen." CR>
348 | 		       <RTRUE>)
349 | 		      (T
350 | 		       <RFALSE>)>)
351 | 	       (<AND <VERB? RUB>
352 | 		     ,BOX-ALIVE?>
353 | 		<SAY-THE ,SMALL-BOX>
354 | 		<COOS-AT "your touch">
355 | 		<RTRUE>)
356 | 	       (<AND <TALKING-TO? ,SMALL-BOX>
357 | 		     ,BOX-ALIVE?>
358 | 		<SAY-THE ,SMALL-BOX>
359 | 		<TELL " doesn't reply, but">
360 | 		<COOS-AT "the sound of your voice">
361 | 		<RFATAL>)
362 | 	       (T
363 | 		<RFALSE>)>>
364 | 	 
365 | <ROUTINE COOS-AT (STR)
366 | 	 <TELL " coos with pleasure at " .STR "." CR>>
367 | 
368 | <GLOBAL SMALL-SCRIPT 0>
369 | <GLOBAL BOX-ALIVE? <>>
370 | 
371 | <ROUTINE I-WAKE-SMALL-BOX ()
372 | 	 <COND (<OR ,FUZZY? ,ECLIPSE?>
373 | 		<RTRUE>)
374 | 	       (<EQUAL? ,HERE ,WEST-OF-HOUSE>
375 | 		<SETG SMALL-SCRIPT <+ ,SMALL-SCRIPT 1>>
376 | 		<CRLF>
377 | 		<COND (<EQUAL? ,SMALL-SCRIPT 1>
378 | 		       <TELL 
379 | "The edges of the " D ,SMALL-BOX " are beginning to twinkle.">)
380 | 		      (<EQUAL? ,SMALL-SCRIPT 2>
381 | 		       <SAY-THE ,SMALL-BOX>
382 | 		       <TELL
383 | " is engulfed in a sparkling aurora! Tremors of anticipation run up and down its length, and the air sings with Magick.">)
384 | 		      (<EQUAL? ,SMALL-SCRIPT 3>
385 | 		       <SETG BOX-ALIVE? T>
386 | 		       <TELL
387 | "With a gentle pop, the " D ,SMALL-BOX " pulls itself out of the " D ,GROUND
388 | " and cavorts about the grass like a happy rabbit!">)
389 | 		      (T
390 | 		       <DISABLE <INT I-WAKE-SMALL-BOX>>
391 | 		       <ENABLE <QUEUE I-FRIENDLY-BOX -1>>
392 | 	               <SAY-THE ,SMALL-BOX>
393 | 		       <TELL
394 | " notices you and snaps its tiny lid with joy. It makes a silly">
395 | 		       <CLUMP>
396 | 		       <TELL "as it">
397 | 		       <HOPS-TO-SIDE>)>
398 | 		<CRLF>)
399 | 	     ; (T
400 | 		<DISABLE <INT I-WAKE-SMALL-BOX>>
401 | 		<ENABLE <QUEUE I-FRIENDLY-BOX -1>>)>>
402 | 
403 | <ROUTINE CLUMP ()
404 | 	 <TELL " \"clump-clump, clump-clump\" sound ">>
405 | 
406 | <ROUTINE HOPS-TO-SIDE ()
407 | 	 <TELL " hops to your side and rubs lovingly against your sleeve.">>
408 | 
409 | <GLOBAL SMALL-BOX-COMING 0>
410 | <GLOBAL PREVIOUS-SMALL-LOC <>>
411 | 
412 | <ROUTINE I-FRIENDLY-BOX ("AUX" TEMP)
413 | 	 <COND (<OR ,FUZZY? ,ECLIPSE?>
414 | 		<RTRUE>)
415 | 	       (<IN? ,SMALL-BOX ,HERE>
416 | 		<SETG SMALL-BOX-COMING 0>
417 | 		<COND (<FIGHT? ,MAILBOX>
418 | 		       <RTRUE>)
419 | 		      (<PROB 50>
420 | 		       <CRLF>
421 | 		       <SAY-THE ,SMALL-BOX>
422 | 		       <TELL " " <PICK-ONE ,CUDDLES> "." CR>)>)
423 | 	       (T
424 | 		<COND (<NO-MAILBOX-ALLOWED?>
425 | 		       <RTRUE>)>
426 | 		<COND (<NOT <EQUAL? ,HERE ,PREVIOUS-SMALL-LOC>>
427 | 		       <SETG PREVIOUS-SMALL-LOC ,HERE>
428 | 		       <SETG SMALL-BOX-COMING 0>)>
429 | 		<SETG SMALL-BOX-COMING <+ ,SMALL-BOX-COMING 1>>
430 | 		<COND (<EQUAL? ,SMALL-BOX-COMING 1>
431 | 		       <RTRUE>)
432 | 		      (<EQUAL? ,SMALL-BOX-COMING 2>
433 | 		       <MOVE ,SMALL-BOX ,HERE>
434 | 		       <CRLF>
435 | 		       <SAY-THE ,SMALL-BOX>
436 | 		       <TELL " \"clump-clumps\" " 
437 | 			     <PICK-ONE ,SMALL-BOX-ARRIVALS> "." CR>
438 | 		       <FIGHT? ,MAILBOX>)>)>>
439 | 
440 | <GLOBAL CUDDLES
441 | 	<LTABLE 0 
442 | 	 "cuddles up around your feet"
443 | 	 "rubs your leg"
444 | 	 "is watching you eagerly"
445 | 	 "nuzzles you lovingly"
446 | 	 "hops around with excitement"
447 | 	 "snaps playfully at your heels"
448 | 	 "is \"clump-clumping\" about happily">>
449 | 
450 | <GLOBAL SMALL-BOX-ARRIVALS
451 | 	<LTABLE 0 
452 |         "into view and snaps a greeting"
453 |         "to your side with a joyful snap"
454 |         "happily into view">>
455 | 
456 | <ROUTINE FIGHT? (ENEMY)
457 | 	 <COND (<AND <IN? .ENEMY ,HERE>
458 | 		     <G? ,BOX-SCRIPT 2>>
459 | 		<REMOVE ,SMALL-BOX>
460 | 		<REMOVE ,MAILBOX>
461 | 		<REMOVE ,EXHIBITS>
462 | 	        <MOVE ,FOSSIL ,MUSEUM>
463 | 		<MOVE-ALL ,SMALL-BOX ,FOSSIL>
464 | 		<DISABLE <INT I-FRIENDLY-BOX>>
465 | 		<COND (<ENABLED? ,I-WAKE-BOX>
466 | 		       <DISABLE <INT I-WAKE-BOX>>)>
467 | 		<COND (<ENABLED? ,I-BAD-BOX>
468 | 		       <DISABLE <INT I-BAD-BOX>>)>
469 | 	        <SETG BOX-ALIVE? <>>
470 | 		<TELL CR
471 | "The two mailboxes freeze at the sight of one another.|
472 | |
473 | The " D ,SMALL-BOX " snarls and stands protectively by your side. The "
474 | D ,MAILBOX " emits a frightful growl and throws its lid wide open, displaying rows of ">
475 | 		<SHARP-TEETH>
476 | 		<TELL 
477 | ". A crowd of postal meters and stamp dispensers gathers as the metal warriors circle each other with tense, snapping lids.|
478 | |
479 | With a sudden rush, the " D ,SMALL-BOX " throws itself at the " D ,MAILBOX
480 | " and clamps onto its forefoot. The " D ,MAILBOX 
481 | " roars with anger, bites the " D ,SMALL-BOX " viciously and tries in vain to shake it off. You stare in wonder as the fighting boxes swell to twice their normal size, then four times larger, eight times!|
482 | |
483 | The " D ,MAILBOX " frees itself with a savage twist and bends to finish its foe. The " D ,SMALL-BOX " dodges, grips the descending lid and holds on for dear life. Locked in mortal combat, the giant boxes roll over and over, shaking the earth with the thunder of battle.|
484 | |
485 | The scene disappears under a cloud of dust. You hear a terrible scream of agony, then an even more terrible silence. When the air clears, the boxes and spectators are gone." CR>
486 | 		<RTRUE>)
487 | 	       (T
488 | 		<RFALSE>)>>
489 | 
490 | "*** BOOTS ***"
491 | 
492 | <OBJECT BOOTS
493 | 	(DESC "boots")
494 | 	(SYNONYM BOOTS PATROL)
495 | 	(ADJECTIVE BOOT TALL)
496 | 	(FLAGS NARTICLEBIT ACTORBIT NDESCBIT)>
497 | 
498 | <ROUTINE DEPOSIT-BRANCH ()
499 | 	 <COND (<IN? ,BRANCH ,PROTAGONIST>
500 | 		<MOVE ,BRANCH ,HERE>)
501 | 	       (<IN? ,BROOM ,PROTAGONIST>
502 | 		<SETG BROOM-SIT? <>>
503 | 		<MOVE ,BROOM ,HERE>)>>
504 | 
505 | <ROUTINE TRAMP ()
506 | 	 <TELL " tramp of marching " D ,BOOTS " ">>
507 | 
508 | <ROUTINE COMING-THIS-WAY ()
509 | 	 <TELL " It sounds as if they're coming this way!">>
510 | 
511 | <GLOBAL JAIL-VISITS 0>  ; "# times jail visited"
512 | 
513 | <ROUTINE TO-JAIL ()
514 | 	 <SETG ON-STUMP? <>>
515 | 	 <COND (<ZERO? ,JAIL-VISITS>
516 | 		<SETG JAIL-SCRIPT 24>
517 | 		<DISABLE <INT I-BREAK-IN>>
518 | 		<ENABLE <QUEUE I-JAIL -1>>)    ; "In case you snuck in"
519 | 	       (T
520 | 		<SETG JAIL-SCRIPT 16>)>        ; "fewer turns for 2nd visit"
521 | 	 <SETG JAIL-VISITS <+ ,JAIL-VISITS 1>> ; "New visit!"
522 | 	 <MOVE ,PROTAGONIST ,JAIL-CELL>
523 | 	 <SETG HERE ,JAIL-CELL>
524 | 	 <MOVE-ALL ,PROTAGONIST ,JAIL-CELL>
525 | 	 <COND (<G? ,JAIL-VISITS 1>
526 | 		<FCLEAR ,BUNK ,RMUNGBIT>
527 | 		<FCLEAR ,UNDER-CELL ,ONBIT>
528 | 		<FCLEAR ,UNDER-CELL ,TOUCHBIT>)>
529 |        	 <CRLF>
530 | 	 <CRLF>
531 | 	 <V-LOOK>
532 | 	 <I-LUCK>
533 | 	 <I-GLOW>>
534 | 
535 | <ROUTINE EVIL-VOICES ()
536 | 	 <TELL "evil voices down the " D ,CORRIDOR>>
537 | 
538 | <ROUTINE HEAR-WAILS ()
539 | 	 <TELL ,YOU-HEAR <PICK-ONE ,JAIL-SOUNDS> " from ">
540 | 	 <COND (<PROB 50>
541 | 		<TELL "an adjacent cell">)
542 | 	       (T
543 | 		<TELL "the " D ,CORRIDOR " outside">)>
544 | 	 <TELL "." CR>>
545 | 
546 | <GLOBAL JAIL-SOUNDS
547 | 	<LTABLE 0
548 | 	 "wails of anguish"
549 | 	 "somebody howling with pain"
550 | 	 "sounds of violence" 
551 | 	 "an agonized cry">>
552 | 
553 | <ROUTINE SHARK-SNACK ()
554 | 	 <TELL 
555 | " with this jailbreaker any more tonight, do we?\" The surrounding "
556 | D ,BOOTS " grunt in sympathy. \"No, of course not. Let's ">
557 | 	 <COND (<NOT <EQUAL? ,HERE ,WHARF ,PLEASURE-WHARF>>
558 | 		<TELL "pay a visit to the " D ,PLEASURE-WHARF ", and ">)>
559 | 	 <TELL "give the " D ,SHARKS " a little bedtime snack!\"">>
560 | 
561 | <ROUTINE THROWN-OVER-SHOULDER ()
562 | 	 <TELL CR CR
563 | "You're thrown into an especially smelly Boot and carried, kicking and screaming, to ">>
564 | 	 
565 | <ROUTINE INTO-BAY ()
566 | 	 <TELL 
567 | "the edge of the " D ,PLEASURE-WHARF ". With a mighty swing, you're thrown high into the air and fall with a splash into the churning waters of">
568 | 	 <WHICH-TOWN "Bay">
569 | 	 <TELL ".|
570 | |
571 | The " D ,BOOTS " on the wharf stomp and hoot as a black fin rises above the waves. It circles slowly, getting closer. You shut your eyes and pray that the end will be quick and not too painful...">
572 | 	 <COND (,HORSE-SAVED?
573 | 		<SAVED-BY-HORSES>)
574 | 	       (T
575 | 		<BAD-ENDING>)>>
576 | 
577 | <ROUTINE SAVED-BY-HORSES ()
578 | 	 <REMOVE ,BOOTS>
579 | 	 <DISABLE <INT I-JAIL>>
580 | 	 <DISABLE <INT I-BOOT-PATROL>>
581 | 	 <TELL CR CR
582 | "\"Hop on!\"|
583 | |
584 | The tiny voice is somewhere near your left ear. \"Don't just thrash about with your eyes shut. Hop on!\"|
585 | |
586 | The " D ,BOOTS " on the " D ,PLEASURE-WHARF " have stopped hooting and started screaming. Timidly, you open one eye.|
587 | |
588 | The bay is boiling with thousands of " D ,HORSE "s! They leap from the waves like wet little rockets, splashing the " D ,PLEASURE-WHARF " with black, oily water. Many of the " D ,BOOTS " have already slipped and fallen into the sea; and a black fin is gliding confidently in their direction.|
589 | |
590 | \"What are you waiting for? Halloween?\"|
591 | |
592 | The familiar " D ,HORSE " at your ear urges you to a nearby buoy. You grasp it with your last ounce of strength and feel yourself speeding across the bay, propelled by dozens of " D ,HORSE "s reined to the buoy with seaweed.|
593 | |
594 | \"I don't mind returning a favor,\" remarks the " D ,HORSE " as your brain sinks into oblivion, \"but can't you pick a better night to go swimming?\"">
595 | 	 <FCLEAR ,POLICE-DOOR ,OPENBIT>
596 | 	 <FSET ,POLICE-DOOR ,LOCKEDBIT>
597 | 	 <MOVE ,PROTAGONIST ,FESTERON-POINT>
598 | 	 <SETG HERE ,FESTERON-POINT>
599 | 	 <MOVE-ALL ,PROTAGONIST ,FESTERON-POINT>
600 | 	 <COME-TO-SENSES>>
601 | 
602 | <ROUTINE JAIL-AGAIN ()
603 | 	 <FSET ,HIDDEN-HATCH ,RMUNGBIT>
604 | 	 <REMOVE ,PSEUDO-BUNK>
605 | 	 <FCLEAR ,HIDDEN-HATCH ,TOUCHBIT>
606 | 	 <TELL "\"Well, well. If it isn't the disappearing mail clerk.\" You open your mouth to reply, but a vicious little kick changes your mind. \"The Tower wants a chat with this troublemaker.\"|
607 | |
608 | \"The " D ,SHARKS " are getting restless,\" remarks the Tall Boot hopefully." 
609 | CR CR D ,MACGUFFIN " smirks. \"So is" ,EONE ".\"">>
610 | 
611 | ; "Table for BUTTON-F"
612 | 
613 | <GLOBAL DESTINATIONS
614 | 	<PLTABLE
615 | 	 <PLTABLE <> <> EDGE-OF-LAKE <> <>>
616 | 	 <PLTABLE <> LOOKOUT-HILL ROTARY-WEST INSIDE-GRAVE <>>
617 | 	 <PLTABLE SOUTH-OF-BRIDGE ROTARY-NORTH PARK ROTARY-SOUTH HILLTOP>
618 | 	 <PLTABLE <> WEST-OF-HOUSE ROTARY-EAST VIDEO-ARCADE <>>
619 | 	 <PLTABLE <> <> PLEASURE-WHARF <> <>>>>
620 | 
621 | 
622 | 


--------------------------------------------------------------------------------
/bridge.zil:
--------------------------------------------------------------------------------
  1 | "BRIDGE for WISHBRINGER: (C)1985 Infocom, Inc. All rights reserved."
  2 | 
  3 | "*** ON BRIDGE ***"
  4 | 
  5 | <OBJECT ON-BRIDGE
  6 | 	(IN ROOMS)
  7 | 	(DESC "Bridge")
  8 | 	(FLAGS ONBIT RLANDBIT INDOORSBIT WETBIT)
  9 | 	(GLOBAL RIVER BRIDGE)
 10 | 	(NORTH PER OFF-BRIDGE)
 11 | 	(EAST PER PROBABLY-DROWN)
 12 | 	(SOUTH TO SOUTH-OF-BRIDGE)
 13 | 	(WEST PER PROBABLY-DROWN)
 14 | 	(DOWN PER PROBABLY-DROWN)
 15 | 	(ACTION ON-BRIDGE-F)>
 16 | 
 17 | <ROUTINE ON-BRIDGE-F (CONTEXT)
 18 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
 19 | 		<TELL
 20 | "You're on a " D ,BRIDGE " that spans the">
 21 | 		<WHICH-TOWN "River">
 22 | 		<TELL ". A sign hangs on an arch overhead." CR>)>>
 23 | 
 24 | <ROUTINE OFF-BRIDGE ()
 25 | 	 <COND (<AND ,SKEWED?
 26 | 		     <IN? ,TROLL ,NORTH-OF-BRIDGE>>
 27 | 	      ; <START-BUZZ 2>
 28 | 		<FCLEAR ,TOLL-GATE ,OPENBIT>
 29 | 		<ENABLE <QUEUE I-SHUT-GATE -1>>)>
 30 | 	 <RETURN ,NORTH-OF-BRIDGE>>
 31 | 
 32 | <ROUTINE I-SHUT-GATE ()
 33 | 	 <DISABLE <INT I-SHUT-GATE>>
 34 | 	 <CRLF>
 35 | 	 <SAY-THE ,TROLL>
 36 | 	 <TELL " lowers the " D ,TOLL-GATE " after you pass." CR>>
 37 | 		
 38 | <OBJECT BRIDGE
 39 | 	(IN LOCAL-GLOBALS)
 40 | 	(DESC "covered bridge")
 41 | 	(SYNONYM BRIDGE)
 42 | 	(ADJECTIVE COVERED)
 43 | 	(FLAGS NDESCBIT)
 44 | 	(ACTION BRIDGE-F)>
 45 | 
 46 | <ROUTINE BRIDGE-F ()
 47 | 	 <COND (<VERB? CROSS WALK-TO THROUGH ENTER>
 48 | 		<COND (<EQUAL? ,HERE ,SOUTH-OF-BRIDGE>
 49 | 		       <DO-WALK ,P?NORTH>)
 50 | 		      (<EQUAL? ,HERE ,NORTH-OF-BRIDGE>
 51 | 		       <DO-WALK ,P?SOUTH>)
 52 | 		      (<EQUAL? ,HERE ,ON-BRIDGE>
 53 | 		       <V-WALK-AROUND>)
 54 | 		      (T
 55 | 		       <RFALSE>)>
 56 | 		<RTRUE>)
 57 | 	       (<VERB? LEAP>
 58 | 		<COND (<EQUAL? ,HERE ,ON-BRIDGE>
 59 | 		       <PERFORM ,V?KILL ,ME>)
 60 | 		      (T
 61 | 		       <ALREADY-ON ,BRIDGE T>)>
 62 | 		<RTRUE>)
 63 | 	       (<VERB? LOOK-UNDER>
 64 | 		<PERFORM ,V?EXAMINE ,RIVER>
 65 | 		<RTRUE>)
 66 | 	       (T
 67 | 		<RFALSE>)>>
 68 | 
 69 | <OBJECT BRIDGE-SIGN
 70 | 	(IN ON-BRIDGE)
 71 | 	(DESC "sign")
 72 | 	(SYNONYM SIGN ARCH)
 73 | 	(ADJECTIVE BIG)
 74 | 	(FLAGS NDESCBIT READBIT)
 75 | 	(ACTION BRIDGE-SIGN-F)>
 76 | 
 77 | <ROUTINE BRIDGE-SIGN-F ()
 78 | 	 <COND (<VERB? READ EXAMINE>
 79 | 		<CRLF>
 80 | 		<FIXED-FONT-ON>
 81 | 		<TELL "   ">
 82 | 		<COND (<EQUAL? ,WHERE-FROM ,SOUTH-OF-BRIDGE>
 83 | 		       <TELL "LEAV">)
 84 | 		      (T
 85 | 		       <TELL "ENTER">)>
 86 | 		<TELL "ING ">
 87 | 		<COND (,SKEWED?
 88 | 		       <TELL "WITCHVILLE">)
 89 | 		      (T
 90 | 		       <TELL "FESTERON">)>
 91 | 		<TELL CR CR>
 92 | 		<COND (,SKEWED?
 93 | 		       <TELL 
 94 | "  Curfew Begins At 6 PM|
 95 |    Boot Patrol On Duty|
 96 | Violators Will Be Jailed!">)
 97 | 		      (T
 98 | 		       <COND (<EQUAL? ,WHERE-FROM ,SOUTH-OF-BRIDGE>
 99 | 			      <TELL "Next Time You're In Town" CR>)>
100 | 		       <TELL 
101 | "  Visit Our Fun-Filled" CR "     " D ,PLEASURE-WHARF>)>
102 | 		<CRLF>
103 | 		<FIXED-FONT-OFF>
104 | 		<RTRUE>)
105 | 	       (T
106 | 		<RFALSE>)>>
107 | 
108 | "*** NORTH OF BRIDGE ***"
109 | 
110 | <OBJECT NORTH-OF-BRIDGE
111 | 	(IN ROOMS)
112 | 	(DESC "North of Bridge")
113 | 	(FLAGS ONBIT RLANDBIT WETBIT)
114 | 	(GLOBAL BRIDGE RIVER CLIFF SIGN)
115 | 	(NORTH PER BUMP-CLIFF)
116 | 	(EAST TO CLIFF-BOTTOM)
117 | 	(SOUTH PER ENTER-BRIDGE?)
118 | 	(WEST PER BUMP-CLIFF)
119 | 	(UP "The cliff is much too steep to climb.")
120 | 	(IN PER ENTER-BRIDGE?)
121 | 	(ACTION NORTH-OF-BRIDGE-F)
122 | 	(PSEUDO "SHORE" HERE-F)>
123 | 
124 | <ROUTINE NORTH-OF-BRIDGE-F (CONTEXT)
125 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
126 | 		<TELL "This is the north side of the">
127 | 		<WHICH-TOWN "Bridge">
128 | 		<TELL ". Sheer cliff walls rise abruptly " <TO-N> " and west. A path wanders east along the shore of the river.">
129 | 		<COND (,SKEWED?
130 | 		       <TELL CR CR
131 | "A rickety " D ,TOLL-GATE " has been thrown up across the " D ,ENTRANCE 
132 | " to the " D ,BRIDGE ". A handpainted sign is nailed to the middle of the">
133 | 		       <OPEN-CLOSED ,TOLL-GATE>
134 | 		       <TELL "gate.">
135 | 		       <COND (<IN? ,TROLL ,NORTH-OF-BRIDGE>
136 | 			      <THIS-IS-IT ,TROLL>
137 | 			      <TELL CR CR
138 | "Standing near the " D ,TOLL-GATE " is an ugly, gnomelike creature. A less original story would probably refer to it as a troll.">)>)>
139 | 		<CRLF>)>>
140 | 
141 | <ROUTINE ENTER-BRIDGE? ()
142 | 	 <SETG WHERE-FROM ,NORTH-OF-BRIDGE>
143 | 	 <COND (<NOT ,SKEWED?>
144 | 		<RETURN ,ON-BRIDGE>)
145 | 	       (<FSET? ,TOLL-GATE ,OPENBIT>
146 | 		<COND (<L? ,WISDOM 3>
147 | 		       <COND (<FSET? ,LAKE-SAND ,TOOLBIT>
148 | 			      <START-BUZZ 4>)
149 | 			     (T
150 | 			      <START-BUZZ 3>)>)>
151 | 		<FSET ,TROLL ,RMUNGBIT>
152 | 		<RETURN ,ON-BRIDGE>)
153 | 	       (T
154 | 		<COND (<IN? ,TROLL ,NORTH-OF-BRIDGE>
155 | 		       <THIS-IS-IT ,TROLL>
156 | 		       <TELL 
157 | "\"" <PICK-ONE ,TOLL-DEMANDS> "\" croaks the troll, palm outstretched." CR>)
158 | 		      (T
159 | 		       <ITS-CLOSED ,TOLL-GATE>)>
160 | 		<RFALSE>)>>
161 | 
162 | <GLOBAL TOLL-DEMANDS
163 | 	<LTABLE 0
164 |   	 "The sign says 'One Gold Coin,'"
165 | 	 "Show me first a gold coin,"
166 | 	 "Ask not for whom the troll tolls,">>
167 | 
168 | <OBJECT TROLL
169 | 	(DESC "troll")
170 | 	(SYNONYM TROLL CREATURE)
171 | 	(ADJECTIVE UGLY GNOMELIKE)
172 | 	(FLAGS ACTORBIT NDESCBIT RMUNGBIT TOOLBIT)
173 | 	(ACTION TROLL-F)>
174 | 
175 | ; "RMUNGBIT = troll has not accepted the coin,
176 |    TOOLBIT = troll has not been given the can"
177 | 
178 | <ROUTINE TROLL-F ("OPTIONAL" (CONTEXT <>))
179 | 	 <COND (<VERB? EXAMINE>
180 | 		<SAY-THE ,TROLL>
181 | 		<TELL " is staring ">
182 | 		<COND (,ECLIPSE?
183 | 		       <TELL "fearfully upward">)
184 | 		      (T
185 | 		       <TELL "back at you stupidly">)>
186 | 		<TELL "." CR>
187 | 		<RTRUE>)
188 | 	       
189 | 	       (<AND <VERB? GIVE>
190 | 		     <EQUAL? ,PRSI ,TROLL>>
191 | 		<COND (,ECLIPSE?
192 | 		       <TROLL-NOT-INTERESTED>
193 | 		       <RTRUE>)
194 | 		      (<EQUAL? ,PRSO ,COIN>
195 | 		       <COND (,COIN-OFFERED?
196 | 		              <REMOVE ,COIN>
197 | 		              <SAY-THE ,TROLL>
198 | 			      <TELL 
199 | " angrily tosses your " D ,COIN " into the river and mutters something indelicate about counterfeiters." CR>
200 | 		              <RTRUE>)>
201 | 		       
202 | 		       <SETG COIN-OFFERED? T>
203 | 		       <SAY-THE ,TROLL>
204 | 		       <TELL
205 | " snatches away your " D ,COIN " with a grunt">
206 | 		
207 | 		       <COND (,LUCKY?
208 | 		              <MOVE ,COIN ,TROLL>
209 | 			      <FSET ,TOLL-GATE ,OPENBIT>
210 | 		              <FCLEAR ,TROLL ,RMUNGBIT>
211 | 		              <THIS-IS-IT ,BRIDGE>
212 | 		              <START-BUZZ 3>
213 | 			      <TELL
214 | ". Luckily, he hides it away without looking at it and opens the "
215 | D ,TOLL-GATE ". \"Pass.\"" CR>
216 | 			      <RTRUE>)
217 | 		             
218 | 			     (T
219 | 		              <MOVE ,COIN ,NORTH-OF-BRIDGE>
220 | 		              <THIS-IS-IT ,COIN>
221 | 		              <TELL " and squints at it suspiciously. \"Ugh!\" he cries, holding it up to the moonlight. \"This is a fake!\" He points accusingly at the familiar">
222 | 		              <SAY-PROFILE>
223 | 		              <TELL ", throws your coin to the " D ,GROUND 
224 | " and pulls out another. \"This is what an OFFICIAL " D ,COIN " looks like!\"|
225 | |
226 | The " D ,TROLL " proudly exhibits his coin. It shows the profile of an evil-looking " D ,OLD-WOMAN>)>
227 | 		       <TELL "." CR>
228 | 		       <RFATAL>)
229 | 		       
230 | 		      (<AND <EQUAL? ,PRSO ,SNAKE-CAN>
231 | 		            <NOT <FSET? ,SNAKE-CAN ,OPENBIT>>>
232 | 		       <SAY-THE ,SNAKE-CAN>
233 | 		       <TELL 
234 | " rattles as you hand it to the " D ,TROLL ". ">
235 | 		       <COND (<FSET? ,TROLL ,TOOLBIT>
236 | 			      <FCLEAR ,TROLL ,TOOLBIT>
237 | 			      <FSET ,SNAKE-CAN ,OPENBIT>
238 | 			      <TELL "\"Mmm, yummy!\" he exclaims, peering at the label and then greedily opening the lid..." CR CR>)>
239 | 		       <COND (,SNAKE-GONE?
240 | 			      <MOVE ,SNAKE-CAN ,HERE>
241 | 			      <TELL
242 | "\"Hurumph!\" he growls, pitching the can to the " D ,GROUND ". \"Not funny!\""
243 | CR>)
244 | 			     (T
245 | 			      <TELL "Yow! As he opens">
246 | 	                      <SNAKE-LEAPS-OUT-AT "the troll">
247 | 	                      <CAN-FALLS>
248 | 		              <FRIGHTEN-TROLL>
249 | 			      <CRLF>
250 | 			      <UPDATE-SCORE 3>)>
251 | 		       <RFATAL>)
252 | 		      
253 | 		      (T
254 | 		       <MOVE ,PRSO ,NORTH-OF-BRIDGE>
255 | 	               <SAY-THE ,TROLL>
256 | 		       <TELL " studies ">
257 | 	               <ARTICLE ,PRSO T>
258 | 	               <TELL D ,PRSO 
259 | " closely to see if it resembles a " D ,COIN ", and pitches it to the " 
260 | D ,GROUND " when he decides that it doesn't." CR>
261 | 		       <RTRUE>)>)
262 | 	       
263 | 	       (<ASKING? ,TROLL>
264 | 		<COND (,ECLIPSE?
265 | 		       <TROLL-NOT-INTERESTED>)
266 | 		      (T
267 | 		       <TELL
268 | "\"No time for questions,\" " <PICK-ONE ,YELL-TYPES> " the idle troll." CR>)>
269 | 		<RFATAL>)
270 | 	       
271 | 	       (<VERB? FEED TELL YELL REPLY HELLO WAVE-AT ; GOODBYE>
272 | 		<COND (,ECLIPSE?
273 | 		       <TROLL-NOT-INTERESTED>)
274 | 		      (T
275 | 		       <SAY-THE ,TROLL>
276 | 		       <TELL " " <PICK-ONE ,YELL-TYPES> 
277 | " something awful and ignores you." CR>)>
278 | 		<RFATAL>)
279 | 	       
280 | 	       (<AND <VERB? FOLLOW>
281 | 		     ,TROLL-SCARED?
282 | 		     <EQUAL? ,HERE ,NORTH-OF-BRIDGE ,ON-BRIDGE>>
283 | 		<DO-WALK ,P?SOUTH>
284 | 		<RTRUE>)
285 | 	       (T
286 | 		<RFALSE>)>>
287 | 
288 | <ROUTINE TROLL-NOT-INTERESTED ()
289 | 	 <SAY-THE ,TROLL>
290 | 	 <TELL " is too busy watching the sky to notice." CR>>
291 | 
292 | <GLOBAL COIN-OFFERED? <>>
293 | 
294 | <OBJECT TOLL-GATE
295 | 	(DESC "toll gate")
296 | 	(SYNONYM GATE)
297 | 	(ADJECTIVE TOLL)
298 | 	(FLAGS NDESCBIT DOORBIT)
299 | 	(ACTION TOLL-GATE-F)>
300 | 
301 | <ROUTINE TOLL-GATE-F ()
302 | 	 <COND (<NOT ,SKEWED?>
303 | 		<CANT-SEE-ANY ,TOLL-GATE>
304 | 		<RFATAL>)
305 | 	       (<VERB? OPEN RAISE>
306 | 		<COND (<FSET? ,TOLL-GATE ,OPENBIT>
307 | 		       <ALREADY-OPEN>)
308 | 		      (T
309 | 		       <NOW-CLOSED-OR-OPEN ,TOLL-GATE T>
310 | 		       <COND (<AND <IN? ,TROLL ,NORTH-OF-BRIDGE>
311 | 			           <FSET? ,TROLL ,RMUNGBIT>>
312 | 		              <FCLEAR ,TOLL-GATE ,OPENBIT>
313 | 			      <CRLF>
314 | 		              <SAY-THE ,TROLL>
315 | 		              <TELL " slams the " D ,TOLL-GATE " shut. \"" 
316 | 			            <PICK-ONE ,TOLL-DEMANDS>
317 | 			            "\" he " <PICK-ONE ,YELL-TYPES> "." CR>)>)>
318 | 		<RTRUE>)
319 | 	       (<VERB? WALK-TO ENTER EXIT THROUGH>
320 | 		<COND (<FSET? ,TOLL-GATE ,OPENBIT>
321 | 		       <DO-WALK ,P?SOUTH>)
322 | 		      (T
323 | 		       <ITS-CLOSED ,TOLL-GATE>)>
324 | 		<RTRUE>)
325 | 	       (<VERB? LEAP CROSS CLIMB-ON CLIMB-UP>
326 | 		<TOO-HIGH ,TOLL-GATE>
327 | 		<RTRUE>)
328 | 	       (<AND <HURT? ,TOLL-GATE>
329 | 		     <IN? ,TROLL ,NORTH-OF-BRIDGE>>
330 | 		<SAY-THE ,TROLL>
331 | 		<MIGHT-NOT-LIKE>
332 | 		<RTRUE>)
333 | 	       (<VERB? CLOSE LOWER>
334 | 		<COND (<NOT <FSET? ,TOLL-GATE ,OPENBIT>>
335 | 		       <ALREADY-CLOSED>)
336 | 		      (<IN? ,TROLL ,NORTH-OF-BRIDGE>
337 | 		       <TELL "\"That's MY job,\" snaps the " D ,TROLL "." CR>)
338 | 		      (T
339 | 		     ; <FCLEAR ,TOLL-GATE ,OPENBIT>
340 | 		     ; <TELL "Closed." CR>
341 | 		       <NOW-CLOSED-OR-OPEN ,TOLL-GATE>)>
342 | 		<RTRUE>)
343 | 	       (<VERB? EXAMINE READ LOOK-ON>
344 | 		<PERFORM ,V?EXAMINE ,SIGN>
345 | 		<RTRUE>)
346 | 	       (T
347 | 		<RFALSE>)>>
348 | 
349 | "*** CLIFF BOTTOM ***"
350 | 
351 | <OBJECT CLIFF-BOTTOM
352 | 	(IN ROOMS)
353 | 	(DESC "Cliff Bottom")
354 | 	(FLAGS ONBIT RLANDBIT WETBIT)
355 | 	(GLOBAL RIVER SAND CLIFF TRAIL)
356 | 	(NORTH PER BUMP-CLIFF)
357 | 	(EAST PER BUMP-CLIFF)
358 | 	(SOUTH PER PROBABLY-DROWN)
359 | 	(WEST PER LIFT-VULTURE)
360 | 	(UP PER ENTER-TRAIL?)
361 | 	(IN PER BUMP-CLIFF)
362 | 	(ACTION CLIFF-BOTTOM-F)>
363 | 
364 | <ROUTINE CLIFF-BOTTOM-F (CONTEXT)
365 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
366 | 		<TELL "You're at the bottom of a cliff that rises up from the north bank of the river.">
367 | 		<COND (<NOT ,SKEWED?>
368 | 		       <TELL " ">
369 | 		       <TRAIL-WINDS-UP>)>		
370 | 		<CRLF>)>>
371 | 
372 | <ROUTINE ENTER-TRAIL? ()
373 | 	 <COND (,SKEWED?
374 | 		<TRAIL-MISPLACED>
375 | 		<RFALSE>)
376 | 	       (T
377 | 		<COND (<FSET? ,STEEP-TRAIL ,RMUNGBIT>
378 | 		       <FCLEAR ,STEEP-TRAIL ,RMUNGBIT>
379 | 		       <TELL "(The " D ,TRAIL " you're climbing is narrow and twisty. It's a good idea to draw a map as you go up.)" CR CR>)>
380 | 		<SETG TLOC 1>
381 | 		<RETURN ,STEEP-TRAIL>)>>
382 | 
383 | <ROUTINE TRAIL-MISPLACED ()
384 | 	 <TELL 
385 | "The steep " D ,TRAIL " seems to have disappeared with the fog." CR>>
386 | 
387 | <ROUTINE TRAIL-WINDS-UP ()
388 | 	 <TELL "A steep " D ,TRAIL " winds upward.">>
389 | 
390 | <ROUTINE FEATURELESS-WALL ()
391 | 	 <TELL "It's a sheer, featureless wall, a hundred feet high." CR>>
392 | 
393 | <OBJECT CLIFF
394 | 	(IN LOCAL-GLOBALS)
395 | 	(DESC "cliff")
396 | 	(SYNONYM CLIFF WALL FACE)
397 | 	(ADJECTIVE SHEER ROCK ROCKY STEEP FEATURELESS)
398 | 	(FLAGS NDESCBIT)
399 | 	(ACTION CLIFF-F)>
400 | 
401 | <ROUTINE CLIFF-F ()
402 | 	 <COND (<VERB? EXAMINE LOOK-UP>
403 | 		<COND (<AND <EQUAL? ,HERE ,CLIFF-BOTTOM>
404 | 			    <NOT ,SKEWED?>>
405 | 		       <TRAIL-WINDS-UP>
406 | 		       <CRLF>)
407 | 		      (T
408 | 		       <FEATURELESS-WALL>)>
409 | 		<RTRUE>)
410 | 	       (<VERB? LEAP>
411 | 		<COND (<EQUAL? ,HERE ,CLIFF-EDGE ,STEEP-TRAIL ,FOG>
412 | 		       <PERFORM ,V?KILL ,ME>)
413 | 		      (T
414 | 		       <ALREADY-ON ,CLIFF T>)>
415 | 		<RTRUE>)
416 | 	       (T
417 | 		<RFALSE>)>> 
418 | 
419 | <OBJECT BRANCH
420 | 	(IN GNARLED-TREE)
421 | 	(DESC "dead branch")
422 | 	(SYNONYM BRANCH)
423 | 	(ADJECTIVE LONE HORIZONTAL DEAD)
424 | 	(FLAGS BURNBIT TAKEBIT)
425 | 	(ACTION BRANCH-F)
426 | 	(DESCFCN DESCRIBE-BRANCH)
427 | 	(VALUE 0)
428 | 	(SIZE 23)>
429 | 
430 | <ROUTINE DESCRIBE-BRANCH (CONTEXT)
431 | 	 <COND (<EQUAL? .CONTEXT ,M-OBJDESC>
432 | 		<TELL "A " D ,BRANCH " is ">
433 | 		<COND (<IN? ,BRANCH ,PIT>
434 | 		       <STICKUP>)
435 | 		      (T
436 | 		       <TELL "lying on the " D ,GROUND>)>
437 | 		<TELL ".">)>>
438 | 
439 | <ROUTINE STICKUP ()
440 | 	 <TELL "sticking up out of the pit">>
441 | 
442 | <ROUTINE BRANCH-F ()
443 | 	 <COND (<VERB? EXAMINE>
444 | 		<SAY-THE ,BRANCH>
445 | 		<TELL " is ">
446 | 	        <COND (<IN? ,BRANCH ,PIT>
447 | 		       <STICKUP>
448 | 		       <COND (<FSET? ,PLATYPUS ,TOOLBIT>
449 | 			      <TELL ". A " D ,PLATYPUS 
450 | " is holding on to the bottom end, and looking up at you expectantly">)>)
451 | 		      (T
452 | 		       <TELL "about six feet long">)>
453 | 		<TELL "." CR>
454 | 		<RTRUE>)
455 | 	       
456 | 	       (<AND <VERB? TAKE MOVE PULL RAISE>
457 | 		     <EQUAL? ,PRSO ,BRANCH>>
458 | 		<COND (<NOT <FSET? ,GNARLED-TREE ,RMUNGBIT>>
459 | 		       <BRANCH-BREAKS>)
460 | 		      (<AND <IN? ,BRANCH ,PIT>
461 | 			    <FSET? ,PLATYPUS ,TOOLBIT>>
462 | 		       <COND (<V-TAKE>
463 | 		              <CRLF>
464 | 			      <UPDATE-SCORE 5>
465 | 		              <CRLF>
466 | 			      <SAY-THE ,PLATYPUS>
467 | 			      <TELL " hangs on to the " D ,BRANCH " as you pull it out of the pit. It lets go when the branch clears the edge and waddles joyfully around on the ">
468 | 			      <COND (,PIT-FULL?
469 | 				     <TELL "wet ">)>
470 | 			      <TELL "sand." CR CR>
471 | 		              <DRAW-X>)>
472 | 		       <RTRUE>)
473 | 		       
474 | 		      (T
475 | 		       <RFALSE>)>
476 | 		<RTRUE>)
477 | 		       
478 | 	       (<AND <VERB? CLIMB-UP CLIMB-ON SIT MUNG>
479 | 		     <EQUAL? ,PRSO ,BRANCH>
480 | 		     <NOT <FSET? ,GNARLED-TREE ,RMUNGBIT>>>
481 | 		<BRANCH-BREAKS>
482 | 		<RTRUE>)
483 | 	       (T
484 | 		<RFALSE>)>>
485 | 
486 | "*** VULTURE ***"
487 | 
488 | <OBJECT VULTURE
489 | 	(DESC "vulture")
490 | 	(SYNONYM VULTURE BIRD)
491 | 	(FLAGS ACTORBIT TRYTAKEBIT NDESCBIT)
492 | 	(ACTION VULTURE-F)>
493 | 
494 | ; "RMUNGBIT = force vulture sighting"
495 | 
496 | <ROUTINE VULTURE-F ("OPTIONAL" (CONTEXT <>))
497 | 	 <COND (<VERB? EXAMINE LOOK-UP>
498 | 		<TELL "Its steady gaze makes you uneasy." CR>
499 | 		<RTRUE>)
500 | 	       (<IMAGE? ,VULTURE>
501 | 		<RFATAL>)
502 | 	       (<OR <TALKING-TO? ,VULTURE>
503 | 		    <VERB? YELL>>
504 | 		<SAY-THE ,VULTURE>
505 | 		<TELL " " <PICK-ONE ,IGNORANCE> "." CR>
506 | 		<RFATAL>)
507 | 	       (<AND <VERB? THROW>
508 | 		     <EQUAL? ,PRSI ,VULTURE>>
509 | 		<SAY-THE ,VULTURE>
510 | 		<COND (<EQUAL? ,PRSO ,WISHBRINGER>
511 | 		       <COND (<ENABLED? ,I-VULTURE>
512 | 			      <DISABLE <INT I-VULTURE>>)>
513 | 		       <REMOVE ,VULTURE>
514 | 		       <REMOVE ,WISHBRINGER>
515 | 		       <TELL " eagerly snatches up the " D ,WISHBRINGER
516 | 			     " in its beak,">
517 | 		       <SOARS-AWAY-OVER>
518 | 		       <TELL "your head with a croak of delight." CR CR>
519 | 		       <UPDATE-SCORE -10>)
520 | 		      (T
521 | 		       <TELL " ignores you." CR>)>
522 | 		<RTRUE>)
523 | 	       (<IN? ,VULTURE ,HERE>
524 | 		<TOO-HIGH ,VULTURE>
525 | 		<RTRUE>)
526 | 	       (<AND <VERB? FEED GIVE>
527 | 		     <EQUAL? ,PRSI ,VULTURE>>
528 | 		<PERFORM ,V?THROW ,PRSO ,VULTURE>
529 | 		<RTRUE>)
530 | 	       (<OR <HURT? ,VULTURE>
531 | 		    <VERB? KISS EAT PLAY SQUEEZE RUB>>
532 | 		<REMOVE ,VULTURE>
533 | 		<SAY-THE ,VULTURE>
534 | 		<TELL
535 | " sees your thought. Before you can do anything, it makes a haughty little croak and flies serenely away." CR>
536 | 		<RFATAL>)
537 | 	       (T
538 | 		<RFALSE>)>>
539 | 
540 | <ROUTINE LIFT-VULTURE ()
541 | 	 <COND (<IN? ,VULTURE ,GNARLED-TREE>
542 | 		<FCLEAR ,VULTURE ,RMUNGBIT>
543 | 		<REMOVE ,VULTURE>
544 | 		<ENABLE <QUEUE I-VULTURE -1>>
545 | 	      	<SAY-THE ,VULTURE>
546 | 		<SOARS-AWAY-OVER>
547 | 		<TELL "your head." CR CR>)>
548 | 	 <RETURN ,NORTH-OF-BRIDGE>>
549 | 
550 | <ROUTINE SOARS-AWAY-OVER ()
551 | 	 <TELL " spreads its wings and soars away over ">>
552 | 
553 | <ROUTINE SEE-VULTURE ()
554 | 	 <SAY-THE ,VULTURE>
555 | 	 <TELL " " <PICK-ONE ,SIGHTINGS> " high overhead." CR>>
556 | 
557 | <GLOBAL SIGHTINGS
558 | 	<LTABLE 0
559 |          "appears" "is circling" "begins to hover" "can be seen circling"
560 | 	 "is watching you from" "hovers in the sky" "hovers" 
561 | 	 "eyes you suspiciously from">>
562 | 
563 | <OBJECT GNARLED-TREE
564 | 	(IN CLIFF-BOTTOM)
565 | 	(DESC "gnarled tree trunk")
566 | 	(SYNONYM TRUNK TREE)
567 | 	(ADJECTIVE GNARLED OLD DEAD)
568 | 	(FLAGS ; NDESCBIT SURFACEBIT ; BURNBIT)
569 | 	(DESCFCN DESCRIBE-TREE)
570 | 	(ACTION GNARLED-TREE-F)>
571 | 
572 | <ROUTINE DESCRIBE-TREE (CONTEXT)
573 | 	 <COND (<EQUAL? .CONTEXT ,M-OBJDESC>
574 | 		<TELL "A " D ,GNARLED-TREE>
575 | 		<COND (<IN? ,BRANCH ,GNARLED-TREE>
576 | 		       <TELL 
577 | " stands nearby, a lone branch its only adornment.">)
578 | 		      (T
579 | 		       <TELL 
580 | ", stripped of all its branches, stands nearby.">)>
581 | 		<COND (<IN? ,VULTURE ,GNARLED-TREE>
582 | 		       <TELL " A " D ,VULTURE " perched on top is watching every move you make.">)>)>>
583 | 
584 | <ROUTINE GNARLED-TREE-F ()
585 | 	 <COND (<VERB? EXAMINE LOOK-INSIDE>
586 | 		<SAY-THE ,GNARLED-TREE>
587 | 		<TELL " is rotten to the core." CR>
588 | 		<RTRUE>)
589 | 	       (<VERB? CLIMB-ON CLIMB-UP SIT>
590 | 		<COND (<FSET? ,GNARLED-TREE ,RMUNGBIT>
591 | 		       <NO-FOOTHOLDS>)
592 | 		      (T
593 | 		       <TELL
594 | "Done. You're sitting on the rotten, creaking branch..." CR CR>
595 | 		       <BRANCH-BREAKS>
596 | 		       <TELL CR 
597 | "You're now sitting on the " D ,GROUND ". Painfully." CR>)>
598 | 		<RTRUE>)
599 | 	       (<AND <VERB? PUT PUT-ON THROW>
600 | 		     <EQUAL? ,PRSI ,GNARLED-TREE>>
601 | 		<WASTE-OF-TIME>
602 | 		<RTRUE>)
603 | 	       (T
604 | 		<RFALSE>)>>
605 | 		       
606 | <ROUTINE BRANCH-BREAKS ()
607 | 	 <FCLEAR ,BRANCH ,NDESCBIT>
608 | 	 <FSET ,GNARLED-TREE ,RMUNGBIT>
609 | 	 <MOVE ,BRANCH ,CLIFF-BOTTOM>
610 | 	 <TELL "Crack! ">
611 | 	 <SAY-THE ,BRANCH>
612 | 	 <TELL " snaps off the " D ,GNARLED-TREE " and falls to the "
613 | 	       D ,GROUND " with a thud. ">
614 | 	 <VULTURE-IN-TREE>
615 | 	 <CRLF>>
616 | 		       
617 | <ROUTINE VULTURE-IN-TREE ()
618 | 	 <COND (<IN? ,VULTURE ,GNARLED-TREE>
619 | 		<FCLEAR ,VULTURE ,RMUNGBIT>
620 | 		<REMOVE ,VULTURE>
621 | 		<ENABLE <QUEUE I-VULTURE -1>>
622 | 		<TELL "Visibly annoyed, the " D ,VULTURE>
623 | 		<SOARS-AWAY-OVER>
624 | 		<TELL "the river.">)>>
625 | 
626 | <ROUTINE CAN-FALLS ()
627 | 	 <MOVE ,SNAKE-CAN ,NORTH-OF-BRIDGE>
628 | 	 <CLATTERS ,SNAKE-CAN>>
629 | 
630 | <ROUTINE CLATTERS (THING)
631 | 	 <CRLF>
632 | 	 <SAY-THE .THING>
633 | 	 <TELL " clatters to the " D ,GROUND "." CR>>
634 | 
635 | <GLOBAL SNAKE-GONE? <>>
636 | 
637 | <ROUTINE SNAKE-LEAPS-OUT-AT (STR)
638 | 	 <SETG SNAKE-GONE? T>
639 | 	 <TELL " the can a ">
640 | 	 <COND (,SKEWED?
641 | 		<THIS-IS-IT ,SNAKE-CAN>
642 | 		<FSET ,SNAKE-CAN ,OPENBIT>
643 | 		<TELL 
644 | "real, live rattlesnake leaps out! It squirms about angrily for a few moments, turns to hiss at " .STR " and slithers out of sight">)
645 | 	       (T
646 | 		<TELL 
647 | "three-foot plastic snake springs out! It hits you in the nose and lands harmlessly at your feet.|
648 | |
649 | \"Oldest trick in the book,\" remarks the " D ,OLD-WOMAN ", chuckling despite herself. \"Try it next time you want to get rid of somebody.\" She stuffs the snake back into the " D ,SNAKE-CAN ", closes the lid and hands it back to you">)>
650 | 	 <TELL "." CR>>
651 | 
652 | <GLOBAL TROLL-SCARED? <>>
653 | 
654 | <ROUTINE FRIGHTEN-TROLL ()
655 | 	 <SETG TROLL-SCARED? T>
656 | 	 <COND (<EQUAL? ,WISDOM 2>
657 | 		<START-BUZZ 3>)>
658 | 	 <MOVE ,TROLL ,STEEP-TRAIL>
659 | 	 <COND (<AND <IN? ,COIN ,TROLL>
660 | 		     ,LUCKY?>
661 | 		<FCLEAR ,COIN ,TOUCHBIT>
662 | 		<FCLEAR ,ON-BRIDGE ,TOUCHBIT>
663 | 		<MOVE ,COIN ,ON-BRIDGE>
664 | 		<PUTP ,COIN ,P?FDESC "Lucky you! Your gold coin is lying here on the bridge. The troll must have dropped it when he ran away.">)>
665 | 	 <TELL CR
666 | "A scream of terror echoes off the cliffs as the " D ,TROLL
667 | " runs away across the " D ,BRIDGE "." CR>>
668 | 
669 | <ROUTINE INTO-NIGHT ()
670 | 	 <TELL " into the night.">>
671 | 
672 | 
673 | 
674 | 
675 | 
676 | 		       
677 | 		
678 | 


--------------------------------------------------------------------------------
/west.zil:
--------------------------------------------------------------------------------
  1 | "WEST for WISHBRINGER: (C)1985 Infocom, Inc. All rights reserved."
  2 | 
  3 | "*** EDGE OF LAKE ***"
  4 | 
  5 | <OBJECT ISLE
  6 | 	(IN LOCAL-GLOBALS)
  7 | 	(DESC "island")
  8 | 	(SYNONYM ISLAND ISLE MIST FOG)
  9 |         (ADJECTIVE MISTY)
 10 | 	(FLAGS NDESCBIT)
 11 | 	(ACTION ISLE-F)>
 12 | 
 13 | <ROUTINE ISLE-F ("AUX" (AT-ISLE? <>))
 14 | 	 <THIS-IS-IT ,ISLE>
 15 | 	 <SET AT-ISLE? <EQUAL? ,HERE ,ISLAND ,THRONE-ROOM>>
 16 | 	 <COND (<VERB? EXAMINE LOOK-ON>
 17 | 		<COND (.AT-ISLE?
 18 | 		       <V-LOOK>)
 19 | 		      (T
 20 | 		       <TELL D ,ISLAND 
 21 | " has been shrouded in fog for as long as you can remember. Strange legends and mysterious rumors abound; but nobody you know has ever been there." CR>)>
 22 | 		<RTRUE>)
 23 | 	       (<OR <EQUAL? ,PRSA ,V?WALK-TO ,V?FOLLOW ,V?THROUGH>
 24 | 		    <EQUAL? ,PRSA ,V?ENTER ,V?FIND ,V?SWIM>>
 25 | 		<COND (.AT-ISLE?
 26 | 		       <ALREADY-ON ,ISLE>)
 27 | 		      (T
 28 | 		       <PROBABLY-DROWN>)>
 29 | 		<RTRUE>)
 30 | 	       (<VERB? STAND-ON SIT LIE-DOWN WEAR>
 31 | 		<COND (.AT-ISLE?
 32 | 		       <ALREADY-ON ,ISLE>)
 33 | 		      (T
 34 | 		       <YOUD-HAVE-TO "get to" ,ISLE>)>
 35 | 		<RTRUE>)
 36 | 	       (<VERB? WALK-AROUND CROSS SEARCH>
 37 | 		<COND (.AT-ISLE?
 38 | 		       <V-WALK-AROUND>)
 39 | 		      (T
 40 | 		       <YOUD-HAVE-TO "get to" ,ISLE>)>
 41 | 		<RTRUE>)
 42 | 	       (T
 43 | 		<YOU-DONT-NEED ,ISLE>
 44 | 		<RFATAL>)>>
 45 | 
 46 | <OBJECT EDGE-OF-LAKE
 47 | 	(IN ROOMS)
 48 | 	(DESC "Lake Edge")
 49 | 	(FLAGS ONBIT RLANDBIT WETBIT)
 50 | 	(GLOBAL LAKE NORTH-GATE ISLE CEMETERY)
 51 | 	(NORTH TO RIVER-OUTLET)
 52 | 	(EAST TO ROTARY-WEST)
 53 | 	(SOUTH PER ARE-YOU-SURE?)
 54 | 	(WEST PER PROBABLY-DROWN)
 55 | 	(IN PER ENTER-PIT?)
 56 | 	(DOWN PER ENTER-PIT?)
 57 | 	(ACTION EDGE-OF-LAKE-F)
 58 | 	(PSEUDO "SHORE" HERE-F)>
 59 | 
 60 | <ROUTINE EDGE ()
 61 | 	 <TELL " the edge of the lake">>
 62 | 
 63 | <ROUTINE EDGE-OF-LAKE-F (CONTEXT)
 64 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
 65 | 		<TELL
 66 | "You're on the sandy shore of the lake. A road heads east towards the " 
 67 | D ,FESTERON ", and another runs north along">
 68 | 		<EDGE>
 69 | 		<TELL ". Looking south, you can see a">
 70 | 		<OPEN-CLOSED ,NORTH-GATE T>
 71 | 		<TELL D ,NORTH-GATE 
 72 | " leading into the">
 73 | 		<WHICH-TOWN "Cemetery">
 74 | 		<TELL "." CR CR D ,ISLAND
 75 | ", its outline shrouded in fog, is visible far across the water." CR CR>
 76 | 		<TELL ,YOU-SEE "a ">
 77 | 		<COND (<FSET? ,PIT ,OPENBIT>
 78 | 		       <TELL "narrow pit">
 79 | 		       <COND (,PIT-FULL?
 80 | 			      <TELL " full of rainwater">)>)
 81 | 	              (T
 82 | 		       <TELL "circular " D ,LEAVES>)>
 83 | 		<TELL " near">
 84 | 		<EDGE>
 85 | 		<TELL ". ">
 86 | 		<COND (<IN? ,BRANCH ,PIT>
 87 | 		       <TELL "A " D ,BRANCH " is sticking out of the pit. ">)>
 88 | 		
 89 | 		<COND (<NOT <FSET? ,LAKE-SAND ,RMUNGBIT>>
 90 | 		       <COND (<FSET? ,PLATYPUS ,RMUNGBIT>
 91 | 		              <TELL "An \"X\" has been drawn">)
 92 | 		             (T
 93 | 		              <COND (,SKEWED?
 94 | 			             <TELL "Animal tracks are visible">)
 95 | 			            (T
 96 | 			             <TELL 
 97 | "Somebody has scrawled a message">)>)>
 98 | 		       <TELL " in the sand next to the ">
 99 | 		       <COND (<FSET? ,PIT ,OPENBIT>
100 | 		              <TELL D ,PIT>)
101 | 		             (T
102 | 		              <TELL D ,LEAVES>)>
103 | 		       <TELL ".">)>
104 | 		<CRLF>)>>
105 | 
106 | <ROUTINE ENTER-PIT? ()
107 | 	 <COND (<FSET? ,PIT ,OPENBIT>
108 | 		<PIT-NOT-WIDE>)
109 | 	       (T
110 | 		<CANT-GO>
111 | 		<RFALSE>)>
112 | 	 <RFALSE>>
113 | 
114 | <ROUTINE PIT-NOT-WIDE ()
115 | 	 <TELL ,CANT " fit into the pit. It's too narrow." CR>>
116 | 
117 | <OBJECT LAKE-SAND
118 | 	(IN EDGE-OF-LAKE)
119 | 	(DESC "sand")
120 | 	(SYNONYM SAND MESSAGE TRACKS X)
121 | 	(ADJECTIVE SCRAWL ANIMAL)
122 | 	(FLAGS TRYTAKEBIT NDESCBIT READBIT)
123 | 	(ACTION LAKE-SAND-F)>
124 | 
125 | ; "TOOLBIT = pile of leaves disturbed"
126 | 
127 | <ROUTINE LAKE-SAND-F ()
128 | 	 <COND (<VERB? DIG SEARCH LOOK-UNDER LOOK-INSIDE>
129 | 		<COND (<AND ,SKEWED?
130 | 			    <FSET? ,PLATYPUS ,RMUNGBIT>
131 | 			    <NOT <FSET? ,LAKE-SAND ,RMUNGBIT>>>
132 | 		       <MOVE ,WHISTLE ,EDGE-OF-LAKE>
133 | 	               <THIS-IS-IT ,WHISTLE>
134 | 		       <TELL 
135 | "You discovered a " D ,WHISTLE " in the sand under the \"X\"!" CR>)
136 | 		      (T
137 | 		       <NOTHING-INTERESTING>)>
138 | 		<FSET ,LAKE-SAND ,RMUNGBIT>
139 | 		<FCLEAR ,LEAVES ,RMUNGBIT>
140 | 		<RTRUE>)
141 | 	       (<VERB? EXAMINE READ LOOK-ON FOLLOW>
142 | 		<COND (<FSET? ,LAKE-SAND ,RMUNGBIT>
143 | 		       <YOU-ERASED-SAND>
144 | 		       <RTRUE>)
145 | 		      (<FSET? ,PLATYPUS ,RMUNGBIT>
146 | 		       <TELL ,YOU-SEE "an \"X\" drawn in the sand." CR>)
147 | 		      (T
148 | 		       <COND (,SKEWED?
149 | 			      <TELL 
150 | "The animal tracks emerge from the lake and lead to the edge of the pit, where they ">
151 | 			      <COND (<FSET? ,LAKE-SAND ,TOOLBIT>
152 | 				     <TELL 
153 | "turn and head back into the water">)
154 | 				    (T
155 | 				     <TELL "disappear abruptly">)>
156 | 			      <TELL "." CR>)
157 | 			     (T
158 | 			      <FCLEAR ,LEAVES ,RMUNGBIT>
159 | 			      <SAY-THE ,SCRAWL>
160 | 			      <TELL 
161 | " in the sand reads, \"Do Not Disturb!\"" CR>)>)>
162 | 		<RTRUE>)
163 | 	       (<AND <VERB? THROUGH ENTER>
164 | 		     <NOT <FSET? ,LAKE-SAND ,RMUNGBIT>>>
165 | 		<WASTE-SAND>
166 | 		<RTRUE>)
167 | 	       (<AND <VERB? TAKE>
168 | 		     <EQUAL? ,PRSO ,LAKE-SAND>>
169 | 		<PERFORM ,V?TAKE ,SAND>
170 | 		<RTRUE>)
171 | 	       (<AND <VERB? PUT PUT-ON THROW>
172 | 		     <EQUAL? ,PRSI ,LAKE-SAND>>
173 | 		<PERFORM ,V?DROP ,PRSO>
174 | 		<RTRUE>)
175 | 	       (<AND <OR <HURT? ,LAKE-SAND>
176 | 			 <VERB? RUB>>
177 | 		     <NOT <FSET? ,LAKE-SAND ,RMUNGBIT>>>
178 | 		<WASTE-SAND>
179 | 		<RTRUE>)
180 | 	       
181 | 	       (T
182 | 		<RFALSE>)>>
183 | 
184 | <ROUTINE WASTE-SAND ()
185 | 	 <FSET ,LAKE-SAND ,RMUNGBIT>
186 | 	 <FCLEAR ,LEAVES ,RMUNGBIT>
187 | 	 <YOU-ERASED-SAND>>
188 | 
189 | <ROUTINE YOU-ERASED-SAND ()
190 | 	 <TELL "You rubbed out all the markings in the sand." CR>>
191 | 
192 | <OBJECT PIT
193 | 	(IN EDGE-OF-LAKE)
194 | 	(DESC "pit")
195 | 	(SYNONYM PIT HOLE TRAP SNARE)
196 | 	(ADJECTIVE DEEP NARROW)
197 | 	(FLAGS CONTBIT NDESCBIT)
198 | 	(CAPACITY 25)
199 | 	(ACTION PIT-F)
200 | 	(CONTFCN IN-PIT)>
201 | 
202 | <GLOBAL PIT-FULL? <>>
203 | 
204 | <ROUTINE IN-PIT (CONTEXT)
205 | 	 <COND (<AND <EQUAL? .CONTEXT ,M-CONT>
206 | 		     <VERB? TAKE>
207 | 		     <NOT <EQUAL? ,PRSO ,BRANCH>>>
208 | 		<TELL ,CANT " reach ">
209 | 		<ARTICLE ,PRSO T>
210 | 		<TELL D ,PRSO ". ">
211 | 		<SAY-THE ,PIT>
212 | 		<TELL " is ">
213 | 		<COND (,PIT-FULL?
214 | 		       <TELL "full of rainwater">)
215 | 		      (T
216 | 		       <TELL "a little too deep">)>
217 | 		<TELL "." CR>
218 | 		<RFATAL>)
219 | 	       (T
220 | 		<RFALSE>)>>
221 | 
222 | <ROUTINE PIT-F ()
223 | 	 <COND (<NOT <FSET? ,PIT ,OPENBIT>>
224 | 		<CANT-SEE-ANY ,PIT>
225 | 		<RFATAL>)>
226 | 	 <THIS-IS-IT ,PIT>
227 | 	 <COND (<VERB? EXAMINE LOOK-INSIDE LOOK-DOWN>
228 | 		<SAY-THE ,PIT>
229 | 		<TELL " is ">
230 | 		<COND (,PIT-FULL?
231 | 		       <FILLED-PIT>)
232 | 		      (T
233 | 		       <TELL "more than five feet deep.">)>
234 | 		<COND (<FIRST? ,PIT>
235 | 		       <TELL " " ,YOU-SEE>
236 | 		       <PRINT-CONTENTS ,PIT>
237 | 		       <TELL " in it.">)>
238 | 		<CRLF>
239 | 		<RTRUE>)
240 | 	       (<VERB? CLOSE HIDE>
241 | 		<TELL ,CANT ". The leaves that used to cover the pit have all blown away." CR>
242 | 		<RTRUE>)
243 | 	       (<GETTING-INTO?>
244 | 		<PIT-NOT-WIDE>
245 | 		<RTRUE>)
246 | 	       (<AND <VERB? PUT THROW>
247 | 		     <EQUAL? ,PRSI ,PIT>>
248 | 		<COND ; (<EQUAL? ,PRSO ,KITTY>
249 | 		         <NOT-LIKELY ,KITTY "would cooperate">
250 | 		         <RTRUE>)
251 | 		      (<PUTTING-OPEN-UMBRELLA?>
252 | 		       <RTRUE>)
253 | 		      (<EQUAL? ,PRSO ,BRANCH>
254 | 		       <MOVE ,BRANCH ,PIT>
255 | 		       <TELL ,OKAY "the " D ,BRANCH
256 | 			     " is now standing up inside the">
257 | 		       <COND (,PIT-FULL?
258 | 		              <TELL " watery">)>
259 | 		       <TELL " pit." CR>
260 | 		       <COND (<IN? ,PLATYPUS ,PIT>
261 | 		              <FSET ,PLATYPUS ,TOOLBIT>
262 | 		              <CRLF>
263 | 			      <SAY-THE ,PLATYPUS>
264 | 			      <TELL
265 | " grabs onto the bottom of the " D ,BRANCH " with its forepaws." CR>)>
266 | 		       <RTRUE>)
267 | 		      (,PIT-FULL?
268 | 		       <REMOVE ,PRSO>
269 | 		       <TELL "You watch as ">
270 | 		       <ARTICLE ,PRSO T>
271 | 		       <TELL D ,PRSO " sinks into the watery pit." CR>
272 | 		       <RTRUE>)
273 | 		      (T
274 | 		       <RFALSE>)>)		       
275 | 	       (<VERB? OPEN>
276 | 		<ALREADY-OPEN>
277 | 		<RTRUE>)
278 | 	       (<VERB? REACH-IN EMPTY>
279 | 		<TELL ,CANT ". ">
280 | 		<SAY-THE ,PIT>
281 | 		<TELL " is ">
282 | 		<COND (,PIT-FULL?
283 | 		       <FILLED-PIT>)
284 | 		      (T
285 | 		       <TELL "too deep.">)>
286 | 		<CRLF>
287 | 		<RTRUE>)
288 | 	       (T
289 | 		<RFALSE>)>>
290 | 
291 | <ROUTINE FILLED-PIT ()
292 | 	 <TELL "filled with rainwater.">>
293 | 
294 | <OBJECT LEAVES
295 | 	(IN EDGE-OF-LAKE)
296 | 	(DESC "pile of leaves")
297 | 	(SYNONYM LEAVES)
298 | 	(ADJECTIVE PATCH PILE CIRCUL ROUND)
299 | 	(FLAGS NDESCBIT TAKEBIT RMUNGBIT)
300 | 	(ACTION LEAVES-F)
301 | 	(VALUE 0)
302 | 	(SIZE 5)>
303 | 
304 | ; "RMUNGBIT = warning not read yet"
305 | 
306 | <ROUTINE LEAVES-F ()
307 | 	 <COND (<FSET? ,PIT ,OPENBIT>
308 | 		<SAY-THE ,LEAVES>
309 | 		<TELL " blew away when you disturbed it." CR>
310 | 		<RFATAL>)
311 |                (<AND <VERB? TAKE>
312 | 		     <EQUAL? ,PRSO ,LEAVES>>
313 | 		<TELL "The leaves slip through your fingers." CR>
314 | 		<RTRUE>)
315 | 	       (<VERB? EXAMINE>
316 | 		<SAY-THE ,LEAVES>
317 | 		<TELL " is crisscrossed with twigs to keep it from blowing away. There seems to be something underneath." CR>
318 | 		<RTRUE>) 
319 | 	       (<AND <VERB? LOOK-UNDER MOVE PULL PUSH SEARCH KICK RAISE RUB>
320 | 		     <EQUAL? ,PRSO ,LEAVES>>
321 | 		<COND (<DISTURB-LEAVES?>
322 | 		       <RTRUE>)
323 | 		      (<WANT-TO-MUNG?>
324 | 		       <TELL "Moving the " D ,LEAVES " reveals">
325 | 		       <DESCRIBE-PIT>)>		       
326 | 		<RTRUE>)
327 | 	       (<VERB? ENTER THROUGH WALK-TO CROSS>
328 | 		<COND (<DISTURB-LEAVES?>
329 | 		       <RTRUE>)
330 | 		      (<WANT-TO-MUNG?>
331 | 		       <SAY-THE ,LEAVES>
332 | 		       <TELL " caves in under your feet, revealing">
333 | 		       <DESCRIBE-PIT>)>
334 | 		<RTRUE>)
335 | 	       (<VERB? COUNT>
336 | 		<COUNT-LEAVES>
337 | 		<RTRUE>)
338 | 	       (T
339 | 		<RFALSE>)>>
340 | 
341 | <ROUTINE COUNT-LEAVES ()
342 | 	 <TELL "A quick count turns up exactly 69,105 leaves." CR>>
343 | 
344 | <ROUTINE DISTURB-LEAVES? ()
345 | 	 <COND (<FSET? ,LEAVES ,RMUNGBIT>
346 | 		<TELL
347 | "(You'd better read the message in the sand before you disturb the " D ,LEAVES
348 | ".)" CR>
349 | 		<RTRUE>)
350 | 	       (T
351 | 		<RFALSE>)>>
352 | 
353 | <ROUTINE WANT-TO-MUNG? ()
354 | 	 <SAY-SURE>
355 | 	 <TELL "disturb that " D ,LEAVES 
356 | "? There's an old saying about curiosity...">
357 | 	 <COND (<YES?>
358 | 		<RTRUE>)
359 | 	       (T
360 | 		<TELL ,OKAY "the leaves are still intact." CR>
361 | 		<RFALSE>)>>
362 | 
363 | <ROUTINE DESCRIBE-PIT ()
364 | 	 <FSET ,PIT ,OPENBIT>
365 | 	 <TELL " a deep, narrow pit in the sand. It appears to be a trap of some kind.|
366 | |
367 | The leaves blow away in the breeze." CR CR>
368 | 	 <UPDATE-SCORE -10>>
369 | 
370 | <OBJECT PLATYPUS
371 | 	(DESC "platypus")
372 | 	(SYNONYM PLATYPUS TASMANIA)
373 | 	(ADJECTIVE PRINCESS)
374 | 	(FLAGS ACTORBIT TRYTAKEBIT NDESCBIT)
375 | 	(ACTION PLATYPUS-F)
376 | 	(VALUE 0)
377 | 	(SIZE 10)>
378 | 
379 | ; "PLATYPUS STATE FLAGS: TOOLBIT = HOLDING ON, RMUNGBIT = GONE"
380 | 
381 | <ROUTINE PLATYPUS-F ("OPTIONAL" (CONTEXT <>)) 
382 | 	 <COND (<VERB? EXAMINE>
383 | 		<SAY-THE ,PLATYPUS>
384 | 		<TELL " is ">
385 | 		<COND (<FSET? ,PLATYPUS ,TOOLBIT>
386 | 		       <TELL 
387 | "clutching the end of the " D ,BRANCH " and looking up at you expectantly">)
388 | 		      (T
389 | 		       <TELL 
390 | "obviously unhappy about being trapped in the pit">)>
391 | 		<TELL "." CR>
392 | 		<RTRUE>)
393 | 	       (<TALKING-TO? ,PLATYPUS>
394 | 		<SAY-THE ,PLATYPUS>
395 | 		<TELL " stares back at you impatiently." CR>
396 | 		<RFATAL>)
397 | 	       (<AND <VERB? GIVE>
398 | 		     <EQUAL? ,PRSI ,PLATYPUS>>
399 | 		<SAY-THE ,PLATYPUS>
400 | 		<TELL " doesn't seem interested." CR>
401 | 		<RTRUE>)
402 | 	       (<VERB? RESCUE RELEASE>
403 | 		<TELL "Very thoughtful of you. ">
404 | 		<HOW?>
405 | 		<RTRUE>)
406 | 	       (<TOUCHING? ,PLATYPUS>
407 | 		<TELL ,CANT " reach the " D ,PLATYPUS 
408 | 		      " while it's in the pit." CR>
409 | 		<RTRUE>)
410 | 	       (T
411 | 		<RFALSE>)>>
412 | 
413 | <ROUTINE DRAW-X ()
414 | 	 <START-BUZZ 4>
415 | 	 <REMOVE ,PLATYPUS>
416 | 	 <FCLEAR ,PLATYPUS ,TOOLBIT>
417 | 	 <FSET ,PLATYPUS ,RMUNGBIT>
418 | 	 <FCLEAR ,LAKE-SAND ,RMUNGBIT>
419 | 	 <TELL "The little creature draws an \"X\" in the ">
420 | 	 <COND (,PIT-FULL?
421 | 		<TELL "wet ">)>
422 | 	 <TELL "sand with its tail. Then it gives you an oddly dignified nod of thanks, waddles to">
423 | 	 <EDGE>
424 | 	 <TELL " and disappears into the dark water." CR>>
425 | 
426 | "*** RIVER OUTLET ***"
427 | 
428 | <OBJECT RIVER-OUTLET
429 | 	(IN ROOMS)
430 | 	(DESC "River Outlet")
431 | 	(FLAGS ONBIT RLANDBIT WETBIT)
432 | 	(GLOBAL LAKE RIVER HILL TRAIL)
433 | 	(NORTH PER PROBABLY-DROWN-IN-RIVER)
434 | 	(EAST TO SOUTH-OF-BRIDGE)
435 | 	(SOUTH TO EDGE-OF-LAKE)
436 | 	(WEST PER PROBABLY-DROWN)
437 | 	(UP TO LOOKOUT-HILL)
438 | 	(ACTION RIVER-OUTLET-F)>
439 | 
440 | <ROUTINE RIVER-OUTLET-F (CONTEXT)
441 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
442 | 		<TELL
443 | "This is where the lake empties into the">
444 | 		<WHICH-TOWN "River">
445 | 		<TELL ". A road leads south along">
446 | 		<EDGE>
447 | 		<TELL ", and bends east to follow the river bank. A narrow "
448 | D ,TRAIL " leads upward to the top of ">
449 | 		<PRINTD ,LOOKOUT-HILL>
450 | 		<TELL "." CR>)>>
451 | 
452 | "*** LOOKOUT HILL ***"
453 | 
454 | <OBJECT TRAIL
455 | 	(IN LOCAL-GLOBALS)
456 | 	(DESC "trail")
457 | 	(SYNONYM TRAIL)
458 | 	(ADJECTIVE STEEP NARROW SHIMMERING)
459 | 	(FLAGS NDESCBIT)
460 | 	(ACTION TRAIL-F)>
461 | 
462 | <ROUTINE TRAIL-F ()
463 | 	 <COND (<AND <EQUAL? ,HERE ,CLIFF-BOTTOM>
464 | 		     ,SKEWED?>
465 | 		<TRAIL-MISPLACED>
466 | 		<RFATAL>)
467 | 	       (<AND <EQUAL? ,HERE ,ROCKY-PATH>
468 | 		     <OR <NOT ,SKEWED?>
469 | 			 ,HOUSE-VISITED?>>
470 | 		<CANT-SEE-ANY ,TRAIL>
471 | 		<RFATAL>)
472 | 	       (<VERB? WALK-TO ENTER THROUGH EXIT USE CLIMB-ON>
473 | 		<COND (<EQUAL? ,HERE ,LOOKOUT-HILL ,CLIFF-EDGE>
474 | 		       <DO-WALK ,P?DOWN>)
475 | 		      (<EQUAL? ,HERE ,RIVER-OUTLET ,CLIFF-BOTTOM>
476 | 		       <DO-WALK ,P?UP>)
477 | 		      (<EQUAL? ,HERE ,ROCKY-PATH>
478 | 		       <DO-WALK ,P?SOUTH>)
479 | 		      (<EQUAL? ,HERE ,WEST-OF-HOUSE>
480 | 		       <DO-WALK ,P?NORTH>)
481 | 		      (T
482 | 		       <V-WALK-AROUND>)>
483 | 		<RTRUE>)
484 | 	       (<VERB? CLIMB-DOWN>
485 | 		<COND (<OR <EQUAL? ,HERE ,STEEP-TRAIL ,FOG ,CLIFF-EDGE>
486 | 			   <EQUAL? ,HERE ,LOOKOUT-HILL>>
487 | 		       <DO-WALK ,P?DOWN>)
488 | 		      (<EQUAL? ,HERE ,ROCKY-PATH>
489 | 		       <DO-WALK ,P?SOUTH>)
490 | 		      (<EQUAL? ,HERE ,WEST-OF-HOUSE>
491 | 		       <DO-WALK ,P?NORTH>)
492 | 		      (T
493 | 		       <ALREADY-AT ,TRAIL>)>
494 | 		<RTRUE>)
495 | 	       (<VERB? CLIMB-UP>
496 | 		<COND (<OR <EQUAL? ,HERE ,RIVER-OUTLET ,CLIFF-BOTTOM ,FOG>
497 | 			   <EQUAL? ,HERE ,STEEP-TRAIL>>
498 | 		       <DO-WALK ,P?UP>)
499 | 		      (<EQUAL? ,HERE ,ROCKY-PATH>
500 | 		       <DO-WALK ,P?SOUTH>)
501 | 		      (<EQUAL? ,HERE ,WEST-OF-HOUSE>
502 | 		       <DO-WALK ,P?NORTH>)
503 | 		      (T
504 | 		       <ALREADY-AT ,TRAIL T>)>
505 | 		<RTRUE>)
506 | 	       (<VERB? EXAMINE LOOK-DOWN LOOK-UP>
507 | 		<V-LOOK>
508 | 		<RTRUE>)
509 | 	       (T
510 | 		<YOU-DONT-NEED ,TRAIL>
511 | 		<RFATAL>)>>
512 | 
513 | <OBJECT LOOKOUT-HILL
514 | 	(IN ROOMS)
515 | 	(DESC "Lookout Hill")
516 | 	(FLAGS ONBIT RLANDBIT)
517 | 	(GLOBAL TRAIL HILL ; TREE HOLE STUMP)
518 | 	(NORTH PER NORTH-DOWN-HILL)
519 | 	(EAST PER TUMBLE)
520 | 	(SOUTH PER TUMBLE)
521 | 	(WEST PER TUMBLE)
522 | 	(DOWN PER DOWN-THE-HILL)
523 | 	(IN TO UNDER-HILL IF STUMP IS OPEN)
524 | 	(ACTION LOOKOUT-HILL-F)>
525 | 
526 | <ROUTINE NORTH-DOWN-HILL ()
527 | 	 <GET-OFF-STUMP?>
528 | 	 <RETURN ,RIVER-OUTLET>>
529 | 
530 | <ROUTINE DOWN-THE-HILL ()
531 | 	 <COND (<FSET? ,STUMP ,OPENBIT>
532 | 		<TELL "(Do you want to go down the north side of the hill, or down into the open stump? Please type NORTH or IN.)" CR>
533 | 		<SETG CLOCK-WAIT T>
534 | 		<RFALSE>)
535 | 	       (T
536 | 	      ; <COND (<NOT <VERB? CLIMB-DOWN>>
537 | 		       <TELL ,I-ASSUME " north, down the hill.)" CR>)>
538 | 		<GET-OFF-STUMP?>
539 | 		<RETURN ,RIVER-OUTLET>)>>
540 | 
541 | <ROUTINE LOOKOUT-HILL-F (CONTEXT)
542 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
543 | 		<STANDING>
544 | 		<TELL 
545 | "at the summit of a high, barren hill. Looking east, you can see">
546 | 		<WHICH-TOWN "Village">
547 | 		<TELL " nestled among the trees. A narrow " D ,TRAIL " winds down the north side of the hill, towards the river.|
548 | |
549 | Crowning the hill is the " D ,STUMP " of what must have been a very large and majestic oak tree.">
550 | 		<COND (<FSET? ,STUMP ,OPENBIT>
551 | 		       <TELL
552 | " An opening in the " D ,STUMP " leads down into " D ,DARKNESS ".">)>
553 | 		<CRLF>)>>
554 | 
555 | <OBJECT STUMP
556 | 	(IN LOCAL-GLOBALS)
557 | 	(DESC "stump")
558 | 	(SYNONYM STUMP UNDERSIDE)
559 |       ; (ADJECTIVE HOLE OPENING)
560 | 	(FLAGS NDESCBIT TRYTAKEBIT DOORBIT RMUNGBIT)
561 | 	(ACTION STUMP-F)>
562 | 
563 | ; "RMUNGBIT = stump not yet opened or examined"
564 | 
565 | <GLOBAL ON-STUMP? <>>
566 | 
567 | <ROUTINE STUMP-F ()
568 | 	 <COND (<VERB? EXAMINE LOOK-ON>
569 | 		<SAY-THE ,STUMP>
570 | 		<COND (<FSET? ,STUMP ,OPENBIT>
571 | 		       <TELL " is open, revealing a round hole that leads ">
572 | 		       <COND (<EQUAL? ,HERE ,LOOKOUT-HILL>
573 | 			      <TELL "downward into " D ,DARKNESS>)
574 | 			     (T
575 | 			      <TELL "upward into moonlight">)>)
576 | 		      (T
577 | 		       <TELL " is huge, easily four feet across">
578 | 		       <COND (,SKEWED?
579 | 		              <FCLEAR ,STUMP ,RMUNGBIT>
580 | 			      <TELL
581 | ". Looking closely, you notice that the edge of the " D ,STUMP 
582 | " is hinged">)>)>
583 | 		<TELL "." CR>
584 | 		<RTRUE>)
585 | 	       
586 | 	       (<VERB? OPEN RAISE>
587 | 		<COND (<FSET? ,STUMP ,OPENBIT>
588 | 		       <ALREADY-OPEN>)>
589 | 		<GET-OFF-STUMP?>
590 | 		<COND (,SKEWED?
591 | 	               <FSET ,UNDER-HILL ,ONBIT>
592 | 		       <SETG LIT T>
593 | 		       <FSET ,STUMP ,OPENBIT>
594 | 		       <FCLEAR ,STUMP ,RMUNGBIT>
595 | 	               <TELL "Lifting the hinged top of the " D ,STUMP 
596 | " reveals a round hole leading ">
597 | 		       <COND (<EQUAL? ,HERE ,LOOKOUT-HILL>
598 | 			      <TELL "downward into " D ,DARKNESS>)
599 | 			     (T
600 | 			      <TELL "upward into moonlight">)>)
601 | 		      (T
602 | 		       <TELL ,CANT>
603 | 		       <DO-TO>
604 | 		       <TELL "an ordinary stump">)>
605 | 		<TELL "." CR>
606 | 		<RTRUE>)
607 | 	       
608 | 	       (<VERB? CLOSE LOWER>
609 | 		<COND (<FSET? ,STUMP ,OPENBIT>
610 | 		       <FCLEAR ,STUMP ,OPENBIT>
611 | 		       <FCLEAR ,UNDER-HILL ,ONBIT>
612 | 		       <SETG LIT <LIT? ,HERE>>
613 | 		       <SAY-THE ,STUMP>
614 | 		       <TELL " closes with a hollow bang">)
615 | 	              (T
616 | 		       <BUT-THE ,STUMP>
617 | 		       <TELL "isn't open">)>
618 | 		<TELL "." CR>
619 | 		<RTRUE>)
620 | 	       
621 | 	       (<AND <VERB? MOVE PULL PUSH>
622 | 		     <EQUAL? ,PRSO ,STUMP>>
623 | 		<COND (<NOT ,SKEWED?>
624 | 		       <TOO-LARGE ,STUMP>)
625 | 		      (<FSET? ,STUMP ,OPENBIT>
626 | 		       <PERFORM ,V?CLOSE ,STUMP>)
627 | 		      (T
628 | 		       <PERFORM ,V?OPEN ,STUMP>)>
629 | 		<RTRUE>)
630 | 	       
631 | 	       (<VERB? SIT STAND-ON CLIMB-ON>
632 | 		<COND (<EQUAL? ,HERE ,UNDER-HILL>
633 | 		       <ALREADY-ON ,STUMP T>)
634 | 		      (,ON-STUMP?
635 | 		       <ALREADY-ON ,STUMP>)
636 | 		      (<FSET? ,STUMP ,OPENBIT>
637 | 		       <UNFORTUNATELY>
638 | 		       <TELL
639 | "you forgot to close the " D ,STUMP " first. Crash!">
640 | 		       <CARRIAGE-RETURNS>
641 | 		       <FCLEAR ,UNDER-HILL ,TOUCHBIT>
642 | 		       <DO-WALK ,P?IN>
643 | 		       <RFATAL>)
644 | 		      (T
645 | 		       <SETG ON-STUMP? T>
646 | 		       <EXCELLENT-VIEW ,STUMP>)>
647 | 		<RTRUE>)
648 | 	       
649 | 	       (<VERB? CLIMB-UP>
650 | 		<COND (<EQUAL? ,HERE ,UNDER-HILL>
651 | 		       <DO-WALK ,P?UP>)
652 | 		      (T
653 | 		       <PERFORM ,V?SIT ,STUMP>)>
654 | 		<RTRUE>)
655 | 	       (<VERB? CLIMB-DOWN TAKE-OFF LEAP>
656 | 		<COND (,ON-STUMP?
657 | 		       <SETG ON-STUMP? <>>
658 | 		       <TELL ,OKAY "you're no longer">)
659 | 		      (<AND <FSET? ,STUMP ,OPENBIT>
660 | 			    <EQUAL? ,HERE ,LOOKOUT-HILL>>
661 | 		       <DO-WALK ,P?IN>
662 | 		       <RTRUE>)
663 | 		      (T
664 | 		       <TELL "But you're not">)>
665 | 		<TELL " on the " D ,STUMP "." CR>
666 | 		<RTRUE>)
667 | 	       
668 | 	       (<VERB? WALK-TO THROUGH ENTER>
669 | 		<COND (<FSET? ,STUMP ,OPENBIT>
670 | 		       <COND (<EQUAL? ,HERE ,LOOKOUT-HILL>
671 | 			      <DO-WALK ,P?IN>)
672 | 			     (T
673 | 			      <DO-WALK ,P?UP>)>)
674 | 		      (T
675 | 		       <STUMP-NOT-OPEN>)>
676 | 		<RTRUE>)
677 | 	       
678 | 	       (<VERB? LOOK-INSIDE>
679 | 		<COND (<FSET? ,STUMP ,OPENBIT>
680 | 		       <CANT-MAKE-OUT-ANYTHING>)
681 | 		      (T
682 | 		       <STUMP-NOT-OPEN>)>
683 | 		<RTRUE>)
684 | 	       	       
685 | 	       (<AND <VERB? PUT THROW>
686 | 		     <EQUAL? ,PRSI ,STUMP>>
687 | 		<COND (<NOT ,SKEWED?>
688 | 		       <WASTE-OF-TIME>
689 | 		       <RTRUE>)
690 | 		      (<NOT <FSET? ,STUMP ,OPENBIT>>
691 | 		       <ITS-CLOSED ,STUMP>
692 | 		       <RTRUE>)
693 | 		      (<EQUAL? ,PRSO ,HANDS>
694 | 		       <NOTHING-EXCITING>
695 | 		       <RTRUE>)
696 | 		    ; (<NOT <THROUGH-HOLE?>>
697 | 		       <RFATAL>)
698 | 		      (<PUTTING-OPEN-UMBRELLA?>
699 | 		       <RTRUE>)
700 | 		      (<G? <GETP ,PRSO ,P?SIZE> 10>
701 | 		       <TOO-LARGE ,PRSO>
702 | 		       <RTRUE>)
703 | 		      (<EQUAL? ,HERE ,LOOKOUT-HILL>
704 | 		       <MOVE ,PRSO ,UNDER-HILL>)
705 | 		      (T
706 | 		       <MOVE ,PRSO ,LOOKOUT-HILL>)>
707 | 		<TELL ,OKAY>
708 | 		<ARTICLE ,PRSO T>
709 | 		<TELL D ,PRSO " disappears into the " D ,STUMP "." CR>
710 | 		<RTRUE>)
711 | 	       (T 
712 | 	        <RFALSE>)>>
713 | 
714 | <ROUTINE GET-OFF-STUMP? ()
715 | 	 <COND (,ON-STUMP?
716 | 		<SETG ON-STUMP? <>>
717 | 		<TELL "(climbing off the " D ,STUMP " first)" CR>
718 | 		<RTRUE>)
719 | 	       (T
720 | 		<RFALSE>)>>
721 | 
722 | <ROUTINE STUMP-NOT-OPEN ()
723 | 	 <COND (<FSET? ,STUMP ,RMUNGBIT>
724 | 		<SAY-THE ,STUMP>
725 | 	        <TELL " has no visible openings." CR>)
726 | 	       (T
727 | 		<ITS-CLOSED ,STUMP>)>>
728 | 	 
729 | <OBJECT SHOE
730 | 	(IN LOOKOUT-HILL)
731 | 	(DESC "horseshoe")
732 | 	(FDESC "A horseshoe is lying in the grass near the stump.")
733 | 	(SYNONYM HORSESHOE SHOE)
734 | 	;(ADJECTIVE HORSE)
735 | 	(FLAGS TAKEBIT WEARBIT)
736 | 	(SIZE 5)
737 | 	(VALUE 0)
738 | 	(ACTION SHOE-F)>
739 | 
740 | <ROUTINE SHOE-F ()
741 | 	 <COND (<AND <VERB? EXAMINE>
742 | 		     <FSET? ,SHOE ,ONBIT>>
743 | 		<SAY-THE ,SHOE>
744 | 		<TELL " is twinkling with lucky Magick." CR>
745 | 		<RTRUE>)
746 | 	       (<VERB? WEAR>
747 | 		<TELL "You don't have any shoeing nails." CR>
748 | 		<RTRUE>)
749 | 	       (<AND <VERB? THROW PLAY>
750 | 		     <NOT ,PRSI>>
751 | 		<TELL "This is no time for lawn games." CR>
752 | 		<RTRUE>)
753 | 	       (T
754 | 		<RFALSE>)>>
755 | 		
756 | <OBJECT LAKE
757 | 	(IN LOCAL-GLOBALS)
758 | 	(DESC "lake")
759 | 	(SYNONYM LAKE POND WATER)
760 | 	(FLAGS NDESCBIT TRYTAKEBIT CONTBIT OPENBIT)
761 | 	(ACTION LAKE-F)>
762 | 
763 | <ROUTINE LAKE-F ()
764 | 	 <COND (<VERB? EXAMINE>
765 | 		<TELL "The surface of the lake is ">
766 | 		<COND (,SKEWED?
767 | 		       <TELL "black and sinister">)
768 | 		      (T
769 | 		       <TELL "bright with ripples">)>
770 | 		<TELL "." CR>
771 | 		<RTRUE>)
772 | 	       (<HANDLE-WATER?>
773 | 		<RTRUE>)
774 | 	       (T
775 | 		<RFALSE>)>>
776 | 
777 | 


--------------------------------------------------------------------------------
/globals.zil:
--------------------------------------------------------------------------------
  1 | "GLOBALS for WISHBRINGER: (C)1985 Infocom, Inc. All Rights Reserved."
  2 | 
  3 | <DIRECTIONS NORTH NE EAST SE SOUTH SW WEST NW UP DOWN IN OUT>
  4 | 
  5 | <GLOBAL HERE 0>
  6 | 
  7 | <GLOBAL LIT T>
  8 | 
  9 | <GLOBAL MOVES 0>
 10 | <GLOBAL SCORE 0>
 11 | 
 12 | <OBJECT GLOBAL-OBJECTS
 13 | 	(FLAGS RMUNGBIT INVISIBLE TOUCHBIT SURFACEBIT
 14 | 	       TRYTAKEBIT OPENBIT SEARCHBIT TRANSBIT
 15 | 	       WEARBIT VOWELBIT ONBIT RLANDBIT
 16 | 	       ACTORBIT TAKEBIT NDESCBIT NARTICLEBIT
 17 | 	       TOOLBIT LOCKEDBIT WISHBIT
 18 | 	       INDOORSBIT FLAMEBIT WORNBIT THROWNBIT
 19 | 	       WETBIT VEHBIT)>
 20 | 
 21 | <OBJECT LOCAL-GLOBALS
 22 | 	(IN GLOBAL-OBJECTS)
 23 | 	(SYNONYM ZZZP)
 24 | 	(DESCFCN 0)
 25 |         (GLOBAL GLOBAL-OBJECTS)
 26 | 	(ADVFCN 0)
 27 | 	(FDESC "F")
 28 | 	(LDESC "L")
 29 | 	(PSEUDO "FOOBAR" V-WALK)
 30 | 	(CONTFCN 0)
 31 | 	(SIZE 0)
 32 | 	;(TEXT "")
 33 | 	(CAPACITY 0)>
 34 | 
 35 | <OBJECT ROOMS
 36 | 	(IN TO ROOMS)>
 37 | 
 38 | <OBJECT INTNUM
 39 | 	(IN GLOBAL-OBJECTS)
 40 | 	(SYNONYM INTNUM)
 41 | 	(DESC "number")>
 42 | 
 43 | <OBJECT PSEUDO-OBJECT
 44 | 	(DESC "pseudo")
 45 | 	(ACTION ME-F)>
 46 | 
 47 | <OBJECT IT
 48 | 	(IN GLOBAL-OBJECTS)
 49 | 	(SYNONYM IT THAT)
 50 | 	(DESC "it")
 51 | 	(FLAGS VOWELBIT NARTICLEBIT NDESCBIT TOUCHBIT)>
 52 | 
 53 | <ROUTINE BE-SPECIFIC ()
 54 | 	 <TELL "(Be specific: what do you want to ">>
 55 | 
 56 | <ROUTINE TO-DO-THING-USE (STR1 STR2)
 57 | 	 <TELL "(To " .STR1 " something, use the command: " 
 58 | 	       .STR2 " THING.)" CR>>
 59 | 
 60 | <ROUTINE CANT-USE (PTR "AUX" BUF) 
 61 | 	<SETG QUOTE-FLAG <>>
 62 | 	<SETG P-OFLAG <>>
 63 | 	<TELL "(This story can't understand the word \"">
 64 | 	<WORD-PRINT <GETB <REST ,P-LEXV <SET BUF <* .PTR 2>>> 2>
 65 | 	<GETB <REST ,P-LEXV .BUF> 3>>
 66 | 	<TELL "\" when you use it that way.)" CR>>
 67 | 
 68 | <ROUTINE DONT-UNDERSTAND ()
 69 | 	<TELL "(That sentence didn't make sense. Please reword it or try something else.)" CR>>
 70 | 
 71 | <ROUTINE NOT-IN-SENTENCE (STR)
 72 | 	 <TELL "(There aren't " .STR " in that sentence!)" CR>>
 73 | 
 74 | <OBJECT DUST
 75 | 	(IN GLOBAL-OBJECTS)
 76 | 	(DESC "dust")
 77 | 	(SYNONYM DUST DIRT GRIME FILTH)>
 78 | 
 79 | <OBJECT GROUND
 80 | 	(IN GLOBAL-OBJECTS)
 81 | 	(DESC "ground")
 82 | 	(SYNONYM FLOOR GROUND LAWN GRASS)
 83 | 	(FLAGS NDESCBIT SURFACEBIT)
 84 | 	(CAPACITY 30000)
 85 | 	(ACTION GROUND-F)>
 86 | 
 87 | <ROUTINE GROUND-F ()
 88 | 	 <COND (<VERB? EXAMINE LOOK-ON SEARCH>
 89 | 		<COND (<AND <EQUAL? ,HERE ,INSIDE-THEATER>
 90 | 			    <FSET? ,GLASSES ,RMUNGBIT>>
 91 | 		       <PERFORM ,V?LOOK-UNDER ,SEAT>)
 92 | 		      (T
 93 | 		       <TELL ,YOU-SEE "nothing " <PICK-ONE ,YAWNS>
 94 | 		             " about the ">
 95 | 		       <GROUND-OR-FLOOR>
 96 | 		       <TELL "." CR>)>
 97 | 		<RTRUE>)		 
 98 | 	       (<VERB? SIT LIE-DOWN>
 99 | 		<V-LIE-DOWN>)
100 | 	       (<VERB? CROSS WALK-TO THROUGH ENTER>
101 | 		<V-WALK-AROUND>)
102 | 	       (<VERB? LOOK-UNDER PUT-UNDER>
103 | 		<HOW?>)
104 | 	       (<AND <VERB? PUT PUT-ON>
105 | 		     <EQUAL? ,PRSI ,GROUND ,AISLE>>
106 | 		<PERFORM ,V?DROP ,PRSO>)
107 | 	       (<AND <VERB? TAKE>
108 | 		     <EQUAL? ,PRSI ,GROUND ,AISLE>>
109 | 		<PERFORM ,V?TAKE ,PRSO>
110 | 		<RTRUE>)
111 | 	       (<EQUAL? ,AISLE ,PRSO ,PRSI>
112 | 		<RFALSE>)
113 | 	       (T
114 | 		<YOU-DONT-NEED ,GROUND>
115 | 		<RFATAL>)>
116 | 	 <RTRUE>>
117 | 
118 | <ROUTINE GROUND-OR-FLOOR ()
119 | 	 <COND (<FSET? ,HERE ,INDOORSBIT>
120 | 		<TELL "floor">)
121 | 	       (T
122 | 		<PRINTD ,GROUND>)>>
123 | 
124 | <OBJECT ROAD 
125 | 	(IN GLOBAL-OBJECTS)
126 | 	(DESC "road")
127 | 	(SYNONYM ROAD STREET PATH)
128 | 	(ACTION HERE-F)>
129 | 
130 | <ROUTINE HERE-F ()
131 | 	 <COND (<VERB? EXAMINE LOOK-INSIDE LOOK-DOWN>
132 | 		<V-LOOK>)
133 | 	       (<VERB? FIND>
134 | 		<TELL "It's right here!" CR>)
135 | 	       (<VERB? FOLLOW WALK-TO WALK LEAVE CROSS CLIMB-ON CLIMB-UP
136 | 		       CLIMB-DOWN ENTER THROUGH>
137 | 		<V-WALK-AROUND>
138 | 		<RFATAL>)
139 | 	       (<VERB? SIT LIE-DOWN DIG>
140 | 		<WASTE-OF-TIME>)
141 | 	       (<AND <VERB? PUT PUT-ON THROW>
142 | 		     <EQUAL? ,PRSI ,PSEUDO-OBJECT>>
143 | 		<PERFORM ,V?DROP ,PRSO>)
144 | 	       (<OR <TALKING-TO? ,ROAD>
145 | 		    <VERB? YELL>>
146 | 		<NOTHING-EXCITING>
147 | 		<RFATAL>)
148 | 	       (T
149 | 		<YOU-DONT-NEED "area" T>)>
150 | 	 <RTRUE>>
151 | 
152 | <OBJECT WALLS
153 | 	(IN GLOBAL-OBJECTS)
154 | 	(FLAGS NDESCBIT TOUCHBIT)
155 | 	(DESC "wall")
156 | 	(SYNONYM WALL WALLS)
157 | 	(ACTION WALLS-F)>
158 | 	 
159 | <ROUTINE WALLS-F ()
160 | 	 <COND (<AND <NOT <FSET? ,HERE ,INDOORSBIT>>
161 | 		     <NOT <EQUAL? ,HERE ,INSIDE-GRAVE>>>
162 | 		<CANT-SEE-ANY ,WALLS>
163 | 		<RFATAL>)
164 | 	       (<OR <GETTING-INTO?>
165 | 		    <VERB? LOOK-BEHIND>>
166 | 		<TELL <PICK-ONE ,YUKS> CR>)
167 | 	       (<VERB? LOOK-UNDER>
168 | 		<TELL "There's a floor there." CR>)
169 | 	       (<OR <HURT? ,WALLS>
170 | 		    <MOVING? ,WALLS>>
171 | 		<SAY-THE ,WALLS>
172 | 		<TELL " is not affected." CR>)
173 | 	       (<OR <TALKING-TO? ,WALLS>
174 | 		    <VERB? YELL>>
175 | 		<TELL "Talking to walls">
176 | 		<SIGN-OF-COLLAPSE>
177 | 		<RFATAL>)
178 | 	       (T
179 | 		<YOU-DONT-NEED ,WALLS>
180 | 		<RFATAL>)>
181 | 	 <RTRUE>>
182 | 		
183 | <OBJECT CEILING
184 | 	(IN GLOBAL-OBJECTS)
185 | 	(FLAGS NDESCBIT TOUCHBIT)
186 | 	(DESC "ceiling")
187 | 	(SYNONYM CEILING)
188 | 	(ACTION CEILING-F)>
189 | 
190 | <ROUTINE CEILING-F ()
191 | 	 <COND (<NOT <FSET? ,HERE ,INDOORSBIT>>
192 | 		<CANT-SEE-ANY ,CEILING>
193 | 		<RFATAL>)
194 | 	       (<VERB? LOOK-UNDER>
195 | 		<V-LOOK>
196 | 		<RTRUE>)
197 | 	       (<VERB? EXAMINE LOOK-ON>
198 | 		<COND (<EQUAL? ,HERE ,UNDER-CELL>
199 | 		       <PERFORM ,V?EXAMINE ,HIDDEN-HATCH>)
200 | 		      (<EQUAL? ,HERE ,ON-BRIDGE>
201 | 		       <TELL "The bridge is covered by a roof." CR>)
202 | 		      (T
203 | 		       <RFALSE>)>
204 | 		<RTRUE>)
205 | 	       (T
206 | 		<RFALSE>)>>
207 | 
208 | <OBJECT HANDS
209 | 	(IN GLOBAL-OBJECTS)
210 | 	(DESC "your hand")
211 | 	(SYNONYM HAND HANDS)
212 | 	(ADJECTIVE MY BARE)
213 | 	(FLAGS NDESCBIT TOOLBIT TOUCHBIT NARTICLEBIT)>
214 | 
215 | <OBJECT PROTAGONIST
216 | 	(IN HILLTOP)
217 | 	(SYNONYM PROTAG)
218 | 	(DESC "yourself")
219 | 	(FLAGS NDESCBIT NARTICLEBIT INVISIBLE)
220 | 	(ACTION 0)
221 | 	(SIZE 0)>
222 | 
223 | ; <OBJECT POCKET
224 | 	(IN PROTAGONIST)
225 | 	(DESC "your pocket")
226 | 	(SYNONYM POCKET)
227 | 	(ADJECTIVE MY)
228 | 	(FLAGS WORNBIT NDESCBIT OPENBIT NARTICLEBIT CONTBIT)
229 | 	(CAPACITY 10)
230 | 	(ACTION POCKET-F)>
231 | 
232 | ; <ROUTINE POCKET-F ("AUX" OBJ NXT)
233 | 	 <COND (<VERB? LOOK-INSIDE SEARCH LOOK-DOWN EXAMINE>
234 | 		<COND (<FIRST? ,POCKET>
235 | 		       <TELL "There's ">
236 | 		       <PRINT-CONTENTS ,POCKET>
237 | 		       <TELL " in " D ,POCKET>)
238 | 		      (T
239 | 		       <TELL "Y">
240 | 		       <POCKET-EMPTY>)>
241 | 		<TELL "." CR>
242 | 		<RTRUE>)
243 | 	       (<AND <VERB? PUT THROW>
244 | 		     <EQUAL? ,PRSI ,POCKET>>
245 | 		<COND (<AND <EQUAL? ,PRSO ,CANDLE>
246 | 			    <FSET? ,CANDLE ,ONBIT>>
247 | 		       <TELL "Putting a lighted " D ,CANDLE
248 | 			     " in " D ,POCKET " isn't a good idea." CR>
249 | 		       <RTRUE>)
250 | 		      (<EQUAL? ,PRSO ,HANDS>
251 | 		       <TELL "No wonder " D ,CRISP " says you're lazy!" CR>
252 | 		       <RTRUE>)
253 | 		      (T
254 | 		       <RFALSE>)>)
255 | 	       (<VERB? OPEN CLOSE>
256 | 		<TELL "You don't need to do that." CR>
257 | 		<RTRUE>)
258 | 	       (<VERB? TAKE-OFF>
259 | 		<TELL <PICK-ONE ,YUKS> CR>
260 | 		<RTRUE>)
261 | 	       (<HURT? ,POCKET>
262 | 		<WASTE-OF-TIME>
263 | 		<RTRUE>)
264 | 	       (T
265 | 		<RFALSE>)>>
266 | 		
267 | <OBJECT ME
268 | 	(IN GLOBAL-OBJECTS)
269 | 	(SYNONYM I ME MYSELF)
270 | 	(DESC "yourself")
271 | 	(FLAGS ACTORBIT TOUCHBIT NARTICLEBIT)
272 | 	(ACTION ME-F)>
273 | 
274 | <ROUTINE ME-F ("OPTIONAL" (CONTEXT <>) "AUX" OLIT) 
275 | 	 <COND (<VERB? ALARM>
276 | 		<TELL "You're already wide awake." CR>
277 | 		<RTRUE>)
278 | 	       (<OR <TALKING-TO? ,ME>
279 | 		    <VERB? YELL>>
280 | 		<TALK-TO-SELF>
281 | 		<RFATAL>)
282 | 	       (<VERB? LISTEN>
283 | 		<TELL ,CANT " help doing that." CR>
284 | 		<RTRUE>)
285 | 	       (<AND <VERB? GIVE>
286 | 		     <EQUAL? ,PRSI ,ME>>
287 | 		<COND (<HELD? ,PRSO>
288 | 		       <TELL "You already have it." CR>)
289 | 		      (T
290 | 		       <PERFORM ,V?TAKE ,PRSO>)>
291 | 		<RTRUE>)
292 | 	       (<VERB? KILL>
293 | 		<TELL "Desperate? Call the Samaritans." CR>
294 | 		<RTRUE>)
295 | 	       (<VERB? FIND>
296 | 		<TELL "You're right here!" CR>
297 | 		<RTRUE>)
298 | 	       (<HURT? ,ME>
299 | 		<TELL "Punishing yourself that way won't help matters." CR>
300 | 		<RTRUE>)
301 | 	       (T
302 | 		<RFALSE>)>>
303 | 
304 | <ROUTINE TALK-TO-SELF ()
305 | 	 <TELL "Talking to yourself">
306 | 	 <SIGN-OF-COLLAPSE>
307 | 	 <PCLEAR>>
308 | 
309 | <ROUTINE SIGN-OF-COLLAPSE ()
310 | 	 <TELL " is said to be a sign of impending mental collapse." CR>>
311 | 
312 | <OBJECT GLOBAL-ROOM
313 | 	(IN GLOBAL-OBJECTS)
314 | 	(DESC "room")
315 | 	(SYNONYM ROOM AREA PLACE)
316 | 	(ACTION GLOBAL-ROOM-F)>
317 | 
318 | <ROUTINE GLOBAL-ROOM-F ()
319 | 	 <COND (<VERB? LOOK EXAMINE LOOK-INSIDE>
320 | 		<V-LOOK>
321 | 		<RTRUE>)
322 | 	       (<VERB? ENTER THROUGH DROP EXIT>
323 | 		<V-WALK-AROUND>
324 | 		<RFATAL>)
325 | 	       (<VERB? WALK-AROUND>
326 | 		<TELL
327 | "Walking around the area reveals nothing new.|
328 | |
329 | (If you want to go somewhere, just type a direction.)" CR>
330 | 		<RTRUE>)
331 | 	       (T
332 | 		<RFALSE>)>>
333 | 	       
334 | <ROUTINE ALREADY-IN (PLACE "OPTIONAL" (NOT? <>))
335 | 	 <TELL "But you're ">
336 | 	 <COND (.NOT?
337 | 		<TELL "not">)
338 | 	       (T
339 | 		<TELL "already">)>
340 | 	 <TELL " in ">
341 | 	 <ARTICLE .PLACE T>
342 | 	 <TELL D .PLACE "!" CR>>
343 | 
344 | <ROUTINE UPDATE-SCORE (POINTS)
345 | 	 <SETG GSCORE <+ ,GSCORE .POINTS>>
346 | 	 <TELL "(Your score just went ">
347 | 	 <COND (<G? .POINTS -1>
348 | 		<TELL "up">)
349 | 	       (T
350 | 		<TELL "DOWN">)>
351 | 	 <TELL " by " N <ABS .POINTS> " point">
352 | 	 <COND (<NOT <EQUAL? .POINTS 1 -1>>
353 | 		<TELL "s">)>
354 | 	 <TELL "! Your total score is " N ,GSCORE " out of 100.)" CR>>
355 | 	      
356 | <ROUTINE GO-INSIDE ()
357 | 	 <TELL "Why not go inside and look around?" CR>>
358 | 
359 | <ROUTINE CANT-MAKE-OUT-ANYTHING ()
360 | 	 <TELL ,CANT " make out anything inside." CR>>
361 | 
362 | <ROUTINE OBJECT-IS-LOCKED ()
363 | 	 <TELL ,CANT " do that. It's locked." CR>>
364 | 
365 | <ROUTINE CANT-SEE-ANY ("OPTIONAL" (THING <>) (STRING? <>))
366 | 	 <YOU-CANT-SEE>
367 | 	 <COND (.STRING?
368 | 		<TELL .THING>)
369 | 	       (.THING
370 | 		<COND (<NOT <FSET? .THING ,NARTICLEBIT>>
371 | 		       <TELL "any ">)>
372 | 		<TELL D .THING>)
373 | 	       (T
374 | 		<TELL "that">)>
375 | 	 <TELL " here!" CR>>
376 | 
377 | <ROUTINE YOU-CANT-SEE ()
378 | 	 <SETG CLOCK-WAIT T>
379 | 	 <PCLEAR>
380 | 	 <TELL ,CANT " see ">>
381 | 
382 | <ROUTINE HOW-WOULD-YOU-LIKE-IT (OBJ)
383 | 	 <TELL
384 | "How would you like it if somebody did that to YOUR " D .OBJ "?" CR>>
385 | 
386 | <OBJECT SIGN
387 | 	(IN LOCAL-GLOBALS)
388 | 	(DESC "sign")
389 | 	(SYNONYM SIGN SIGNPOST POST MESSAGE)
390 | 	(ADJECTIVE PAINT PAINTED HANDPAINTED NEON)
391 | 	(FLAGS NDESCBIT READBIT TRYTAKEBIT)
392 | 	(ACTION SIGN-F)>
393 | 
394 | <ROUTINE SIGN-F ()
395 | 	 <COND (<VERB? READ EXAMINE>
396 | 		
397 | 		<COND (<EQUAL? ,HERE ,HILLTOP>
398 | 	               <TELL
399 | "There are two arrows on the signpost. The arrow pointing west says \"To Cemetery.\" The east arrow is marked \"To">
400 | 		       <WHICH-TOWN>
401 | 		       <TELL ".\"" CR>)
402 | 	              
403 | 		      (<EQUAL? ,HERE ,ROTARY-WEST>
404 | 		       <SAY-THE ,SIGN>
405 | 		       <TELL " over the " D ,ENTRANCE " says, \"">
406 | 		       <COND (,SKEWED?
407 | 			      <TELL "Witchville">)
408 | 			     (T
409 | 			      <TELL "Festeron">)>
410 | 		       <TELL " Police Headquarters.\"" CR>) 
411 | 		      
412 | 	       	      (<EQUAL? ,HERE ,NORTH-OF-BRIDGE>
413 | 		       <COND (,SKEWED?
414 | 			      <TELL  
415 | "The childlike scrawl is hard to decipher. With a little imagination, you can make out the phrase \"Toll Bridge, One Gold Coin.\"" CR>)
416 | 			     (T
417 | 			      <CANT-SEE-ANY ,SIGN>)>)
418 | 		      
419 | 		      (<EQUAL? ,HERE ,CLIFF-EDGE>
420 | 		       <DESCRIBE-SIGN>)
421 | 		      
422 | 		      (<EQUAL? ,HERE ,PLEASURE-WHARF>
423 | 		       <TELL "The neon sign says, \"VIDEO GAMES.\"" CR>)
424 | 		      
425 | 		      (<EQUAL? ,HERE ,EDGE-OF-LAKE>
426 | 		       <PERFORM ,V?READ ,SAND>)
427 | 		      
428 | 		      (<EQUAL? ,HERE ,GRUE-NEST>
429 | 		       <PERFORM ,V?EXAMINE ,REFRIGERATOR>)
430 | 
431 | 		      (<EQUAL? ,HERE ,VIDEO-ARCADE>
432 | 		       <ARCADE-SIGN>)
433 | 		      
434 | 		      (<EQUAL? ,HERE ,CIRCULATION-DESK>
435 | 		       <SAY-THE ,SIGN>
436 | 		       <TELL 
437 | " over the hall says, \"To " D ,MUSEUM ".\"" CR>)
438 | 		      
439 | 		      (<EQUAL? ,HERE ,MUSEUM>
440 | 		       <SAY-DCASE-SIGN>)
441 | 		      
442 | 		      (T
443 | 		       <RFALSE>)>
444 | 		<RTRUE>)
445 | 	       
446 | 	       (<OR <HURT? ,SIGN>
447 | 		    <VERB? TAKE RUB PUT PUSH MOVE>>
448 | 		<WASTE-OF-TIME>
449 | 		<RTRUE>)
450 | 	       
451 | 	       (T
452 | 		<YOU-DONT-NEED ,SIGN>
453 | 		<RFATAL>)>>
454 | 
455 | <ROUTINE CANT-FIT-INTO? (PLACE)
456 | 	 <COND (<IN? ,BRANCH ,PROTAGONIST>
457 | 		<NEVER-GET-IN .PLACE "that branch">
458 | 		<RTRUE>)
459 | 	       (<AND <IN? ,UMBRELLA ,PROTAGONIST>
460 | 		     <FSET? ,UMBRELLA ,OPENBIT>>
461 | 		<NEVER-GET-IN .PLACE "that open umbrella">
462 | 		<RTRUE>)
463 | 	       (<G? <WEIGHT ,PROTAGONIST> 18>
464 | 		<NEVER-GET-IN .PLACE "all that stuff">
465 | 		<RTRUE>)
466 | 	       (T
467 | 	        <RFALSE>)>>
468 | 
469 | <ROUTINE NEVER-GET-IN (PLACE THING)
470 | 	 <TELL
471 | "You'll never get into the " .PLACE " holding " .THING "!" CR>>
472 | 
473 | <ROUTINE GET-INTO (PLACE)
474 | 	 <TELL "With great effort, you manage to squeeze yourself into the "
475 | .PLACE "." CR CR>>
476 | 
477 | <ROUTINE NOT-LIQUID ()
478 | 	 <ITS-NOT-A "liquid">>
479 | 
480 | <ROUTINE NOT-SOLID ()
481 | 	 <ITS-NOT-A "solid">>
482 | 
483 | <ROUTINE ITS-NOT-A (STR)
484 | 	 <TELL "It's not a " .STR "." CR>>
485 | 
486 | <ROUTINE COME-TO-SENSES ()
487 | 	 <CARRIAGE-RETURNS>
488 | 	 <SETG BROOM-SIT? <>>
489 | 	 <TELL 
490 | "You come to your senses empty-handed and aching all over." CR CR>
491 | 	 <V-LOOK>
492 | 	 <I-LUCK>
493 | 	 <I-GLOW>>
494 | 
495 | <ROUTINE PROBABLY-DROWN-IN-RIVER ()
496 | 	 <PROBABLY-DROWN T>
497 | 	 <RFALSE>>
498 | 
499 | <ROUTINE PROBABLY-DROWN ("OPTIONAL" (RIVER? <>))
500 | 	 <TELL "You'd probably drown in the ">
501 | 	 <COND (.RIVER?
502 | 		<PRINTD ,RIVER>)
503 | 	       (<EQUAL? ,HERE ,WHARF ,TIDAL-POOL ,FESTERON-POINT>
504 | 		<PRINTD ,BAY>)
505 | 	       (<EQUAL? ,HERE ,EDGE-OF-LAKE ,RIVER-OUTLET ,ISLAND>
506 | 		<PRINTD ,LAKE>)
507 | 	       (<EQUAL? ,HERE ,PARK>
508 | 		<PRINTD ,FOUNTAIN>)
509 | 	       (<AND <EQUAL? ,HERE ,HILLTOP>
510 | 		     ,SKEWED?>
511 | 		<PRINTD ,MOAT>)
512 | 	       (T
513 | 		<PRINTD ,RIVER>)>
514 | 	 <WENT-THAT-WAY>
515 | 	 <RFALSE>>
516 | 
517 | <ROUTINE WENT-THAT-WAY ()
518 | 	 <TELL " if you went that way." CR>>
519 | 
520 | <ROUTINE WATER-DIRTY ()
521 | 	 <TELL "Better not. The water might be dirty." CR>>
522 | 
523 | <ROUTINE HANDLE-WATER? ()
524 | 	 <COND (<GETTING-INTO?>
525 | 	        <PROBABLY-DROWN>)
526 | 	       (<VERB? DRINK TASTE>
527 | 		<WATER-DIRTY>)
528 | 	       (<VERB? EAT BITE>
529 | 		<NOT-SOLID>)
530 | 	       (<AND <VERB? PUT PUT-ON PUT-UNDER THROW>
531 | 		     <OR <EQUAL? ,PRSI ,BAY ,RIVER ,LAKE>
532 | 			 <EQUAL? ,PRSI ,MOAT>>>
533 | 	        <REMOVE ,PRSO>
534 | 		<TELL "Splash!" CR CR>
535 | 		<COND (<EQUAL? ,PRSO ,HORSE ,DHORSE>
536 | 		       <COND (<ENABLED? ,I-HORSE-DEATH>
537 | 			      <DISABLE <INT I-HORSE-DEATH>>)>
538 | 		       <SAY-THE ,PRSO>
539 | 		       <TELL 
540 | " floats without moving for a few anxious moments. Then it ">
541 | 		       <COND (<EQUAL? ,PRSO ,DHORSE>
542 | 		              <TELL
543 | "sinks slowly into the dark water">)
544 | 		             (T 
545 | 		              <SETG HORSE-SAVED? T>
546 | 		              <TELL "springs suddenly to life, circling and splashing joyfully in the waves. Before it swims away it looks up at you with an unmistakable expression of gratitude">)>
547 | 		       <TELL "." CR>)
548 | 		      
549 | 		      (<AND <EQUAL? ,PRSO ,CANDLE>
550 | 			    <FSET? ,CANDLE ,ONBIT>>
551 | 		       <TELL "Weird! ">
552 | 		       <SAY-THE ,CANDLE>
553 | 		       <TELL " remains lit even as it">
554 | 		       <SINKS-INTO-WATER>)
555 | 		      
556 | 		      (T
557 | 		       <TELL "Silently, ">
558 | 		       <ARTICLE ,PRSO T>
559 | 		       <TELL D ,PRSO>
560 | 		       <SINKS-INTO-WATER>)>)
561 | 	       (<AND <VERB? PUSH-TO>
562 | 		     <OR <EQUAL? ,PRSI ,BAY ,RIVER ,LAKE>
563 | 			 <EQUAL? ,PRSI ,MOAT>>>
564 | 		<COND (<HELD? ,PRSO>
565 | 		       <PRESUMABLY-YOU-WANT-TO "PUT it in" ,PRSI>
566 | 		       <PERFORM ,V?PUT ,PRSO ,PRSI>
567 | 		       <RTRUE>)
568 | 		      (<AND <IN? ,PRSO ,HERE>
569 | 			    <FSET? ,PRSO ,TAKEBIT>>
570 | 		       <MOVE ,PRSO ,PROTAGONIST>
571 | 		       <TELL "(with your foot)" CR>
572 | 		       <PERFORM ,V?PUT ,PRSO ,PRSI>
573 | 		       <RTRUE>)
574 | 		      (T
575 | 		       <V-PUSH-TO>)>)
576 | 	       (<SEE-VERB?>
577 | 		<TELL "The water is too deep to see much of anything." CR>)
578 | 	       (T
579 | 		<YOU-DONT-NEED "water" T>
580 | 		<RFATAL>)>
581 | 	 <RTRUE>>
582 | 
583 | <ROUTINE SINKS-INTO-WATER ()
584 | 	 <TELL " disappears beneath the surface of ">
585 | 	 <ARTICLE ,PRSI T>
586 | 	 <TELL D ,PRSI "." CR>>
587 | 			    
588 | <ROUTINE YOU-ARE-HOLDING (THING "OPTIONAL" (AGAIN <>))
589 | 	 <THIS-IS-IT .THING>
590 | 	 <TELL CR CR "(You are ">
591 | 	 <COND (.AGAIN
592 | 		<TELL "again">)
593 | 	       (T
594 | 		<TELL "now">)>
595 | 	 <TELL " holding ">
596 | 	 <ARTICLE .THING .AGAIN>
597 | 	 <TELL D .THING ".)">>
598 | 
599 | <ROUTINE NOTHING-EXCITING ()
600 | 	 <TELL "Nothing exciting happens." CR>>
601 | 
602 | <ROUTINE THAT-WAS-CLOSE ()
603 | 	 <TELL "Whew! That was close." CR>>
604 | 
605 | <ROUTINE GOOD-PLACE-TO-SAVE ()
606 | 	 <TELL CR 
607 | "(This might be a good time to SAVE your story position.)" CR>>
608 | 
609 | <ROUTINE HOW? ()
610 | 	 <TELL "How do you intend to do that?" CR>>
611 | 
612 | <OBJECT CORNER
613 | 	(IN LOCAL-GLOBALS)
614 | 	(DESC "corner")
615 | 	(SYNONYM CORNER)
616 | 	(FLAGS NDESCBIT)
617 | 	(ACTION CORNER-F)>
618 | 
619 | <ROUTINE CORNER-F ()
620 | 	 <COND (<VERB? EXAMINE LOOK-ON LOOK-INSIDE>
621 | 	        <V-LOOK>
622 | 	        <RTRUE>)
623 | 	       (<GETTING-INTO?>
624 | 	        <TELL 
625 | "You're close enough to the " D ,CORNER " already." CR>
626 | 	        <RTRUE>)
627 | 	       (T
628 | 	        <YOU-DONT-NEED ,CORNER>
629 | 		<RFATAL>)>>
630 | 
631 | <ROUTINE TOO-FAR-AWAY (OBJ)
632 | 	 <UNFORTUNATELY>
633 | 	 <ARTICLE .OBJ T>
634 | 	 <TELL D .OBJ " is too far away for you to do that." CR>>
635 | 
636 | <ROUTINE UNFORTUNATELY ()
637 | 	 <TELL "Unfortunately, ">>
638 | 
639 | <ROUTINE EXCELLENT-VIEW (OBJ)
640 | 	 <SAY-THE .OBJ>
641 | 	 <TELL " affords an excellent view of the surrounding area." CR>>
642 | 
643 | <ROUTINE ALREADY-AT (OBJ "OPTIONAL" (TOP? <>))
644 | 	 <TELL "You're already at the ">
645 | 	 <COND (.TOP?
646 | 		<TELL "top">)
647 | 	       (T
648 | 		<TELL "bottom">)>
649 | 	 <TELL " of the " D .OBJ "!" CR>>
650 | 
651 | <ROUTINE LOITERING-ON (OBJ)
652 | 	 <TELL "There's no reason to loiter around the " D .OBJ "." CR>>
653 | 
654 | <ROUTINE PRESUMABLY-YOU-WANT-TO (STR "OPTIONAL" (THING <>))
655 | 	 <TELL ,I-ASSUME " " .STR " ">
656 | 	 <COND (.THING
657 | 		<ARTICLE .THING T>
658 | 	        <TELL D .THING>)
659 | 	       (T
660 | 		<TELL "it">)>
661 | 	 <TELL ".)" CR>>
662 | 
663 | <ROUTINE MAKE-IT-SNAPPY ()
664 | 	 <TELL
665 | " If you want to make a wish, you'd better make it snappy!)">>
666 | 
667 | <ROUTINE HOLD-YOUR-PEACE ()
668 | 	 <TELL
669 | " Wish now, or forever hold your peace!)">>
670 | 
671 | <ROUTINE IT-IGNORES-YOU (WHO)
672 | 	 <SAY-THE .WHO>
673 | 	 <TELL " " <PICK-ONE ,IGNORANCE> "." CR>>
674 | 
675 | <GLOBAL IGNORANCE
676 | 	<LTABLE 0
677 | 	 "studiously ignores you"
678 | 	 "pretends not to understand you"
679 | 	 "pays no attention to you"
680 | 	 "makes a rude little noise">>
681 | 	 
682 | <OBJECT SOUND
683 | 	(IN GLOBAL-OBJECTS)
684 | 	(DESC "sound")
685 | 	(SYNONYM SOUND VOICE VOICES MUSIC)
686 | 	(ADJECTIVE NOISE NOISES)
687 | 	(FLAGS NDESCBIT NARTICLEBIT)
688 | 	(ACTION SOUND-F)>
689 | 
690 | <ROUTINE SOUND-F ()
691 | 	 <COND (<VERB? LISTEN>
692 | 		<COND (<EQUAL? ,HERE ,INSIDE-THEATER>
693 | 		       <COND (<OR <EQUAL? ,MOVIE-SCRIPT 6>
694 | 				  ,ECLIPSE?>
695 | 			      <BLANK-SCREEN>)
696 | 			     (T
697 | 			      <TELL 
698 | "The soundtrack is an artless mix of Witchville slogans and John Philip Sousa marches, played at earsplitting volume." CR>)>
699 | 		       <RTRUE>)
700 | 		      
701 | 		      (<AND <EQUAL? ,HERE ,LOBBY>
702 | 		            <L? ,MOVIE-SCRIPT 6>
703 | 			    <NOT ,ECLIPSE?>>
704 | 		       <TELL ,YOU-HEAR  
705 | "a blare of noise coming from inside the " D ,MOVIE-THEATER>)
706 | 		      
707 | 		      (<AND <EQUAL? ,HERE ,HILLTOP>
708 | 			    <NOT <FSET? ,ENVELOPE ,RMUNGBIT>>> ; "Not given?"
709 | 		       <TELL
710 | "Uh-oh! The calling voice belongs to">
711 | 		       <BOSS>
712 | 		       <TELL "!" CR>
713 | 		       <RTRUE>)
714 | 
715 | 		      (<AND <EQUAL? ,HERE ,MUSEUM>
716 | 			    <ENABLED? ,I-PLEA>>
717 | 		       <TELL "The voice sounds just like the " 
718 | D ,OLD-WOMAN " you met at the " D ,MAGICK-SHOPPE>)
719 | 		      
720 | 		      (<AND <EQUAL? ,HERE ,INSIDE-SHOPPE>
721 | 			    <FSET? ,CLOCK ,RMUNGBIT>>
722 | 		       <PERFORM ,V?LISTEN ,CLOCK>
723 | 		       <RTRUE>)
724 | 		      
725 | 		      (<EQUAL? ,HERE ,JAIL-CELL>
726 | 		       <COND (<L? ,JAIL-SCRIPT 9>
727 | 			      <TELL "The ">
728 | 			      <EVIL-VOICES>
729 | 			      <TELL " don't sound very friendly." CR>)
730 | 			     (T
731 | 			      <HEAR-WAILS>)>
732 | 		       <RTRUE>)
733 | 		      
734 | 		      (T
735 | 		       <TELL 
736 | "At the moment, you hear nothing " <PICK-ONE ,YAWNS>>)>
737 | 		<TELL "." CR>
738 | 		<RTRUE>)
739 | 	       (<VERB? FOLLOW WALK-TO>
740 | 		<V-WALK-AROUND>)
741 | 	       (<VERB? WAIT-FOR>
742 | 		<V-WAIT>)
743 | 	       (<AND <VERB? REPLY>
744 | 		     <EQUAL? ,HERE ,HILLTOP>
745 | 		     <NOT <FSET? ,ENVELOPE ,RMUNGBIT>>> ; "Not given?"
746 | 	        <TELL "You'll have to go inside to do that." CR>)
747 | 	       (<OR <TALKING-TO? ,SOUND>
748 | 		    <VERB? YELL>>
749 | 		<TELL "Try addressing the source of the sound." CR>
750 | 		<RFATAL>)
751 | 	       (T
752 | 		<TELL ,CANT>
753 | 		<DO-TO>
754 | 		<TELL "a " D ,SOUND "!" CR>)>
755 | 	 <RTRUE>>
756 | 
757 | <ROUTINE TOO-LARGE (THING "OPTIONAL" (SMALL? <>))
758 | 	 <BUT-THE .THING>
759 | 	 <TELL "is much too ">
760 | 	 <COND (.SMALL?
761 | 		<TELL "small">)
762 | 	       (T
763 | 		<TELL "large">)>
764 | 	 <TELL "!" CR>>
765 | 			      
766 | <ROUTINE FROBOZZ (STR)
767 | 	 <TELL "Frobozz Magic " .STR " Company">>
768 | 
769 | <ROUTINE NOT-LIKELY (THING STR)
770 | 	 <TELL "It" <PICK-ONE ,LIKELIES> " that ">
771 | 	 <ARTICLE .THING T>
772 | 	 <TELL D .THING " " .STR "." CR>>
773 | 
774 | <GLOBAL LIKELIES 
775 | 	<LTABLE 0
776 | 	 " isn't likely"
777 | 	 " seems doubtful"
778 | 	 " seems unlikely"
779 | 	 "'s unlikely"
780 | 	 "'s not likely"
781 | 	 "'s doubtful">>
782 | 
783 | <ROUTINE YOUD-HAVE-TO (STR THING)
784 | 	 <TELL "You'd have to " .STR " ">
785 | 	 <ARTICLE .THING T>
786 | 	 <TELL D .THING " to do that." CR>>
787 | 
788 | <ROUTINE CLOSED-AND-LOCKED ()
789 | 	 <TELL " closed and locked." CR>>
790 | 
791 | ; <ROUTINE OPENED ()
792 | 	 <TELL "Opened.">>
793 | 
794 | <ROUTINE STANDING ()
795 | 	 <TELL "You're standing ">>
796 | 
797 | <ROUTINE DO-TO ()
798 | 	 <TELL " do that to ">>
799 | 
800 | <ROUTINE INTRO ()
801 | 	 <TELL "\"Behind you!\" cries the Princess. \"It's a trap!\"|
802 | |
803 | Too late. The " D ,DRAWBRIDGE " crashes shut against the " D ,TOWER " wall. You turn to face your enemy, and find yourself staring into the open maw of">>
804 | 
805 | <ROUTINE FIRED ("OPTIONAL" (TIMEOUT? <>))
806 | 	 <TELL CR "\"There you are, " <PICK-ONE ,INSULTS> "!\"|
807 | |
808 | You wince as " D ,CRISP " strides into view and grabs you by the front of your uniform.|
809 | |
810 | \"You good-for-nothing " <PICK-ONE ,INSULTS> "!\" he bellows in your face. \"I wanted you to ">
811 | 	 <COND (.TIMEOUT?
812 | 		<TELL "deliver that envelope BEFORE five o'clock! Now the " 
813 | D ,MAGICK-SHOPPE " is closed... and y">)
814 | 	       (T
815 | 		<TELL "get back to the " D ,POST-OFFICE
816 | 		      " as soon as you were done with that envelope! Y">)>
817 | 	 <TELL "ou're FIRED!\"">
818 |          <BAD-ENDING>>
819 | 
820 | <ROUTINE SAY-HURRY ()
821 | 	 <TELL CR "(It's ">
822 | 	 <TELL-TIME>
823 | 	 <TELL ". Better hurry! ">>
824 | 
825 | <ROUTINE BETTER-HURRY ("OPTIONAL" (HALF? <>))
826 | 	 <SAY-HURRY>
827 | 	 <SAY-THE ,MAGICK-SHOPPE>
828 | 	 <TELL " closes in less than ">
829 | 	 <COND (.HALF?
830 | 		<TELL "half ">)>
831 | 	 <TELL "an hour!)" CR>>
832 | 
833 | ; <ROUTINE PLACE-HOLDER (STR)
834 | 	 <TELL CR "[TESTER: " .STR ". Film at eleven. -BM]" CR>>
835 | 
836 | ; <ROUTINE VPRINT ("AUX" TMP)
837 | 	 <SET TMP <GET ,P-OTBL ,P-VERBN>>
838 | 	 <COND (<EQUAL? .TMP 0> <TELL "tell">)
839 | 	       (<ZERO? <GETB ,P-VTBL 2>>
840 | 		<PRINTB <GET .TMP 0>>)
841 | 	       (T
842 | 		<WORD-PRINT <GETB .TMP 2> <GETB .TMP 3>>)>>
843 | 
844 | ; <ROUTINE NOT-HERE (OBJ)
845 | 	 <SETG CLOCK-WAIT T>
846 | 	 <TELL ,CANT " see ">
847 | 	 <COND (<NOT <FSET? .OBJ ,NARTICLEBIT>> <TELL "any ">)>
848 | 	 <TELL D .OBJ " here." CR>>
849 | 
850 | <OBJECT HER
851 | 	(IN GLOBAL-OBJECTS)
852 | 	(SYNONYM SHE HER ; WOMAN ; GIRL ; LADY)
853 | 	(DESC "her")
854 | 	(FLAGS NARTICLEBIT)>
855 | 
856 | <OBJECT HIM
857 | 	(IN GLOBAL-OBJECTS)
858 | 	(SYNONYM HE HIM ; MAN ;BOY)
859 | 	(DESC "him")
860 | 	(FLAGS NARTICLEBIT)>
861 | 
862 | <OBJECT THEM
863 | 	(IN GLOBAL-OBJECTS)
864 | 	(SYNONYM THEY THEM)
865 | 	(DESC "them")
866 | 	(FLAGS NARTICLEBIT)>
867 | 
868 | <GLOBAL GAME "Wishbringer">
869 | <GLOBAL I-ASSUME "(Presumably, you mean">
870 | <GLOBAL CANT "You can't">
871 | 
872 | <SYNONYM EAST RIGHT>
873 | <SYNONYM WEST LEFT>
874 | 
875 | <OBJECT INTDIR
876 | 	(IN GLOBAL-OBJECTS)
877 | 	(DESC "direction")
878 | 	(SYNONYM DIRECTION)
879 | 	(ADJECTIVE NORTH EAST SOUTH WEST ; "UP DOWN" ; "NE NW SE SW")
880 |     ;  "(NE 0)
881 | 	(SE 0)
882 | 	(SW 0)
883 | 	(NW 0)" >
884 | 
885 | 
886 | 
887 | 
888 | 
889 | 


--------------------------------------------------------------------------------
/cemetery.zil:
--------------------------------------------------------------------------------
  1 | "CEMETERY for WISHBRINGER: (C)1985 Infocom, Inc. All rights reserved."
  2 | 
  3 | <OBJECT CREEPY-CORNER
  4 | 	(IN ROOMS)
  5 | 	(DESC "Creepy Corner")
  6 | 	(FLAGS ONBIT RLANDBIT)
  7 | 	(GLOBAL MONUMENTS TREE VAPORS SOUTH-GATE CORNER CEMETERY)
  8 | 	(NORTH PER ENTER-SPOOKY-COPSE)
  9 | 	(EAST PER EXIT-TO-OUTSIDE)
 10 | 	(SOUTH PER TOMBS-BLOCK)
 11 | 	(WEST PER TOMBS-BLOCK)
 12 | 	(OUT PER EXIT-TO-OUTSIDE)
 13 | 	(PSEUDO "LANE" HERE-F)
 14 | 	(ACTION CREEPY-CORNER-F)>
 15 | 
 16 | <ROUTINE TOMBS-BLOCK ()
 17 | 	 <THIS-IS-IT ,MONUMENTS>
 18 | 	 <SAY-THE ,MONUMENTS>
 19 | 	 <TELL "s block your path." CR>
 20 | 	 <RFALSE>>
 21 | 
 22 | <ROUTINE CREEPY-CORNER-F (CONTEXT)
 23 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
 24 | 		<TELL "You're in a creepy " D ,CORNER " of the">
 25 | 		<WHICH-TOWN "Cemetery">
 26 | 		<TELL ", surrounded by silent " D ,MONUMENTS "s. A">
 27 | 		<COND (<FSET? ,SOUTH-GATE ,OPENBIT>
 28 | 		       <TELL "n iron gate opens">)
 29 | 		      (T
 30 | 		       <TELL " closed iron gate stands">)>
 31 | 		<TELL 
 32 | " " <TO-E> ", and a narrow lane wanders north." CR>)>>
 33 | 
 34 | <ROUTINE EXIT-TO-OUTSIDE ()
 35 | 	 <COND (<FSET? ,SOUTH-GATE ,OPENBIT>
 36 | 		<COND (,SKEWED?
 37 | 		       <SLAM-THE-GATE>
 38 | 		       <RFALSE>)
 39 | 		      (T
 40 | 		       <SURE-IS-SPOOKY>
 41 | 		       <RETURN ,OUTSIDE-CEMETERY>)>)
 42 | 	       (T
 43 | 		<ITS-CLOSED ,SOUTH-GATE>
 44 | 		<RFALSE>)>>
 45 | 
 46 | <ROUTINE SURE-IS-SPOOKY ()
 47 | 	 <TELL "Whew! That " D ,CEMETERY " sure is spooky." CR CR>>
 48 | 
 49 | <OBJECT SPOOKY-COPSE
 50 | 	(IN ROOMS)
 51 | 	(DESC "Spooky Copse")
 52 | 	(FLAGS ONBIT RLANDBIT)
 53 | 	(GLOBAL MONUMENTS VAPORS CEMETERY)
 54 | 	(NORTH PER TOMBS-BLOCK)
 55 | 	(EAST PER TOMBS-BLOCK)
 56 | 	(SOUTH PER COPSE-TO-CORNER)
 57 | 	(WEST PER COPSE-TO-GLEN)
 58 | 	(DOWN PER ENTER-GRAVE)
 59 | 	(IN PER ENTER-GRAVE)
 60 | 	(PSEUDO "LANE" HERE-F)
 61 | 	(ACTION SPOOKY-COPSE-F)>
 62 | 
 63 | <ROUTINE SPOOKY-COPSE-F (CONTEXT)
 64 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
 65 | 		<TELL 
 66 | "A copse of " D ,WILLOWS "s makes this part of the " D ,CEMETERY " look really spooky. Narrow lanes wander south and west.|
 67 | |
 68 | There's an " D ,OPEN-GRAVE " nearby, freshly dug, with a " D ,MONUMENTS " erected next to it.">
 69 | 		<COND (<IN? ,GRAVEDIGGER ,SPOOKY-COPSE>
 70 | 		       <TELL CR CR
 71 | "An old " D ,GRAVEDIGGER " is resting under a " D ,WILLOWS ".">)>
 72 | 		<CRLF>)>>
 73 | 
 74 | <OBJECT TWILIGHT-GLEN
 75 | 	(IN ROOMS)
 76 | 	(DESC "Twilight Glen")
 77 | 	(FLAGS ONBIT RLANDBIT)
 78 | 	(GLOBAL MONUMENTS TREE VAPORS NORTH-GATE CEMETERY)
 79 | 	(NORTH PER EXIT-TO-LAKE)
 80 | 	(EAST PER RETURN-TO-COPSE)
 81 | 	(SOUTH PER TOMBS-BLOCK)
 82 | 	(WEST PER TOMBS-BLOCK)
 83 | 	(OUT PER EXIT-TO-LAKE)
 84 | 	(PSEUDO "LANE" HERE-F)
 85 | 	(ACTION TWILIGHT-GLEN-F)>
 86 | 
 87 | <ROUTINE EXIT-TO-LAKE ()
 88 | 	 <COND (<FSET? ,NORTH-GATE ,OPENBIT>
 89 | 		<COND (,SKEWED?
 90 | 		       <ESCAPE-VAPORS>)
 91 | 		      (T
 92 | 		       <SURE-IS-SPOOKY>)>
 93 | 		<RETURN ,EDGE-OF-LAKE>)
 94 | 	       (T
 95 | 		<ITS-CLOSED ,NORTH-GATE>
 96 | 		<RFALSE>)>>
 97 | 
 98 | <ROUTINE RETURN-TO-COPSE ()
 99 | 	 <COND (<IN? ,GRAVEDIGGER ,EDGE-OF-LAKE>
100 | 		<REMOVE ,GRAVEDIGGER>)>
101 | 	 <RETURN ,SPOOKY-COPSE>>
102 | 
103 | <ROUTINE TWILIGHT-GLEN-F (CONTEXT)
104 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
105 | 		<TELL 
106 | "The trees here are so thick, it's almost too dark to see! You can make out a">
107 | 		<OPEN-CLOSED ,NORTH-GATE T>
108 | 		<TELL D ,NORTH-GATE " " <TO-N> ", and a narrow lane between the " D ,MONUMENTS "s winds off " <TO-E> "." CR>)>>
109 | 
110 | <OBJECT NORTH-GATE
111 | 	(IN LOCAL-GLOBALS)
112 | 	(DESC "iron gate")
113 | 	(SYNONYM GATE GATES LOCK BARS)
114 | 	(ADJECTIVE IRON TALL)
115 | 	(FLAGS NDESCBIT VOWELBIT DOORBIT LOCKEDBIT OPENBIT RMUNGBIT)
116 | 	(ACTION NORTH-GATE-F)>
117 | 
118 | ; "RMUNGBIT = skewed gate not opened"
119 | 
120 | <ROUTINE NORTH-GATE-F ()
121 | 	 <THIS-IS-IT ,NORTH-GATE>
122 | 	 <COND (<VERB? ENTER THROUGH WALK-TO USE>
123 | 		<COND (<EQUAL? ,HERE ,TWILIGHT-GLEN>
124 | 		       <DO-WALK ,P?NORTH>)
125 | 		      (T
126 | 		       <DO-WALK ,P?SOUTH>)>
127 | 		<RTRUE>)
128 | 	       (<GENERIC-GATE? ,NORTH-GATE>
129 | 		<RTRUE>)
130 | 	       (T
131 | 		<RFALSE>)>>
132 | 
133 | <OBJECT INSIDE-GRAVE
134 | 	(IN ROOMS)
135 | 	(DESC "Open Grave")
136 | 	(FLAGS ONBIT RLANDBIT)
137 | 	(GLOBAL HOLE VAPORS)
138 | 	(NORTH PER ENTER-HOLE?)
139 | 	(EAST PER WALL-OF-DIRT)
140 | 	(SOUTH PER WALL-OF-DIRT)
141 | 	(WEST PER WALL-OF-DIRT)
142 | 	(UP PER GRAVE-TO-COPSE)
143 | 	(IN PER ENTER-HOLE?)
144 | 	(OUT PER GRAVE-TO-COPSE)
145 | 	(DOWN PER ENTER-HOLE?)
146 | 	(ACTION INSIDE-GRAVE-F)
147 | 	(PSEUDO "DIRT" WALLS-F)>
148 | 
149 | <ROUTINE WALL-OF-DIRT ()
150 | 	 <TELL "You just walked into a wall of dirt." CR>
151 | 	 <RFALSE>>
152 | 
153 | <ROUTINE ENTER-HOLE? ()
154 | 	 <COND (<NOT ,SKEWED?>
155 | 	        <CANT-GO>
156 | 	        <RFALSE>)
157 | 	       (<CANT-FIT-INTO? "hole">
158 | 		<RFALSE>)
159 | 	       (T
160 | 	        <MOVE-ALL ,INSIDE-GRAVE ,OPEN-GRAVE>
161 | 		<MOVE ,GRAVE ,INSIDE-GRAVE>
162 | 		<RETURN ,TUNNEL-FORK>)>>
163 | 
164 | <ROUTINE ENTER-GRAVE ()
165 | 	 <COND (<CANT-FIT-INTO? "grave">
166 | 		<RFALSE>)
167 | 	       (,SKEWED?
168 | 		<ESCAPE-VAPORS>)
169 | 	       (<IN? ,GRAVEDIGGER ,SPOOKY-COPSE>
170 | 		<SAY-THE ,GRAVEDIGGER>
171 | 		<TELL 
172 | " reaches into the " D ,OPEN-GRAVE " and pulls you out. \"Don't go in there!\" he cries. \"You might get buried alive!\"" CR>
173 | 		<RFALSE>)>
174 | 	 <MOVE-ALL ,OPEN-GRAVE ,INSIDE-GRAVE>
175 | 	 <RETURN ,INSIDE-GRAVE>>
176 | 		
177 | <ROUTINE ESCAPE-VAPORS ()
178 | 	 <DISABLE <INT I-VAPORS>>
179 | 	 <FCLEAR ,VAPORS ,RMUNGBIT>
180 | 	 <COND (<AND <EQUAL? ,DIGGER-SCRIPT 1 0>
181 | 		     <NOT <EQUAL? ,HERE ,SPOOKY-COPSE>>>
182 | 		<SURE-IS-SPOOKY>)
183 | 	       (T
184 | 		<SAY-THE ,VAPORS>
185 | 	        <TELL "s " <PICK-ONE ,VAPOR-YELLS>
186 | " as you escape their misty clutches." CR CR>)>>
187 | 
188 | <GLOBAL VAPOR-YELLS
189 | 	<LTABLE 0 
190 | 	 "moan with disappointment"
191 | 	 "howl with anguish"
192 | 	 "wail with dismay">>
193 | 
194 | <ROUTINE GRAVE-TO-COPSE ()
195 | 	 <COND (<IN? ,BRANCH ,PROTAGONIST>
196 | 		<NEVER-GET-OUT-WITH "that branch">
197 | 		<RFALSE>)
198 | 	       (<AND <IN? ,UMBRELLA ,PROTAGONIST>
199 | 		     <FSET? ,UMBRELLA ,OPENBIT>>
200 | 		<NEVER-GET-OUT-WITH "that open umbrella">
201 | 		<RFALSE>)
202 | 	       (<G? <WEIGHT ,PROTAGONIST> 18>
203 | 		<NEVER-GET-OUT-WITH "all those things">
204 | 		<RFALSE>)
205 | 	       (T
206 | 		<TELL
207 | "With great difficulty, you manage to climb out of the " 
208 | D ,OPEN-GRAVE "." CR CR>
209 | 		<COND (,SKEWED?
210 | 		       <SETG DIGGER-SCRIPT 0>
211 | 		       <ENABLE <QUEUE I-VAPORS -1>>)>
212 | 		<MOVE-ALL ,INSIDE-GRAVE ,OPEN-GRAVE>
213 | 		<MOVE ,GRAVE ,INSIDE-GRAVE>
214 | 		<RETURN ,SPOOKY-COPSE>)>>
215 | 
216 | <ROUTINE NEVER-GET-OUT-WITH (STR)
217 | 	 <TELL
218 | "You'll never climb out of the " D ,OPEN-GRAVE " holding " .STR "!" CR>>
219 | 
220 | <ROUTINE ARE-YOU-SURE? ()
221 | 	 <COND (<EQUAL? ,HERE ,OUTSIDE-CEMETERY>
222 | 		<COND (<FSET? ,SOUTH-GATE ,OPENBIT>
223 | 		       <COND (<BE-SURE>
224 | 		              <COND (,SKEWED?
225 | 			             <SLAM-THE-GATE>
226 | 			             <RFALSE>)
227 | 			            (T
228 | 			             <RETURN ,CREEPY-CORNER>)>)
229 | 			     (T
230 | 		              <RFALSE>)>)
231 | 		      (T
232 | 		       <ITS-CLOSED ,SOUTH-GATE>
233 | 		       <RFALSE>)>)
234 | 	       (<EQUAL? ,HERE ,EDGE-OF-LAKE>
235 | 		<COND (<FSET? ,NORTH-GATE ,OPENBIT>
236 | 		       <COND (<BE-SURE>
237 | 		              <RETURN ,TWILIGHT-GLEN>)
238 | 		             (T
239 | 		              <RFALSE>)>)
240 | 		      (T
241 | 		       <ITS-CLOSED ,NORTH-GATE>
242 | 		       <RFALSE>)>)>>
243 | 
244 | <ROUTINE BE-SURE ()
245 | 	 <SAY-THE ,CEMETERY>
246 | 	 <TELL " is a " <PICK-ONE ,FRIGHTS> " place">
247 | 	 <COND (,SKEWED?
248 | 		<TELL ", especially at night">)>
249 | 	 <TELL ". ">
250 | 	 <SAY-SURE>
251 | 	 <TELL "go in there?">
252 | 	 <COND (<YES?>
253 | 	        <COND (,SKEWED?
254 |                        <SETG DIGGER-SCRIPT 0>
255 |                        <ENABLE <QUEUE I-VAPORS -1>>)>
256 | 	        <TELL CR "You have been warned." CR CR>
257 | 	        <RTRUE>)
258 | 	       (T
259 | 	        <THAT-WAS-CLOSE>
260 | 	        <RFALSE>)>>
261 | 
262 | <GLOBAL FRIGHTS
263 | 	<LTABLE 0 "spooky" "fearful" "creepy">>
264 | 
265 | <ROUTINE SLAM-THE-GATE ()
266 | 	 <FCLEAR ,SOUTH-GATE ,OPENBIT>
267 | 	 <FSET ,SOUTH-GATE ,LOCKEDBIT>
268 | 	 <TELL "Clang! ">
269 | 	 <SUDDEN-GUST>
270 | 	 <TELL "blows the " D ,SOUTH-GATE " shut in your face."
271 | 	       CR CR ,YOU-HEAR "misty voices giggling ">
272 | 	 <COND (<EQUAL? ,HERE ,OUTSIDE-CEMETERY>
273 | 		<TELL "on the other side">)
274 | 	       (T
275 | 		<TELL "all around you">)>
276 | 	 <TELL ", and a loud \"click\" as the gate locks." CR>>
277 | 
278 | <OBJECT CEMETERY
279 | 	(IN LOCAL-GLOBALS)
280 | 	(DESC "cemetery")
281 | 	(SYNONYM CEMETERY GRAVEYARD)
282 | 	(ADJECTIVE FESTERON)
283 | 	(FLAGS NDESCBIT)
284 | 	(ACTION CEMETERY-F)>
285 | 
286 | <ROUTINE CEMETERY-F ()
287 | 	 <COND (<VERB? EXAMINE LOOK-INSIDE FIND>
288 | 		<COND (<IN-CEMETERY?>
289 | 		       <RTRUE>)
290 | 		      (<EQUAL? ,HERE ,OUTSIDE-CEMETERY>
291 | 		       <SEE-IT "west">)
292 | 		      (<EQUAL? ,HERE ,EDGE-OF-LAKE>
293 | 		       <SEE-IT "south">)
294 | 		      (T
295 | 		       <REFER-TO-MAP>)>
296 | 		<RTRUE>)
297 | 	       (<VERB? WALK-TO THROUGH ENTER>
298 | 		<COND (<IN-CEMETERY?>
299 | 		       <RTRUE>)
300 | 		      (<EQUAL? ,HERE ,OUTSIDE-CEMETERY>
301 | 		       <DO-WALK ,P?WEST>)
302 | 		      (<EQUAL? ,HERE ,EDGE-OF-LAKE>
303 | 		       <DO-WALK ,P?SOUTH>)
304 | 		      (T
305 | 		       <REFER-TO-MAP>)>
306 | 		<RTRUE>)
307 | 	       (T
308 | 		<RFALSE>)>>
309 | 
310 | <ROUTINE IN-CEMETERY? ()
311 | 	 <COND (<EQUAL? ,HERE ,CREEPY-CORNER ,SPOOKY-COPSE ,TWILIGHT-GLEN>
312 | 	        <TELL "It's all around you!" CR>
313 | 		<RTRUE>)
314 | 	       (T
315 | 		<RFALSE>)>>
316 | 
317 | <ROUTINE SEE-IT (STR)
318 | 	 <TELL ,YOU-SEE "it to the " .STR "." CR>>
319 | 
320 | <OBJECT MONUMENTS
321 | 	(IN LOCAL-GLOBALS)
322 | 	(DESC "tombstone")
323 | 	(SYNONYM STONES STONE TOMBSTONES MONUMENTS)
324 | 	(ADJECTIVE TOMB TOMBS)
325 | 	(FLAGS READBIT)
326 | 	(ACTION MONUMENTS-F)>
327 | 
328 | <ROUTINE MONUMENTS-F ()
329 | 	 <COND (<VERB? READ EXAMINE>
330 | 		<COND (<EQUAL? ,HERE ,SPOOKY-COPSE>
331 | 		       <SAY-THE ,MONUMENTS>
332 | 		       <TELL " next to the " D ,OPEN-GRAVE>
333 | 		       <COND (,SKEWED?
334 | 			      <HAS-YOUR-NAME>)
335 | 			     (T
336 | 			      <TELL " is blank." CR>)>)
337 | 		      (T
338 | 		       <TELL "The lettering">
339 | 		       <TOO-FADED>)>
340 | 		<RTRUE>)
341 | 	       (<MOVING? ,MONUMENTS>
342 | 		<TOO-LARGE ,MONUMENTS>
343 | 		<RTRUE>)
344 | 	       (T
345 | 		<RFALSE>)>>
346 | 
347 | <ROUTINE TOO-FADED ()
348 | 	 <TELL " is too faded to read clearly." CR>>
349 | 
350 | <OBJECT OPEN-GRAVE
351 |         (IN SPOOKY-COPSE)
352 | 	(DESC "open grave")
353 | 	(SYNONYM GRAVE HOLE)
354 | 	(ADJECTIVE OPEN)
355 | 	(FLAGS NDESCBIT VOWELBIT CONTBIT OPENBIT TRANSBIT)
356 | 	(CAPACITY 50)
357 | 	(CONTFCN IN-OPEN-GRAVE)
358 | 	(ACTION OPEN-GRAVE-F)>
359 | 
360 | <ROUTINE IN-OPEN-GRAVE (CONTEXT)
361 | 	 <COND (<AND <EQUAL? .CONTEXT ,M-CONT>
362 | 		     <TOUCHING? ,PRSO>>
363 | 		<TELL ,CANT " reach ">
364 | 		<ARTICLE ,PRSO T>
365 | 		<TELL D ,PRSO " from here. The " D ,OPEN-GRAVE
366 | 		      " is too deep." CR>
367 | 		<RFATAL>)
368 | 	       (T
369 | 		<RFALSE>)>>
370 | 
371 | <ROUTINE OPEN-GRAVE-F ()
372 | 	 <COND (<VERB? WALK-TO ENTER THROUGH CLIMB-DOWN CLIMB-ON>
373 | 		<DO-WALK ,P?DOWN>
374 | 		<RTRUE>)
375 | 	       (<VERB? EXIT CLIMB-UP>
376 | 		<ALREADY-IN ,OPEN-GRAVE T>
377 | 		<RTRUE>)
378 | 	       (<VERB? EXAMINE SEARCH LOOK-DOWN LOOK-INSIDE>
379 | 		<TELL "It's six feet deep and freshly dug.">
380 | 	        <COND (<FIRST? ,OPEN-GRAVE>
381 | 		       <TELL " " ,YOU-SEE>
382 | 		       <PRINT-CONTENTS ,OPEN-GRAVE>
383 | 		       <TELL " inside.">)>
384 | 		<CRLF>
385 | 		<RTRUE>)
386 | 	       (<AND <VERB? PUT THROW>
387 | 		     <EQUAL? ,PRSI ,OPEN-GRAVE>>
388 | 		<COND (<EQUAL? ,PRSO ,HANDS>
389 | 		       <NOTHING-EXCITING>
390 | 		       <RTRUE>)
391 | 		    ; (<G? <GETP ,PRSO ,P?SIZE> 10>
392 | 		       <TOO-LARGE ,PRSO>
393 | 		       <RTRUE>)
394 | 		      (<AND <EQUAL? ,PRSO ,UMBRELLA>
395 | 			    <FSET? ,UMBRELLA ,OPENBIT>>
396 | 		       <YOUD-HAVE-TO "close" ,UMBRELLA>
397 | 		       <RTRUE>)
398 | 		      (T
399 | 		       <RFALSE>)>)
400 | 	       (<GENERIC-GRAVE?>
401 | 		<RTRUE>)
402 | 	       (T
403 | 	        <RFALSE>)>>
404 | 
405 | <ROUTINE GENERIC-GRAVE? ()
406 | 	 <COND (<VERB? DIG>
407 | 		<TELL "It's deep enough already." CR>
408 | 		<RTRUE>)
409 | 	       (<VERB? CLOSE>
410 | 		<HOW?>
411 | 		<RTRUE>)
412 | 	       (T
413 | 		<RFALSE>)>>
414 | 
415 | <OBJECT GRAVE
416 | 	(IN INSIDE-GRAVE)
417 | 	(DESC "open grave")
418 | 	(SYNONYM GRAVE HOLE)
419 | 	(ADJECTIVE OPEN)
420 | 	(FLAGS NDESCBIT VOWELBIT CONTBIT OPENBIT TRANSBIT)
421 | 	(CAPACITY 50)
422 | 	(ACTION GRAVE-F)>
423 | 
424 | <ROUTINE GRAVE-F ()
425 | 	 <COND (<VERB? ENTER WALK-TO THROUGH CLIMB-DOWN>
426 | 		<COND (,SKEWED?
427 | 		       <DO-WALK ,P?NORTH>)
428 | 		      (T
429 | 		       <ALREADY-AT ,GRAVE>)>
430 | 		<RTRUE>)
431 | 	       (<VERB? EXIT CLIMB-UP CLIMB-ON>
432 | 		<DO-WALK ,P?OUT>
433 | 		<RTRUE>)
434 | 	       (<VERB? LOOK-DOWN EXAMINE SEARCH LOOK-INSIDE>
435 | 		<V-LOOK>
436 | 		<RTRUE>)
437 | 	       (<AND <VERB? TAKE>
438 | 		     <EQUAL? ,PRSI ,GRAVE>>
439 | 		<PERFORM ,V?TAKE ,PRSO>
440 | 		<RTRUE>)
441 | 	       (<AND <VERB? PUT THROW>
442 | 		     <EQUAL? ,PRSI ,GRAVE>>
443 | 		<PERFORM ,V?DROP ,PRSO>
444 | 		<RTRUE>)
445 | 	       (<GENERIC-GRAVE?>
446 | 		<RTRUE>)
447 | 	       (T
448 | 	        <RFALSE>)>>
449 | 
450 | <ROUTINE ENTER-SPOOKY-COPSE ()
451 | 	 <COND (<AND <NOT ,SKEWED?>
452 | 		     <ZERO? ,DIGGER-SCRIPT>>
453 | 		<ENABLE <QUEUE I-DIGGER-TALK -1>>)>
454 | 	 <RETURN ,SPOOKY-COPSE>>
455 | 
456 | <ROUTINE COPSE-TO-GLEN ()
457 | 	 <COND (<IN? ,GRAVEDIGGER ,TWILIGHT-GLEN>
458 | 		<ENABLE <QUEUE I-BYE-DIGGER -1>>)
459 | 	       (<IN? ,GRAVEDIGGER ,SPOOKY-COPSE>
460 | 		<DISABLE <INT I-DIGGER-TALK>>
461 | 		<ENABLE <QUEUE I-DIGGER-FOLLOWS -1>>)>
462 | 	 <RETURN ,TWILIGHT-GLEN>>
463 | 
464 | <ROUTINE I-BYE-DIGGER ()
465 | 	 <DISABLE <INT I-BYE-DIGGER>>
466 | 	 <CRLF>
467 | 	 <SAY-THE ,GRAVEDIGGER>
468 | 	 <TELL " is locking the " D ,NORTH-GATE 
469 | 	       " from the outside as you approach.">
470 | 	 <OUT-OF-TROUBLE>> 
471 | 
472 | <ROUTINE OUT-OF-TROUBLE ()
473 | 	 <THIS-IS-IT ,GRAVEDIGGER>
474 | 	 <THIS-IS-IT ,NORTH-GATE>
475 | 	 <MOVE ,GRAVEDIGGER ,EDGE-OF-LAKE>
476 | 	 <FCLEAR ,NORTH-GATE ,OPENBIT>
477 |          <FSET ,NORTH-GATE ,LOCKEDBIT>
478 | 	 <TELL " \"Keep out of the " D ,CEMETERY 
479 | 	       " after Dark,\" he tells you with a sly wink." 
480 | 	       CR CR ,YOU-HEAR "him chuckling as he disappears " 
481 | 	       <TO-N> "." CR>>
482 | 
483 | <ROUTINE I-DIGGER-FOLLOWS ()
484 | 	 <DISABLE <INT I-DIGGER-FOLLOWS>>
485 | 	 <CRLF>
486 | 	 <SAY-THE ,GRAVEDIGGER>
487 | 	 <TELL " follows behind you. ">
488 | 	 <COND (<OR <IN? ,ENVELOPE ,GRAVEDIGGER>
489 | 		    <IN? ,ENVELOPE ,SPOOKY-COPSE>>
490 | 		<MOVE ,ENVELOPE ,PROTAGONIST>
491 | 		<FORGOT>
492 | 		<TELL " he says, handing it back to you.">
493 | 		<YOU-ARE-HOLDING ,ENVELOPE T>)
494 | 	       (T
495 | 		<TELL 
496 | "\"What's your hurry?\" he complains.">)>
497 | 	 <TELL CR CR 
498 | "Throwing a shovel over his shoulder, the " D ,GRAVEDIGGER
499 | " ambles through the " D ,NORTH-GATE " and locks it.">
500 | 	 <OUT-OF-TROUBLE>>
501 | 
502 | <ROUTINE FORGOT ()
503 | 	 <TELL "\"Hey! You forgot your envelope!\"">>
504 | 
505 | <ROUTINE COPSE-TO-CORNER ()
506 | 	 <COND (<AND <IN? ,GRAVEDIGGER ,SPOOKY-COPSE>
507 | 		     <OR <IN? ,ENVELOPE ,GRAVEDIGGER>
508 | 			 <IN? ,ENVELOPE ,SPOOKY-COPSE>>>
509 | 		<SAY-THE ,GRAVEDIGGER>
510 | 		<TELL " yells, ">
511 | 		<FORGOT>
512 | 		<CRLF>
513 | 		<CRLF>)>
514 | 	 <RETURN ,CREEPY-CORNER>>
515 | 
516 | <OBJECT WILLOWS
517 | 	(IN SPOOKY-COPSE)
518 | 	(DESC "willow tree")
519 | 	(SYNONYM TREE TREES BOUGH BOUGHS)
520 | 	(ADJECTIVE WILLOW)
521 | 	(FLAGS NDESCBIT)
522 | 	(ACTION WILLOWS-F)>
523 | 
524 | <ROUTINE WILLOWS-F ()
525 | 	 <COND (<VERB? EXAMINE>
526 | 		<TELL "The droopy boughs sway eerily in the breeze." CR>
527 | 		<RTRUE>)
528 | 	       (<GETTING-INTO?>
529 | 		<NO-FOOTHOLDS>
530 | 		<RTRUE>)
531 | 	       (T
532 | 		<RFALSE>)>>
533 | 
534 | <ROUTINE NO-FOOTHOLDS ()
535 | 	 <TELL ,CANT ". There aren't any good footholds." CR>>
536 | 
537 | <OBJECT VAPORS
538 | 	(IN LOCAL-GLOBALS)
539 | 	(DESC "eldritch vapor")
540 | 	(SYNONYM VAPOR VAPORS MIST MISTS)
541 | 	(ADJECTIVE ELDRITCH RIBBON GHOSTLY)
542 | 	(FLAGS VOWELBIT NDESCBIT NARTICLEBIT)
543 | 	(ACTION VAPORS-F)>
544 | 
545 | ; "RMUNGBIT = Vapors have stolen a possession"
546 | 
547 | <ROUTINE VAPORS-F ("OPTIONAL" (CONTEXT <>))
548 | 	 <COND (<NOT ,SKEWED?>
549 | 		<CANT-SEE-ANY ,VAPORS>
550 | 		<RFATAL>)
551 | 	       (<VERB? EXAMINE>
552 | 		<SAY-THE ,VAPORS>
553 | 		<TELL 
554 | "s stare back at you with translucent curiosity." CR>
555 | 		<RTRUE>)
556 | 	       (<TOUCHING? ,VAPORS>
557 | 		<TELL ,CANT " touch an " D ,VAPORS "!" CR>
558 | 		<RTRUE>) 
559 | 	       (<TALKING-TO? ,VAPORS>
560 | 		<SAY-THE ,VAPORS>
561 | 		<TELL "s pay no heed." CR>
562 | 		<RTRUE>)
563 | 	       (<VERB? LISTEN>
564 | 		<SAY-THE ,VAPORS>
565 | 		<TELL "s' voices are hard to hear, but sinister." CR>
566 | 		<RTRUE>)
567 | 	       (<AND <VERB? GIVE FEED THROW>
568 | 		     <EQUAL? ,PRSI ,VAPORS>>
569 | 		<REMOVE ,PRSO>
570 | 		<TELL "Silently, ">
571 | 		<ARTICLE ,PRSO T>
572 | 		<TELL D ,PRSO " disappears into the ghostly mist." CR>
573 | 		<COND (<EQUAL? ,PRSO ,WISHBRINGER ,SHOE>
574 | 		       <I-LUCK>)>
575 | 		<RTRUE>)
576 | 	       (T
577 | 		<RFALSE>)>>
578 | 
579 | <ROUTINE I-VAPORS ("AUX" OBJ NXT (DO-LUCK? <>))
580 | 	 <COND (<OR ,FUZZY? ,ECLIPSE?>
581 | 		<RTRUE>)
582 | 	       (<EQUAL? ,HERE ,TWILIGHT-GLEN ,SPOOKY-COPSE ,CREEPY-CORNER>
583 | 		<SETG DIGGER-SCRIPT <+ ,DIGGER-SCRIPT 1>>
584 | 		<CRLF>
585 | 		<COND (<EQUAL? ,DIGGER-SCRIPT 1>
586 | 		       <TELL
587 | "As you glance around you notice luminous ribbons of mist darting among the "
588 | D ,MONUMENTS "s. The air is filled with sinister voices." CR>)
589 | 		      
590 | 		      (<EQUAL? ,DIGGER-SCRIPT 2>
591 | 		       <COND (<FSET? ,VAPORS ,RMUNGBIT>
592 | 			      <SET OBJ <FIRST? ,PROTAGONIST>>
593 | 			      <SAY-THE ,VAPORS>
594 | 			      <COND (.OBJ
595 | 				     <TELL "s are eyeing ">
596 | 				     <ARTICLE .OBJ T>
597 | 				     <TELL D .OBJ>
598 | 				     <COND (<FSET? .OBJ ,WORNBIT>
599 | 					    <TELL " you're wearing">)
600 | 					   (T
601 | 					    <TELL " in " D ,HANDS "s">)>)
602 | 				    (T
603 | 				     <TELL "s are hovering around you">)>
604 | 			      <TELL " fiendishly">)
605 | 			     (T
606 | 			      <COND (,LUCKY?
607 | 				     <FSET ,VAPORS ,RMUNGBIT>
608 | 				     <SETG DIGGER-SCRIPT 1>)>
609 | 			      <TELL "The luminous mists suddenly condense into a cloud of " D ,VAPORS "s! Circling like " D ,SHARKS ", they stroke your face with ghostly fingers and whisper dreadful secrets into your ears">)>
610 | 		       <TELL "." CR>)
611 | 		      
612 | 		      (T
613 | 		       <SET OBJ <FIRST? ,PROTAGONIST>>
614 | 		       <TELL
615 | "Giggling with mischievous Glee, the " D ,VAPORS "s ">
616 | 		       <COND (<OR <NOT ,LUCKY?>
617 | 				  <NOT .OBJ>>
618 | 			      <FCLEAR ,VAPORS ,RMUNGBIT>
619 | 			      <DISABLE <INT I-VAPORS>>
620 | 		              <TELL 
621 | "clutch your legs and cover your eyes with their luminous hands. ">
622 | 			      <SAY-THE ,GROUND>
623 | 			      <BENEATH-FEET>
624 | 			      <TELL  
625 | " as the foggy fiends lift you high above the treetops">
626 | 		              <COND (.OBJ
627 | 			             <TELL ", scatter your possessions">)>
628 | 		              <TELL " and carry you screaming">
629 | 			      <INTO-NIGHT>
630 | 		       		       
631 | 		            ; "Move player somewhere else"
632 | 		
633 | 		              <SETG HERE <PICK-ONE ,DROP-OFFS>>
634 | 		              <MOVE ,PROTAGONIST ,HERE>
635 | 		              		       
636 | 		            ; "Scatter player's possessions"
637 | 			      		              
638 | 		              <REPEAT ()
639 | 			              <COND (.OBJ
640 | 				             <SET NXT <NEXT? .OBJ>>
641 | 				             <FCLEAR .OBJ ,WORNBIT>
642 | 					     <MOVE .OBJ <PICK-ONE ,DROP-OFFS>>
643 | 				             <COND (<EQUAL? .OBJ ,WISHBRINGER
644 | 							    ,SHOE>
645 | 						    <SET DO-LUCK? T>)>
646 | 					     <SET OBJ .NXT>)
647 | 				            (T
648 | 				             <RETURN>)>>
649 | 		        
650 | 		              <COME-TO-SENSES>
651 | 			      <COND (.DO-LUCK?
652 | 				     <I-LUCK>
653 | 				     <I-GLOW>)>)
654 | 			     
655 | 			   ; "Steal one of player's possessions"
656 | 
657 | 			     (T
658 | 			      <SETG DIGGER-SCRIPT 1>
659 | 			      <FCLEAR .OBJ ,WORNBIT>
660 | 			      <MOVE .OBJ <PICK-ONE ,DROP-OFFS>>
661 | 			      <FSET ,VAPORS ,RMUNGBIT>
662 | 			      <TELL "snatch ">
663 | 			      <ARTICLE .OBJ T>
664 | 			      <TELL D .OBJ
665 | " out of " D ,HANDS "s and carry it away">
666 | 			      <INTO-NIGHT>
667 | 			      <CRLF>
668 | 			      <COND (<EQUAL? .OBJ ,BROOM>
669 | 				     <SETG BROOM-SIT? <>>)
670 | 				    (<EQUAL? .OBJ ,WISHBRINGER ,SHOE>
671 | 				     <I-LUCK>
672 | 				     <I-GLOW>)>)>)>)>>
673 | 
674 | <GLOBAL DROP-OFFS
675 | 	<LTABLE 0
676 | 	 LOOKOUT-HILL PARK FESTERON-POINT
677 | 	 SOUTH-OF-BRIDGE EDGE-OF-LAKE ROCKY-PATH WHARF
678 | 	 CLIFF-BOTTOM RIVER-OUTLET>>
679 | 
680 | <ROUTINE INSIDE-GRAVE-F (CONTEXT)
681 | 	 <COND (<EQUAL? .CONTEXT ,M-LOOK>
682 | 		<TELL "You're at the bottom of an " D ,OPEN-GRAVE 
683 | ", surrounded by six-foot walls of dirt.">
684 | 		<COND (,SKEWED?
685 | 		       <COND (<ZERO? ,DIGGER-SCRIPT>
686 | 			      <TELL " A">)
687 | 			     (T
688 | 			      <TELL
689 | " Luminous ribbons of mist are swarming overhead, and a">)>
690 | 		       <TELL " dark hole is visible in the north wall.">)>
691 | 		<CRLF>)>>
692 | 
693 | <OBJECT HOLE
694 | 	(IN LOCAL-GLOBALS)
695 | 	(DESC "hole")
696 | 	(SYNONYM HOLE OPENING)
697 | 	(ADJECTIVE DARK)
698 | 	(ACTION HOLE-F)>
699 | 
700 | <ROUTINE HOLE-F ()
701 | 	 <COND (<OR <NOT ,SKEWED?>
702 | 		    <AND <EQUAL? ,HERE ,LOOKOUT-HILL ,UNDER-HILL>
703 | 		         <NOT <FSET? ,STUMP ,OPENBIT>>>>
704 | 		<CANT-SEE-ANY ,HOLE>
705 | 		<RFATAL>)
706 | 	       (<VERB? WALK-TO ENTER THROUGH>
707 | 		<COND (<EQUAL? ,HERE ,INSIDE-GRAVE ,LOOKOUT-HILL>
708 | 		       <DO-WALK ,P?IN>)
709 | 		      (<EQUAL? ,HERE ,TUNNEL-FORK>
710 | 		       <DO-WALK ,P?SOUTH>)
711 | 		      (T
712 | 		       <DO-WALK ,P?OUT>)>
713 | 		<RTRUE>)
714 | 	       (<VERB? EXAMINE LOOK-INSIDE>
715 | 	        <CANT-MAKE-OUT-ANYTHING>
716 | 	        <RTRUE>)
717 | 	       (T 
718 | 	        <YOU-DONT-NEED ,HOLE>
719 | 		<RFATAL>)>>
720 | 
721 | <OBJECT UMBRELLA
722 | 	(IN TWILIGHT-GLEN)
723 | 	(DESC "umbrella")
724 | 	(FDESC "There must have been a burial here recently. Somebody left their umbrella leaning up against a tombstone.")
725 | 	(SYNONYM UMBRELLA HANDLE HEAD)
726 |         (ADJECTIVE PARROT)
727 | 	(FLAGS VOWELBIT CONTBIT TAKEBIT)
728 | 	(SIZE 10)
729 | 	(CAPACITY 10)
730 | 	(VALUE 0)
731 | 	(ACTION UMBRELLA-F)>
732 | 
733 | <ROUTINE UMBRELLA-F ()
734 | 	 <COND (<VERB? EXAMINE>
735 | 		<TELL "The handle of the">
736 | 		<OPEN-CLOSED ,UMBRELLA>
737 | 		<TELL D ,UMBRELLA " is carved like a parrot's head." CR>
738 | 		<RTRUE>)
739 | 	       (<VERB? LOOK-INSIDE LOOK-ON LOOK-DOWN>
740 | 		<COND (<FSET? ,UMBRELLA ,OPENBIT>
741 | 		       <NOTHING-INTERESTING T>)
742 | 		      (T
743 | 		       <ITS-CLOSED ,UMBRELLA>)>
744 | 		<RTRUE>)
745 | 	       (<AND <VERB? OPEN RAISE>
746 | 		     <EQUAL? ,PRSO ,UMBRELLA>>
747 | 		<COND (<FSET? ,UMBRELLA ,OPENBIT>
748 | 		       <ALREADY-OPEN>
749 | 		       <RTRUE>)
750 | 		      (<NOT <IN? ,UMBRELLA ,PROTAGONIST>>
751 | 		       <YOUD-HAVE-TO "be holding" ,UMBRELLA>
752 | 		       <RTRUE>)
753 | 		      (<EQUAL? ,HERE ,INSIDE-GRAVE>
754 | 		       <TELL "There's no room here!" CR>
755 | 		       <RTRUE>)>
756 | 		<PUTP ,UMBRELLA ,P?SIZE 20>
757 | 		<FSET ,UMBRELLA ,SURFACEBIT>
758 | 	        <NOW-CLOSED-OR-OPEN ,UMBRELLA T>
759 | 		<COND (<FSET? ,HERE ,INDOORSBIT>
760 | 		       <BAD-LUCK "open an umbrella indoors">)>
761 | 		<RTRUE>)
762 | 	       (<AND <VERB? CLOSE LOWER>
763 | 		     <FSET? ,UMBRELLA ,OPENBIT>>
764 | 	        <COND (<NOT <IN? ,UMBRELLA ,PROTAGONIST>>
765 | 		       <YOUD-HAVE-TO "be holding" ,UMBRELLA>
766 | 		       <RTRUE>)>
767 | 		<PUTP ,UMBRELLA ,P?SIZE 10>
768 | 		<FCLEAR ,UMBRELLA ,SURFACEBIT>
769 | 		<RFALSE>)
770 | 	       (<AND <VERB? PUT PUT-ON>
771 | 		     <EQUAL? ,PRSI ,UMBRELLA>>
772 | 		<COND (<EQUAL? ,PRSO ,UMBRELLA>
773 | 		       <TELL <PICK-ONE ,YUKS> CR>
774 | 		       <RTRUE>)
775 | 		      (<NOT <IN? ,UMBRELLA ,PROTAGONIST>>
776 | 		       <YOUD-HAVE-TO "be holding" ,UMBRELLA>)
777 | 		      (<EQUAL? ,PRSO ,HAT ,COAT ,SNAKE-CAN>
778 | 		       <TELL "That would look silly." CR>)
779 | 		      (<AND <EQUAL? ,PRSA ,V?PUT>
780 | 			    <NOT <FSET? ,UMBRELLA ,OPENBIT>>>
781 | 		       <ITS-CLOSED ,UMBRELLA>)
782 | 		      (<G? <GETP ,PRSO ,P?SIZE> 5>
783 | 		       <TOO-LARGE ,PRSO>)
784 | 		      (T
785 | 		       <TELL "It immediately slides ">
786 | 		       <COND (<EQUAL? ,PRSA ,V?PUT-ON>
787 | 			      <TELL "off">)
788 | 			     (T
789 | 			      <TELL "out">)>
790 | 		       <AND-DROPS-OUT ,PRSO>)>
791 | 		<RTRUE>)
792 | 	       (<VERB? STAND-UNDER RAISE>
793 | 		<COND (<DONT-HAVE? ,UMBRELLA>
794 | 		       <RTRUE>)
795 | 		      (<NOT <FSET? ,UMBRELLA ,OPENBIT>>
796 | 		       <YOUD-HAVE-TO "open" ,UMBRELLA>)
797 | 		      (T
798 | 		       <TELL ,OKAY "you look very cosmopolitan." CR>)>
799 | 		<RTRUE>)
800 | 	       (<AND <VERB? SIT STAND-ON LIE-DOWN MUNG BURN>
801 | 		     <EQUAL? ,PRSO ,UMBRELLA>>
802 | 		<RUIN ,UMBRELLA>
803 | 		<RTRUE>)
804 | 	       (T
805 | 		<RFALSE>)>>
806 | 
807 | <ROUTINE PUTTING-OPEN-UMBRELLA? ()
808 | 	 <COND (<AND <EQUAL? ,PRSO ,UMBRELLA>
809 | 	             <FSET? ,UMBRELLA ,OPENBIT>>
810 | 	        <YOUD-HAVE-TO "close" ,UMBRELLA>
811 | 		<RTRUE>)
812 | 	       (T
813 | 		<RFALSE>)>>
814 | 
815 | <OBJECT TREE
816 | 	(IN LOCAL-GLOBALS)
817 | 	(DESC "tree")
818 | 	(SYNONYM TREE TREES)
819 | 	(FLAGS NDESCBIT)
820 | 	(ACTION TREE-F)>
821 | 
822 | <ROUTINE TREE-F ()
823 | 	 <COND (<VERB? EXAMINE>
824 | 		<TELL "This is no time for botanizing." CR>
825 | 		<RTRUE>)
826 | 	       (<GETTING-INTO?>
827 | 		<NO-FOOTHOLDS>
828 | 		<RTRUE>)
829 | 	       (T
830 | 		<RFALSE>)>>
831 | 
832 | 


--------------------------------------------------------------------------------