├── LICENSE
├── README.md
├── log4mql.conf
└── log4mql.mqh
/LICENSE:
--------------------------------------------------------------------------------
1 | GNU GENERAL PUBLIC LICENSE
2 | Version 2, June 1991
3 |
4 | Copyright (C) 1989, 1991 Free Software Foundation, Inc.,
5 | 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
6 | Everyone is permitted to copy and distribute verbatim copies
7 | of this license document, but changing it is not allowed.
8 |
9 | Preamble
10 |
11 | The licenses for most software are designed to take away your
12 | freedom to share and change it. By contrast, the GNU General Public
13 | License is intended to guarantee your freedom to share and change free
14 | software--to make sure the software is free for all its users. This
15 | General Public License applies to most of the Free Software
16 | Foundation's software and to any other program whose authors commit to
17 | using it. (Some other Free Software Foundation software is covered by
18 | the GNU Lesser General Public License instead.) You can apply it to
19 | your programs, too.
20 |
21 | When we speak of free software, we are referring to freedom, not
22 | price. Our General Public Licenses are designed to make sure that you
23 | have the freedom to distribute copies of free software (and charge for
24 | this service if you wish), that you receive source code or can get it
25 | if you want it, that you can change the software or use pieces of it
26 | in new free programs; and that you know you can do these things.
27 |
28 | To protect your rights, we need to make restrictions that forbid
29 | anyone to deny you these rights or to ask you to surrender the rights.
30 | These restrictions translate to certain responsibilities for you if you
31 | distribute copies of the software, or if you modify it.
32 |
33 | For example, if you distribute copies of such a program, whether
34 | gratis or for a fee, you must give the recipients all the rights that
35 | you have. You must make sure that they, too, receive or can get the
36 | source code. And you must show them these terms so they know their
37 | rights.
38 |
39 | We protect your rights with two steps: (1) copyright the software, and
40 | (2) offer you this license which gives you legal permission to copy,
41 | distribute and/or modify the software.
42 |
43 | Also, for each author's protection and ours, we want to make certain
44 | that everyone understands that there is no warranty for this free
45 | software. If the software is modified by someone else and passed on, we
46 | want its recipients to know that what they have is not the original, so
47 | that any problems introduced by others will not reflect on the original
48 | authors' reputations.
49 |
50 | Finally, any free program is threatened constantly by software
51 | patents. We wish to avoid the danger that redistributors of a free
52 | program will individually obtain patent licenses, in effect making the
53 | program proprietary. To prevent this, we have made it clear that any
54 | patent must be licensed for everyone's free use or not licensed at all.
55 |
56 | The precise terms and conditions for copying, distribution and
57 | modification follow.
58 |
59 | GNU GENERAL PUBLIC LICENSE
60 | TERMS AND CONDITIONS FOR COPYING, DISTRIBUTION AND MODIFICATION
61 |
62 | 0. This License applies to any program or other work which contains
63 | a notice placed by the copyright holder saying it may be distributed
64 | under the terms of this General Public License. The "Program", below,
65 | refers to any such program or work, and a "work based on the Program"
66 | means either the Program or any derivative work under copyright law:
67 | that is to say, a work containing the Program or a portion of it,
68 | either verbatim or with modifications and/or translated into another
69 | language. (Hereinafter, translation is included without limitation in
70 | the term "modification".) Each licensee is addressed as "you".
71 |
72 | Activities other than copying, distribution and modification are not
73 | covered by this License; they are outside its scope. The act of
74 | running the Program is not restricted, and the output from the Program
75 | is covered only if its contents constitute a work based on the
76 | Program (independent of having been made by running the Program).
77 | Whether that is true depends on what the Program does.
78 |
79 | 1. You may copy and distribute verbatim copies of the Program's
80 | source code as you receive it, in any medium, provided that you
81 | conspicuously and appropriately publish on each copy an appropriate
82 | copyright notice and disclaimer of warranty; keep intact all the
83 | notices that refer to this License and to the absence of any warranty;
84 | and give any other recipients of the Program a copy of this License
85 | along with the Program.
86 |
87 | You may charge a fee for the physical act of transferring a copy, and
88 | you may at your option offer warranty protection in exchange for a fee.
89 |
90 | 2. You may modify your copy or copies of the Program or any portion
91 | of it, thus forming a work based on the Program, and copy and
92 | distribute such modifications or work under the terms of Section 1
93 | above, provided that you also meet all of these conditions:
94 |
95 | a) You must cause the modified files to carry prominent notices
96 | stating that you changed the files and the date of any change.
97 |
98 | b) You must cause any work that you distribute or publish, that in
99 | whole or in part contains or is derived from the Program or any
100 | part thereof, to be licensed as a whole at no charge to all third
101 | parties under the terms of this License.
102 |
103 | c) If the modified program normally reads commands interactively
104 | when run, you must cause it, when started running for such
105 | interactive use in the most ordinary way, to print or display an
106 | announcement including an appropriate copyright notice and a
107 | notice that there is no warranty (or else, saying that you provide
108 | a warranty) and that users may redistribute the program under
109 | these conditions, and telling the user how to view a copy of this
110 | License. (Exception: if the Program itself is interactive but
111 | does not normally print such an announcement, your work based on
112 | the Program is not required to print an announcement.)
113 |
114 | These requirements apply to the modified work as a whole. If
115 | identifiable sections of that work are not derived from the Program,
116 | and can be reasonably considered independent and separate works in
117 | themselves, then this License, and its terms, do not apply to those
118 | sections when you distribute them as separate works. But when you
119 | distribute the same sections as part of a whole which is a work based
120 | on the Program, the distribution of the whole must be on the terms of
121 | this License, whose permissions for other licensees extend to the
122 | entire whole, and thus to each and every part regardless of who wrote it.
123 |
124 | Thus, it is not the intent of this section to claim rights or contest
125 | your rights to work written entirely by you; rather, the intent is to
126 | exercise the right to control the distribution of derivative or
127 | collective works based on the Program.
128 |
129 | In addition, mere aggregation of another work not based on the Program
130 | with the Program (or with a work based on the Program) on a volume of
131 | a storage or distribution medium does not bring the other work under
132 | the scope of this License.
133 |
134 | 3. You may copy and distribute the Program (or a work based on it,
135 | under Section 2) in object code or executable form under the terms of
136 | Sections 1 and 2 above provided that you also do one of the following:
137 |
138 | a) Accompany it with the complete corresponding machine-readable
139 | source code, which must be distributed under the terms of Sections
140 | 1 and 2 above on a medium customarily used for software interchange; or,
141 |
142 | b) Accompany it with a written offer, valid for at least three
143 | years, to give any third party, for a charge no more than your
144 | cost of physically performing source distribution, a complete
145 | machine-readable copy of the corresponding source code, to be
146 | distributed under the terms of Sections 1 and 2 above on a medium
147 | customarily used for software interchange; or,
148 |
149 | c) Accompany it with the information you received as to the offer
150 | to distribute corresponding source code. (This alternative is
151 | allowed only for noncommercial distribution and only if you
152 | received the program in object code or executable form with such
153 | an offer, in accord with Subsection b above.)
154 |
155 | The source code for a work means the preferred form of the work for
156 | making modifications to it. For an executable work, complete source
157 | code means all the source code for all modules it contains, plus any
158 | associated interface definition files, plus the scripts used to
159 | control compilation and installation of the executable. However, as a
160 | special exception, the source code distributed need not include
161 | anything that is normally distributed (in either source or binary
162 | form) with the major components (compiler, kernel, and so on) of the
163 | operating system on which the executable runs, unless that component
164 | itself accompanies the executable.
165 |
166 | If distribution of executable or object code is made by offering
167 | access to copy from a designated place, then offering equivalent
168 | access to copy the source code from the same place counts as
169 | distribution of the source code, even though third parties are not
170 | compelled to copy the source along with the object code.
171 |
172 | 4. You may not copy, modify, sublicense, or distribute the Program
173 | except as expressly provided under this License. Any attempt
174 | otherwise to copy, modify, sublicense or distribute the Program is
175 | void, and will automatically terminate your rights under this License.
176 | However, parties who have received copies, or rights, from you under
177 | this License will not have their licenses terminated so long as such
178 | parties remain in full compliance.
179 |
180 | 5. You are not required to accept this License, since you have not
181 | signed it. However, nothing else grants you permission to modify or
182 | distribute the Program or its derivative works. These actions are
183 | prohibited by law if you do not accept this License. Therefore, by
184 | modifying or distributing the Program (or any work based on the
185 | Program), you indicate your acceptance of this License to do so, and
186 | all its terms and conditions for copying, distributing or modifying
187 | the Program or works based on it.
188 |
189 | 6. Each time you redistribute the Program (or any work based on the
190 | Program), the recipient automatically receives a license from the
191 | original licensor to copy, distribute or modify the Program subject to
192 | these terms and conditions. You may not impose any further
193 | restrictions on the recipients' exercise of the rights granted herein.
194 | You are not responsible for enforcing compliance by third parties to
195 | this License.
196 |
197 | 7. If, as a consequence of a court judgment or allegation of patent
198 | infringement or for any other reason (not limited to patent issues),
199 | conditions are imposed on you (whether by court order, agreement or
200 | otherwise) that contradict the conditions of this License, they do not
201 | excuse you from the conditions of this License. If you cannot
202 | distribute so as to satisfy simultaneously your obligations under this
203 | License and any other pertinent obligations, then as a consequence you
204 | may not distribute the Program at all. For example, if a patent
205 | license would not permit royalty-free redistribution of the Program by
206 | all those who receive copies directly or indirectly through you, then
207 | the only way you could satisfy both it and this License would be to
208 | refrain entirely from distribution of the Program.
209 |
210 | If any portion of this section is held invalid or unenforceable under
211 | any particular circumstance, the balance of the section is intended to
212 | apply and the section as a whole is intended to apply in other
213 | circumstances.
214 |
215 | It is not the purpose of this section to induce you to infringe any
216 | patents or other property right claims or to contest validity of any
217 | such claims; this section has the sole purpose of protecting the
218 | integrity of the free software distribution system, which is
219 | implemented by public license practices. Many people have made
220 | generous contributions to the wide range of software distributed
221 | through that system in reliance on consistent application of that
222 | system; it is up to the author/donor to decide if he or she is willing
223 | to distribute software through any other system and a licensee cannot
224 | impose that choice.
225 |
226 | This section is intended to make thoroughly clear what is believed to
227 | be a consequence of the rest of this License.
228 |
229 | 8. If the distribution and/or use of the Program is restricted in
230 | certain countries either by patents or by copyrighted interfaces, the
231 | original copyright holder who places the Program under this License
232 | may add an explicit geographical distribution limitation excluding
233 | those countries, so that distribution is permitted only in or among
234 | countries not thus excluded. In such case, this License incorporates
235 | the limitation as if written in the body of this License.
236 |
237 | 9. The Free Software Foundation may publish revised and/or new versions
238 | of the General Public License from time to time. Such new versions will
239 | be similar in spirit to the present version, but may differ in detail to
240 | address new problems or concerns.
241 |
242 | Each version is given a distinguishing version number. If the Program
243 | specifies a version number of this License which applies to it and "any
244 | later version", you have the option of following the terms and conditions
245 | either of that version or of any later version published by the Free
246 | Software Foundation. If the Program does not specify a version number of
247 | this License, you may choose any version ever published by the Free Software
248 | Foundation.
249 |
250 | 10. If you wish to incorporate parts of the Program into other free
251 | programs whose distribution conditions are different, write to the author
252 | to ask for permission. For software which is copyrighted by the Free
253 | Software Foundation, write to the Free Software Foundation; we sometimes
254 | make exceptions for this. Our decision will be guided by the two goals
255 | of preserving the free status of all derivatives of our free software and
256 | of promoting the sharing and reuse of software generally.
257 |
258 | NO WARRANTY
259 |
260 | 11. BECAUSE THE PROGRAM IS LICENSED FREE OF CHARGE, THERE IS NO WARRANTY
261 | FOR THE PROGRAM, TO THE EXTENT PERMITTED BY APPLICABLE LAW. EXCEPT WHEN
262 | OTHERWISE STATED IN WRITING THE COPYRIGHT HOLDERS AND/OR OTHER PARTIES
263 | PROVIDE THE PROGRAM "AS IS" WITHOUT WARRANTY OF ANY KIND, EITHER EXPRESSED
264 | OR IMPLIED, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
265 | MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE. THE ENTIRE RISK AS
266 | TO THE QUALITY AND PERFORMANCE OF THE PROGRAM IS WITH YOU. SHOULD THE
267 | PROGRAM PROVE DEFECTIVE, YOU ASSUME THE COST OF ALL NECESSARY SERVICING,
268 | REPAIR OR CORRECTION.
269 |
270 | 12. IN NO EVENT UNLESS REQUIRED BY APPLICABLE LAW OR AGREED TO IN WRITING
271 | WILL ANY COPYRIGHT HOLDER, OR ANY OTHER PARTY WHO MAY MODIFY AND/OR
272 | REDISTRIBUTE THE PROGRAM AS PERMITTED ABOVE, BE LIABLE TO YOU FOR DAMAGES,
273 | INCLUDING ANY GENERAL, SPECIAL, INCIDENTAL OR CONSEQUENTIAL DAMAGES ARISING
274 | OUT OF THE USE OR INABILITY TO USE THE PROGRAM (INCLUDING BUT NOT LIMITED
275 | TO LOSS OF DATA OR DATA BEING RENDERED INACCURATE OR LOSSES SUSTAINED BY
276 | YOU OR THIRD PARTIES OR A FAILURE OF THE PROGRAM TO OPERATE WITH ANY OTHER
277 | PROGRAMS), EVEN IF SUCH HOLDER OR OTHER PARTY HAS BEEN ADVISED OF THE
278 | POSSIBILITY OF SUCH DAMAGES.
279 |
280 | END OF TERMS AND CONDITIONS
281 |
282 | How to Apply These Terms to Your New Programs
283 |
284 | If you develop a new program, and you want it to be of the greatest
285 | possible use to the public, the best way to achieve this is to make it
286 | free software which everyone can redistribute and change under these terms.
287 |
288 | To do so, attach the following notices to the program. It is safest
289 | to attach them to the start of each source file to most effectively
290 | convey the exclusion of warranty; and each file should have at least
291 | the "copyright" line and a pointer to where the full notice is found.
292 |
293 | {description}
294 | Copyright (C) {year} {fullname}
295 |
296 | This program is free software; you can redistribute it and/or modify
297 | it under the terms of the GNU General Public License as published by
298 | the Free Software Foundation; either version 2 of the License, or
299 | (at your option) any later version.
300 |
301 | This program is distributed in the hope that it will be useful,
302 | but WITHOUT ANY WARRANTY; without even the implied warranty of
303 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
304 | GNU General Public License for more details.
305 |
306 | You should have received a copy of the GNU General Public License along
307 | with this program; if not, write to the Free Software Foundation, Inc.,
308 | 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
309 |
310 | Also add information on how to contact you by electronic and paper mail.
311 |
312 | If the program is interactive, make it output a short notice like this
313 | when it starts in an interactive mode:
314 |
315 | Gnomovision version 69, Copyright (C) year name of author
316 | Gnomovision comes with ABSOLUTELY NO WARRANTY; for details type `show w'.
317 | This is free software, and you are welcome to redistribute it
318 | under certain conditions; type `show c' for details.
319 |
320 | The hypothetical commands `show w' and `show c' should show the appropriate
321 | parts of the General Public License. Of course, the commands you use may
322 | be called something other than `show w' and `show c'; they could even be
323 | mouse-clicks or menu items--whatever suits your program.
324 |
325 | You should also get your employer (if you work as a programmer) or your
326 | school, if any, to sign a "copyright disclaimer" for the program, if
327 | necessary. Here is a sample; alter the names:
328 |
329 | Yoyodyne, Inc., hereby disclaims all copyright interest in the program
330 | `Gnomovision' (which makes passes at compilers) written by James Hacker.
331 |
332 | {signature of Ty Coon}, 1 April 1989
333 | Ty Coon, President of Vice
334 |
335 | This General Public License does not permit incorporating your program into
336 | proprietary programs. If your program is a subroutine library, you may
337 | consider it more useful to permit linking proprietary applications with the
338 | library. If this is what you want to do, use the GNU Lesser General
339 | Public License instead of this License.
340 |
341 |
--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
1 | # log4mql
2 | Log4mql is a mql4 (MetaQuotes MetaTrader 4 Language) library for flexible logging to files and the terminal console. It is modeled after the Log4j Java library.
3 |
4 | ## Usage in your code
5 |
6 | CLog4mql::getInstance().error(__FILE__, __LINE__, "Something unexpected happen");
7 |
8 | or (for more frequent usage)
9 |
10 | CLog4mql* logger = CLog4mql::getInstance();
11 | logger.error(__FILE__, __LINE__, "Something unexpected happen");
12 | logger.info(__FILE__, __LINE__, "Calcumation done");
13 | logger.debug(__FILE__, __LINE__, StringFormat("The result of %s is %d", string1, value1));
14 |
15 |
16 | Dont forget at the end of your EA / Indicator / Script:
17 |
18 | CLog4mql::release();
19 |
20 | or
21 |
22 | logger.release();
23 |
24 |
25 | ## Directories
26 | The directory for the log4mql.conf and the log4mql.log files
27 | * Normal mode: `/MQL4/Files/`
28 | * Test mode: `/tester/files/`
29 |
30 | ## Log Levels
31 | You can configure the required log level for output in the configfile for each appending file and / or a global default.
32 | * TRACE
33 | * DEBUG
34 | * INFO
35 | * WARN
36 | * ERROR
37 | * CRIT
38 |
--------------------------------------------------------------------------------
/log4mql.conf:
--------------------------------------------------------------------------------
1 | ##
2 | # General settings
3 |
4 | # Loglevel for logging class internal messages
5 | log4mql = info
6 |
7 | # Set the default log level
8 | # This level is applied to each file which is not configured explicitly
9 | defaultLevel = info
10 |
11 | # File for logging entrys
12 | # Set to off to disable logging to file
13 | logfile = log4mql.log
14 |
15 |
16 | # Set true to logging on console even when IsTesting() return true
17 | logToConsoleWhenInTesting = false
18 |
19 |
20 | ##
21 | # Log file rotation (logrotate)
22 |
23 | # rotateEnabled set to true to enable log file rotation
24 | # rotateEnabled set to false to disable log file rotation
25 | rotateEnable = true
26 |
27 | # Checking file size is an expensive operation So we check each X log events for
28 | # the log file size. A lower value will decrease performance, but rotates more
29 | # excact to the configured size. A higher value will increase perfoermance, but
30 | # rotates less exact to the configured size
31 | rotateCheckPeriod = 1000
32 |
33 | # Rotate log files when they growth above this value (in megabytes)
34 | rotateSizeMb = 1
35 |
36 | # Generations of log files to keep
37 | rotateGenerations = 8
38 |
39 |
40 | ##
41 | # Log levels by files
42 |
43 | # =
44 | # Set an explicit log level to your mql files
45 | #
46 | #
47 | # The name of the source file (mq4 / mqh) without file extension. Case will be
48 | # ignored. For example, if filename of your source file, wich is the origin of
49 | # your log event is 'MyCustomIndicator.mq4'. Than you can use for :
50 | # - MyCustomIndicator
51 | # - mycustomindicator
52 | # - MYCUSTOMINDICATOR
53 | #
54 | #
55 | # Each logfile can contain logging events with any log level. Here you can
56 | # configure the minimum required level of the log event, which should be shown
57 | # in the MetaTrader console (Experts tab) and written to log file.
58 | # (Excepting all events in optimisation mode or console output in test mode)
59 | # Valid log level values
60 | # - trace
61 | # - debug
62 | # - info
63 | # - warn
64 | # - error
65 | # - crit
66 | MyCustomIndicator = info
67 | MyExperimentalScript = debug
68 | MyProductionalExpertAdvisor = warn
69 | SomeOtherBuddy = crit
70 | CurrentPrototype = trace
71 |
72 |
--------------------------------------------------------------------------------
/log4mql.mqh:
--------------------------------------------------------------------------------
1 | #ifndef __LOG4MQL__
2 | #define __LOG4MQL__
3 |
4 | #property copyright "GPL2 Written by Michael Schmidt (m@swayp.net)"
5 | #property link "https://swayp.net"
6 | #property strict
7 |
8 | /**
9 | * Log4mql
10 | *
11 | * Log4mql is a mql4 (MetaQuotes MetaTrader 4 Language) library for flexible
12 | * logging to files and the terminal console. It is modeled after the Log4j
13 | * Java library.
14 | *
15 | * Usage in your code:
16 | *
17 | * CLog4mql::getInstance().error(__FILE__, __LINE__,
18 | * "Something unexpected happen");
19 | *
20 | * or (for more frequent usage)
21 | *
22 | * CLog4mql* logger = CLog4mql::getInstance();
23 | * logger.error(__FILE__, __LINE__, "Something unexpected happen");
24 | * logger.info(__FILE__, __LINE__, "Calcumation done");
25 | * logger.debug(__FILE__, __LINE__, StringFormat("The result of %s is %d",
26 | * string1, value1));
27 | *
28 | * Dont forget at the end of your EA / Indicator / Script:
29 | * CLog4mql::release();
30 | * or
31 | * logger.release();
32 | *
33 | * You can configure the required log level for output in the configfile
34 | * For each appending file and / or a global default.
35 | *
36 | * Log Levels:
37 | * TRACE
38 | * DEBUG
39 | * INFO
40 | * WARN
41 | * ERROR
42 | * CRIT
43 | */
44 |
45 | /**
46 | * Log levels
47 | */
48 | #define LOG4MQL_LEVEL_TRACE 6
49 | #define LOG4MQL_LEVEL_DEBUG 5
50 | #define LOG4MQL_LEVEL_INFO 4
51 | #define LOG4MQL_LEVEL_WARN 3
52 | #define LOG4MQL_LEVEL_ERROR 2
53 | #define LOG4MQL_LEVEL_CRIT 1
54 |
55 | /**
56 | * Configuation file
57 | */
58 | #define LOG4MQL_CONFFILE "log4mql.conf"
59 |
60 | /**
61 | * Default configuration
62 | */
63 | #define LOG4MQL_DEFAULT_LOGFILE "log4mql.log"
64 | #define LOG4MQL_DEFAULT_LEVEL 4
65 | #define LOG4MQL_DEFAULT_LOG_TO_CONSOLE_WHEN_IN_TESTING true
66 | #define LOG4MQL_DEFAULT_ROTATE_ENABLE true
67 | #define LOG4MQL_DEFAULT_ROTATE_CHECK_PERIOD 1000
68 | #define LOG4MQL_DEFAULT_ROTATE_SIZE_MB 1
69 | #define LOG4MQL_DEFAULT_ROTATE_GENERATIONS 8
70 |
71 | /**
72 | * Class CLog4mql
73 | *
74 | * Dynamic logger designed to provide log4j style logging to mql4
75 | */
76 | class CLog4mql {
77 | private:
78 | static CLog4mql *instance;
79 | string confLogFile;
80 | int confDefaultLevel;
81 | bool confLogToConsoleWhenInTesting;
82 | bool confRotateEnabled;
83 | int confRotateCheckPeriod;
84 | ulong confRotateSize;
85 | int confRotateGenerations;
86 | int logFileHandle;
87 | int configs;
88 | string configFile[100];
89 | int configLevel[100];
90 | int actionsLastRotate;
91 |
92 | protected:
93 | /**
94 | * Constructor
95 | */
96 | CLog4mql() {
97 | confLogFile = LOG4MQL_DEFAULT_LOGFILE;
98 | confDefaultLevel = LOG4MQL_DEFAULT_LEVEL;
99 | confLogToConsoleWhenInTesting = LOG4MQL_DEFAULT_LOG_TO_CONSOLE_WHEN_IN_TESTING;
100 | confRotateEnabled = LOG4MQL_DEFAULT_ROTATE_ENABLE;
101 | confRotateCheckPeriod = LOG4MQL_DEFAULT_ROTATE_CHECK_PERIOD;
102 | confRotateSize = LOG4MQL_DEFAULT_ROTATE_SIZE_MB * 1024 * 1024;
103 | confRotateGenerations = LOG4MQL_DEFAULT_ROTATE_GENERATIONS;
104 | logFileHandle = INVALID_HANDLE;
105 | configs = 0;
106 | loadConfig();
107 | actionsLastRotate = confRotateCheckPeriod;
108 | }
109 |
110 | /**
111 | * Destructor
112 | */
113 | ~CLog4mql() {
114 | closeLogFile();
115 | }
116 |
117 | private:
118 | /**
119 | * Prevent copy of singleton instance
120 | */
121 | CLog4mql(const CLog4mql&);
122 |
123 | public:
124 | /**
125 | * GetInstance
126 | *
127 | * Get singleton instance
128 | */
129 | static CLog4mql * getInstance() {
130 | if(instance == NULL) {
131 | instance = new CLog4mql();
132 | instance.debug(__FILE__, __LINE__, "Instance created");
133 | }
134 | return instance;
135 | }
136 |
137 | /**
138 | * Release
139 | *
140 | * Release singleton instance
141 | */
142 | static void release() {
143 | if(instance != NULL) {
144 | instance.debug(__FILE__, __LINE__, "Instance released");
145 | delete instance;
146 | }
147 | instance = NULL;
148 | }
149 |
150 | public:
151 | /**
152 | * Trace
153 | *
154 | * Log trace message
155 | *
156 | * @var string file
157 | * Origin file name which sends the log message (__FILE__)
158 | * @var int line
159 | * Line of log method call in origin file (__LINE__)
160 | * @var string msg
161 | * Message to log
162 | * @return void
163 | */
164 | void trace(string file, int line, string msg) {
165 | log(LOG4MQL_LEVEL_TRACE, file, line, msg);
166 | }
167 |
168 | /**
169 | * Debug
170 | *
171 | * Log debug message
172 | *
173 | * @var string file
174 | * Origin file name which sends the log message (__FILE__)
175 | * @var int line
176 | * Line of log method call in origin file (__LINE__)
177 | * @var string msg
178 | * Message to log
179 | * @return void
180 | */
181 | void debug(string file, int line, string msg) {
182 | log(LOG4MQL_LEVEL_DEBUG, file, line, msg);
183 | }
184 |
185 | /**
186 | * Info
187 | *
188 | * Log info message
189 | *
190 | * @var string file
191 | * Origin file name which sends the log message (__FILE__)
192 | * @var int line
193 | * Line of log method call in origin file (__LINE__)
194 | * @var string msg
195 | * Message to log
196 | * @return void
197 | */
198 | void info(string file, int line, string msg) {
199 | log(LOG4MQL_LEVEL_INFO, file, line, msg);
200 | }
201 |
202 | /**
203 | * Warn
204 | *
205 | * Log warn message
206 | *
207 | * @var string file
208 | * Origin file name which sends the log message (__FILE__)
209 | * @var int line
210 | * Line of log method call in origin file (__LINE__)
211 | * @var string msg
212 | * Message to log
213 | * @return void
214 | */
215 | void warn(string file, int line, string msg) {
216 | log(LOG4MQL_LEVEL_WARN, file, line, msg);
217 | }
218 |
219 | /**
220 | * Error
221 | *
222 | * Log error message
223 | *
224 | * @var string file
225 | * Origin file name which sends the log message (__FILE__)
226 | * @var int line
227 | * Line of log method call in origin file (__LINE__)
228 | * @var string msg
229 | * Message to log
230 | * @return void
231 | */
232 | void error(string file, int line, string msg) {
233 | log(LOG4MQL_LEVEL_ERROR, file, line, msg);
234 | }
235 |
236 | /**
237 | * Crit
238 | *
239 | * Log critical message
240 | *
241 | * @var string file
242 | * Origin file name which sends the log message (__FILE__)
243 | * @var int line
244 | * Line of log method call in origin file (__LINE__)
245 | * @var string msg
246 | * Message to log
247 | * @return void
248 | */
249 | void crit(string file, int line, string msg) {
250 | log(LOG4MQL_LEVEL_CRIT, file, line, msg);
251 | }
252 |
253 | private:
254 | /**
255 | * Log
256 | *
257 | * Create a log message (console / log file)
258 | * Called by trace, debug, info, warn, error and crit methods
259 | *
260 | * Different targets per run mode
261 | *
262 | * File Console
263 | * Normal x x
264 | * Testing x -
265 | * Optimization - -
266 | *
267 | * @var int level
268 | * Level of log message
269 | * @var string file
270 | * Origin file name which sends the log message (__FILE__)
271 | * @var int line
272 | * Line of log method call in origin file (__LINE__)
273 | * @var string msg
274 | * Message to log
275 | * @return void
276 | */
277 | void log(int level, string file, int line, string msg) {
278 | if(IsOptimization()) {
279 | return;
280 | }
281 | if(!IsTesting() || confLogToConsoleWhenInTesting) {
282 | logToConsole(level, file, line, msg);
283 | }
284 | logToFile(level, file, line, msg);
285 | }
286 |
287 | /**
288 | * LogToConsole
289 | *
290 | * Log a message to MetaTrader console
291 | *
292 | * @var int level
293 | * Level of log message
294 | * @var string file
295 | * Origin file name which sends the log message (__FILE__)
296 | * @var int line
297 | * Line of log method call in origin file (__LINE__)
298 | * @var string msg
299 | * Message to log
300 | * @return void
301 | */
302 | void logToConsole(int level, string file, int line, string msg) {
303 | if(level <= getFileLevel(file)) {
304 | PrintFormat("%-8s [%-20s:%-3d] %s", levelToString(level), file, line, msg);
305 | }
306 | }
307 |
308 | /**
309 | * LogToFile
310 | *
311 | * Log a message to log file
312 | *
313 | * @var int level
314 | * Level of log message
315 | * @var string file
316 | * Origin file name which sends the log message (__FILE__)
317 | * @var int line
318 | * Line of log method call in origin file (__LINE__)
319 | * @var string msg
320 | * Message to log
321 | * @return void
322 | */
323 | void logToFile(int level, string file, int line, string msg) {
324 | if(confLogFile == "off") {
325 | return;
326 | }
327 | openLogFile();
328 | if(logFileHandle == INVALID_HANDLE) {
329 | return;
330 | }
331 | if(level <= getFileLevel(file)) {
332 | int bytes = (int) FileWriteString(logFileHandle, StringFormat("%s %-8s [%-20s:%-3d] %s\n", getDate(),
333 | levelToString(level), file, line, msg));
334 | if(bytes <= 0) {
335 | Print("LOG4MQL ERROR: Failed to write to logfile " + confLogFile);
336 | closeLogFile();
337 | }
338 | FileFlush(logFileHandle);
339 | actionsLastRotate++;
340 | if(confRotateEnabled && actionsLastRotate >= confRotateCheckPeriod) {
341 | actionsLastRotate = 0;
342 | if(FileSize(logFileHandle) >= confRotateSize) {
343 | rotate();
344 | }
345 | }
346 | }
347 | }
348 |
349 | /**
350 | * GetDate
351 | *
352 | * Generate date string for log file message
353 | *
354 | * @return string
355 | * Date in format YYYY-MM-DD hh:mm:ss
356 | */
357 | string getDate() {
358 | datetime t = TimeLocal();
359 | return StringFormat("%04d-%02d-%02d %02d:%02d:%02d", TimeYear(t), TimeMonth(t), TimeDay(t), TimeHour(t),
360 | TimeMinute(t), TimeSeconds(t));
361 | }
362 |
363 | /**
364 | * OpenLogFile
365 | *
366 | * @return void
367 | */
368 | void openLogFile() {
369 | if(logFileHandle != INVALID_HANDLE) {
370 | return;
371 | }
372 | logFileHandle = FileOpen(confLogFile, FILE_WRITE|FILE_SHARE_WRITE|FILE_READ|FILE_SHARE_READ|FILE_TXT);
373 | if(logFileHandle == INVALID_HANDLE) {
374 | Print("LOG4MQL ERROR: Failed to open logfile " + confLogFile);
375 | return;
376 | }
377 | FileSeek(logFileHandle, 0, SEEK_END);
378 | }
379 |
380 | /**
381 | * CloseLogFile
382 | *
383 | * @return void
384 | */
385 | void closeLogFile() {
386 | if(logFileHandle != INVALID_HANDLE) {
387 | FileClose(logFileHandle);
388 | logFileHandle = INVALID_HANDLE;
389 | }
390 | }
391 |
392 | /**
393 | * Rotate
394 | *
395 | * Rotate logfiles / delete old rotated log files
396 | *
397 | * Example for 4 Generations:
398 | * log4mql.log -> log4mql.log.1
399 | * log4mql.log.1 -> log4mql.log.2
400 | * log4mql.log.2 -> log4mql.log.3
401 | * log4mql.log.3 -> log4mql.log.4
402 | * log4mql.log.4 -> delete
403 | *
404 | * @return void
405 | */
406 | void rotate() {
407 | if(!confRotateEnabled) {
408 | return;
409 | }
410 | if(!FileIsExist(confLogFile)) {
411 | return;
412 | }
413 | info(__FILE__, __LINE__, "Rotate");
414 | closeLogFile();
415 | string delFile = confLogFile + "." + IntegerToString(confRotateGenerations);
416 | if(FileIsExist(delFile)) {
417 | info(__FILE__, __LINE__, " delete %s" + delFile);
418 | FileDelete(delFile);
419 | }
420 | for(int i = confRotateGenerations - 1; i >= 0; i--) {
421 | string fileFrom;
422 | if(i > 0) {
423 | fileFrom = confLogFile + "." + IntegerToString(i);
424 | } else {
425 | fileFrom = confLogFile;
426 | }
427 | if(!FileIsExist(fileFrom)) {
428 | continue;
429 | }
430 | string fileTo = confLogFile + "." + IntegerToString(i + 1);
431 | info(__FILE__, __LINE__, StringFormat(" %-20s => %s", fileFrom, fileTo));
432 | FileMove(fileFrom, 0, fileTo, 0);
433 | }
434 | FileDelete(confLogFile);
435 | openLogFile();
436 | }
437 |
438 | /**
439 | * LoadConfig
440 | *
441 | * Read log4mql configuration from
442 | * Normal mode: /Files/log4mql.conf
443 | * Test mode: /tester/files/log4mql.conf
444 | *
445 | * @return void
446 | */
447 | void loadConfig() {
448 | if(!FileIsExist(LOG4MQL_CONFFILE)) {
449 | warn(__FILE__, __LINE__, "No configuration file " + LOG4MQL_CONFFILE + " found");
450 | return;
451 | }
452 | int confFileHandle = FileOpen(LOG4MQL_CONFFILE, FILE_READ);
453 | if(confFileHandle == INVALID_HANDLE) {
454 | warn(__FILE__, __LINE__, "Failed to read configuration file " + LOG4MQL_CONFFILE);
455 | return;
456 | }
457 | while(!FileIsEnding(confFileHandle)) {
458 | string line = FileReadString(confFileHandle);
459 | StringReplace(line, " ", "");
460 | StringReplace(line, "\t", "");
461 | string key = getConfigEntry(line, 0);
462 | string value = getConfigEntry(line, 1);
463 | if(key == "" || value == "") {
464 | continue;
465 | }
466 | if(key == "defaultLevel") {
467 | confDefaultLevel = stringToLevel(value);
468 | } else if(key == "logfile") {
469 | confLogFile = value;
470 | debug(__FILE__, __LINE__, StringFormat("Config %-20s = %s", key, value));
471 | } else if (key == "logToConsoleWhenInTesting") {
472 | confLogToConsoleWhenInTesting = "true" == value;
473 | debug(__FILE__, __LINE__, StringFormat("Config %-20s = %s", key, (confLogToConsoleWhenInTesting ? "ENABLED" : "DISABLED")));
474 | } else if(key == "rotateEnable") {
475 | if(value == "true") {
476 | confRotateEnabled = true;
477 | debug(__FILE__, __LINE__, StringFormat("Config %-20s = %s", key, "ENABLED"));
478 | } else {
479 | confRotateEnabled = false;
480 | debug(__FILE__, __LINE__, StringFormat("Config %-20s = %s", key, "DISABLED"));
481 | }
482 | } else if(key == "rotateCheckPeriod") {
483 | confRotateCheckPeriod = StrToInteger(value);
484 | debug(__FILE__, __LINE__, StringFormat("Config %-20s = %s", key, value));
485 | } else if(key == "rotateSizeMb") {
486 | confRotateSize = (ulong) StrToInteger(value) * 1024 * 1024;
487 | debug(__FILE__, __LINE__, StringFormat("Config %-20s = %s", key, value));
488 | } else if(key == "rotateGenerations") {
489 | confRotateGenerations = StrToInteger(value);
490 | debug(__FILE__, __LINE__, StringFormat("Config %-20s = %s", key, value));
491 | } else {
492 | int level = stringToLevel(value);
493 | StringToUpper(key);
494 | StringToUpper(value);
495 | configFile[configs] = key;
496 | configLevel[configs] = level;
497 | configs++;
498 | debug(__FILE__, __LINE__, StringFormat("Config file %-15s = %s", key, levelToString(level)));
499 | }
500 | }
501 | FileClose(confFileHandle);
502 | }
503 |
504 | /**
505 | * GetConfigEntry
506 | *
507 | * Parse a config line
508 | * Cut comments and whitspaces
509 | *
510 | * Example
511 | * Log line: foo = bar # Comment
512 | * Key (col 0) is 'foo'
513 | * Value (col 1) is 'bar'
514 | *
515 | * @var string line
516 | * Line from configuration file
517 | * @var int col
518 | * 1 = key
519 | * 2 = value
520 | * @return string
521 | * Key or value
522 | * Empty string if
523 | * Parse failed
524 | * Line empty
525 | * Comment line
526 | */
527 | string getConfigEntry(string line, int col) {
528 | if(StringFind(line, "=") == EMPTY) {
529 | return "";
530 | }
531 | int comment = StringFind(line, "#");
532 | if(comment == 0) {
533 | return "";
534 | } else if(comment > 0) {
535 | line = StringSubstr(line, 0, comment - 1);
536 | }
537 | string spl[];
538 | StringSplit(line, StringGetCharacter("=", 0), spl);
539 | string str = spl[col];
540 | StringTrimLeft(str);
541 | StringTrimRight(str);
542 | return str;
543 | }
544 |
545 | /**
546 | * GetFileLevel
547 | *
548 | * Get loglevel for origin file of log message from configuration / default
549 | *
550 | * @var string file
551 | * Origin file of log message
552 | * @return int
553 | * Log level
554 | */
555 | int getFileLevel(const string file) {
556 | string f = file;
557 | StringReplace(f, ".mqh", "");
558 | StringReplace(f, ".mq4", "");
559 | StringToUpper(f);
560 | for(int i = 0; i < configs; i++) {
561 | if(configFile[i] == f) {
562 | return configLevel[i];
563 | }
564 | }
565 | return confDefaultLevel;
566 | }
567 |
568 | /**
569 | * LevelToString
570 | *
571 | * Convert level integer to string
572 | *
573 | * @var int l
574 | * Level to convert
575 | * @return string
576 | * Log level string
577 | */
578 | string levelToString(int l) {
579 | switch(l) {
580 | case LOG4MQL_LEVEL_TRACE:
581 | return "TRACE";
582 | case LOG4MQL_LEVEL_DEBUG:
583 | return "DEBUG";
584 | case LOG4MQL_LEVEL_INFO:
585 | return "INFO";
586 | case LOG4MQL_LEVEL_WARN:
587 | return "WARNING";
588 | case LOG4MQL_LEVEL_ERROR:
589 | return "ERROR";
590 | case LOG4MQL_LEVEL_CRIT:
591 | return "CRITICAL";
592 | default:
593 | return "";
594 | }
595 | }
596 |
597 | /**
598 | * StringToLevel
599 | *
600 | * Convert string to level integer
601 | *
602 | * @var string s
603 | * Level string to convert
604 | * @return int
605 | * Log level
606 | */
607 | int stringToLevel(string str) {
608 | StringToUpper(str);
609 | if(str == "TRACE") {
610 | return LOG4MQL_LEVEL_TRACE;
611 | } else if(str == "DEBUG") {
612 | return LOG4MQL_LEVEL_DEBUG;
613 | } else if(str == "WARN" || str == "WARNING") {
614 | return LOG4MQL_LEVEL_WARN;
615 | } else if(str == "ERROR") {
616 | return LOG4MQL_LEVEL_ERROR;
617 | } else if(str == "CRIT" || str == "CRITICAL") {
618 | return LOG4MQL_LEVEL_CRIT;
619 | } else {
620 | return confDefaultLevel;
621 | }
622 | }
623 | };
624 |
625 | /**
626 | * Initialize singleon
627 | */
628 | CLog4mql * CLog4mql::instance = NULL;
629 |
630 | #endif /* __LOG4MQL__ */
631 |
--------------------------------------------------------------------------------