├── README.md
└── plugin
    └── github.vim


/README.md:
--------------------------------------------------------------------------------
 1 | github.vim 
 2 | =
 3 | http://github.com/solars/github_vim/
 4 | 
 5 | I tried to remove the dependency on drnics github-tmbundle scripts in this branch,
 6 | please report any errors and feel free to correct/suggest/add.
 7 | 
 8 | ##Description
 9 | 
10 | 
11 | This is a quick and dirty vim plugin to use some github features locally from vim.
12 | 
13 | It enables you to:
14 |   
15 |   - open a link to the corresponding github file of a local vim selection
16 |   - add a comment to the corresponding github commit of a locally selected line
17 |   - yank a link to the corresponding github file of a local vim selection into the system clipboard
18 | 
19 | ##Suggested installation
20 | 
21 | The file structure should be clear, just copy the github.vim into ~/.vim/plugin/
22 | 
23 | ##Installing when using [Pathogen](https://github.com/tpope/vim-pathogen)
24 | 
25 |     cd ~/.vim/bundle
26 |     git clone git@github.com:solars/github-vim.git
27 | 
28 | ##Usage
29 | 
30 |   - Comment Commit: on the relevant line Press 'ghc' in normal mode
31 |   - Open Selection: create a selection in visual mode and press 'gho'
32 |   - Yank Selection: create a selection in visual mode and press 'ghy'
33 | 
34 | To remap the keybinding in your ~/.vimrc use:
35 | 
36 |   - map <F5> <Plug>GithubOpen
37 |   - map <F6> <Plug>GithubComment
38 | 
39 | ##Notes
40 | 
41 | Since this is my first vim plugins, feel free to send corrections or improvements :)
42 | sol@textmode.at
43 | 


--------------------------------------------------------------------------------
/plugin/github.vim:
--------------------------------------------------------------------------------
  1 | " https://github.com/solars/github-vim/
  2 | " sol@textmode.at
  3 | 
  4 | if exists("loaded_github") || &cp 
  5 |   finish 
  6 | endif
  7 | 
  8 | 
  9 | " --- main functions --- "
 10 | function! s:Hash(n1,n2)
 11 |   if a:n1 == a:n2
 12 |     return '#L' . a:n1
 13 |   else
 14 |     return '#L' . a:n1 . ',L' . a:n2
 15 |   endif
 16 | endfunction
 17 | 
 18 | function! s:Open() range
 19 |   if empty(s:RepositoryRoot()) || empty(s:Remote())
 20 |     call s:error("File not in repository or no remote found!")
 21 |   else
 22 |     let url = s:ReposUrl().'/'.s:RelPath(). s:Hash(a:firstline,a:lastline)
 23 |     call s:OpenUrl(url)
 24 |   end
 25 | endfunction
 26 | 
 27 | function! s:Yank()
 28 |   if empty(s:RepositoryRoot()) || empty(s:Remote())
 29 |     call s:error("File not in repository or no remote found!")
 30 |   else
 31 |     let url = s:ReposUrl().'/'.s:RelPath() . s:Hash(a:firstline,a:lastline)
 32 |     call s:YankUrl(url)
 33 |     echo "GitHub URL: " . url
 34 |   end
 35 | endfunction
 36 | 
 37 | function! s:Comment()
 38 |   if empty(s:RepositoryRoot()) || empty(s:Remote())
 39 |     call s:error("File not in repository or no remote found!")
 40 |   else
 41 |     let url = s:ReposUrl().'/'.s:RelPath() . s:Hash(a:firstline,a:lastline)
 42 |     let line = line('.')
 43 |     let output = s:CdExec(s:RepositoryRoot(),'git blame -l -s -L '.line.','.line.' '.s:RelPath())
 44 |     if empty(output)
 45 |       s:error("No commit found")
 46 |       return
 47 |     end
 48 |     let commit = split(output)[0]
 49 |     let index=s:CommitIndex(commit)
 50 |     let url = s:ProjectUrl().'/commit/'.commit.'/'.s:RelPath().'#diff-'.index
 51 |     call s:OpenUrl(url)
 52 |   endif
 53 | endfunction
 54 | 
 55 | 
 56 | " --- key mappings --- "
 57 | 
 58 | if !hasmapto('<Plug>GithubComment', 'n')
 59 |   nmap <unique>ghc <Plug>GithubComment
 60 | endif
 61 | nnoremap <unique> <script> <Plug>GithubComment <SID>Comment
 62 | nnoremap <silent> <SID>Comment :call <SID>Comment()<CR>
 63 | 
 64 | if !hasmapto('<Plug>GithubOpen', 'v')
 65 |   vmap <unique>gho <Plug>GithubOpen
 66 | endif
 67 | vnoremap <unique> <script> <Plug>GithubOpen <SID>Open
 68 | vnoremap <silent> <SID>Open :call <SID>Open()<CR>
 69 | 
 70 | if !hasmapto('<Plug>GithubYank', 'v')
 71 |   map <unique>ghy <Plug>GithubYank
 72 | endif
 73 | 
 74 | noremap <unique> <script> <Plug>GithubYank <SID>Yank
 75 | noremap <silent> <SID>Yank :call <SID>Yank()<CR>
 76 | 
 77 | " --- helpers --- "
 78 | 
 79 | " repository root path of current file
 80 | function! s:RepositoryRoot() "+error checks
 81 |   if !exists('b:repos_root')
 82 |     let dir = expand("%:p:h")
 83 |     let rel_path = s:CdExec(dir,'git rev-parse --show-cdup')
 84 |     if !empty(matchstr(rel_path,'fatal'))
 85 |       return
 86 |     end
 87 |     let rel_path = substitute(rel_path, "\n",'','g')
 88 |     let b:repos_root = simplify(dir.'/'.rel_path)
 89 |   endif
 90 |   return b:repos_root
 91 | endfunction
 92 | 
 93 | " current branch name
 94 | function! s:CurrentBranch()
 95 |   if !exists('b:branch')
 96 |     let branches = s:CdExec(expand("%:p:h"),"git branch")
 97 |     if empty(branches)
 98 |       return
 99 |     endif
