├── .github
└── workflows
│ └── lint-and-test-code.yml
├── .gitignore
├── CHANGELOG.md
├── LICENSE
├── README.md
├── build.edn
├── deps.edn
├── img
├── transductio-logo-1024.png
├── transductio-logo-150.png
├── transductio-logo-300.png
└── transductio-logo.svg
├── src
└── systems
│ └── thoughtfull
│ └── transductio.clj
└── test
└── systems
└── thoughtfull
└── transductio_test.clj
/.github/workflows/lint-and-test-code.yml:
--------------------------------------------------------------------------------
1 | name: Lint and test code
2 | on: [push]
3 | jobs:
4 | lint:
5 | name: Lint code
6 | runs-on: ubuntu-latest
7 | steps:
8 | - name: Checkout code
9 | uses: actions/checkout@v4
10 | - name: Setup Java
11 | uses: actions/setup-java@v4
12 | with:
13 | distribution: adopt
14 | java-version: 17
15 | - name: Setup Clojure
16 | uses: DeLaGuardo/setup-clojure@13.2
17 | with:
18 | cli: 1.12.0.1479
19 | clj-kondo: 2025.02.20
20 | - name: Cache Clojure dependencies
21 | uses: actions/cache@v3
22 | with:
23 | path: |
24 | ~/.m2/repository
25 | ~/.gitlibs
26 | ~/.deps.clj
27 | key: cljdeps-${{ hashFiles('deps.edn') }}
28 | restore-keys: cljdeps-
29 | - name: Lint code
30 | run: |
31 | (echo '```';
32 | clj-kondo --lint src --lint test;
33 | echo '```') >>$GITHUB_STEP_SUMMARY
34 | test:
35 | name: Test code
36 | runs-on: ubuntu-latest
37 | steps:
38 | - name: Checkout code
39 | uses: actions/checkout@v4
40 | - name: Setup Java
41 | uses: actions/setup-java@v4
42 | with:
43 | distribution: adopt
44 | java-version: 17
45 | - name: Setup Clojure
46 | uses: DeLaGuardo/setup-clojure@13.2
47 | with:
48 | cli: 1.12.0.1479
49 | clj-kondo: 2025.02.20
50 | - name: Cache Clojure dependencies
51 | uses: actions/cache@v3
52 | with:
53 | path: |
54 | ~/.m2/repository
55 | ~/.gitlibs
56 | ~/.deps.clj
57 | key: cljdeps-${{ hashFiles('deps.edn') }}
58 | restore-keys: cljdeps-
59 | - name: Test code
60 | run: |
61 | (echo '```';
62 | clojure -X:test;
63 | echo '```') >>$GITHUB_STEP_SUMMARY
64 |
--------------------------------------------------------------------------------
/.gitignore:
--------------------------------------------------------------------------------
1 | /.cpcache/
2 | /.nrepl-port
3 | /target/
4 |
--------------------------------------------------------------------------------
/CHANGELOG.md:
--------------------------------------------------------------------------------
1 | # Changelog
2 |
3 | All notable changes to this project will be documented in this file.
4 |
5 | The format is based on [Keep a Changelog 1.1.0](https://keepachangelog.com/en/1.1.0/), and this
6 | project adheres to [Semantic Versioning 2.0.0](https://semver.org/spec/v2.0.0.html).
7 |
8 | ## [Unreleased]
9 |
10 | ## [1.1.0] - 2025-03-16
11 |
12 | ### Added
13 |
14 | - clojure-decoder decodes Clojure data from a java.io.PushbackReader
15 | - clojure-encoder encodes Clojure data to a java.io.Writer
16 | - edn-decoder decodes EDN data from a java.io.PushbackReader
17 |
18 | ## [1.0.0] - 2025-03-15
19 |
20 | ### Added
21 |
22 | - Initial release with core functions (decoder, encoder) along with some convenience functions
23 |
24 | [unreleased]: https://github.com/thoughtfull-clojure/transductio/compare/v1.1.0...main
25 | [1.1.0]: https://github.com/thoughtfull-clojure/transductio/compare/v1.0.0...v1.1.0
26 | [1.0.0]: https://github.com/thoughtfull-clojure/transductio/releases/tag/v1.0.0
27 |
--------------------------------------------------------------------------------
/LICENSE:
--------------------------------------------------------------------------------
1 | Mozilla Public License Version 2.0
2 | ==================================
3 |
4 | 1. Definitions
5 | --------------
6 |
7 | 1.1. "Contributor"
8 | means each individual or legal entity that creates, contributes to
9 | the creation of, or owns Covered Software.
10 |
11 | 1.2. "Contributor Version"
12 | means the combination of the Contributions of others (if any) used
13 | by a Contributor and that particular Contributor's Contribution.
14 |
15 | 1.3. "Contribution"
16 | means Covered Software of a particular Contributor.
17 |
18 | 1.4. "Covered Software"
19 | means Source Code Form to which the initial Contributor has attached
20 | the notice in Exhibit A, the Executable Form of such Source Code
21 | Form, and Modifications of such Source Code Form, in each case
22 | including portions thereof.
23 |
24 | 1.5. "Incompatible With Secondary Licenses"
25 | means
26 |
27 | (a) that the initial Contributor has attached the notice described
28 | in Exhibit B to the Covered Software; or
29 |
30 | (b) that the Covered Software was made available under the terms of
31 | version 1.1 or earlier of the License, but not also under the
32 | terms of a Secondary License.
33 |
34 | 1.6. "Executable Form"
35 | means any form of the work other than Source Code Form.
36 |
37 | 1.7. "Larger Work"
38 | means a work that combines Covered Software with other material, in
39 | a separate file or files, that is not Covered Software.
40 |
41 | 1.8. "License"
42 | means this document.
43 |
44 | 1.9. "Licensable"
45 | means having the right to grant, to the maximum extent possible,
46 | whether at the time of the initial grant or subsequently, any and
47 | all of the rights conveyed by this License.
48 |
49 | 1.10. "Modifications"
50 | means any of the following:
51 |
52 | (a) any file in Source Code Form that results from an addition to,
53 | deletion from, or modification of the contents of Covered
54 | Software; or
55 |
56 | (b) any new file in Source Code Form that contains any Covered
57 | Software.
58 |
59 | 1.11. "Patent Claims" of a Contributor
60 | means any patent claim(s), including without limitation, method,
61 | process, and apparatus claims, in any patent Licensable by such
62 | Contributor that would be infringed, but for the grant of the
63 | License, by the making, using, selling, offering for sale, having
64 | made, import, or transfer of either its Contributions or its
65 | Contributor Version.
66 |
67 | 1.12. "Secondary License"
68 | means either the GNU General Public License, Version 2.0, the GNU
69 | Lesser General Public License, Version 2.1, the GNU Affero General
70 | Public License, Version 3.0, or any later versions of those
71 | licenses.
72 |
73 | 1.13. "Source Code Form"
74 | means the form of the work preferred for making modifications.
75 |
76 | 1.14. "You" (or "Your")
77 | means an individual or a legal entity exercising rights under this
78 | License. For legal entities, "You" includes any entity that
79 | controls, is controlled by, or is under common control with You. For
80 | purposes of this definition, "control" means (a) the power, direct
81 | or indirect, to cause the direction or management of such entity,
82 | whether by contract or otherwise, or (b) ownership of more than
83 | fifty percent (50%) of the outstanding shares or beneficial
84 | ownership of such entity.
85 |
86 | 2. License Grants and Conditions
87 | --------------------------------
88 |
89 | 2.1. Grants
90 |
91 | Each Contributor hereby grants You a world-wide, royalty-free,
92 | non-exclusive license:
93 |
94 | (a) under intellectual property rights (other than patent or trademark)
95 | Licensable by such Contributor to use, reproduce, make available,
96 | modify, display, perform, distribute, and otherwise exploit its
97 | Contributions, either on an unmodified basis, with Modifications, or
98 | as part of a Larger Work; and
99 |
100 | (b) under Patent Claims of such Contributor to make, use, sell, offer
101 | for sale, have made, import, and otherwise transfer either its
102 | Contributions or its Contributor Version.
103 |
104 | 2.2. Effective Date
105 |
106 | The licenses granted in Section 2.1 with respect to any Contribution
107 | become effective for each Contribution on the date the Contributor first
108 | distributes such Contribution.
109 |
110 | 2.3. Limitations on Grant Scope
111 |
112 | The licenses granted in this Section 2 are the only rights granted under
113 | this License. No additional rights or licenses will be implied from the
114 | distribution or licensing of Covered Software under this License.
115 | Notwithstanding Section 2.1(b) above, no patent license is granted by a
116 | Contributor:
117 |
118 | (a) for any code that a Contributor has removed from Covered Software;
119 | or
120 |
121 | (b) for infringements caused by: (i) Your and any other third party's
122 | modifications of Covered Software, or (ii) the combination of its
123 | Contributions with other software (except as part of its Contributor
124 | Version); or
125 |
126 | (c) under Patent Claims infringed by Covered Software in the absence of
127 | its Contributions.
128 |
129 | This License does not grant any rights in the trademarks, service marks,
130 | or logos of any Contributor (except as may be necessary to comply with
131 | the notice requirements in Section 3.4).
132 |
133 | 2.4. Subsequent Licenses
134 |
135 | No Contributor makes additional grants as a result of Your choice to
136 | distribute the Covered Software under a subsequent version of this
137 | License (see Section 10.2) or under the terms of a Secondary License (if
138 | permitted under the terms of Section 3.3).
139 |
140 | 2.5. Representation
141 |
142 | Each Contributor represents that the Contributor believes its
143 | Contributions are its original creation(s) or it has sufficient rights
144 | to grant the rights to its Contributions conveyed by this License.
145 |
146 | 2.6. Fair Use
147 |
148 | This License is not intended to limit any rights You have under
149 | applicable copyright doctrines of fair use, fair dealing, or other
150 | equivalents.
151 |
152 | 2.7. Conditions
153 |
154 | Sections 3.1, 3.2, 3.3, and 3.4 are conditions of the licenses granted
155 | in Section 2.1.
156 |
157 | 3. Responsibilities
158 | -------------------
159 |
160 | 3.1. Distribution of Source Form
161 |
162 | All distribution of Covered Software in Source Code Form, including any
163 | Modifications that You create or to which You contribute, must be under
164 | the terms of this License. You must inform recipients that the Source
165 | Code Form of the Covered Software is governed by the terms of this
166 | License, and how they can obtain a copy of this License. You may not
167 | attempt to alter or restrict the recipients' rights in the Source Code
168 | Form.
169 |
170 | 3.2. Distribution of Executable Form
171 |
172 | If You distribute Covered Software in Executable Form then:
173 |
174 | (a) such Covered Software must also be made available in Source Code
175 | Form, as described in Section 3.1, and You must inform recipients of
176 | the Executable Form how they can obtain a copy of such Source Code
177 | Form by reasonable means in a timely manner, at a charge no more
178 | than the cost of distribution to the recipient; and
179 |
180 | (b) You may distribute such Executable Form under the terms of this
181 | License, or sublicense it under different terms, provided that the
182 | license for the Executable Form does not attempt to limit or alter
183 | the recipients' rights in the Source Code Form under this License.
184 |
185 | 3.3. Distribution of a Larger Work
186 |
187 | You may create and distribute a Larger Work under terms of Your choice,
188 | provided that You also comply with the requirements of this License for
189 | the Covered Software. If the Larger Work is a combination of Covered
190 | Software with a work governed by one or more Secondary Licenses, and the
191 | Covered Software is not Incompatible With Secondary Licenses, this
192 | License permits You to additionally distribute such Covered Software
193 | under the terms of such Secondary License(s), so that the recipient of
194 | the Larger Work may, at their option, further distribute the Covered
195 | Software under the terms of either this License or such Secondary
196 | License(s).
197 |
198 | 3.4. Notices
199 |
200 | You may not remove or alter the substance of any license notices
201 | (including copyright notices, patent notices, disclaimers of warranty,
202 | or limitations of liability) contained within the Source Code Form of
203 | the Covered Software, except that You may alter any license notices to
204 | the extent required to remedy known factual inaccuracies.
205 |
206 | 3.5. Application of Additional Terms
207 |
208 | You may choose to offer, and to charge a fee for, warranty, support,
209 | indemnity or liability obligations to one or more recipients of Covered
210 | Software. However, You may do so only on Your own behalf, and not on
211 | behalf of any Contributor. You must make it absolutely clear that any
212 | such warranty, support, indemnity, or liability obligation is offered by
213 | You alone, and You hereby agree to indemnify every Contributor for any
214 | liability incurred by such Contributor as a result of warranty, support,
215 | indemnity or liability terms You offer. You may include additional
216 | disclaimers of warranty and limitations of liability specific to any
217 | jurisdiction.
218 |
219 | 4. Inability to Comply Due to Statute or Regulation
220 | ---------------------------------------------------
221 |
222 | If it is impossible for You to comply with any of the terms of this
223 | License with respect to some or all of the Covered Software due to
224 | statute, judicial order, or regulation then You must: (a) comply with
225 | the terms of this License to the maximum extent possible; and (b)
226 | describe the limitations and the code they affect. Such description must
227 | be placed in a text file included with all distributions of the Covered
228 | Software under this License. Except to the extent prohibited by statute
229 | or regulation, such description must be sufficiently detailed for a
230 | recipient of ordinary skill to be able to understand it.
231 |
232 | 5. Termination
233 | --------------
234 |
235 | 5.1. The rights granted under this License will terminate automatically
236 | if You fail to comply with any of its terms. However, if You become
237 | compliant, then the rights granted under this License from a particular
238 | Contributor are reinstated (a) provisionally, unless and until such
239 | Contributor explicitly and finally terminates Your grants, and (b) on an
240 | ongoing basis, if such Contributor fails to notify You of the
241 | non-compliance by some reasonable means prior to 60 days after You have
242 | come back into compliance. Moreover, Your grants from a particular
243 | Contributor are reinstated on an ongoing basis if such Contributor
244 | notifies You of the non-compliance by some reasonable means, this is the
245 | first time You have received notice of non-compliance with this License
246 | from such Contributor, and You become compliant prior to 30 days after
247 | Your receipt of the notice.
248 |
249 | 5.2. If You initiate litigation against any entity by asserting a patent
250 | infringement claim (excluding declaratory judgment actions,
251 | counter-claims, and cross-claims) alleging that a Contributor Version
252 | directly or indirectly infringes any patent, then the rights granted to
253 | You by any and all Contributors for the Covered Software under Section
254 | 2.1 of this License shall terminate.
255 |
256 | 5.3. In the event of termination under Sections 5.1 or 5.2 above, all
257 | end user license agreements (excluding distributors and resellers) which
258 | have been validly granted by You or Your distributors under this License
259 | prior to termination shall survive termination.
260 |
261 | ************************************************************************
262 | * *
263 | * 6. Disclaimer of Warranty *
264 | * ------------------------- *
265 | * *
266 | * Covered Software is provided under this License on an "as is" *
267 | * basis, without warranty of any kind, either expressed, implied, or *
268 | * statutory, including, without limitation, warranties that the *
269 | * Covered Software is free of defects, merchantable, fit for a *
270 | * particular purpose or non-infringing. The entire risk as to the *
271 | * quality and performance of the Covered Software is with You. *
272 | * Should any Covered Software prove defective in any respect, You *
273 | * (not any Contributor) assume the cost of any necessary servicing, *
274 | * repair, or correction. This disclaimer of warranty constitutes an *
275 | * essential part of this License. No use of any Covered Software is *
276 | * authorized under this License except under this disclaimer. *
277 | * *
278 | ************************************************************************
279 |
280 | ************************************************************************
281 | * *
282 | * 7. Limitation of Liability *
283 | * -------------------------- *
284 | * *
285 | * Under no circumstances and under no legal theory, whether tort *
286 | * (including negligence), contract, or otherwise, shall any *
287 | * Contributor, or anyone who distributes Covered Software as *
288 | * permitted above, be liable to You for any direct, indirect, *
289 | * special, incidental, or consequential damages of any character *
290 | * including, without limitation, damages for lost profits, loss of *
291 | * goodwill, work stoppage, computer failure or malfunction, or any *
292 | * and all other commercial damages or losses, even if such party *
293 | * shall have been informed of the possibility of such damages. This *
294 | * limitation of liability shall not apply to liability for death or *
295 | * personal injury resulting from such party's negligence to the *
296 | * extent applicable law prohibits such limitation. Some *
297 | * jurisdictions do not allow the exclusion or limitation of *
298 | * incidental or consequential damages, so this exclusion and *
299 | * limitation may not apply to You. *
300 | * *
301 | ************************************************************************
302 |
303 | 8. Litigation
304 | -------------
305 |
306 | Any litigation relating to this License may be brought only in the
307 | courts of a jurisdiction where the defendant maintains its principal
308 | place of business and such litigation shall be governed by laws of that
309 | jurisdiction, without reference to its conflict-of-law provisions.
310 | Nothing in this Section shall prevent a party's ability to bring
311 | cross-claims or counter-claims.
312 |
313 | 9. Miscellaneous
314 | ----------------
315 |
316 | This License represents the complete agreement concerning the subject
317 | matter hereof. If any provision of this License is held to be
318 | unenforceable, such provision shall be reformed only to the extent
319 | necessary to make it enforceable. Any law or regulation which provides
320 | that the language of a contract shall be construed against the drafter
321 | shall not be used to construe this License against a Contributor.
322 |
323 | 10. Versions of the License
324 | ---------------------------
325 |
326 | 10.1. New Versions
327 |
328 | Mozilla Foundation is the license steward. Except as provided in Section
329 | 10.3, no one other than the license steward has the right to modify or
330 | publish new versions of this License. Each version will be given a
331 | distinguishing version number.
332 |
333 | 10.2. Effect of New Versions
334 |
335 | You may distribute the Covered Software under the terms of the version
336 | of the License under which You originally received the Covered Software,
337 | or under the terms of any subsequent version published by the license
338 | steward.
339 |
340 | 10.3. Modified Versions
341 |
342 | If you create software not governed by this License, and you want to
343 | create a new license for such software, you may create and use a
344 | modified version of this License if you rename the license and remove
345 | any references to the name of the license steward (except to note that
346 | such modified license differs from this License).
347 |
348 | 10.4. Distributing Source Code Form that is Incompatible With Secondary
349 | Licenses
350 |
351 | If You choose to distribute Source Code Form that is Incompatible With
352 | Secondary Licenses under the terms of this version of the License, the
353 | notice described in Exhibit B of this License must be attached.
354 |
355 | Exhibit A - Source Code Form License Notice
356 | -------------------------------------------
357 |
358 | This Source Code Form is subject to the terms of the Mozilla Public
359 | License, v. 2.0. If a copy of the MPL was not distributed with this
360 | file, You can obtain one at http://mozilla.org/MPL/2.0/.
361 |
362 | If it is not possible or desirable to put the notice in a particular
363 | file, then You may include the notice in a location (such as a LICENSE
364 | file in a relevant directory) where a recipient would be likely to look
365 | for such a notice.
366 |
367 | You may add additional accurate notices of copyright ownership.
368 |
369 | Exhibit B - "Incompatible With Secondary Licenses" Notice
370 | ---------------------------------------------------------
371 |
372 | This Source Code Form is "Incompatible With Secondary Licenses", as
373 | defined by the Mozilla Public License, v. 2.0.
374 |
--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
1 | # transductio
2 |
3 |
4 |
5 | [](https://clojars.org/systems.thoughtfull/transductio/versions/1.1.0) [](https://cljdoc.org/d/systems.thoughtfull/transductio/1.1.0/doc/readme)
6 |
7 | A bridge from I/O to transducers, and back!
8 |
9 | This library provides two core functions to bridge I/O with transducers, and convenience functions
10 | building on them. `decoder` creates a function that can produce data from input for use with
11 | transducers and `encoder` makes a function that takes data, possibly through a transducer, and
12 | writes it to output.
13 |
14 | `decoder` is analogous to a source collection in a transduction pipeline. `encoder` is analogous to
15 | `into`, it is a transduction context that takes a transducer and an input collection, but writes to
16 | output instead of building a collection.
17 |
18 | `decoder` takes four arguments: open, decode, done?, close. It returns a function that takes a
19 | source and returns a reducible. This reducible calls open with the source, then decode with that
20 | result, and eventually, when done? returns true, the reduction completes and it calls close.
21 |
22 | For example, if you want to decode Clojure data:
23 |
24 | ```clojure
25 | (def clojure-decoder
26 | (decoder (comp PushbackReader/new io/reader)
27 | #(read % false ::eof)
28 | #{::eof}
29 | AutoCloseable/.close))
30 |
31 | (into [] (clojure-decoder (StringReader. "1 2 3")))
32 | ;;=> [1 2 3]
33 | ```
34 |
35 | `encoder` takes three arguments: open, encode!, close. It returns a function that acts like `into`.
36 | Like `into` it has two arities. The first takes a sink and a source and reduces the source into the
37 | sink. It calls open with the sink, then encode! with that result and each value from the source,
38 | and eventually, when it exhausts the source, the reduction completes and it calls close.
39 |
40 | The second arity takes a sink, a transduction, and a source. The process is the same as above, but
41 | the data flows from the source, through the transduction, then into the sink.
42 |
43 | For example, if you want to encode Clojure data:
44 |
45 | ```clojure
46 | (def clojure-encoder
47 | (encoder io/writer
48 | (fn [^Writer out value] (.write out (prn-str value)))
49 | AutoCloseable/.close))
50 |
51 | (clojure-encoder "/tmp/foo.clj" (map inc) [1 2 3])
52 |
53 | (slurp "/tmp/foo.clj")
54 | ;;=> "2\n3\n4\n"
55 | ```
56 |
57 | ## Comparison to `clojure.core/iteration`
58 |
59 | Unlike `clojure.core/iteration`, a decoder repeatedly calls `decode` with the return value from
60 | `open`. `open` should return a stateful, mutable object that produces a new value every time it is
61 | given to `decode`, there is no succession of continuation tokens. This is simpler to think about
62 | and use in common situations like `java.io` streams and readers.
63 |
64 | A decoder also cleans up resources when its reduction completes (early or otherwise). This makes it
65 | suitable for working with things like database connection, file descriptors, etc. If an error
66 | occurs during the reduction, or if the reduction returns early (i.e. someone returns a `reduced`),
67 | there is still an opportunity to release resources when the decoder calls `close`.
68 |
69 | ## Clojure and EDN data
70 |
71 | There are three functions for decoding/encoding Clojure and EDN data.
72 |
73 | `clojure-decoder` decodes Clojure data. It takes `:encoding` which it sends to
74 | `clojure.java.io/reader`, `:features` and `:read-cond` as options which it passes along to
75 | `clojure.core/read`, and `:data-readers`, `:default-data-reader-fn`, and `:read-eval` which it binds
76 | to the appropriate dynamic variables for the duration of the reduction/transduction.
77 |
78 | `clojure-encoder` encodes Clojure data. It takes `:encoding` and `:append` as options which it
79 | passes along to `clojure.java.io/writer`. It encodes Clojure data using `prn-str`.
80 |
81 | `edn-decoder` decodes EDN data. It takes `:encoding` which it sends to `clojure.java.io./reader`
82 | and `:features` and `:read-cond` as options which it passes along to `clojure.edn/read`.
83 |
84 | There is no EDN encoder, because there isn't really such a thing in Clojure. `clojure-encoder` can
85 | substitute, but EDN is probably best hand written because `prn-str` isn't necessarily guaranteed to
86 | produce valid EDN data.[^1]
87 |
88 | [^1]: See https://nitor.com/en/articles/pitfalls-and-bumps-clojures-extensible-data-notation-edn
89 |
90 | ## License
91 |
92 | > Copyright © technosophist
93 | >
94 | > This Source Code Form is subject to the terms of the Mozilla Public License, v. 2.0. If a copy of
95 | > the MPL was not distributed with this file, You can obtain one at http://mozilla.org/MPL/2.0/.
96 | >
97 | > This Source Code Form is "Incompatible With Secondary Licenses", as defined by the Mozilla Public
98 | > License, v. 2.0.
99 |
--------------------------------------------------------------------------------
/build.edn:
--------------------------------------------------------------------------------
1 | {:description "A bridge from I/O to transducers and back"
2 | :lib systems.thoughtfull/transductio
3 | :version "1.1.0"}
4 |
--------------------------------------------------------------------------------
/deps.edn:
--------------------------------------------------------------------------------
1 | {:aliases {:build {:deps {systems.thoughtfull/build {:mvn/version "0.5.0"}}
2 | :ns-default systems.thoughtfull.build}
3 | :test {:exec-fn cognitect.test-runner.api/test
4 | :extra-deps {io.github.cognitect-labs/test-runner
5 | {:git/tag "v0.5.1" :git/sha "dfb30dd"}}
6 | :extra-paths ["test"]}}
7 | :deps {org.clojure/clojure {:mvn/version "1.12.0"}}
8 | :paths ["src"]}
9 |
--------------------------------------------------------------------------------
/img/transductio-logo-1024.png:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/thoughtfull-clojure/transductio/20f692638b890732fe5d263b74ad62a86ffa0a81/img/transductio-logo-1024.png
--------------------------------------------------------------------------------
/img/transductio-logo-150.png:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/thoughtfull-clojure/transductio/20f692638b890732fe5d263b74ad62a86ffa0a81/img/transductio-logo-150.png
--------------------------------------------------------------------------------
/img/transductio-logo-300.png:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/thoughtfull-clojure/transductio/20f692638b890732fe5d263b74ad62a86ffa0a81/img/transductio-logo-300.png
--------------------------------------------------------------------------------
/img/transductio-logo.svg:
--------------------------------------------------------------------------------
1 |
2 |
3 |
4 |
91 |
--------------------------------------------------------------------------------
/src/systems/thoughtfull/transductio.clj:
--------------------------------------------------------------------------------
1 | ;; Copyright © technosophist
2 | ;;
3 | ;; This Source Code Form is subject to the terms of the Mozilla Public License, v. 2.0. If a copy of
4 | ;; the MPL was not distributed with this file, You can obtain one at http://mozilla.org/MPL/2.0/.
5 | ;;
6 | ;; This Source Code Form is "Incompatible With Secondary Licenses", as defined by the Mozilla Public
7 | ;; License, v. 2.0.
8 | (ns systems.thoughtfull.transductio
9 | (:require
10 | [clojure.edn :as edn]
11 | [clojure.java.io :as io])
12 | (:import
13 | (clojure.lang IReduceInit)
14 | (java.io OutputStream PushbackReader Writer)
15 | (java.lang AutoCloseable)))
16 |
17 | (set! *warn-on-reflection* true)
18 | (set! *unchecked-math* :warn-on-boxed)
19 |
20 | (defn decoder
21 | "Returns a function that takes a source and returns a reducible that, opens the source, repeatedly
22 | decodes data from it, and closes it when it is done.
23 |
24 | open takes the source and returns a stateful, mutable object that will be given to decode and
25 | eventually to close.
26 |
27 | decode is given the opened source and must return either a decoded value or a sentinel
28 | indicating there is no more data.
29 |
30 | done? is given each decoded value and if it returns truthy, then the decoding ends.
31 |
32 | When the reduction completes whether normally, early (someone returns a reduced), or because of
33 | an exception, then close is called.
34 |
35 | If close is not given, then it defaults to java.lang.AutoCloseable/.close.
36 |
37 | See stream-decoder and reader-decoder."
38 | ([open decode done?]
39 | (decoder open decode done? nil))
40 | ([open decode done? close]
41 | (fn [source]
42 | (let [close (or close AutoCloseable/.close)]
43 | (reify
44 | IReduceInit
45 | (reduce
46 | [_ rf init]
47 | (let [in (open source)]
48 | (try
49 | (loop [acc init
50 | v (decode in)]
51 | (if (done? v)
52 | acc
53 | (let [acc (rf acc v)]
54 | (if (reduced? acc)
55 | @acc
56 | (recur acc (decode in))))))
57 | (finally
58 | (close in))))))))))
59 |
60 | (defn stream-decoder
61 | "Returns a function that takes a source and returns a reducible that, opens the source as a
62 | java.io.InputStream, repeatedly decodes data from it, and closes it when it is done.
63 |
64 | The decoder opens the source with clojure.java.io/input-stream.
65 |
66 | decode is given the opened source and must return either a decoded value or a sentinel
67 | indicating there is no more data.
68 |
69 | done? is given each decoded value and if it returns truthy, then the decoding ends.
70 |
71 | The decoder closes the source with java.lang.AutoCloseable/.close.
72 |
73 | See decoder, clojure-decoder, edn-decoder, and reader-decoder."
74 | [decode done?]
75 | (decoder io/input-stream decode done?))
76 |
77 | (defn reader-decoder
78 | "Returns a function that takes a source and returns a reducible that, opens the source as a
79 | java.io.Reader, repeatedly decodes data from it, and closes it when it is done.
80 |
81 | The decoder opens the source with clojure.java.io/reader. If encoding is given, then it is
82 | passed along to clojure.java.io/reader.
83 |
84 | decode is given the opened source and must return either a decoded value or a sentinel
85 | indicating there is no more data.
86 |
87 | done? is given each decoded value and if it returns truthy, then the decoding ends.
88 |
89 | The decoder closes the source with java.lang.AutoCloseable/.close.
90 |
91 | See decoder, clojure-decoder, edn-decoder, and stream-decoder."
92 | ([decode done?]
93 | (decoder io/reader decode done?))
94 | ([decode done? encoding]
95 | (decoder #(io/reader % :encoding encoding) decode done?)))
96 |
97 | (defn- pushback-reader
98 | [encoding]
99 | (fn [source]
100 | (if (instance? PushbackReader source)
101 | source
102 | (PushbackReader. (io/reader source :encoding encoding)))))
103 |
104 | (defn clojure-decoder
105 | "Returns a function that takes a source and returns a reducible that, opens the source as a
106 | java.io.PushbackReader, repeatedly decodes Clojure data from it, and closes it when it is done.
107 |
108 | The decoder opens the source as a java.io.PushbackReader. If the source is already a
109 | PushbackReader, then it is used without modification. If it is not a PushbackReader, then it is
110 | given to clojure.java.io/reader with the encoding (if specified) and then wrapped in a
111 | PushbackReader.
112 |
113 | If features or read-cond are specified, they are given as options to clojure.core/read.
114 |
115 | If data-readers, default-data-readers-fn, or read-eval are given they are bound to
116 | *data-readers*, *default-data-reader-fn*, and *read-eval* (respectively) for the duration of the
117 | reduction/transduction.
118 |
119 | See decoder, edn-decoder, reader-decoder, and stream-decoder."
120 | [& {:keys [data-readers default-data-reader-fn encoding features read-cond read-eval]}]
121 | (let [eof (Object.)
122 | opts (merge {:eof eof}
123 | (when (some? features)
124 | {:features features})
125 | (when (some? read-cond)
126 | {:read-cond read-cond}))
127 | bindings (merge {}
128 | (when (some? data-readers)
129 | {#'*data-readers* data-readers})
130 | (when (some? default-data-reader-fn)
131 | {#'*default-data-reader-fn* default-data-reader-fn})
132 | (when (some? read-eval)
133 | {#'*read-eval* read-eval}))
134 | decoder* (decoder (pushback-reader encoding) #(read opts %) #{eof})]
135 | (fn [source]
136 | (reify IReduceInit
137 | (reduce [_ rf init]
138 | (with-bindings bindings
139 | (.reduce ^IReduceInit (decoder* source) rf init)))))))
140 |
141 | (defn edn-decoder
142 | "Returns a function that takes a source and returns a reducible that, opens the source as a
143 | java.io.PushbackReader, repeatedly decodes EDN data from it, and closes it when it is done.
144 |
145 | The decoder opens the source as a java.io.PushbackReader. If the source is already a
146 | PushbackReader, then it is used without modification. If it is not a PushbackReader, then it is
147 | given to clojure.java.io/reader with the encoding (if specified) and then wrapped in a
148 | PushbackReader.
149 |
150 | If default or readers are specified, they are given as options to clojure.edn/read.
151 |
152 | See decoder, clojure-decoder, reader-decoder, and stream-decoder."
153 | [& {:keys [default encoding readers]}]
154 | (let [eof (Object.)
155 | opts (merge {:eof eof}
156 | (when (some? default)
157 | {:default default})
158 | (when (some? readers)
159 | {:readers readers}))]
160 | (decoder (pushback-reader encoding)
161 | #(edn/read opts %)
162 | #{eof})))
163 |
164 | (defn encoder
165 | "Returns a function that takes either a sink and a source, reducing the source into the sink, or a
166 | sink, a transducer, and a source, transducing the source into the sink through the transducer.
167 | This is an analog of into but for a mutable sink.
168 |
169 | open takes the sink and returns a stateful, mutable object that will be given to encode! and
170 | eventually to close.
171 |
172 | encode! is given the opened sink and a value and must mutate the sink with the value. The
173 | return value from encode! is ignored.
174 |
175 | When the reduction/transduction completes whether normally, early (someone returns a reduced),
176 | or because of an exception, then close is called.
177 |
178 | If close is not given, then it defaults to java.lang.AutoCloseable/.close.
179 |
180 | See clojure-encoder, stream-encoder, and writer-encoder"
181 | ([open encode!]
182 | (encoder open encode! nil))
183 | ([open encode! close]
184 | (fn
185 | ([sink source]
186 | (let [out (open sink)
187 | close (or close AutoCloseable/.close)]
188 | (try
189 | (reduce (fn [out value] (encode! out value) out) out source)
190 | nil
191 | (finally
192 | (close out)))))
193 | ([sink xf source]
194 | (let [out (open sink)
195 | close (or close AutoCloseable/.close)]
196 | (try
197 | (transduce xf (fn ([out] out) ([out value] (encode! out value) out)) out source)
198 | nil
199 | (finally
200 | (close out))))))))
201 |
202 | (defn stream-encoder
203 | "Returns a function that takes either a sink and a source, reducing the source into the sink, or a
204 | sink, a transducer, and a source, transducing the source into the sink through the transducer.
205 | This is an analog of into but for a java.io.OutputStream.
206 |
207 | The encoder opens the sink with clojure.java.io/output-stream. If append is given, then it is
208 | passed along to clojure.java.io/output-stream.
209 |
210 | The source (or the transducer applied to the source) must return byte arrays which are written
211 | to the output stream.
212 |
213 | When the reduction/transduction completes whether normally, early (someone returns a reduced),
214 | or because of an exception, then the stream is closed.
215 |
216 | See encoder, clojure-encoder, and writer-encoder"
217 | ([]
218 | (encoder io/output-stream ^[bytes] OutputStream/.write))
219 | ([append]
220 | (encoder #(io/output-stream % :append append) ^[bytes] OutputStream/.write)))
221 |
222 | (defn writer-encoder
223 | "Returns a function that takes either a sink and a source, reducing the source into the sink, or a
224 | sink, a transducer, and a source, transducing the source into the sink through the transducer.
225 | This is an analog of into but for a java.io.Writer.
226 |
227 | The encoder opens the sink with clojure.java.io/writer. If append is given, then it is passed
228 | along to clojure.java.io/writer.
229 |
230 | The source (or the transducer applied to the source) must return Strings which are written to
231 | the output stream.
232 |
233 | When the reduction/transduction completes whether normally, early (someone returns a reduced),
234 | or because of an exception, then the stream is closed.
235 |
236 | See encoder, clojure-encoder, and stream-encoder"
237 | ([]
238 | (encoder io/writer ^[String] Writer/.write))
239 | ([append]
240 | (encoder #(io/writer % :append append) ^[String] Writer/.write)))
241 |
242 | (defn clojure-encoder
243 | "Returns a function that takes either a sink and a source, reducing the source as Clojure data
244 | into the sink, or a sink, a transducer, and a source, transducing the source as Clojure data
245 | into the sink through the transducer. This is an analog of into but for Clojure data into a
246 | java.io.Writer.
247 |
248 | The encoder opens the sink with clojure.java.io/writer. If encoding or append are given, then
249 | they are passed along to clojure.java.io/writer.
250 |
251 | The data from the source (or the transducer applied to the source) is written to the sink using
252 | prn-str.
253 |
254 | When the reduction/transduction completes whether normally, early (someone returns a reduced),
255 | or because of an exception, then the stream is closed.
256 |
257 | See encoder, stream-encoder, and writer-encoder"
258 | [& {:keys [encoding append]}]
259 | (encoder #(io/writer % :encoding encoding :append append)
260 | (fn [^Writer sink value]
261 | (.write sink (prn-str value)))))
262 |
--------------------------------------------------------------------------------
/test/systems/thoughtfull/transductio_test.clj:
--------------------------------------------------------------------------------
1 | ;; Copyright © technosophist
2 | ;;
3 | ;; This Source Code Form is subject to the terms of the Mozilla Public License, v. 2.0. If a copy of
4 | ;; the MPL was not distributed with this file, You can obtain one at http://mozilla.org/MPL/2.0/.
5 | ;;
6 | ;; This Source Code Form is "Incompatible With Secondary Licenses", as defined by the Mozilla Public
7 | ;; License, v. 2.0.
8 | (ns systems.thoughtfull.transductio-test
9 | (:require
10 | [clojure.test :refer [deftest is]]
11 | [systems.thoughtfull.transductio :refer [clojure-decoder clojure-encoder decoder edn-decoder
12 | reader-decoder stream-decoder stream-encoder encoder
13 | writer-encoder]])
14 | (:import
15 | (java.io ByteArrayInputStream ByteArrayOutputStream File InputStream PushbackReader Reader
16 | StringReader StringWriter)))
17 |
18 | (defn close-fn
19 | [closed?]
20 | (fn [_] (deliver closed? true)))
21 |
22 | (defn test-decoder
23 | ([]
24 | (test-decoder #(read % false ::eof)))
25 | ([decode]
26 | (let [closed? (promise)]
27 | [closed? (decoder (comp PushbackReader/new StringReader/new) decode #{::eof}
28 | (close-fn closed?))])))
29 |
30 | (deftest t-decoder-closes
31 | (let [[closed? decoder] (test-decoder)]
32 | (is (= [1 2 3] (into [] (decoder "1 2 3"))))
33 | (is (deref closed? 1000 false))))
34 |
35 | (deftest t-decoder-closes-with-reduced
36 | (let [[closed? decoder] (test-decoder)]
37 | (is (= [1] (into [] (take 1) (decoder "1 2 3"))))
38 | (is (deref closed? 1000 false))))
39 |
40 | (deftest t-decoder-closes-with-exception
41 | (let [[closed? decoder] (test-decoder (fn [_] (throw (Exception.))))]
42 | (try
43 | (into [] (take 1) (decoder "1 2 3"))
44 | (catch Exception _))
45 | (is (deref closed? 1000 false))))
46 |
47 | (deftest t-stream-decoder
48 | (is (= [102 111 111]
49 | (into [] ((stream-decoder InputStream/.read #{-1})
50 | (ByteArrayInputStream. (.getBytes "foo")))))))
51 |
52 | (deftest t-reader-decoder
53 | (is (= [102 111 111]
54 | (into [] ((reader-decoder Reader/.read #{-1})
55 | (ByteArrayInputStream. (.getBytes "foo")))))))
56 |
57 | (deftest t-reader-decoder-uses-encoding
58 | (is (= [8220]
59 | (into [] ((reader-decoder Reader/.read #{-1} "windows-1252")
60 | (ByteArrayInputStream. (byte-array [147])))))))
61 |
62 | (deftest t-clojure-decoder
63 | (is (= [1 2 3] (into [] ((clojure-decoder) (StringReader. "1\n2\n3\n"))))))
64 |
65 | (deftest t-clojure-decoder-uses-features
66 | (is (= [] (into [] ((clojure-decoder :read-cond :allow) (StringReader. "#?(:blah \"blah\")")))))
67 | (is (= ["blah"]
68 | (into [] ((clojure-decoder :read-cond :allow :features #{:blah})
69 | (StringReader. "#?(:blah \"blah\")"))))))
70 |
71 | (deftest t-clojure-decoder-uses-read-cond
72 | (is (= [(reader-conditional '(:clj "clj" :cljs "cljs") false)]
73 | (into [] ((clojure-decoder :read-cond :preserve)
74 | (StringReader. "#?(:clj \"clj\" :cljs \"cljs\")")))))
75 | (is (thrown-with-msg? RuntimeException
76 | #"^Conditional read not allowed$"
77 | (into [] ((clojure-decoder :read-cond false)
78 | (StringReader. "#?(:clj \"clj\" :cljs \"cljs\")"))))))
79 |
80 | (deftest t-clojure-decoder-uses-encoding
81 | (is (= ["“"]
82 | (into [] ((clojure-decoder :encoding "windows-1252")
83 | (ByteArrayInputStream. (byte-array [34 147 34])))))))
84 |
85 | (defn foo [val] val)
86 |
87 | (deftest t-clojure-decoder-binds-data-readers
88 | (is (= [[1 2 3]]
89 | (into [] ((clojure-decoder :data-readers {'foo #'systems.thoughtfull.transductio-test/foo})
90 | (StringReader. "#foo [1 2 3]"))))))
91 |
92 | (deftest t-clojure-decoder-binds-default-data-reader-fn
93 | (is (= [:blah]
94 | (into [] ((clojure-decoder :default-data-reader-fn (fn [_ _] :blah))
95 | (StringReader. "#foo [1 2 3]"))))))
96 |
97 | (deftest t-clojure-decoder-binds-read-eval
98 | (is (= [42] (into [] ((clojure-decoder :read-eval true) (StringReader. "#=(* 21 2)")))))
99 | (is (thrown-with-msg? RuntimeException
100 | #"^EvalReader not allowed when \*read-eval\* is false.$"
101 | (into [] ((clojure-decoder :read-eval false)
102 | (StringReader. "#=(* 21 2)"))))))
103 |
104 | (deftest t-edn-decoder
105 | (is (= [1 2 3] (into [] ((edn-decoder) (StringReader. "1\n2\n3\n"))))))
106 |
107 | (deftest t-edn-decoder-uses-default
108 | (is (= [:blah]
109 | (into [] ((edn-decoder :default (fn [_ _] :blah)) (StringReader. "#foo [1 2 3]"))))))
110 |
111 | (deftest t-edn-decoder-uses-readers
112 | (is (= [[1 2 3]]
113 | (into [] ((edn-decoder :readers {'foo #'systems.thoughtfull.transductio-test/foo})
114 | (StringReader. "#foo [1 2 3]"))))))
115 |
116 | (deftest t-edn-decoder-uses-encoding
117 | (is (= ["“"]
118 | (into [] ((edn-decoder :encoding "windows-1252")
119 | (ByteArrayInputStream. (byte-array [34 147 34])))))))
120 |
121 | (defn test-encoder
122 | ([]
123 | (test-encoder #(.write %1 (prn-str %2))))
124 | ([encode!]
125 | (let [closed? (promise)]
126 | [closed? (encoder identity encode! (close-fn closed?))])))
127 |
128 | (deftest t-encoder-closes
129 | (let [out (StringWriter.)
130 | [closed? encoder] (test-encoder)]
131 | (encoder out [1 2 3])
132 | (is (= "1\n2\n3\n" (.toString out)))
133 | (is (deref closed? 1000 false))))
134 |
135 | (deftest t-encoder-closes-with-reduced
136 | (let [out (StringWriter.)
137 | [closed? encoder] (test-encoder)]
138 | (encoder out (take 1) [1 2 3])
139 | (is (= "1\n" (.toString out)))
140 | (is (deref closed? 1000 false))))
141 |
142 | (deftest t-encoder-closes-with-exception
143 | (let [out (StringWriter.)
144 | [closed? encoder] (test-encoder (fn [_ _] (throw (Exception.))))]
145 | (try
146 | (encoder out [1 2 3])
147 | (catch Exception _))
148 | (is (= "" (.toString out)))
149 | (is (deref closed? 1000 false))))
150 |
151 | (deftest t-stream-encoder
152 | (let [out (ByteArrayOutputStream.)]
153 | ((stream-encoder) out [(.getBytes "foo")])
154 | (is (= [102 111 111] (seq (.toByteArray out))))))
155 |
156 | (deftest t-stream-encoder-uses-append
157 | (let [out (File/createTempFile "transductio-" nil)]
158 | ((stream-encoder true) out [(.getBytes "foo")])
159 | ((stream-encoder true) out [(.getBytes "foo")])
160 | (is (= "foofoo" (slurp out)))))
161 |
162 | (deftest t-writer-encoder
163 | (let [out (StringWriter.)]
164 | ((writer-encoder) out ["foo"])
165 | (is (= "foo" (.toString out)))))
166 |
167 | (deftest t-writer-encoder-uses-append
168 | (let [out (File/createTempFile "transductio-" nil)]
169 | ((writer-encoder true) out ["foo"])
170 | ((writer-encoder true) out ["foo"])
171 | (is (= "foofoo" (slurp out)))))
172 |
173 | (deftest t-clojure-encoder
174 | (let [out (StringWriter.)]
175 | (is (empty? (into [] ((clojure-encoder) out [1 2 3]))))
176 | (is (= "1\n2\n3\n" (.toString out)))))
177 |
178 | (deftest t-clojure-encoder-uses-encoding
179 | (let [out (ByteArrayOutputStream.)]
180 | ((clojure-encoder :encoding "windows-1252") out ["“"])
181 | (is (= "\"“\"\n" (String. (.toByteArray out) "windows-1252")))))
182 |
183 | (deftest t-clojure-encoder-uses-append
184 | (let [out (File/createTempFile "transductio-" nil)]
185 | ((clojure-encoder :append true) out ["a"])
186 | ((clojure-encoder :append true) out ["b"])
187 | (is (= "\"a\"\n\"b\"\n" (slurp out)))))
188 |
--------------------------------------------------------------------------------