├── .gitignore
├── visualrepeat.manifest
├── .github
    └── ISSUE_TEMPLATE
    │   ├── feature_request.md
    │   └── bug_report.md
├── plugin
    └── visualrepeat.vim
├── autoload
    ├── visualrepeat
    │   └── reapply.vim
    └── visualrepeat.vim
├── README.md
└── doc
    └── visualrepeat.txt


/.gitignore:
--------------------------------------------------------------------------------
1 | *.msgout
2 | *.msgresult
3 | *.out
4 | *.tap
5 | doc/*.description
6 | doc/*.install
7 | tags
8 | 


--------------------------------------------------------------------------------
/visualrepeat.manifest:
--------------------------------------------------------------------------------
1 | autoload/visualrepeat.vim
2 | autoload/visualrepeat/reapply.vim
3 | plugin/visualrepeat.vim
4 | doc/visualrepeat.txt
5 | 


--------------------------------------------------------------------------------
/.github/ISSUE_TEMPLATE/feature_request.md:
--------------------------------------------------------------------------------
 1 | ---
 2 | name: Feature request
 3 | about: Suggest an enhancement for the plugin
 4 | title: ''
 5 | labels: enhancement
 6 | 
 7 | ---
 8 | 
 9 | **Motivation**
10 | 
11 | _A clear and concise description of what currently is hard to do._
12 | 
13 | **Request and Purpose**
14 | 
15 | _A clear and concise description of what you want to happen. Possible fit criteria._
16 | 
17 | **Alternatives**
18 | 
19 | _A clear and concise description of any alternative solutions or features you've considered._
20 | 


--------------------------------------------------------------------------------
/.github/ISSUE_TEMPLATE/bug_report.md:
--------------------------------------------------------------------------------
 1 | ---
 2 | name: Bug report
 3 | about: The plugin isn't working at all or shows wrong or unexpected behavior
 4 | title: ''
 5 | labels: ''
 6 | 
 7 | ---
 8 | **Frequent Issues**
 9 | 
10 | * **Sudden problems after updating**: Did you check out the default _master_ branch? Unless you want to participate in feature development and alpha testing, I would recommend that you switch from _master_ to the _stable_ branch; this way, you'll only update to released versions that are (hopefully) better tested and documented.
11 | * **Neovim**: I don't explicitly consider nor test Neovim compatibility; my plugins are written for Vim. If a plugin can be made to work on Neovim with trivial changes, I wouldn't mind including them, but anything more involved should in my opinion be filed as a compatibility bug against Neovim (as its homepage proclaims: _Fully compatible with Vim's editing model and the Vimscript language._)
12 | 
13 | **Describe the bug**
14 | 
15 | _A clear and concise description of what the bug is._
16 | 
17 | **How to Reproduce**
18 | 
19 | _Detailed steps to reproduce the behavior._
20 | 
21 | **Expected Behavior**
22 | 
23 | _A clear and concise description of what you expected to happen._
24 | 
25 | **Environment**
26 |  - Plugin version (e.g. stable version _1.10_) / revision _a1b2c3d4_ from the master branch
27 |  - Vim version (e.g. _8.1.1234_) Or paste the result of `vim --version`.
28 |  - OS: (e.g. _Ubuntu 18.04_, _Windows 10 1809_, _macOS 10.14_)
29 |  - Install method: (e.g. manually via Vimball or ZIP file, GitHub clone as pack plugin, Plugin manager _NAME_)
30 |  - Other plugins / additional context if you think this could be important
31 | 


--------------------------------------------------------------------------------
/plugin/visualrepeat.vim:
--------------------------------------------------------------------------------
 1 | " visualrepeat.vim: Repeat command extended to visual mode.
 2 | "
 3 | " DEPENDENCIES:
 4 | "   - visualrepeat.vim autoload script
 5 | "
 6 | " Copyright: (C) 2011-2019 Ingo Karkat
 7 | "   The VIM LICENSE applies to this script; see ':help copyright'.
 8 | "
 9 | " Maintainer:	Ingo Karkat <ingo@karkat.de>
10 | 
11 | " Avoid installing twice or when in unsupported Vim version.
12 | if exists('g:loaded_visualrepeat') || (v:version < 700)
13 |     finish
14 | endif
15 | let g:loaded_visualrepeat = 1
16 | let s:save_cpo = &cpo
17 | set cpo&vim
18 | 
19 | " In linewise visual mode, after entering the command line with :, the current
20 | " cursor position is lost. Therefore, capture the cursor's virtual column via a
21 | " no-op expression mapping.
22 | xnoremap <expr> <SID>(CaptureVirtCol) visualrepeat#CaptureVirtCol()
23 | 
24 | xnoremap <script> <silent> . <SID>(CaptureVirtCol):<C-u>
25 | \if ! visualrepeat#repeat()<Bar>
26 | \   echoerr visualrepeat#ErrorMsg()<Bar>
27 | \   if &cmdheight == 1<Bar>
28 | \       sleep 500m<Bar>
29 | \   endif<Bar>
30 | \   execute 'normal! gv'<Bar>
31 | \endif<CR>
32 | " In visual mode, the mode message will override the error message. Therefore,
33 | " sleep() for a short while to allow the user to notice it.
34 | 
35 | vnoremap <script> <silent> <Plug>(visualrepeatForceBuiltInRepeat) <SID>(CaptureVirtCol):<C-u>
36 | \if ! visualrepeat#repeat(1)<Bar>
37 | \   echoerr visualrepeat#ErrorMsg()<Bar>
38 | \   if &cmdheight == 1<Bar>
39 | \       sleep 500m<Bar>
40 | \   endif<Bar>
41 | \   execute 'normal! gv'<Bar>
42 | \endif<CR>
43 | if ! hasmapto('<Plug>(visualrepeatForceBuiltInRepeat)', 'x')
44 |     xmap g. <Plug>(visualrepeatForceBuiltInRepeat)
45 | endif
46 | 
47 | let &cpo = s:save_cpo
48 | unlet s:save_cpo
49 | " vim: set ts=8 sts=4 sw=4 noexpandtab ff=unix fdm=syntax :
50 | 


--------------------------------------------------------------------------------
/autoload/visualrepeat/reapply.vim:
--------------------------------------------------------------------------------
 1 | " visualrepeat/reapply.vim: Functions to cross-apply a visual mode mapping in a normal mode repeat.
 2 | "
 3 | " DEPENDENCIES:
 4 | "
 5 | " Copyright: (C) 2013-2024 Ingo Karkat
 6 | "   The VIM LICENSE applies to this script; see ':help copyright'.
 7 | "
 8 | " Maintainer:	Ingo Karkat <ingo@karkat.de>
 9 | 
10 | function! visualrepeat#reapply#VisualMode( isStayInVisualMode )
11 | "****D echomsg '****' v:count g:repeat_count
12 |     let l:appendix = (a:isStayInVisualMode ? '' : "\<Esc>")
13 |     let l:isOnlyRepeatCount = (g:repeat_count == v:count)
14 |     let l:count = (l:isOnlyRepeatCount ? 1 : v:count1)
15 |     let l:isLinewise = (visualmode() ==# 'V')
16 |     if ! l:isOnlyRepeatCount && l:isLinewise
17 | 	" Select [count] lines, not [count] times the previously selected lines.
18 | 	" It would be more correct to do this for the other selection modes,
19 | 	" too, but it's difficult to multiply their size.
20 | 	return 'V' . (l:count > 1 ? l:count . '_' : '') . l:appendix
21 |     else
22 | 	" A normal-mode repeat of the visual mapping is triggered by repeat.vim.
23 | 	" It establishes a new selection at the cursor position, of the same
24 | 	" mode and size as the last selection.
25 | 	" If [count] is given, the size is multiplied accordingly. This has the
26 | 	" side effect that a repeat with [count] will persist the expanded size,
27 | 	" just as it should.
28 | 	return l:count . 'v' . (&selection ==# 'exclusive' && ! l:isLinewise && (v:version < 900 || v:version == 900 && ! has('patch1172')) ? ' ' : '') . l:appendix
29 | 	" For ':set selection=exclusive', the final character must be
30 | 	" re-included with <Space>, but only if this is not linewise visual
31 | 	" mode; in that case, the <Space> would add the next line in case the
32 | 	" last selected line is empty.
33 |     endif
34 | endfunction
35 | function! visualrepeat#reapply#RepeatCount()
36 |     return (g:repeat_count ? g:repeat_count : '')
37 | endfunction
38 | " Note: We don't need to check for the existence of g:repeat_count here; the
39 | " normal mode repeat mapping of a visual mode mapping can only be triggered
40 | " through an installed repeat.vim.
41 | 
42 | 
43 | finish
44 | " Note: The count cannot be injected inside the :normal; it is ignored:
45 | nmap <F12> :<C-u>execute 'normal! gv32'<CR>:<C-u>echomsg '****' v:count<CR>
46 | " What works is prepending via a map-expr:
47 | nmap <F12> :<C-u>execute 'normal! gv'<CR>32:<C-u>echomsg '****' v:count<CR>
48 | " But somehow only when used with : Ex commands, not normal-mode commands; this
49 | " fails:
50 | nmap <F12> :<C-u>execute 'normal! gv'<CR>32A$<Esc>
51 | " But this works again:
52 | nmap <F12> :<C-u>execute 'normal! gv'<CR>32:<C-u>execute 'normal! gv' . v:count . "A$\<lt>Esc>"<CR>
53 | 
54 | " This is how you would use this in your plugin; we don't define a
55 | " <Plug>-mapping here, as you probably want to keep using :noremap (now with
56 | " <script> argument and below <SID>-mapping).
57 | vnoremap <silent> <expr> <SID>(ReapplyRepeatCount) visualrepeat#reapply#RepeatCount()
58 | 
59 | " vim: set ts=8 sts=4 sw=4 noexpandtab ff=unix fdm=syntax :
60 | 


--------------------------------------------------------------------------------
/autoload/visualrepeat.vim:
--------------------------------------------------------------------------------
  1 | " visualrepeat.vim: Repeat command extended to visual mode.
  2 | "
  3 | " DEPENDENCIES:
  4 | "   - ingo-library.vim plugin (optional; for register override only)
  5 | "
  6 | " Copyright: (C) 2011-2020 Ingo Karkat
  7 | "   The VIM LICENSE applies to this script; see ':help copyright'.
  8 | "
  9 | " Maintainer:	Ingo Karkat <ingo@karkat.de>
 10 | let s:save_cpo = &cpo
 11 | set cpo&vim
 12 | 
 13 | let g:visualrepeat_tick = -1
 14 | 
 15 | function! visualrepeat#set( sequence, ... )
 16 |     let g:visualrepeat_sequence = a:sequence
 17 |     let g:visualrepeat_count = a:0 ? a:1 : v:count
 18 |     let g:visualrepeat_tick = b:changedtick
 19 | endfunction
 20 | 
 21 | 
 22 | let s:virtcol = 1
 23 | function! visualrepeat#CaptureVirtCol()
 24 |     let s:virtcol = virtcol('.')
 25 |     return ''
 26 | endfunction
 27 | function! visualrepeat#repeatOnVirtCol( virtcol, count, normalCmd )
 28 |     execute 'normal!' a:virtcol . '|'
 29 |     if virtcol('.') >= a:virtcol
 30 | 	execute a:normalCmd a:count . '.'
 31 |     endif
 32 | endfunction
 33 | function! visualrepeat#RepeatOnRange( range, command )
 34 |     " The use of :global keeps track of lines added or deleted by the repeat, so
 35 |     " that we apply exactly to the selected lines.
 36 |     execute a:range . "global/^/" . a:command
 37 |     call histdel('search', -1)
 38 | endfunction
 39 | function! visualrepeat#repeat( ... )
 40 |     let l:isForceBuildInRepeat = (a:0 && a:1)
 41 | 
 42 |     " Note: Unless forced, :normal has no bang to allow a remapped '.' command
 43 |     " here to enable repeat.vim functionality.
 44 |     let l:normalCmd = 'normal' . (l:isForceBuildInRepeat ? '!' : '')
 45 | 
 46 |     if g:visualrepeat_tick == b:changedtick
 47 | 	" visualrepeat.vim should handle the repeat.
 48 | 	let l:repeat_sequence = g:visualrepeat_sequence
 49 | 	let l:repeat_count = g:visualrepeat_count
 50 |     elseif exists('g:repeat_tick') && g:repeat_tick == b:changedtick
 51 | 	" repeat.vim is enabled and would handle a normal-mode repeat.
 52 | 	let l:repeat_sequence = g:repeat_sequence
 53 | 	let l:repeat_count = g:repeat_count
 54 |     endif
 55 | 
 56 |     if ! l:isForceBuildInRepeat && exists('l:repeat_sequence')
 57 | 	" A mapping for visualrepeat.vim or repeat.vim to repeat has been set.
 58 | 	" Ensure that a corresponding visual mode mapping exists; some plugins
 59 | 	" that only use repeat.vim may not have this.
 60 | 	if ! empty(maparg(substitute(l:repeat_sequence, '^.\{3}', '<Plug>', 'g'), 'x'))
 61 | 	    " Handle mappings that use a register and want the same register
 62 | 	    " used on repetition.
 63 | 	    let l:reg = ''
 64 | 	    if exists('g:repeat_reg') && exists('g:repeat_sequence') &&
 65 | 	    \   g:repeat_reg[0] ==# g:repeat_sequence && ! empty(g:repeat_reg[1])
 66 | 		" Take the original register, unless another (non-default, we
 67 | 		" unfortunately cannot detect no vs. a given default register)
 68 | 		" register has been supplied to the repeat command (as an
 69 | 		" explicit override).
 70 | 		let l:regName = g:repeat_reg[1]
 71 | 		silent! let l:regName = (v:register ==# ingo#register#Default() ? g:repeat_reg[1] : v:register) " Register override needs the optional ingo-library dependency.
 72 | 		if l:regName ==# '='
 73 | 		    " This causes a re-evaluation of the expression on repeat, which
 74 | 		    " is what we want.
 75 | 		    let l:reg = '"=' . getreg('=', 1) . "\<CR>"
 76 | 		else
 77 | 		    let l:reg = '"' . l:regName
 78 | 		endif
 79 | 	    endif
 80 | 
 81 | 	    " The normal mode mapping to be repeated has a corresponding visual
 82 | 	    " mode mapping. Use this so that the repetition will affect the
 83 | 	    " current selection. With this we also avoid the clumsy application
 84 | 	    " of the normal mode command to the visual selection, and can
 85 | 	    " support blockwise visual mode.
 86 | 	    let l:cnt = l:repeat_count == -1 ? '' : (v:count ? v:count : (l:repeat_count ? l:repeat_count : ''))
 87 | 
 88 | 	    if ((v:version == 703 && has('patch100')) || (v:version == 704 && !has('patch601')))
 89 |                 exe 'normal gv' . l:reg . l:cnt . l:repeat_sequence
 90 | 	    elseif v:version <= 703
 91 | 		call feedkeys('gv' . l:reg . l:cnt, 'n')
 92 | 		call feedkeys(l:repeat_sequence, '')
 93 | 	    else
 94 | 		call feedkeys(l:repeat_sequence, 'i')
 95 | 		call feedkeys('gv' . l:reg . l:cnt, 'ni')
 96 | 	    endif
 97 | 	    return 1
 98 | 	endif
 99 |     endif
100 | 
101 |     try
102 | 	if visualmode() ==# 'v'
103 | 	    " Repeat the last change starting from the current cursor position.
104 | 	    execute l:normalCmd . ' ' . (v:count ? v:count : '') . '.'
105 | 	elseif visualmode() ==# 'V'
106 | 	    call visualrepeat#RepeatOnEachLine(l:normalCmd)
107 | 	else
108 | 	    call visualrepeat#RepeatOnBlock(l:normalCmd)
109 | 	endif
110 | 	return 1
111 |     catch /^Vim\%((\a\+)\)\=:E117:.*ingo#selection#Get/ " E117: Unknown function: ingo#selection#Get
112 | 	let s:errorMsg = 'For blockwise repeat, you need to install the ingo-library dependency'
113 |     catch /^Vim\%((\a\+)\)\=:/
114 | 	" v:exception contains what is normally in v:errmsg, but with extra
115 | 	" exception source info prepended, which we cut away.
116 | 	let s:errorMsg = substitute(v:exception, '^\CVim\%((\a\+)\)\=:', '', '')
117 |     catch
118 | 	let s:errorMsg = v:exception
119 |     endtry
120 | 
121 |     return 0
122 | endfunction
123 | function! visualrepeat#RepeatOnEachLine( normalCmd )
124 |     let [l:changeStart, l:changeEnd] = [getpos("'<"), getpos("'>")]
125 | 
126 |     " For all selected lines, repeat the last change in the line.
127 |     if s:virtcol == 1
128 | 	" The cursor is set to the first column.
129 | 	call visualrepeat#RepeatOnRange("'<,'>", a:normalCmd . ' ' . (v:count ? v:count : '') . '.')
130 |     else
131 | 	" The cursor is set to the cursor column; the last change is
132 | 	" only applied to lines that have at least that many characters.
133 | 	call visualrepeat#RepeatOnRange("'<,'>", printf('call visualrepeat#repeatOnVirtCol(%d, %s, %s)',
134 | 	\   s:virtcol,
135 | 	\   string(v:count ? v:count : ''),
136 | 	\   string(a:normalCmd)
137 | 	\))
138 |     endif
139 | 
140 |     call setpos("'[", l:changeStart)
141 |     call setpos("']", l:changeEnd)
142 | endfunction
143 | function! visualrepeat#RepeatOnBlock( normalCmd )
144 |     " Yank the selected block and repeat the last change in scratch
145 |     " lines at the end of the buffer (using a different buffer would be
146 |     " easier, but the repeated command may depend on the current
147 |     " buffer's settings), so that the change is limited to the
148 |     " selection. The vis.vim plugin does the same, but we cannot use it,
149 |     " because it performs the movement (to the bottom of the current
150 |     " buffer) via regular paste commands (which clobber the repeat
151 |     " command). We need to be careful to avoid doing that, using only
152 |     " lower level functions.
153 |     let l:changeStart = getpos("'<")
154 |     let l:startVirtCol = virtcol("'<")
155 |     let [l:count, l:startColPattern, l:startLnum, l:endLnum] = [v:count, ('\%>' . (l:startVirtCol - 1) . 'v'), line("'<"), line("'>")]
156 |     let l:selection = split(ingo#selection#Get(), '\n', 1)
157 | 
158 |     let l:result = ingo#buffer#temprange#Call(l:selection, function('visualrepeat#RepeatOnRange'), ['.,$', a:normalCmd . ' ' . (l:count ? l:count : '') . '.'], 1)
159 | 
160 |     for l:lnum in range(l:startLnum, l:endLnum)
161 | 	let l:idx = l:lnum - l:startLnum
162 | 	let l:line = getline(l:lnum)
163 | 	let l:startCol = match(l:line, l:startColPattern)
164 | 	let l:endCol = l:startCol + len(l:selection[l:idx])
165 | 	let l:resultLine = get(l:result, l:idx, '') " Replace the line part with an empty string if there are less lines after the repeat.
166 | 	let l:newLine = strpart(l:line, 0, l:startCol) . l:resultLine . strpart(l:line, l:endCol)
167 | 	call setline(l:lnum, l:newLine)
168 |     endfor
169 | 
170 |     let l:addedNum = len(l:result) - l:idx - 1
171 |     if l:addedNum == 0
172 | 	let l:changeEnd = [0, l:lnum, l:startCol + len(l:resultLine), 0]
173 |     else
174 | 	" The repeat has introduced additional lines; append those (as
175 | 	" new lines) properly indented to the start of the blockwise
176 | 	" selection.
177 | 	let l:indent = repeat(' ', l:startVirtCol - 1)
178 | 
179 | 	" To use the buffer's indent settings, first insert spaces and
180 | 	" have :retab convert those to the proper indent. Then, append
181 | 	" the additional lines.
182 | 	call append(l:lnum, repeat([l:indent], l:addedNum))
183 | 
184 | 	silent execute printf('%d,%dretab!', l:lnum + 1, l:lnum + l:addedNum + 1)
185 | 
186 | 	for l:addedIdx in range(l:addedNum)
187 | 	    let l:addedLnum = l:lnum + 1 + l:addedIdx
188 | 	    call setline(l:addedLnum, getline(l:addedLnum) . l:result[l:idx + 1 + l:addedIdx])
189 | 	endfor
190 | 
191 | 	let l:changeEnd = [0, l:addedLnum, len(getline(l:addedLnum)) + 1, 0]
192 |     endif
193 | 
194 |     " The change marks still point to the (removed) temporary range.
195 |     " Make them valid by setting them to the changed selection.
196 |     call setpos("'[", l:changeStart)
197 |     call setpos("']", l:changeEnd)
198 | endfunction
199 | 
200 | let s:errorMsg = ''
201 | function! visualrepeat#ErrorMsg()
202 |     return s:errorMsg
203 | endfunction
204 | 
205 | augroup visualrepeatPlugin
206 |     autocmd!
207 |     autocmd BufLeave,BufWritePre,BufReadPre * let g:visualrepeat_tick = (g:visualrepeat_tick == b:changedtick || g:visualrepeat_tick == 0) ? 0 : -1
208 |     autocmd BufEnter,BufWritePost * if g:visualrepeat_tick == 0|let g:visualrepeat_tick = b:changedtick|endif
209 | augroup END
210 | 
211 | let &cpo = s:save_cpo
212 | unlet s:save_cpo
213 | " vim: set ts=8 sts=4 sw=4 noexpandtab ff=unix fdm=syntax :
214 | 


--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
  1 | VISUALREPEAT
  2 | ===============================================================================
  3 | _by Ingo Karkat_
  4 | 
  5 | DESCRIPTION
  6 | ------------------------------------------------------------------------------
  7 | 
  8 | This plugin defines repetition of Vim built-in normal mode commands via .
  9 | for visual mode. Additionally, it offers functions like the popular repeat.vim
 10 | plugin that allow mappings to be repeated in visual mode, too.
 11 | 
 12 | ### VISUAL MODE REPETITION
 13 | 
 14 | This extends the built-in normal mode repeat . to visual mode.
 15 | 
 16 | ### VISUAL MODE MAPPING REPETITION
 17 | 
 18 | Like with repeat.vim for normal mode, visual mode mappings can register a
 19 | &lt;Plug&gt; mapping to be used for visual mode repetition.
 20 | 
 21 | Likewise, normal mode mappings can (in addition to the repeat.vim registration
 22 | of a normal mode mapping) register a visual mode mapping with visualrepeat.vim
 23 | that will be repeated in visual mode.
 24 | 
 25 | Operator-pending mappings end with g@ and repeat naturally; i.e. Vim
 26 | re-applies the 'opfunc' on the equivalent text (but at the current cursor
 27 | position). But without a call to repeat#set(), it is impossible to repeat this
 28 | operator-pending mapping to the current visual selection. Plugins cannot call
 29 | repeat#set() in their operator-pending mapping, because then Vim's built-in
 30 | repeat would be circumvented, the full mapping ending with g@ would be
 31 | re-executed, and the repetition would then wait for the {motion}, what is not
 32 | wanted.
 33 | Therefore, this plugin offers a separate visualrepeat#set() function that can
 34 | be invoked for operator-pending mappings. It can also be invoked for
 35 | normal-mode mappings that have already called repeat#set(), and may override
 36 | that mapping with a special repeat mapping for visual mode repeats. Together
 37 | with the remapped {Visual}. command, this allows repetition - similar to what
 38 | the built-in Vim commands do - across normal, operator-pending and visual
 39 | mode.
 40 | 
 41 | ### SOURCE
 42 | 
 43 | - [Based on vimtip #1142, Repeat last command and put cursor at start of change](http://vim.wikia.com/wiki/Repeat_last_command_and_put_cursor_at_start_of_change)
 44 | - The client interface and implementation has been based on repeat.vim
 45 |   ([vimscript #2136](http://www.vim.org/scripts/script.php?script_id=2136)) by Tim Pope.
 46 | 
 47 | ### RELATED WORKS
 48 | 
 49 | - repeat.vim ([vimscript #2136](http://www.vim.org/scripts/script.php?script_id=2136)) has been the basis for this plugin and should
 50 |   be used in conjunction with visualrepeat.vim. (Otherwise, you'd have visual
 51 |   mode repeat, but no repeat in normal mode.)
 52 | 
 53 | USAGE
 54 | ------------------------------------------------------------------------------
 55 | 
 56 |     {Visual}.               Repeat last change in all visually selected lines.
 57 |                             - characterwise: Start from cursor position.
 58 |                             - linewise: Each line separately, starting from the
 59 |                               current column (usually the first in this mode).
 60 |                             - blockwise: Only the selected text. This is
 61 |                               implemented by temporarily duplicating the selection
 62 |                               to separate lines and repeating over those, starting
 63 |                               from the first column.
 64 | 
 65 |                             Note: If the last normal mode command included a
 66 |                             {motion} (e.g. g~e), the repetition will also move
 67 |                             exactly over this {motion}, NOT the visual selection!
 68 |                             It is thus best to repeat commands that work on the
 69 |                             entire line (e.g. g~$).
 70 | 
 71 |     {Visual}g.              Repeat last built-in command in all visually selected
 72 |                             lines. Skips any plugin repeat actions; only repeats
 73 |                             the last Vim command.
 74 | 
 75 | INSTALLATION
 76 | ------------------------------------------------------------------------------
 77 | 
 78 | The code is hosted in a Git repo at
 79 |     https://github.com/inkarkat/vim-visualrepeat
 80 | You can use your favorite plugin manager, or "git clone" into a directory used
 81 | for Vim packages. Releases are on the "stable" branch, the latest unstable
 82 | development snapshot on "master".
 83 | 
 84 | This script is also packaged as a vimball. If you have the "gunzip"
 85 | decompressor in your PATH, simply edit the \*.vmb.gz package in Vim; otherwise,
 86 | decompress the archive first, e.g. using WinZip. Inside Vim, install by
 87 | sourcing the vimball or via the :UseVimball command.
 88 | 
 89 |     vim visualrepeat*.vmb.gz
 90 |     :so %
 91 | 
 92 | To uninstall, use the :RmVimball command.
 93 | 
 94 | ### DEPENDENCIES
 95 | 
 96 | - Requires Vim 7.0 or higher.
 97 | - repeat.vim ([vimscript #2136](http://www.vim.org/scripts/script.php?script_id=2136)) plugin (highly recommended)
 98 | - ingo-library.vim plugin ([vimscript #4433](http://www.vim.org/scripts/script.php?script_id=4433)), version 1.013 or higher;
 99 |   optional, for blockwise repeat only
100 | 
101 | INTEGRATION
102 | ------------------------------------------------------------------------------
103 | 
104 | This plugin is meant to be used together with repeat.vim.
105 | 
106 | This plugin has helper functions that plugins with cross-repeat functionality
107 | can use in their normal mode repeat mappings of repeated visual mode mappings.
108 | With this, you save work and allow for a consistent user experience.
109 | Define your normal mode repeat mapping like this:
110 | 
111 |     nnoremap <silent> <Plug>(MyPluginVisual)
112 |     \ :<C-u>execute 'normal!' visualrepeat#reapply#VisualMode(0)<Bar>
113 |     \call MyPlugin#Operator('visual', "\<lt>Plug>(MyPluginVisual)")<CR>
114 | 
115 | If your plugin uses a passed [count] (i.e. the count is not only used to
116 | determine the text area the mapping is applied to), you need to define a
117 | mapping:
118 | 
119 |     vnoremap <silent> <expr> <SID>(ReapplyRepeatCount) visualrepeat#reapply#RepeatCount()
120 | 
121 | and apply the function followed by the mapping like this:
122 | 
123 |     nnoremap <silent> <script> <Plug>(MyPluginVisual)
124 |     \ :<C-u>execute 'normal!' visualrepeat#reapply#VisualMode(1)<CR>
125 |     \<SID>(ReapplyRepeatCount)
126 |     \:<C-u>call MyPlugin#Operator('visual', v:count, "\<lt>Plug>(MyPluginVisual)")<CR>
127 | 
128 | If you want to support running without visualrepeat.vim, too, provide a
129 | wrapper that defaults to 1v:
130 | 
131 |     function! s:VisualMode()
132 |         let l:keys = "1v\<Esc>"
133 |         silent! let l:keys = visualrepeat#reapply#VisualMode(0)
134 |         return l:keys
135 |     endfunction
136 |     nnoremap <silent> <Plug>(MyPluginVisual)
137 |     \ :<C-u>execute 'normal!' <SID>VisualMode()<Bar>
138 |     \call MyPlugin#Operator('visual', "\<lt>Plug>(MyPluginVisual)")<CR>
139 | 
140 | CONTRIBUTING
141 | ------------------------------------------------------------------------------
142 | 
143 | Report any bugs, send patches, or suggest features via the issue tracker at
144 | https://github.com/inkarkat/vim-visualrepeat/issues or email (address below).
145 | 
146 | HISTORY
147 | ------------------------------------------------------------------------------
148 | 
149 | ##### 1.33    12-Nov-2024
150 | - Adapt: Compatibility: Adding one character to previous exclusive selection
151 |   not needed since Vim 9.0.1172 in visualrepeat#reapply#VisualMode().
152 | 
153 | ##### 1.32    23-Feb-2020
154 | - BUG: visualrepeat#reapply#VisualMode() mistakenly adds the next full line
155 |   when restoring a linewise visual selection (to a smaller target).
156 | - Use :normal for Vim 7.3.100..7.4.601 and feedkeys(..., 'i') for newer
157 |   versions, aligning the used mechanism with what repeat.vim uses.
158 | 
159 | ##### 1.31    17-Mar-2019
160 | - ENH: Add g. mapping that forces built-in repeat; i.e. skips any custom
161 |   repeat.vim or visualrepeat.vim actions. This can be useful if a plugin
162 |   offers a special repeat for visual mode, but a built-in repeat on each
163 |   selected line may make sense, too. For example, my KeepText.vim plugin would
164 |   keep the entire linewise selection; forcing a built-in repeat (of the custom
165 |   operator) would reapply e.g. a &lt;Leader&gt;ka" to all selected lines instead.
166 | - Factor out ingo#buffer#temprange#Call() into ingo-library. !!! You need to
167 |   update the optional dependency to ingo-library ([vimscript #4433](http://www.vim.org/scripts/script.php?script_id=4433)) version
168 |   1.018! !!!
169 | - ENH: Make an explicit register on repeat override g:repeat\_reg. As with
170 |   built-in commands, this allows to override the original register on repeat,
171 |   e.g. "a. uses register a instead of the original one. One limitation is that
172 |   we cannot detect whether no or the default register has been given, so an
173 |   override from a non-default to the default register (e.g. via "".) is not
174 |   possible.
175 | 
176 | ##### 1.30    15-Nov-2013
177 | - ENH: When repeating over multiple lines / a blockwise selection, keep track
178 |   of added or deleted lines, and only repeat exactly on the selected lines.
179 |   Thanks to Israel Chauca for sending a patch!
180 | - When a repeat on a blockwise selection has introduced additional lines,
181 |   append those properly indented instead of omitting them.
182 | - With linewise and blockwise repeat, set the change marks '[,'] to the
183 |   changed selection. With the latter, one previously got "E19: Mark has
184 |   invalid line number" due to the removed temporary range.
185 | 
186 | ##### 1.20    14-Nov-2013
187 | - ENH: Implement blockwise repeat through temporarily moving the block to a
188 |   temporary range at the end of the buffer, like the vis.vim plugin. This
189 |   feature requires the ingo-library.
190 | 
191 | __You need to separately install
192 |   ingo-library ([vimscript #4433](http://www.vim.org/scripts/script.php?script_id=4433)) version 1.013 (or higher)!__
193 | 
194 | ##### 1.10    05-Sep-2013
195 | - Check for existence of actual visual mode mapping; do not accept a select
196 |   mode mapping, because we're applying it to a visual selection.
197 | - Pass through a [count] to the :normal . command.
198 | - Add visualrepeat#reapply#VisualMode() and visualrepeat#reapply#RepeatCount()
199 |   helper functions that plugins can use in their normal mode repeat mappings
200 |   of repeated visual mode mappings.
201 | - Minor: Make substitute() robust against 'ignorecase'.
202 | - ENH: Use the current cursor virtual column when repeating in linewise visual
203 |   mode. Inspired by
204 |   http://stackoverflow.com/questions/18610564/vim-is-possible-to-use-dot-command-in-visual-block-mode
205 | - Abort further commands on error by using echoerr inside the mapping.
206 | 
207 | ##### 1.03    21-Feb-2013
208 | - REGRESSION: Fix in 1.02 does not repeat recorded register when the mappings in
209 | repeat.vim and visualrepeat.vim differ.
210 | 
211 | ##### 1.02    27-Dec-2012
212 | - BUG: "E121: Undefined variable: g:repeat\_sequence" when using visual repeat of
213 | a mapping using registers without having used repeat.vim beforehand.
214 | 
215 | ##### 1.01    05-Apr-2012
216 | - FIX: Avoid error about undefined g:repeat\_reg when (a proper version of)
217 | repeat.vim isn't available.
218 | 
219 | ##### 1.00    14-Dec-2011
220 | - First published version.
221 | 
222 | ##### 0.01    17-Mar-2011
223 | - Split off into dedicated plugin.
224 | 
225 | ##### 0.00    30-Jul-2008
226 | - Started development.
227 | 
228 | ------------------------------------------------------------------------------
229 | Copyright: (C) 2008-2024 Ingo Karkat -
230 | The [VIM LICENSE](http://vimdoc.sourceforge.net/htmldoc/uganda.html#license) applies to this plugin.
231 | 
232 | Maintainer:     Ingo Karkat &lt;ingo@karkat.de&gt;
233 | 


--------------------------------------------------------------------------------
/doc/visualrepeat.txt:
--------------------------------------------------------------------------------
  1 | *visualrepeat.txt*      Repeat command extended to visual mode.
  2 | 
  3 | 			VISUALREPEAT    by Ingo Karkat
  4 | 							    *visualrepeat.vim*
  5 | description			|visualrepeat-description|
  6 | usage				|visualrepeat-usage|
  7 | installation			|visualrepeat-installation|
  8 | integration			|visualrepeat-integration|
  9 | limitations			|visualrepeat-limitations|
 10 | known problems			|visualrepeat-known-problems|
 11 | todo				|visualrepeat-todo|
 12 | history				|visualrepeat-history|
 13 | 
 14 | ==============================================================================
 15 | DESCRIPTION					    *visualrepeat-description*
 16 | 
 17 | This plugin defines repetition of Vim built-in normal mode commands via |.|
 18 | for visual mode. Additionally, it offers functions like the popular repeat.vim
 19 | plugin that allow mappings to be repeated in visual mode, too.
 20 | 
 21 | VISUAL MODE REPETITION							     *
 22 | 
 23 | This extends the built-in normal mode repeat |.| to visual mode.
 24 | 
 25 | VISUAL MODE MAPPING REPETITION						     *
 26 | 
 27 | Like with repeat.vim for normal mode, visual mode mappings can register a
 28 | <Plug> mapping to be used for visual mode repetition.
 29 | 
 30 | Likewise, normal mode mappings can (in addition to the repeat.vim registration
 31 | of a normal mode mapping) register a visual mode mapping with visualrepeat.vim
 32 | that will be repeated in visual mode.
 33 | 
 34 | Operator-pending mappings end with |g@| and repeat naturally; i.e. Vim
 35 | re-applies the 'opfunc' on the equivalent text (but at the current cursor
 36 | position). But without a call to repeat#set(), it is impossible to repeat this
 37 | operator-pending mapping to the current visual selection. Plugins cannot call
 38 | repeat#set() in their operator-pending mapping, because then Vim's built-in
 39 | repeat would be circumvented, the full mapping ending with g@ would be
 40 | re-executed, and the repetition would then wait for the {motion}, what is not
 41 | wanted.
 42 | Therefore, this plugin offers a separate visualrepeat#set() function that can
 43 | be invoked for operator-pending mappings. It can also be invoked for
 44 | normal-mode mappings that have already called repeat#set(), and may override
 45 | that mapping with a special repeat mapping for visual mode repeats. Together
 46 | with the remapped {Visual}. command, this allows repetition - similar to what
 47 | the built-in Vim commands do - across normal, operator-pending and visual
 48 | mode.
 49 | 
 50 | SOURCE									     *
 51 | 
 52 | - Based on vimtip #1142, Repeat last command and put cursor at start of change
 53 |     http://vim.wikia.com/wiki/Repeat_last_command_and_put_cursor_at_start_of_change
 54 | - The client interface and implementation has been based on repeat.vim
 55 |   (vimscript #2136) by Tim Pope.
 56 | 
 57 | RELATED WORKS								     *
 58 | 
 59 | - repeat.vim (vimscript #2136) has been the basis for this plugin and should
 60 |   be used in conjunction with visualrepeat.vim. (Otherwise, you'd have visual
 61 |   mode repeat, but no repeat in normal mode.)
 62 | 
 63 | ==============================================================================
 64 | USAGE							  *visualrepeat-usage*
 65 | 									 *v_.*
 66 | {Visual}.		Repeat last change in all visually selected lines.
 67 | 			- characterwise: Start from cursor position.
 68 | 			- linewise: Each line separately, starting from the
 69 | 			  current column (usually the first in this mode).
 70 | 			- blockwise: Only the selected text. This is
 71 | 			  implemented by temporarily duplicating the selection
 72 | 			  to separate lines and repeating over those, starting
 73 | 			  from the first column.
 74 | 
 75 | 			Note: If the last normal mode command included a
 76 | 			{motion} (e.g. g~e), the repetition will also move
 77 | 			exactly over this {motion}, NOT the visual selection!
 78 | 			It is thus best to repeat commands that work on the
 79 | 			entire line (e.g. g~$).
 80 | 									*v_g.*
 81 | {Visual}g.		Repeat last built-in command in all visually selected
 82 | 			lines. Skips any plugin repeat actions; only repeats
 83 | 			the last Vim command.
 84 | 
 85 | ==============================================================================
 86 | INSTALLATION					   *visualrepeat-installation*
 87 | 
 88 | The code is hosted in a Git repo at
 89 |     https://github.com/inkarkat/vim-visualrepeat
 90 | You can use your favorite plugin manager, or "git clone" into a directory used
 91 | for Vim |packages|. Releases are on the "stable" branch, the latest unstable
 92 | development snapshot on "master".
 93 | 
 94 | This script is also packaged as a |vimball|. If you have the "gunzip"
 95 | decompressor in your PATH, simply edit the *.vmb.gz package in Vim; otherwise,
 96 | decompress the archive first, e.g. using WinZip. Inside Vim, install by
 97 | sourcing the vimball or via the |:UseVimball| command. >
 98 |     vim visualrepeat*.vmb.gz
 99 |     :so %
100 | To uninstall, use the |:RmVimball| command.
101 | 
102 | DEPENDENCIES					   *visualrepeat-dependencies*
103 | 
104 | - Requires Vim 7.0 or higher.
105 | - repeat.vim (vimscript #2136) plugin (highly recommended)
106 | - |ingo-library.vim| plugin (vimscript #4433), version 1.013 or higher;
107 |   optional, for blockwise repeat only
108 | 
109 | ==============================================================================
110 | INTEGRATION					    *visualrepeat-integration*
111 | 
112 | This plugin is meant to be used together with repeat.vim.
113 | 
114 | This plugin has helper functions that plugins with cross-repeat functionality
115 | can use in their normal mode repeat mappings of repeated visual mode mappings.
116 | With this, you save work and allow for a consistent user experience.
117 | Define your normal mode repeat mapping like this: >
118 |     nnoremap <silent> <Plug>(MyPluginVisual)
119 |     \ :<C-u>execute 'normal!' visualrepeat#reapply#VisualMode(0)<Bar>
120 |     \call MyPlugin#Operator('visual', "\<lt>Plug>(MyPluginVisual)")<CR>
121 | If your plugin uses a passed [count] (i.e. the count is not only used to
122 | determine the text area the mapping is applied to), you need to define a
123 | mapping: >
124 |     vnoremap <silent> <expr> <SID>(ReapplyRepeatCount) visualrepeat#reapply#RepeatCount()
125 | and apply the function followed by the mapping like this: >
126 |     nnoremap <silent> <script> <Plug>(MyPluginVisual)
127 |     \ :<C-u>execute 'normal!' visualrepeat#reapply#VisualMode(1)<CR>
128 |     \<SID>(ReapplyRepeatCount)
129 |     \:<C-u>call MyPlugin#Operator('visual', v:count, "\<lt>Plug>(MyPluginVisual)")<CR>
130 | If you want to support running without visualrepeat.vim, too, provide a
131 | wrapper that defaults to |1v|: >
132 |     function! s:VisualMode()
133 | 	let l:keys = "1v\<Esc>"
134 | 	silent! let l:keys = visualrepeat#reapply#VisualMode(0)
135 | 	return l:keys
136 |     endfunction
137 |     nnoremap <silent> <Plug>(MyPluginVisual)
138 |     \ :<C-u>execute 'normal!' <SID>VisualMode()<Bar>
139 |     \call MyPlugin#Operator('visual', "\<lt>Plug>(MyPluginVisual)")<CR>
140 | <
141 | ==============================================================================
142 | LIMITATIONS					    *visualrepeat-limitations*
143 | 
144 | KNOWN PROBLEMS					 *visualrepeat-known-problems*
145 | 
146 | TODO							   *visualrepeat-todo*
147 | 
148 | IDEAS							  *visualrepeat-ideas*
149 | 
150 | CONTRIBUTING					     *visualrepeat-contribute*
151 | 
152 | Report any bugs, send patches, or suggest features via the issue tracker at
153 | https://github.com/inkarkat/vim-visualrepeat/issues or email (address below).
154 | 
155 | ==============================================================================
156 | HISTORY							*visualrepeat-history*
157 | 
158 | 1.33	12-Nov-2024
159 | - Adapt: Compatibility: Adding one character to previous exclusive selection
160 |   not needed since Vim 9.0.1172 in visualrepeat#reapply#VisualMode().
161 | 
162 | 1.32	23-Feb-2020
163 | - BUG: visualrepeat#reapply#VisualMode() mistakenly adds the next full line
164 |   when restoring a linewise visual selection (to a smaller target).
165 | - Use :normal for Vim 7.3.100..7.4.601 and feedkeys(..., 'i') for newer
166 |   versions, aligning the used mechanism with what repeat.vim uses.
167 | 
168 | 1.31	17-Mar-2019
169 | - ENH: Add g. mapping that forces built-in repeat; i.e. skips any custom
170 |   repeat.vim or visualrepeat.vim actions. This can be useful if a plugin
171 |   offers a special repeat for visual mode, but a built-in repeat on each
172 |   selected line may make sense, too. For example, my KeepText.vim plugin would
173 |   keep the entire linewise selection; forcing a built-in repeat (of the custom
174 |   operator) would reapply e.g. a <Leader>ka" to all selected lines instead.
175 | - Factor out ingo#buffer#temprange#Call() into ingo-library. *** You need to
176 |   update the optional dependency to ingo-library (vimscript #4433) version
177 |   1.018! ***
178 | - ENH: Make an explicit register on repeat override g:repeat_reg. As with
179 |   built-in commands, this allows to override the original register on repeat,
180 |   e.g. "a. uses register a instead of the original one. One limitation is that
181 |   we cannot detect whether no or the default register has been given, so an
182 |   override from a non-default to the default register (e.g. via "".) is not
183 |   possible.
184 | 
185 | 1.30	15-Nov-2013
186 | - ENH: When repeating over multiple lines / a blockwise selection, keep track
187 |   of added or deleted lines, and only repeat exactly on the selected lines.
188 |   Thanks to Israel Chauca for sending a patch!
189 | - When a repeat on a blockwise selection has introduced additional lines,
190 |   append those properly indented instead of omitting them.
191 | - With linewise and blockwise repeat, set the change marks '[,'] to the
192 |   changed selection. With the latter, one previously got "E19: Mark has
193 |   invalid line number" due to the removed temporary range.
194 | 
195 | 1.20	14-Nov-2013
196 | - ENH: Implement blockwise repeat through temporarily moving the block to a
197 |   temporary range at the end of the buffer, like the vis.vim plugin. This
198 |   feature requires the ingo-library. *** You need to separately install
199 |   ingo-library (vimscript #4433) version 1.013 (or higher)! ***
200 | 
201 | 1.10	05-Sep-2013
202 | - Check for existence of actual visual mode mapping; do not accept a select
203 |   mode mapping, because we're applying it to a visual selection.
204 | - Pass through a [count] to the :normal . command.
205 | - Add visualrepeat#reapply#VisualMode() and visualrepeat#reapply#RepeatCount()
206 |   helper functions that plugins can use in their normal mode repeat mappings
207 |   of repeated visual mode mappings.
208 | - Minor: Make substitute() robust against 'ignorecase'.
209 | - ENH: Use the current cursor virtual column when repeating in linewise visual
210 |   mode. Inspired by
211 |   http://stackoverflow.com/questions/18610564/vim-is-possible-to-use-dot-command-in-visual-block-mode
212 | - Abort further commands on error by using echoerr inside the mapping.
213 | 
214 | 1.03	21-Feb-2013
215 | REGRESSION: Fix in 1.02 does not repeat recorded register when the mappings in
216 | repeat.vim and visualrepeat.vim differ.
217 | 
218 | 1.02	27-Dec-2012
219 | BUG: "E121: Undefined variable: g:repeat_sequence" when using visual repeat of
220 | a mapping using registers without having used repeat.vim beforehand.
221 | 
222 | 1.01	05-Apr-2012
223 | FIX: Avoid error about undefined g:repeat_reg when (a proper version of)
224 | repeat.vim isn't available.
225 | 
226 | 1.00	14-Dec-2011
227 | First published version.
228 | 
229 | 0.01	17-Mar-2011
230 | Split off into dedicated plugin.
231 | 
232 | 0.00	30-Jul-2008
233 | Started development.
234 | 
235 | ==============================================================================
236 | Copyright: (C) 2008-2024 Ingo Karkat
237 | The VIM LICENSE applies to this plugin; see |copyright|.
238 | 
239 | Maintainer:	Ingo Karkat <ingo@karkat.de>
240 | ==============================================================================
241 |  vim:tw=78:ts=8:ft=help:norl:
242 | 


--------------------------------------------------------------------------------