100 |     let b:branch = matchstr(branches, '\* \zs.\{-}\ze\n.*')
101 |   endif
102 |   return b:branch
103 | endfunction
104 | 
105 | " relative path of the current file to the repository root 
106 | function! s:RelPath()
107 |   if !exists('b:rel_path')
108 |     let root = escape(s:RepositoryRoot(),'./')
109 |     let file = expand('%:p')
110 |     let b:rel_path = strpart(file,matchend(file, root))
111 |   endif
112 |   return b:rel_path
113 | endfunction
114 | 
115 | " finds the github remote repository identifier
116 | " precedence: github > origin > other
117 | function! s:Remote()
118 |   if !exists('b:remote')
119 |     let remotes = split(s:CdExec(expand("%:p:h"),'git remote -v'),"\n")
120 |     let github_remotes = filter(remotes, 'v:val =~ "github\."')
121 |     if empty(github_remotes)
122 |       return
123 |     endif
124 |     let dict={}
125 |     for line in github_remotes
126 |       let [name,url]=remove(split(line),0,1)
127 |       let dict[name]=url
128 |     endfor
129 |     let fallback = split(github_remotes[0])[1]
130 |     if has_key(dict, 'github')
131 |       let b:remote = dict['github']
132 |     elseif has_key(dict,'origin')
133 |       let b:remote = dict['origin']
134 |     else
135 |       let b:remote = fallback
136 |     end
137 |   endif
138 |   return b:remote
139 | endfunction
140 | 
141 | " the github project url
142 | function! s:ProjectUrl()
143 |   if !exists('b:project_url')
144 |     let remote_url = s:Remote()
145 |     let basename = matchstr(remote_url, 'github.[^:/]\+')
146 |     let user = matchstr(remote_url, 'github.[^:/]\+[:\/]\zs[^/]*')
147 |     let project = matchstr(remote_url, 'github.[^:/]\+[:\/][^/]\+\/\zs[^.]\+\ze\(\.git\)\=')
148 |     let b:project_url = 'https://'.basename.'/'.user.'/'.project
149 |   endif
150 |   return b:project_url
151 | endfunction
152 | 
153 | " the github repository url
154 | function! s:ReposUrl()
155 |   if !exists('b:repos_url')
156 |     let b:repos_url = s:ProjectUrl().'/blob/'.s:CurrentBranch()
157 |   endif
158 |   return b:repos_url
159 | endfunction
160 | 
161 | " index of a filename in the diff output
162 | function! s:CommitIndex(commit)
163 |   if !exists('b:index')
164 |     let output = s:CdExec(s:RepositoryRoot(),'git diff --name-only '.a:commit.'^..'.a:commit)
165 |     let b:index = index(split(output,'\n'),s:RelPath())
166 |   endif
167 |   return b:index
168 | endfunction
169 | 
170 | " executes cmd in the given dir
171 | function! s:CdExec(dir,cmd)
172 |   let cur_dir=getcwd()
173 |   exe 'lcd '.a:dir
174 |   let output=system(a:cmd)
175 |   exe 'lcd '.cur_dir
176 |   return output
177 | endfunction
178 | 
179 | function! s:EscapeUrl(str)
180 |   return substitute(a:str,'\C[ !%#]','\\&','g')
181 | endfunction
182 | 
183 | " print and set error msg
184 | function! s:error(msg)
185 |   echohl ErrorMsg
186 |   echomsg a:msg
187 |   echohl None
188 |   let v:errmsg = a:msg
189 | endfunction
190 | 
191 | " OpenURL helper
192 | function! s:OpenUrl(url)
193 |   if !exists(":OpenURL")
194 |     let os = substitute(system('uname'), '\n', '', '')
195 |     if has("gui_mac") || os == 'Darwin'
196 |       command -bar -nargs=1 OpenURL :!open <args>
197 |     elseif has("gui_win32")
198 |       command -bar -nargs=1 OpenURL :!start cmd /cstart /b <args>
199 |     elseif executable("sensible-browser")
200 |       command -bar -nargs=1 OpenURL :!sensible-browser <args>
201 |     endif
202 |   endif
203 |   if exists(":OpenURL")
204 |     exe "OpenURL ".s:EscapeUrl(a:url)
205 |   else
206 |     call s:error('Please define the OpenURL cmd for your system (:help OpenURL)')
207 |   endif
208 | endfunction
209 | 
210 | " YankURL helper
211 | function! s:YankUrl(url)
212 |   let os = substitute(system('uname'), '\n', '', '')
213 |   if has("gui_mac") || os == 'Darwin'
214 |     silent call system('pbcopy', a:url)
215 |   elseif has("gui_win32")
216 |     silent call system('clip', a:url) 
217 |   else
218 |     silent call system('xsel --clipboard --input', a:url) 
219 |   endif
220 | endfunction
221 | 
222 | let loaded_github = 1
223 | 


--------------------------------------------------------------------------------