├── README.md
└── cygwin-install.bat


/README.md:
--------------------------------------------------------------------------------
 1 | cygwin-auto-install
 2 | ===================
 3 | 
 4 | Automated cygwin install. Just download the project as a zip file, extract and run cygwin-install.bat to install cygwin + apt-cyg + packages required for apt-cyg + optional packages.
 5 | 
 6 | You can edit the batch file to specify which optional packages you'd like installed.
 7 | 
 8 | Created by wjrogers: https://gist.github.com/wjrogers/1016065.
 9 | 
10 | Suggest this workflow for this project: http://scottchacon.com/2011/08/31/github-flow.html
11 | 
12 | Source URL:
13 | https://github.com/rtwolf/cygwin-auto-install/
14 | 
15 | If you've found this project helpful, please support me by buying me a coffee: http://www.mind-manual.com/blog/buy-me-a-coffee/
16 | 
17 | As you may know, "A programmer is just a tool which converts caffeine into code". Thanks in advance!
18 | 


--------------------------------------------------------------------------------
/cygwin-install.bat:
--------------------------------------------------------------------------------
 1 | @ECHO OFF
 2 | REM -- Automates cygwin installation
 3 | REM -- Source: https://github.com/rtwolf/cygwin-auto-install
 4 | REM -- Based on: https://gist.github.com/wjrogers/1016065
 5 |  
 6 | SETLOCAL
 7 |  
 8 | REM -- Change to the directory of the executing batch file
 9 | CD %~dp0
10 | 
11 | REM -- Download the Cygwin installer
12 | IF NOT EXIST cygwin-setup.exe (
13 | 	ECHO cygwin-setup.exe NOT found! Downloading installer...
14 | 	bitsadmin /transfer cygwinDownloadJob /download /priority normal https://cygwin.com/setup-x86_64.exe %CD%\\cygwin-setup.exe
15 | ) ELSE (
16 | 	ECHO cygwin-setup.exe found! Skipping installer download...
17 | )
18 |  
19 | REM -- Configure our paths
20 | SET SITE=http://cygwin.mirrors.pair.com/
21 | SET LOCALDIR=%CD%
22 | SET ROOTDIR=C:/cygwin
23 |  
24 | REM -- These are the packages we will install (in addition to the default packages)
25 | SET PACKAGES=mintty,wget,ctags,diffutils,git,git-completion,git-svn,stgit,mercurial
26 | REM -- These are necessary for apt-cyg install, do not change. Any duplicates will be ignored.
27 | SET PACKAGES=%PACKAGES%,wget,tar,gawk,bzip2,subversion
28 |  
29 | REM -- More info on command line options at: https://cygwin.com/faq/faq.html#faq.setup.cli
30 | REM -- Do it!
31 | ECHO *** INSTALLING DEFAULT PACKAGES
32 | cygwin-setup --quiet-mode --no-desktop --download --local-install --no-verify -s %SITE% -l "%LOCALDIR%" -R "%ROOTDIR%"
33 | ECHO.
34 | ECHO.
35 | ECHO *** INSTALLING CUSTOM PACKAGES
36 | cygwin-setup -q -d -D -L -X -s %SITE% -l "%LOCALDIR%" -R "%ROOTDIR%" -P %PACKAGES%
37 |  
38 | REM -- Show what we did
39 | ECHO.
40 | ECHO.
41 | ECHO cygwin installation updated
42 | ECHO  - %PACKAGES%
43 | ECHO.
44 | 
45 | ECHO apt-cyg installing.
46 | set PATH=%ROOTDIR%/bin;%PATH%
47 | %ROOTDIR%/bin/bash.exe -c 'svn --force export http://apt-cyg.googlecode.com/svn/trunk/ /bin/'
48 | %ROOTDIR%/bin/bash.exe -c 'chmod +x /bin/apt-cyg'
49 | ECHO apt-cyg installed if it says somin like "A    /bin" and "A   /bin/apt-cyg" and "Exported revision 18" or some other number.
50 | 
51 | ENDLOCAL
52 |  
53 | PAUSE
54 | EXIT /B 0
55 | 


--------------------------------------------------------------------------------