├── .gitignore
├── CONTRIBUTING.markdown
├── README.markdown
├── autoload
    ├── fireplace.vim
    └── fireplace
    │   ├── session.vim
    │   └── transport.vim
├── doc
    └── fireplace.txt
├── plugin
    └── fireplace.vim
└── pythonx
    └── fireplace.py


/.gitignore:
--------------------------------------------------------------------------------
1 | /doc/tags
2 | *.pyc
3 | 


--------------------------------------------------------------------------------
/CONTRIBUTING.markdown:
--------------------------------------------------------------------------------
 1 | ## Contributing
 2 | 
 3 | Open [GitHub issues][] for bug reports and feature requests.
 4 | 
 5 | I'm a stickler for [commit messages][], so if you send me a pull
 6 | request with so much as superfluous period in the subject line, I will
 7 | reject it, then TP your house.
 8 | 
 9 | [GitHub issues]: http://github.com/tpope/vim-fireplace/issues
10 | [commit messages]: http://tbaggery.com/2008/04/19/a-note-about-git-commit-messages.html
11 | 


--------------------------------------------------------------------------------
/README.markdown:
--------------------------------------------------------------------------------
  1 | # fireplace.vim
  2 | 
  3 | There's a REPL in Fireplace, but you probably wouldn't have noticed if I hadn't
  4 | told you.  Such is the way with fireplace.vim.  By the way, this plugin is for
  5 | Clojure.
  6 | 
  7 | ## Installation
  8 | 
  9 | First, set up [cider-nrepl][].  (If you skip this step, only a subset of
 10 | functionality will be available.)
 11 | 
 12 | Install Fireplace using your favorite package manager, or use Vim's built-in
 13 | package support:
 14 | 
 15 |     mkdir -p ~/.vim/pack/tpope/start
 16 |     cd ~/.vim/pack/tpope/start
 17 |     git clone https://tpope.io/vim/fireplace.git
 18 |     vim -u NONE -c "helptags fireplace/doc" -c q
 19 | 
 20 | You might also want [salve.vim][] for assorted static project support.
 21 | 
 22 | ## Features
 23 | 
 24 | This list isn't exhaustive; see the `:help` for details.
 25 | 
 26 | ### Transparent setup
 27 | 
 28 | Fireplace talks to nREPL.  With Leiningen and Boot, it connects automatically
 29 | using the `.nrepl-port` file created when you run `lein repl` or `boot repl`.
 30 | If you are starting nREPL some other way, run `:FireplaceConnect host:port`.
 31 | You can connect to multiple instances of nREPL for different projects, and it
 32 | will use the right one automatically.  ClojureScript support is just as
 33 | seamless with [Piggieback][].
 34 | 
 35 | If you're using the new [Clojure CLI][], you can follow the instructions for
 36 | [running cider-nrepl with `clj`][cider-nrepl-via-clj].
 37 | Briefly, `clj -Sdeps '{:deps {cider/cider-nrepl {:mvn/version "0.21.1"} }}'
 38 | -m nrepl.cmdline --middleware "[cider.nrepl/cider-middleware]"` should do the trick.
 39 | The [cider-nrepl][cider-nrepl-via-clj] docs also show you how you can add an alias to
 40 | your user's `~/.clojure/deps.edn` file, letting you more simply run `clj -A:cider-clj`.
 41 | 
 42 | Oh, and if you don't have an nREPL connection, installing [salve.vim][]
 43 | lets it fall back to using `java clojure.main` for some of the basics, using a
 44 | class path based on your Leiningen or Boot config.  It's a bit slow, but a
 45 | two-second delay is vastly preferable to being forced out of my flow for a
 46 | single command, in my book.
 47 | 
 48 | [cider-nrepl]: https://docs.cider.mx/cider-nrepl/usage.html
 49 | [cider-nrepl-via-clj]: https://docs.cider.mx/cider-nrepl/usage.html#via-clj
 50 | [Piggieback]: https://github.com/nrepl/piggieback
 51 | [Clojure CLI]: https://clojure.org/guides/deps_and_cli
 52 | [classpath.vim]: https://github.com/tpope/vim-classpath
 53 | [salve.vim]: https://github.com/tpope/vim-salve
 54 | 
 55 | ### Not quite a REPL
 56 | 
 57 | You know that one plugin that provides a REPL in a split window and works
 58 | absolutely flawlessly, never breaking just because you did something innocuous
 59 | like backspace through part of the prompt?  No?  Such a shame, you really
 60 | would have liked it.
 61 | 
 62 | I've taken a different approach in Fireplace.  `cq`  (Think "Clojure
 63 | Quasi-REPL") is the prefix for a set of commands that bring up a *command-line
 64 | window* — the same thing you get when you hit `q:` — but set up for Clojure
 65 | code.
 66 | 
 67 | `cqq` prepopulates the command-line window with the expression under the
 68 | cursor.  `cqc` gives you a blank line in insert mode.
 69 | 
 70 | ### Evaluating from the buffer
 71 | 
 72 | Standard stuff here.  `:Eval` evaluates a range (`:%Eval` gets the whole
 73 | file), `:Require` requires a namespace with `:reload` (`:Require!` does
 74 | `:reload-all`), either the current buffer or a given argument.  `:RunTests`
 75 | kicks off `(clojure.test/run-tests)` and loads the results into the quickfix
 76 | list.
 77 | 
 78 | There's a `cp` operator that evaluates a given motion (`cpp` for the
 79 | innermost form under the cursor). `cm` and `c1m` are similar, but they only
 80 | run `clojure.walk/macroexpand-all` and `macroexpand-1` instead of evaluating
 81 | the form entirely.
 82 | 
 83 | Any failed evaluation loads the stack trace into the location list, which
 84 | can be easily accessed with `:lopen`.
 85 | 
 86 | ### Navigating and Comprehending
 87 | 
 88 | I was brand new to Clojure when I started this plugin, so stuff that helped me
 89 | understand code was a top priority.
 90 | 
 91 | * `:Source`, `:Doc`, and `:FindDoc`, which map to the underlying
 92 |   `clojure.repl` macro (with tab complete, of course).
 93 | 
 94 | * `K` is mapped to look up the symbol under the cursor with `doc`.
 95 | 
 96 | * `]D` is mapped to look up the symbol under the cursor with `source`.
 97 | 
 98 | * `]<C-D>` jumps to the definition of a symbol (even if it's inside a jar
 99 |   file).  `<C-]>` does the same and uses the tag stack.
100 | 
101 | * `gf`, everybody's favorite "go to file" command, works on namespaces.
102 | 
103 | Where possible, I favor enhancing built-ins over inventing a bunch of
104 | `<Leader>` maps.
105 | 
106 | ### Omnicomplete
107 | 
108 | Because why not?  It works in the quasi-REPL too.
109 | 
110 | ## FAQ
111 | 
112 | > Why does it take so long for Vim to start up?
113 | 
114 | That's either [classpath.vim][] or [salve.vim][].
115 | 
116 | ## Self-Promotion
117 | 
118 | Like fireplace.vim? Follow the repository on
119 | [GitHub](https://github.com/tpope/vim-fireplace) and vote for it on
120 | [vim.org](http://www.vim.org/scripts/script.php?script_id=4978).  And if
121 | you're feeling especially charitable, follow [tpope](http://tpo.pe/) on
122 | [Twitter](http://twitter.com/tpope) and
123 | [GitHub](https://github.com/tpope).
124 | 
125 | ## License
126 | 
127 | Copyright © Tim Pope.  Distributed under the same terms as Vim itself.
128 | See `:help license`.
129 | 


--------------------------------------------------------------------------------
/autoload/fireplace.vim:
--------------------------------------------------------------------------------
   1 | " Location: autoload/fireplace.vim
   2 | " Author: Tim Pope <http://tpo.pe/>
   3 | 
   4 | if exists('g:autoloaded_fireplace')
   5 |   finish
   6 | endif
   7 | let g:autoloaded_fireplace = 1
   8 | 
   9 | " Section: Utilities
  10 | 
  11 | function! s:map(mode, lhs, rhs, ...) abort
  12 |   if get(g:, 'fireplace_no_maps')
  13 |     return
  14 |   endif
  15 |   let flags = (a:0 ? a:1 : '') . (a:rhs =~# '^<Plug>' ? '' : '<script>')
  16 |   let head = a:lhs
  17 |   let tail = ''
  18 |   let keys = get(g:, a:mode.'remap', {})
  19 |   if type(keys) != type({})
  20 |     return
  21 |   endif
  22 |   while !empty(head)
  23 |     if has_key(keys, head)
  24 |       let head = keys[head]
  25 |       if empty(head)
  26 |         return
  27 |       endif
  28 |       break
  29 |     endif
  30 |     let tail = matchstr(head, '<[^<>]*>$\|.$') . tail
  31 |     let head = substitute(head, '<[^<>]*>$\|.$', '', '')
  32 |   endwhile
  33 |   if flags !~# '<unique>' || empty(mapcheck(head.tail, a:mode))
  34 |     exe a:mode.'map <buffer>' flags head.tail a:rhs
  35 |   endif
  36 | endfunction
  37 | 
  38 | function! s:pr(obj) abort
  39 |   if type(a:obj) == v:t_string
  40 |     return a:obj
  41 |   elseif type(a:obj) == v:t_list
  42 |     return '(' . join(map(copy(a:obj), 's:pr(v:val)'), ' ') . ')'
  43 |   elseif type(a:obj) == v:t_dict
  44 |     return '{' . join(map(keys(a:obj), 's:pr(v:val) . " " . s:pr(a:obj[v:val])'), ', ') . '}'
  45 |   else
  46 |     return string(a:obj)
  47 |   endif
  48 | endfunction
  49 | 
  50 | function! s:cword() abort
  51 |   let isk = &l:iskeyword
  52 |   try
  53 |     setlocal iskeyword+=',#,%,&,/,.
  54 |     return substitute(expand('<cword>'), "^#*''*", '', '')
  55 |   finally
  56 |     let &l:iskeyword = isk
  57 |   endtry
  58 | endfunction
  59 | 
  60 | function! s:zipfile_url(archive, path) abort
  61 |   if get(g:, 'loaded_zipPlugin')[1:-1] > 31
  62 |     return 'zipfile://' . a:archive . '::' . a:path
  63 |   else
  64 |     return 'zipfile:' . a:archive . '::' . a:path
  65 |   endif
  66 | endfunction
  67 | 
  68 | " Section: Escaping
  69 | 
  70 | function! s:str(string) abort
  71 |   return '"' . escape(a:string, '"\') . '"'
  72 | endfunction
  73 | 
  74 | function! s:qsym(symbol) abort
  75 |   if a:symbol =~# '^[[:alnum:]?*!+/=<>.:-]\+$'
  76 |     return "'".a:symbol
  77 |   else
  78 |     return '(symbol '.s:str(a:symbol).')'
  79 |   endif
  80 | endfunction
  81 | 
  82 | function! s:to_ns(path) abort
  83 |   return tr(substitute(a:path, '\.\w\+$', '', ''), '\/_', '..-')
  84 | endfunction
  85 | 
  86 | " Section: Completion
  87 | 
  88 | let s:jar_contents = {}
  89 | 
  90 | function! fireplace#jar_contents(path) abort
  91 |   if !exists('s:pythonx')
  92 |     let s:pythonx = 0
  93 |     if has('pythonx')
  94 |       try
  95 |         pythonx import zipfile
  96 |         let s:pythonx = 1
  97 |       catch /^Vim(pythonx):Traceback/
  98 |       endtry
  99 |     endif
 100 |   endif
 101 | 
 102 |   if !exists('s:zipinfo')
 103 |     if executable('zipinfo')
 104 |       let s:zipinfo = 'zipinfo -1 '
 105 |     elseif executable('jar')
 106 |       let s:zipinfo = 'jar tf '
 107 |     elseif executable('python')
 108 |       let s:zipinfo = 'python -c '.shellescape('import zipfile, sys; print chr(10).join(zipfile.ZipFile(sys.argv[1]).namelist())').' '
 109 |     elseif executable('python3')
 110 |       let s:zipinfo = 'python3 -c '.shellescape('import zipfile, sys; print chr(10).join(zipfile.ZipFile(sys.argv[1]).namelist())').' '
 111 |     else
 112 |       let s:zipinfo = ''
 113 |     endif
 114 |   endif
 115 | 
 116 |   if !has_key(s:jar_contents, a:path)
 117 |     if !filereadable(a:path)
 118 |       let s:jar_contents[a:path] = []
 119 |     elseif s:pythonx
 120 |       try
 121 |         let s:jar_contents[a:path] = pyxeval('zipfile.ZipFile(' . json_encode(a:path) . ').namelist()')
 122 |       catch /^Vim(let):Traceback/
 123 |         let s:jar_contents[a:path] = []
 124 |       endtry
 125 |     elseif !empty(s:zipinfo)
 126 |       let s:jar_contents[a:path] = split(system(s:zipinfo . shellescape(a:path)), "\n")
 127 |       if v:shell_error
 128 |         let s:jar_contents[a:path] = []
 129 |       endif
 130 |     endif
 131 |   endif
 132 | 
 133 |   return copy(get(s:jar_contents, a:path, []))
 134 | endfunction
 135 | 
 136 | function! fireplace#EvalComplete(A, L, P, ...) abort
 137 |   let prefix = matchstr(a:A, '\%(.* \|^\)\%(#\=[\[{('']\)*')
 138 |   let keyword = strpart(a:A, strlen(prefix))
 139 |   try
 140 |     return sort(map(fireplace#omnicomplete(a:0 ? a:1() : fireplace#client(), keyword, ''), 'prefix . v:val.word'))
 141 |   catch /^Fireplace:/
 142 |     return []
 143 |   endtry
 144 | endfunction
 145 | 
 146 | function! fireplace#eval_complete(A, L, P) abort
 147 |   return fireplace#EvalComplete(a:A, a:L, a:P)
 148 | endfunction
 149 | 
 150 | function! fireplace#CljEvalComplete(A, L, P) abort
 151 |   return fireplace#EvalComplete(a:A, a:L, a:P, function('fireplace#clj'))
 152 | endfunction
 153 | 
 154 | function! fireplace#CljsEvalComplete(A, L, P) abort
 155 |   return fireplace#EvalComplete(a:A, a:L, a:P, function('fireplace#cljs'))
 156 | endfunction
 157 | 
 158 | function! fireplace#NsComplete(A, L, P) abort
 159 |   let matches = []
 160 |   for dir in fireplace#path()
 161 |     if dir =~# '\.jar$'
 162 |       let files = filter(fireplace#jar_contents(dir), 'v:val =~# "\\.clj$"')
 163 |     else
 164 |       let files = split(glob(dir."/**/*.clj", 1), "\n")
 165 |       call map(files, 'v:val[strlen(dir)+1 : -1]')
 166 |     endif
 167 |     let matches += files
 168 |   endfor
 169 |   return filter(map(matches, 's:to_ns(v:val)'), 'a:A ==# "" || a:A ==# v:val[0 : strlen(a:A)-1]')
 170 | endfunction
 171 | 
 172 | function! fireplace#ns_complete(A, L, P) abort
 173 |   return fireplace#NsComplete(a:A, a:L, a:P)
 174 | endfunction
 175 | 
 176 | let s:short_types = {
 177 |       \ 'function': 'f',
 178 |       \ 'macro': 'm',
 179 |       \ 'var': 'v',
 180 |       \ 'special-form': 's',
 181 |       \ 'class': 'c',
 182 |       \ 'keyword': 'k',
 183 |       \ 'local': 'l',
 184 |       \ 'namespace': 'n',
 185 |       \ 'field': 'i',
 186 |       \ 'method': 'f',
 187 |       \ 'static-field': 'i',
 188 |       \ 'static-method': 'f',
 189 |       \ 'resource': 'r'
 190 |       \ }
 191 | 
 192 | function! s:candidate(val) abort
 193 |   let type = get(a:val, 'type', '')
 194 |   let arglists = get(a:val, 'arglists', [])
 195 |   return {
 196 |         \ 'word': get(a:val, 'candidate'),
 197 |         \ 'kind': get(s:short_types, type, type),
 198 |         \ 'info': get(a:val, 'doc', ''),
 199 |         \ 'menu': empty(arglists) ? '' : '(' . join(arglists, ' ') . ')'
 200 |         \ }
 201 | endfunction
 202 | 
 203 | function! s:get_complete_context() abort
 204 |   " Find toplevel form
 205 |   " If cursor is on start parenthesis we don't want to find the form
 206 |   " If cursor is on end parenthesis we want to find the form
 207 |   let [line1, col1] = searchpairpos('(', '', ')', 'Wrnb', g:fireplace#skip)
 208 |   let [line2, col2] = searchpairpos('(', '', ')', 'Wrnc', g:fireplace#skip)
 209 | 
 210 |   if (line1 == 0 && col1 == 0) || (line2 == 0 && col2 == 0)
 211 |     return ""
 212 |   endif
 213 | 
 214 |   if line1 == line2
 215 |     let expr = getline(line1)[col1-1 : col2-1]
 216 |   else
 217 |     let expr = getline(line1)[col1-1 : -1] . ' '
 218 |           \ . join(getline(line1+1, line2-1), ' ')
 219 |           \ . getline(line2)[0 : col2-1]
 220 |   endif
 221 | 
 222 |   " Calculate the position of cursor inside the expr
 223 |   if line1 == line('.')
 224 |     let p = col('.') - col1
 225 |   else
 226 |     let p = strlen(getline(line1)[col1-1 : -1])
 227 |           \ + strlen(join(getline(line1 + 1, line('.') - 1), ' '))
 228 |           \ + col('.')
 229 |   endif
 230 | 
 231 |   return strpart(expr, 0, p) . ' __prefix__ ' . strpart(expr, p)
 232 | endfunction
 233 | 
 234 | function! s:complete_extract(msg) abort
 235 |   let trans = '{"word": (v:val =~# ''[./]'' ? "" : matchstr(a:base, ''^.\+/'')) . v:val}'
 236 |   let value = get(a:msg, 'value', get(a:msg, 'completions'))
 237 |   if type(value) == type([])
 238 |     if type(get(value, 0)) == type({})
 239 |       return map(value, 's:candidate(v:val)')
 240 |     elseif type(get(value, 0)) == type([])
 241 |       return map(value[0], trans)
 242 |     elseif type(get(value, 0)) == type('')
 243 |       return map(value, trans)
 244 |     else
 245 |       return []
 246 |     endif
 247 |   endif
 248 | endfunction
 249 | 
 250 | function! s:complete_add(msg) abort
 251 |   for entry in s:complete_extract(a:msg)
 252 |     call complete_add(entry)
 253 |   endfor
 254 | endfunction
 255 | 
 256 | function! s:complete_delegate(queue, callback, msg) abort
 257 |   call extend(a:queue, s:complete_extract(a:msg))
 258 |   if index(get(a:msg, 'status', []), 'done') !=# -1
 259 |     call a:callback(a:queue)
 260 |   endif
 261 | endfunction
 262 | 
 263 | function! fireplace#omnicomplete(findstart, base, ...) abort
 264 |   if a:findstart is# 1 || a:findstart is# '1'
 265 |     let line = strpart(getline('.'), 0, col('.') - 1)
 266 |     return col('.') - strlen(matchstr(line, '\k\+$')) - 1
 267 |   else
 268 |     let err = s:op_missing_error('complete', 'cider-nrepl')
 269 |     if len(err)
 270 |       throw err
 271 |     endif
 272 |     let request = {
 273 |           \ 'op': 'complete',
 274 |           \ 'symbol': a:base,
 275 |           \ 'ns': type(a:findstart) == v:t_dict ? v:null : v:true,
 276 |           \ 'extra-metadata': ['arglists', 'doc'],
 277 |           \ 'context': a:0 ? a:1 : s:get_complete_context()
 278 |           \ }
 279 |     if type(a:findstart) == v:t_func
 280 |       return fireplace#message(request, function('s:complete_delegate', [[], a:findstart]))
 281 |     elseif type(a:findstart) == v:t_dict
 282 |       return s:complete_extract(a:findstart.Message(request, v:t_dict))
 283 |     endif
 284 |     let id = fireplace#message(request, function('s:complete_add')).id
 285 |     while !fireplace#client().done(id)
 286 |       call complete_check()
 287 |       sleep 1m
 288 |     endwhile
 289 |     return []
 290 |   endif
 291 | endfunction
 292 | 
 293 | " Section: REPL client
 294 | 
 295 | function! s:NormalizeNs(client, payload) abort
 296 |   if get(a:payload, 'ns') is# v:true
 297 |     let a:payload.ns = a:client.BufferNs()
 298 |   elseif get(a:payload, 'ns') is# v:false
 299 |     let a:payload.ns = a:client.UserNs()
 300 |   elseif type(get(a:payload, 'ns', '')) == v:t_number
 301 |     let a:payload.ns = a:client.BufferNs(a:payload.ns)
 302 |   endif
 303 |   if empty(get(a:payload, 'ns', 1))
 304 |     call remove(a:payload, 'ns')
 305 |   endif
 306 |   return a:payload
 307 | endfunction
 308 | 
 309 | let s:clj = {}
 310 | 
 311 | function! s:CljBufferNs(...) dict abort
 312 |   if call('s:bufext', a:0 ? a:000 : get(self, 'args', [])) =~# '^clj[cx]\=$'
 313 |     let ns = call('fireplace#ns', a:000)
 314 |     return ns =~# '^\%(cljs\.\)\=user$' ? '' : ns
 315 |   else
 316 |     return ''
 317 |   endif
 318 | endfunction
 319 | 
 320 | function! s:CljExt() dict abort
 321 |   return 'clj'
 322 | endfunction
 323 | 
 324 | function! s:CljReplNs() dict abort
 325 |   return 'clojure.repl'
 326 | endfunction
 327 | 
 328 | function! s:CljUserNs() dict abort
 329 |   return 'user'
 330 | endfunction
 331 | 
 332 | let s:clj = {
 333 |       \ 'BufferNs': function('s:CljBufferNs'),
 334 |       \ 'Ext': function('s:CljExt'),
 335 |       \ 'ReplNs': function('s:CljReplNs'),
 336 |       \ 'UserNs': function('s:CljUserNs')}
 337 | 
 338 | function! s:CljsBufferNs(...) dict abort
 339 |   if call('s:bufext', a:0 ? a:000 : get(self, 'args', [])) =~# '^clj[scx]$'
 340 |     let ns = call('fireplace#ns', a:000)
 341 |     return ns =~# '^\%(cljs\.\)\=user$' ? '' : ns
 342 |   else
 343 |     return ''
 344 |   endif
 345 | endfunction
 346 | 
 347 | function! s:CljsExt() dict abort
 348 |   return 'cljs'
 349 | endfunction
 350 | 
 351 | function! s:CljsReplNs() dict abort
 352 |   return 'cljs.repl'
 353 | endfunction
 354 | 
 355 | function! s:CljsUserNs() dict abort
 356 |   return 'cljs.user'
 357 | endfunction
 358 | 
 359 | let s:cljs = {
 360 |       \ 'BufferNs': function('s:CljsBufferNs'),
 361 |       \ 'Ext': function('s:CljsExt'),
 362 |       \ 'ReplNs': function('s:CljsReplNs'),
 363 |       \ 'UserNs': function('s:CljsUserNs')}
 364 | 
 365 | function! s:EvalQuery(...) dict abort
 366 |   let opts = {'session': v:false}
 367 |   for l:Arg in a:000
 368 |     if type(Arg) == v:t_string
 369 |       let opts.code = Arg
 370 |     elseif type(Arg) == v:t_dict && type(get(Arg, 'Session')) ==# v:t_func
 371 |       let client = Arg
 372 |     elseif type(Arg) == v:t_dict
 373 |       call extend(opts, Arg)
 374 |     elseif type(Arg) == v:t_func
 375 |       let l:Callback = Arg
 376 |     endif
 377 |   endfor
 378 |   let opts.code = printf(g:fireplace#reader, get(opts, 'code', 'null'))
 379 |   if exists('Callback')
 380 |     return self.Eval(opts, { m -> len(get(m, 'value', '')) ? Callback(eval(m.value)) : 0 })
 381 |   endif
 382 |   let response = self.Eval(opts)
 383 |   call s:output_response(response)
 384 | 
 385 |   if get(response, 'ex', '') !=# ''
 386 |     let err = 'Clojure: '.response.ex
 387 |   elseif has_key(response, 'value')
 388 |     return empty(response.value) ? '' : eval(response.value[-1])
 389 |   else
 390 |     let err = 'fireplace.vim: No value in '.string(response)
 391 |   endif
 392 |   throw err
 393 | endfunction
 394 | 
 395 | let s:common = {'Query': function('s:EvalQuery')}
 396 | 
 397 | let s:repl = extend(extend({"requires": {}}, s:clj), s:common)
 398 | 
 399 | let s:repl.user_ns = s:repl.UserNs
 400 | 
 401 | if !exists('s:repls')
 402 |   let s:repls = []
 403 |   let s:repl_paths = {}
 404 |   let s:repl_portfiles = {}
 405 | endif
 406 | 
 407 | function! s:repl.Client() dict abort
 408 |   return self
 409 | endfunction
 410 | 
 411 | function! s:repl.Session() dict abort
 412 |   return self.session
 413 | endfunction
 414 | 
 415 | function! s:repl.Path() dict abort
 416 |   return self.transport._path
 417 | endfunction
 418 | 
 419 | let s:repl.path = s:repl.Path
 420 | 
 421 | function! s:repl.message(payload, ...) dict abort
 422 |   call s:NormalizeNs(self, a:payload)
 423 |   if has_key(a:payload, 'ns') && a:payload.ns !=# self.UserNs()
 424 |     let ignored_error = self.Preload(a:payload.ns)
 425 |   endif
 426 |   let session = self.Session()
 427 |   return call(session.message, [a:payload] + a:000, session)
 428 | endfunction
 429 | 
 430 | let s:repl.Message = s:repl.message
 431 | 
 432 | function! s:repl.done(id) dict abort
 433 |   if type(a:id) == v:t_string
 434 |     return !has_key(self.transport.requests, a:id)
 435 |   elseif type(a:id) == v:t_dict
 436 |     return index(get(a:id, 'status', []), 'done') >= 0
 437 |   else
 438 |     return -1
 439 |   endif
 440 | endfunction
 441 | 
 442 | let s:repl.Done = s:repl.done
 443 | 
 444 | function! s:repl.preload(lib) dict abort
 445 |   if !empty(a:lib) && a:lib !=# self.UserNs() && !get(self.requires, a:lib)
 446 |     let reload = has_key(self.requires, a:lib) ? ' :reload' : ''
 447 |     let self.requires[a:lib] = 0
 448 |     if self.Ext() ==# 'clj'
 449 |       let qsym = s:qsym(a:lib)
 450 |       let expr = '(clojure.core/when-not (clojure.core/find-ns '.qsym.') (try'
 451 |             \ . ' ((or (clojure.core/resolve ''clojure.core/load-one) (fn [x _ _] (clojure.core/require x))) '.qsym.' true true)'
 452 |             \ . ' (catch Exception e (clojure.core/when-not (clojure.core/find-ns '.qsym.') (throw e)))))'
 453 |     else
 454 |       let expr = '(ns '.self.UserNs().' (:require '.a:lib.reload.'))'
 455 |     endif
 456 |     let result = self.Message({'op': 'eval', 'code': expr, 'ns': self.UserNs(), 'session': ''}, v:t_dict)
 457 |     let self.requires[a:lib] = !has_key(result, 'ex')
 458 |     if has_key(result, 'ex')
 459 |       return result
 460 |     endif
 461 |   endif
 462 |   return {}
 463 | endfunction
 464 | 
 465 | let s:repl.Preload = s:repl.preload
 466 | 
 467 | function! s:repl.Eval(...) dict abort
 468 |   let options = {'op': 'eval', 'code': ''}
 469 |   for l:Arg in a:000
 470 |     if type(Arg) == v:t_string
 471 |       let options.code = Arg
 472 |     elseif type(Arg) == v:t_dict
 473 |       call extend(options, Arg)
 474 |     elseif type(Arg) == v:t_func
 475 |       let l:Callback = Arg
 476 |     endif
 477 |   endfor
 478 |   let options = s:NormalizeNs(self, options)
 479 |   if has_key(options, 'ns') && options.ns !=# self.UserNs()
 480 |     let error = self.Preload(options.ns)
 481 |     if !empty(error)
 482 |       return error
 483 |     endif
 484 |   endif
 485 |   let response = self.Message(options, exists('l:Callback') ? Callback : v:t_dict)
 486 |   if index(get(response, 'status', []), 'namespace-not-found') < 0
 487 |     return response
 488 |   endif
 489 |   throw 'Fireplace: namespace not found: ' . get(options, 'ns', '?')
 490 | endfunction
 491 | 
 492 | let s:repl.eval = s:repl.Eval
 493 | 
 494 | function! s:repl.HasOp(op) abort
 495 |   return self.transport.HasOp(a:op)
 496 | endfunction
 497 | 
 498 | let s:piggieback = extend(copy(s:repl), s:cljs)
 499 | 
 500 | let s:piggieback.user_ns = s:piggieback.UserNs
 501 | 
 502 | function! s:piggieback.Piggieback(arg, ...) abort
 503 |   if a:0 && a:1
 504 |     if len(self.sessions)
 505 |       let session = remove(self.sessions, 0)
 506 |       call session.Message({'op': 'eval', 'code': ':cljs/quit'}, v:t_list)
 507 |       call session.Close()
 508 |     endif
 509 |     return {}
 510 |   endif
 511 |   let session = self.clj_session.Clone()
 512 |   if empty(a:arg)
 513 |     let arg = get(self, 'default', '')
 514 |   elseif a:arg =~# '^\d\{1,5}$'
 515 |     if len(fireplace#findresource('weasel/repl/websocket.clj', self.Path()))
 516 |       let arg = '(weasel.repl.websocket/repl-env :port ' . a:arg . ')'
 517 |     else
 518 |       let arg = '(cljs.repl.browser/repl-env :port ' . a:arg .')'
 519 |     endif
 520 |   else
 521 |     let arg = a:arg
 522 |   endif
 523 |   if empty(arg)
 524 |     throw 'Fireplace: no default ClojureScript REPL'
 525 |   endif
 526 |   let replns = matchstr(arg, '^\%((\w\+\.piggieback/cljs-repl \)\=(\=\zs[a-z][a-z0-9-]\+\.[a-z0-9.-]\+\ze/')
 527 |   if len(replns)
 528 |     call session.Message({'op': 'eval', 'code': "(require '" . replns . ")"}, v:t_dict)
 529 |   endif
 530 |   if arg =~# '^\S*repl-env\>' || arg !~# '('
 531 |     if len(fireplace#findresource('cemerick/piggieback.clj', self.Path())) && !len(fireplace#findresource('cider/piggieback.clj', self.Path()))
 532 |       let arg = '(cemerick.piggieback/cljs-repl ' . arg . ')'
 533 |     else
 534 |       let arg = '(cider.piggieback/cljs-repl ' . arg . ')'
 535 |     endif
 536 |   endif
 537 |   let response = session.Message({'op': 'eval', 'code': arg}, v:t_dict)
 538 |   if !has_key(response, 'ex') && get(response, 'ns', 'user') ==# 'cljs.user'
 539 |     call insert(self.sessions, session)
 540 |   else
 541 |     call session.Close()
 542 |   endif
 543 |   return response
 544 | endfunction
 545 | 
 546 | function! s:piggieback.Session() abort
 547 |   if len(self.sessions)
 548 |     return self.sessions[0]
 549 |   endif
 550 |   let response = self.Piggieback('')
 551 |   if len(self.sessions)
 552 |     return self.sessions[0]
 553 |   endif
 554 |   call s:output_response(response)
 555 |   throw 'Fireplace: error starting ClojureScript REPL'
 556 | endfunction
 557 | 
 558 | function! s:register(session, ...) abort
 559 |   call insert(s:repls, extend({'session': a:session, 'transport': a:session.transport, 'cljs_sessions': []}, deepcopy(s:repl)))
 560 |   if a:0 && a:1 !=# ''
 561 |     let s:repl_paths[a:1] = s:repls[0]
 562 |   endif
 563 |   return s:repls[0]
 564 | endfunction
 565 | 
 566 | function! s:unregister(transport) abort
 567 |   let transport = get(a:transport, 'transport', a:transport)
 568 |   let criteria = 'has_key(v:val, "transport") && v:val.transport isnot# transport'
 569 |   call filter(s:repl_paths, criteria)
 570 |   call filter(s:repls, criteria)
 571 |   call filter(s:repl_portfiles, criteria)
 572 | endfunction
 573 | 
 574 | function! s:unregister_dead() abort
 575 |   let criteria = 'has_key(v:val, "transport") && v:val.transport.Alive()'
 576 |   call filter(s:repl_paths, criteria)
 577 |   call filter(s:repls, criteria)
 578 |   call filter(s:repl_portfiles, criteria)
 579 | endfunction
 580 | 
 581 | function! fireplace#register_port_file(portfile, ...) abort
 582 |   let portfile = fnamemodify(a:portfile, ':p')
 583 |   let old = get(s:repl_portfiles, portfile, {})
 584 |   if has_key(old, 'time') && getftime(portfile) !=# old.time
 585 |     call s:unregister(old)
 586 |     let old = {}
 587 |   endif
 588 |   if empty(old) && getfsize(portfile) > 0
 589 |     let port = matchstr(readfile(portfile, 'b', 1)[0], '\d\+')
 590 |     try
 591 |       let transport = fireplace#transport#connect(port)
 592 |       let session = transport.Clone()
 593 |       let s:repl_portfiles[portfile] = {
 594 |             \ 'time': getftime(portfile),
 595 |             \ 'session': session,
 596 |             \ 'transport': transport}
 597 |       call s:register(session, a:0 ? a:1 : '')
 598 |       return session
 599 |     catch /^Fireplace:/
 600 |       if &verbose
 601 |         echohl WarningMSG
 602 |         echomsg v:exception
 603 |         echohl None
 604 |       endif
 605 |       return {}
 606 |     endtry
 607 |   else
 608 |     return get(old, 'transport', {})
 609 |   endif
 610 | endfunction
 611 | 
 612 | " Section: :Connect
 613 | 
 614 | function! fireplace#ConnectComplete(A, L, P) abort
 615 |   let proto = matchstr(a:A, '\w\+\ze://')
 616 |   if proto ==# ''
 617 |     let options = map(['nrepl'], 'v:val."://"')
 618 |   else
 619 |     let rest = matchstr(a:A, '://\zs.*')
 620 |     let options = ['localhost:']
 621 |     call map(options, 'proto."://".v:val')
 622 |   endif
 623 |   if a:A !=# ''
 624 |     call filter(options, 'v:val[0 : strlen(a:A)-1] ==# a:A')
 625 |   endif
 626 |   return options
 627 | endfunction
 628 | 
 629 | function! fireplace#ConnectCommand(line1, line2, range, bang, mods, arg, args) abort
 630 |   let str = get(a:args, 0, '')
 631 |   if empty(str)
 632 |     let str = input('Port or URL: ')
 633 |     if empty(str)
 634 |       return ''
 635 |     endif
 636 |   endif
 637 |   let str = substitute(str, '^file:[\/]\{' . (has('win32') ? '3' : '2') . '\}', '', '')
 638 |   if str =~# '^[%#]'
 639 |     let str = expand(str)
 640 |   endif
 641 |   if str !~# '^\d\+$\|:\d\|:[\/][\/]' && filereadable(str)
 642 |     let path = fnamemodify(str, ':p:h')
 643 |     let str = readfile(str, '', 1)[0]
 644 |   elseif str !~# '^\d\+$\|:\d\|:[\/][\/]' && filereadable(str . '/.nrepl-port')
 645 |     let path = fnamemodify(str, ':p:h')
 646 |     let str = readfile(str . '/.nrepl-port', '', 1)[0]
 647 |   else
 648 |     let path = fnamemodify(exists('b:java_root') ? b:java_root : getcwd(), ':~')
 649 |   endif
 650 |   try
 651 |     let transport = fireplace#transport#connect(str)
 652 |   catch /.*/
 653 |     return 'echoerr '.string(v:exception)
 654 |   endtry
 655 |   if type(transport) !=# type({}) || empty(transport)
 656 |     return ''
 657 |   endif
 658 |   let client = s:register(transport.Clone())
 659 |   echo 'Connected to ' . transport.url
 660 |   let root = len(a:args) > 1 ? expand(a:args[1]) : input('Scope connection to: ', path, 'dir')
 661 |   if root !=# '' && root !=# '-'
 662 |     let s:repl_paths[fnamemodify(root, ':p:s?.\zs[\/]$??')] = client
 663 |   endif
 664 |   return ''
 665 | endfunction
 666 | 
 667 | function! s:piggieback(count, arg, remove) abort
 668 |   try
 669 |     let response = s:Cljs().Piggieback(a:arg, a:remove)
 670 |     call s:output_response(response)
 671 |     return ''
 672 |   catch /^Fireplace:/
 673 |     return 'echoerr ' . string(v:exception)
 674 |   endtry
 675 | endfunction
 676 | 
 677 | function! s:set_up_connect() abort
 678 |   command! -buffer -bang -bar -complete=customlist,fireplace#ConnectComplete -nargs=*
 679 |         \ Connect FireplaceConnect<bang> <args>
 680 |   command! -buffer -bang -range=-1 -complete=customlist,fireplace#eval_complete -nargs=*
 681 |         \ Piggieback exe s:piggieback(<count>, <q-args>, <bang>0)
 682 | endfunction
 683 | 
 684 | " Section: Java runner
 685 | 
 686 | if !exists('s:spawns')
 687 |   let s:spawns = {}
 688 | endif
 689 | 
 690 | function! s:spawn_interrupt(id) abort
 691 |   let message = get(s:spawns, a:id, {})
 692 |   if type(get(message, 'job', '')) == v:t_number
 693 |     call jobstop(message.job)
 694 |   elseif type(get(message, 'job', '')) != v:t_string
 695 |     call job_stop(message.job)
 696 |   endif
 697 | endfunction
 698 | 
 699 | function! s:spawn_wait(id, ...) abort
 700 |   let message = get(s:spawns, a:id, {})
 701 |   let finished = v:true
 702 |   if type(get(message, 'job', '')) == v:t_number
 703 |     let finished = jobwait([message.job], a:0 ? a:1 : -1)[0] == -1 ? v:false : v:true
 704 |   elseif type(get(message, 'job', '')) != v:t_string
 705 |     let ms = 0
 706 |     let max = a:0 ? a:1 : -1
 707 |     while job_status(message.job) ==# 'run'
 708 |       if ms == max
 709 |         let finished = v:false
 710 |         break
 711 |       endif
 712 |       let ms += 1
 713 |       sleep 1m
 714 |     endwhile
 715 |   endif
 716 |   if has_key(s:spawns, a:id)
 717 |     throw 'Fireplace: race condition waiting on spawning eval?'
 718 |   endif
 719 |   return finished
 720 | endfunction
 721 | 
 722 | function! s:spawn_complete(id, name, callback) abort
 723 |   let result = {'id': a:id}
 724 |   let result.value = join(readfile(a:name . '.pr' , 'b'), "\n")
 725 |   let result.out   = join(readfile(a:name . '.out', 'b'), "\n")
 726 |   let result.err   = join(readfile(a:name . '.err', 'b'), "\n")
 727 |   let result.ex    = join(readfile(a:name . '.ex' , 'b'), "\n")
 728 |   if empty(result.ex)
 729 |     let result.status = ['done']
 730 |   else
 731 |     let result.status = ['eval-error', 'done']
 732 |   endif
 733 |   call filter(result, '!empty(v:val)')
 734 |   call remove(s:spawns, a:id)
 735 |   try
 736 |     call a:callback(result)
 737 |   catch
 738 |   endtry
 739 | endfunction
 740 | 
 741 | function! s:spawn_eval(id, classpath, expr, ns, callback) abort
 742 |   if a:ns !=# '' && a:ns !=# 'user'
 743 |     let ns = '(require '.s:qsym(a:ns).') (in-ns '.s:qsym(a:ns).') '
 744 |   else
 745 |     let ns = ''
 746 |   endif
 747 |   let tempname = tempname()
 748 |   call writefile([], tempname . '.pr', 'b')
 749 |   call writefile([], tempname . '.ex', 'b')
 750 |   call writefile(split('(do '.a:expr.')', "\n"), tempname . '.in', 'b')
 751 |   call writefile([], tempname . '.out', 'b')
 752 |   call writefile([], tempname . '.err', 'b')
 753 |   let java_cmd = split(exists('$JAVA_CMD') ? $JAVA_CMD : 'java', ' ')
 754 |   let command = java_cmd + ['-cp', a:classpath, 'clojure.main', '-e',
 755 |         \   '  (try' .
 756 |         \   '    (require ''clojure.repl ''clojure.java.javadoc) '. ns .
 757 |         \   '    (spit '.s:str(tempname . '.pr').' (pr-str (eval (read-string (slurp '.s:str(tempname . '.in').')))))' .
 758 |         \   '    (catch Exception e' .
 759 |         \   '      (spit *err* (.toString e))' .
 760 |         \   '      (spit '.s:str(tempname . '.ex').' (class e))))']
 761 |   let s:spawns[a:id] = {}
 762 |   if has('job')
 763 |     let opts = {
 764 |           \ 'out_io': 'file', 'out_name': tempname . '.out',
 765 |           \ 'err_io': 'file', 'err_name': tempname . '.err',
 766 |           \ 'exit_cb': { j, data -> s:spawn_complete(a:id, tempname, a:callback) }}
 767 |     let s:spawns[a:id].job = job_start(command, opts)
 768 |   elseif exists('*jobstart')
 769 |     let opts = {
 770 |           \ 'on_stdout': { j, data, type -> writefile(data, tempname . '.out', 'ab') },
 771 |           \ 'on_stderr': { j, data, type -> writefile(data, tempname . '.err', 'ab') },
 772 |           \ 'on_exit': { j, data, type -> s:spawn_complete(a:id, tempname, a:callback) }}
 773 |     let s:spawns[a:id].job = jobstart(command, opts)
 774 |   endif
 775 |   return {'id': a:id}
 776 | endfunction
 777 | 
 778 | let s:no_repl = 'Fireplace: no live REPL connection'
 779 | 
 780 | let s:oneoff = extend(copy(s:clj), s:common)
 781 | 
 782 | let s:oneoff.user_ns = s:repl.UserNs
 783 | 
 784 | function! s:oneoff.Client() dict abort
 785 |   return self
 786 | endfunction
 787 | 
 788 | function! s:oneoff.Path() dict abort
 789 |   return self._path
 790 | endfunction
 791 | 
 792 | let s:oneoff.path = s:oneoff.Path
 793 | 
 794 | function! s:oneoff.Eval(...) dict abort
 795 |   let options = {'op': 'eval', 'code': ''}
 796 |   for l:Arg in a:000
 797 |     if type(Arg) == v:t_string
 798 |       let options.code = Arg
 799 |     elseif type(Arg) == v:t_dict
 800 |       call extend(options, Arg)
 801 |     elseif type(Arg) == v:t_func
 802 |       let l:Callback = Arg
 803 |     endif
 804 |   endfor
 805 |   if !empty(get(options, 'session', 1))
 806 |     throw s:no_repl
 807 |   endif
 808 |   let id = has_key(options, 'id') ? options.id : fireplace#transport#id()
 809 |   let path = join(self.Path(), has('win32') ? ';' : ':')
 810 |   let options = s:NormalizeNs(self, options)
 811 |   let ns = get(options, 'ns', self.UserNs())
 812 |   let queue = []
 813 |   if exists('l:Callback')
 814 |     return s:spawn_eval(id, path, options.code, ns, l:Callback)
 815 |   endif
 816 |   call s:spawn_eval(id, path, options.code, ns, function('add', [queue]))
 817 |   call s:spawn_wait(id)
 818 |   return fireplace#transport#combine(queue)
 819 | endfunction
 820 | 
 821 | let s:oneoff.eval = s:oneoff.Eval
 822 | 
 823 | function! s:oneoff.Session(...) abort
 824 |   throw s:no_repl
 825 | endfunction
 826 | 
 827 | function! s:oneoff.HasOp(op) abort
 828 |   return 0
 829 | endfunction
 830 | 
 831 | let s:oneoff.message = s:oneoff.Session
 832 | let s:oneoff.Message = s:oneoff.Session
 833 | 
 834 | " Section: Client
 835 | 
 836 | function! s:buffer_absolute(...) abort
 837 |   let buffer = call('s:buf', a:000)
 838 |   let path = substitute(fnamemodify(bufname(buffer), ':p'), '\C^zipfile:\%([\/][\/]\)\=\(.*\)::', '\1/', '')
 839 |   let scheme = substitute(matchstr(path, '^\a\a\+\ze:'), '^.', '\u&', '')
 840 |   if len(scheme) && exists('*' . scheme . 'Real')
 841 |     let path = {scheme}Real(path)
 842 |   elseif getbufvar(buffer, '&buftype') !~# '^$\|^acwrite$'
 843 |     return ''
 844 |   endif
 845 |   if path !~# '^/\|^\a\+:\|^$' && isdirectory(matchstr(path, '^[^\/]\+[\/]'))
 846 |     let path = getcwd() . matchstr(path, '[\/]') . path
 847 |   endif
 848 |   return path =~# '^\a:[\/]\|^/' ? simplify(path) : ''
 849 | endfunction
 850 | 
 851 | function! s:buffer_path(...) abort
 852 |   let buffer = call('s:buf', a:000)
 853 |   let path = s:buffer_absolute(buffer)
 854 |   for dir in fireplace#path(buffer)
 855 |     if dir !=# '' && path[0 : strlen(dir)-1] ==# dir && path[strlen(dir)] =~# '[\/]'
 856 |       return path[strlen(dir)+1:-1]
 857 |     endif
 858 |   endfor
 859 |   return ''
 860 | endfunction
 861 | 
 862 | function! fireplace#ns(...) abort
 863 |   let buffer = call('s:buf', a:000)
 864 |   if !empty(getbufvar(buffer, 'fireplace_ns'))
 865 |     return getbufvar(buffer, 'fireplace_ns')
 866 |   endif
 867 |   let head = getbufline(buffer, 1, 500)
 868 |   let blank = '^\s*\%(\%(;\|#!\).*\)\=$'
 869 |   call filter(head, 'v:val !~# blank')
 870 |   let keyword_group = '[A-Za-z0-9_?*!+/=<>.-]'
 871 |   let lines = join(head[0:49], ' ')
 872 |   let lines = substitute(lines, '"\%(\\.\|[^"]\)*"\|\\.', '', 'g')
 873 |   let lines = substitute(lines, '\^\={[^{}]*}', '', '')
 874 |   let lines = substitute(lines, '\^:'.keyword_group.'\+', '', 'g')
 875 |   let ns = matchstr(lines, '\C^(\s*\%(in-ns\s*''\|ns\s\+\)\zs'.keyword_group.'\+\ze')
 876 |   if ns !=# ''
 877 |     return ns
 878 |   endif
 879 |   let path = s:buffer_path(buffer)
 880 |   return s:to_ns(path ==# '' ? s:user_ns(buffer) : path)
 881 | endfunction
 882 | 
 883 | function! s:buf(...) abort
 884 |   if exists('s:input') && !a:0
 885 |     return s:input
 886 |   endif
 887 |   let bufnr = a:0 && a:1 >= 0 && a:1 isnot# v:true ? a:1 : bufnr('')
 888 |   let fullname = fnamemodify(bufname(bufnr), ':p')
 889 |   if has_key(s:qffiles, fullname)
 890 |     return s:qffiles[fullname].buffer
 891 |   else
 892 |     return bufnr
 893 |   endif
 894 | endfunction
 895 | 
 896 | function! s:bufext(...) abort
 897 |   return matchstr(bufname(call('s:buf', a:000)), '\.\zs\w\+$')
 898 | endfunction
 899 | 
 900 | function! s:impl_ns(...) abort
 901 |   let buf = a:0 ? a:1 : s:buf()
 902 |   let ext = fnamemodify(bufname(buf), ':e')
 903 |   if ext ==# 'cljs'
 904 |     return 'cljs'
 905 |   elseif ext ==# 'clj'
 906 |     return 'clojure'
 907 |   elseif !empty(get(b:, 'fireplace_cljc_platform', ''))
 908 |     return b:fireplace_cljc_platform is# 'cljs' ? 'cljs' : 'clj'
 909 |   else
 910 |     try
 911 |       if len(get(call('fireplace#native', a:000), 'cljs_sessions', []))
 912 |         return 'cljs'
 913 |       endif
 914 |     catch /^Fireplace: no live REPL connection/
 915 |     endtry
 916 |     return 'clojure'
 917 |   endif
 918 | endfunction
 919 | 
 920 | function! s:repl_ns(...) abort
 921 |   return s:impl_ns(a:0 ? a:1 : s:buf()) . '.repl'
 922 | endfunction
 923 | 
 924 | function! s:user_ns(...) abort
 925 |   return s:impl_ns(a:0 ? a:1 : s:buf()) ==# 'cljs' ? 'cljs.user' : 'user'
 926 | endfunction
 927 | 
 928 | function! s:slash() abort
 929 |   return exists('+shellslash') && !&shellslash ? '\' : '/'
 930 | endfunction
 931 | 
 932 | function! s:includes_file(file, path) abort
 933 |   for path in a:path
 934 |     if len(path) && strpart(a:file, 0, len(path)) ==? path
 935 |       return 1
 936 |     endif
 937 |   endfor
 938 | endfunction
 939 | 
 940 | function! s:path_extract(path, ...) abort
 941 |   let path = []
 942 |   if a:0 || a:path =~# '\.jar'
 943 |     for elem in split(substitute(a:path, ',$', '', ''), a:0 ? '[=,]' : ',')
 944 |       if elem ==# ''
 945 |         let path += ['.']
 946 |       else
 947 |         let path += split(glob(substitute(elem, '\\\ze[\\ ,]', '', 'g'), 1), "\n")
 948 |       endif
 949 |     endfor
 950 |   endif
 951 |   return path
 952 | endfunction
 953 | 
 954 | function! fireplace#path(...) abort
 955 |   let buf = a:0 ? a:1 : s:buf()
 956 |   let absolute = s:buffer_absolute(buf)
 957 |   for repl in s:repls
 958 |     if s:includes_file(absolute, repl.Path())
 959 |       return repl.Path()
 960 |     endif
 961 |   endfor
 962 |   return s:path_extract(getbufvar(buf, '&path'))
 963 | endfunction
 964 | 
 965 | function! fireplace#native(...) abort
 966 |   call s:unregister_dead()
 967 |   for [k, v] in items(s:repl_portfiles)
 968 |     if getftime(k) != v.time
 969 |       call s:unregister(v)
 970 |     endif
 971 |   endfor
 972 | 
 973 |   let buf = a:0 ? a:1 : s:buf()
 974 |   let path = s:buffer_absolute(buf)
 975 | 
 976 |   let portfile = findfile('.nrepl-port', (a:0 ? fnamemodify(path, ':h') : '.') . ';')
 977 |   if !empty(portfile) && filereadable(portfile)
 978 |     call fireplace#register_port_file(portfile, fnamemodify(portfile, ':p:h'))
 979 |   else
 980 |     let portfile = findfile('.shadow-cljs/nrepl.port', (a:0 ? fnamemodify(path, ':h') : '') . ';')
 981 |     if !empty(portfile) && filereadable(portfile)
 982 |       call fireplace#register_port_file(portfile, fnamemodify(portfile, ':p:h:h'))
 983 |     endif
 984 |   endif
 985 | 
 986 |   if !a:0
 987 |     silent doautocmd <nomodeline> User FireplacePreConnect
 988 |   endif
 989 | 
 990 |   let root = substitute(path, '[\/]$', '', '')
 991 |   let previous = ""
 992 |   while root !=# previous
 993 |     if has_key(s:repl_paths, root)
 994 |       return s:repl_paths[root]
 995 |     endif
 996 |     let previous = root
 997 |     let root = fnamemodify(root, ':h')
 998 |   endwhile
 999 |   for repl in s:repls
1000 |     if s:includes_file(path, repl.Path())
1001 |       return repl
1002 |     endif
1003 |   endfor
1004 |   let path = s:path_extract(getbufvar(buf, '&path'))
1005 |   if !empty(path)
1006 |     return extend({'_path': path, 'nr': bufnr(buf)}, s:oneoff)
1007 |   endif
1008 |   throw s:no_repl
1009 | endfunction
1010 | 
1011 | function! s:PlatformDelegate(func, ...) dict abort
1012 |   if self.Ext() ==# 'cljs'
1013 |     let fn = 's:Cljs'
1014 |   else
1015 |     let fn = 'fireplace#native'
1016 |   endif
1017 |   let obj = call(fn, get(self, 'args', []))
1018 |   return call(obj[a:func], a:000, obj)
1019 | endfunction
1020 | 
1021 | function! s:NativeDelegate(func, ...) dict abort
1022 |   let obj = call('fireplace#native', get(self, 'args', []))
1023 |   return call(obj[a:func], a:000, obj)
1024 | endfunction
1025 | 
1026 | let s:delegate = {
1027 |       \ 'Client': function('s:PlatformDelegate', ['Client']),
1028 |       \ 'Eval': function('s:PlatformDelegate', ['Eval']),
1029 |       \ 'HasOp': function('s:NativeDelegate', ['HasOp']),
1030 |       \ 'Query': function('s:PlatformDelegate', ['Query']),
1031 |       \ 'Message': function('s:PlatformDelegate', ['Message']),
1032 |       \ 'Path': function('s:NativeDelegate', ['Path']),
1033 |       \ 'Session': function('s:PlatformDelegate', ['Session']),
1034 |       \ }
1035 | 
1036 | let s:clj_delegate = extend(copy(s:clj), s:delegate)
1037 | let s:cljs_delegate = extend(copy(s:cljs), s:delegate)
1038 | 
1039 | function! fireplace#clj(...) abort
1040 |   return extend({'args': a:000}, s:clj_delegate)
1041 | endfunction
1042 | 
1043 | function! fireplace#cljs(...) abort
1044 |   return extend({'args': a:000}, s:cljs_delegate)
1045 | endfunction
1046 | 
1047 | function! fireplace#platform(...) abort
1048 |   if call('s:impl_ns', a:000) ==# 'cljs'
1049 |     return call('fireplace#cljs', a:000)
1050 |   else
1051 |     return call('fireplace#clj', a:000)
1052 |   endif
1053 | endfunction
1054 | 
1055 | function! s:Cljs(...) abort
1056 |   let client = call('fireplace#native', a:000)
1057 |   if !has_key(client, 'cljs_sessions')
1058 |     throw s:no_repl
1059 |   endif
1060 |   let buf = bufnr(a:0 ? a:1 : s:buf())
1061 |   let default = getbufvar(buf, 'fireplace_cljs_repl', get(g:, 'fireplace_cljs_repl', ''))
1062 |   let cljs = extend({'default': default, 'transport': client.transport, 'sessions': client.cljs_sessions, 'clj_session': client.session}, s:piggieback)
1063 |   return cljs
1064 | endfunction
1065 | 
1066 | function! fireplace#client(...) abort
1067 |   let buf = a:0 ? a:1 : s:buf()
1068 |   let ext = fnamemodify(bufname(buf), ':e')
1069 |   if ext ==# 'cljs'
1070 |     return call('s:Cljs', a:000)
1071 |   endif
1072 |   let client = call('fireplace#native', a:000)
1073 |   if ext !=# 'clj' && len(get(client, 'cljs_sessions', []))
1074 |     return call('s:Cljs', a:000)
1075 |   endif
1076 |   return client
1077 | endfunction
1078 | 
1079 | function! fireplace#message(payload, ...) abort
1080 |   let client = fireplace#client()
1081 |   let payload = copy(a:payload)
1082 |   if !has_key(payload, 'ns')
1083 |     let payload.ns = v:true
1084 |   endif
1085 |   return call(client.Message, [payload] + a:000, client)
1086 | endfunction
1087 | 
1088 | function! fireplace#interrupt(msg_or_id) abort
1089 |   let id = type(a:msg_or_id) ==# v:t_dict ? get(a:msg_or_id, 'id', '') : a:msg_or_id
1090 |   call s:spawn_interrupt(id)
1091 |   call fireplace#transport#interrupt(id)
1092 |   return a:msg_or_id
1093 | endfunction
1094 | 
1095 | function! fireplace#wait(msg_or_id_or_list, ...) abort
1096 |   if type(a:msg_or_id_or_list) != v:t_list
1097 |     return call('fireplace#wait', [[a:msg_or_id_or_list]] + a:000)[0]
1098 |   endif
1099 |   try
1100 |     let results = []
1101 |     for item in a:msg_or_id_or_list
1102 |       let id = type(item) ==# v:t_dict ? get(item, 'id', '') : item
1103 |       call add(results, (call('s:spawn_wait', [id] + a:000) &&
1104 |             \ call('fireplace#transport#wait', [id] + a:000)) ? v:true : v:false)
1105 |     endfor
1106 |     let finished = 1
1107 |     return results
1108 |   finally
1109 |     if !a:0 && !exists('finished')
1110 |       for item in a:msg_or_id_or_list
1111 |         call fireplace#interrupt(item)
1112 |       endfor
1113 |     endif
1114 |   endtry
1115 | endfunction
1116 | 
1117 | function! fireplace#id() abort
1118 |   return fireplace#transport#id()
1119 | endfunction
1120 | 
1121 | function! s:op_missing_error(op, ...) abort
1122 |   try
1123 |     let client = fireplace#native()
1124 |     if !has_key(client, 'transport')
1125 |       return s:no_repl
1126 |     elseif client.transport.HasOp(a:op)
1127 |       return ''
1128 |     elseif a:0
1129 |       return 'Fireplace: no ' . string(a:op) . ' nREPL op available (is ' . a:1 . ' installed?)'
1130 |     else
1131 |       return 'Fireplace: no ' . string(a:op) . ' nREPL op available'
1132 |     endif
1133 |   catch /^Fireplace: no live REPL connection/
1134 |     return s:no_repl
1135 |   endtry
1136 | endfunction
1137 | 
1138 | function! s:op_guard(...) abort
1139 |   let err = call('s:op_missing_error', a:000)
1140 |   if empty(err)
1141 |     return ''
1142 |   endif
1143 |   return 'return ' . string('echoerr ' . string(err))
1144 | endfunction
1145 | 
1146 | function! fireplace#op_available(op) abort
1147 |   return empty(s:op_missing_error(a:op))
1148 | endfunction
1149 | 
1150 | function! fireplace#findresource(resource, ...) abort
1151 |   if a:resource ==# ''
1152 |     return ''
1153 |   endif
1154 |   let resource = a:resource
1155 |   if a:0 > 2 && type(a:3) == type([])
1156 |     let suffixes = a:3
1157 |   else
1158 |     let suffixes = [''] + split(get(a:000, 2, ''), ',')
1159 |   endif
1160 |   for dir in a:0 ? a:1 : fireplace#path()
1161 |     for suffix in suffixes
1162 |       if fnamemodify(dir, ':e') ==# 'jar' && index(fireplace#jar_contents(dir), resource . suffix) >= 0
1163 |         return s:zipfile_url(dir, resource . suffix)
1164 |       elseif filereadable(dir . '/' . resource . suffix)
1165 |         return dir . s:slash() . resource . suffix
1166 |       endif
1167 |     endfor
1168 |   endfor
1169 |   return ''
1170 | endfunction
1171 | 
1172 | function! s:output_response(response) abort
1173 |   let substitution_pat =  '\e\[[0-9;]*m\|\r\|\n$'
1174 |   if get(a:response, 'err', '') !=# ''
1175 |     echohl ErrorMSG
1176 |     echo substitute(a:response.err, substitution_pat, '', 'g')
1177 |     echohl NONE
1178 |   endif
1179 |   if get(a:response, 'out', '') !=# ''
1180 |     echo substitute(a:response.out, substitution_pat, '', 'g')
1181 |   endif
1182 | endfunction
1183 | 
1184 | function! s:temp_response(response, ext) abort
1185 |   let output = []
1186 |   call extend(output, map(split(get(a:response, 'err', ''), "\n"), '";!".v:val'))
1187 |   call extend(output, map(split(get(a:response, 'out', ''), "\n"), '";=".v:val'))
1188 |   for str in type(get(a:response, 'value')) == v:t_string ? [a:response.value] : get(a:response, 'value', [])
1189 |     call extend(output, split(str, "\n"))
1190 |   endfor
1191 |   let temp = tempname() . '.' . a:ext
1192 |   call writefile(output, temp)
1193 |   return temp
1194 | endfunction
1195 | 
1196 | if !exists('s:history')
1197 |   let s:history = []
1198 | endif
1199 | 
1200 | if !exists('s:qffiles')
1201 |   let s:qffiles = {}
1202 | endif
1203 | 
1204 | function! s:qfhistory_item(entry) abort
1205 |   if !has_key(a:entry, 'tempfile')
1206 |     let a:entry.tempfile = s:temp_response(a:entry.response, get(a:entry, 'ext', 'clj'))
1207 |   endif
1208 |   let s:qffiles[a:entry.tempfile] = a:entry
1209 |   return {'filename': a:entry.tempfile, 'text': a:entry.code, 'type': 'E', 'module': a:entry.response.id}
1210 | endfunction
1211 | 
1212 | function! s:qfhistory() abort
1213 |   let list = []
1214 |   for entry in reverse(copy(s:history))
1215 |     call extend(list, [s:qfhistory_item(entry)])
1216 |   endfor
1217 |   return list
1218 | endfunction
1219 | 
1220 | function! s:echon(state, str, hlgroup) abort
1221 |   let str = get(a:state, 'echo_buffer', '') . a:str
1222 |   let a:state.echo_buffer = matchstr(str, "\n$")
1223 |   if get(a:state, 'echo', v:true)
1224 |     exe 'echohl' a:hlgroup
1225 |     echon len(a:state.echo_buffer) ? str[0:-2] : str
1226 |     echohl NONE
1227 |   endif
1228 | endfunction
1229 | 
1230 | function! s:eval_callback(state, delegates, message) abort
1231 |   call add(a:state.history.messages, a:message)
1232 |   if has_key(a:message, 'ex')
1233 |     let a:state.ex = a:message.ex
1234 |   endif
1235 |   if has_key(a:message, 'ns')
1236 |     let a:state.ns = a:message.ns
1237 |   endif
1238 |   if has_key(a:message, 'out')
1239 |     call s:echon(a:state, a:message.out, 'Question')
1240 |   endif
1241 |   if has_key(a:message, 'err')
1242 |     call s:echon(a:state, a:message.err, 'WarningMsg')
1243 |   endif
1244 |   if has_key(a:message, 'value')
1245 |     call s:echon(a:state, a:message.value, 'NONE')
1246 |     if has_key(a:message, 'ns')
1247 |       call s:echon(a:state, "\n", 'NONE')
1248 |     endif
1249 |   endif
1250 | 
1251 |   for Delegate in a:delegates
1252 |     try
1253 |       call call(Delegate, [a:message])
1254 |     catch
1255 |     endtry
1256 |   endfor
1257 |   if index(get(a:message, 'status', []), 'done') >= 0
1258 |     if has_key(a:state, 'client')
1259 |       let client = a:state.client
1260 |       if len(get(client, 'sessions', [])) && a:state.code =~# '^\s*:cljs/quit\s*$' && !has_key(state, 'ex')
1261 |         let old_session = remove(client.sessions, 0)
1262 |         call old_session.Close()
1263 |       elseif has_key(client, 'cljs_sessions') && get(a:state, 'ns', '') ==# 'cljs.user'
1264 |         call insert(client.cljs_sessions, client.Session().Clone())
1265 |         call client.Message({'op': 'eval', 'code': ':cljs/quit'}, v:t_dict)
1266 |       endif
1267 |     endif
1268 |     let a:state.history.response = fireplace#transport#combine(a:state.history.messages)
1269 |     let response = a:state.history.response
1270 |     let buffer = []
1271 |     for [prefix, value] in [[';!', get(response, 'err', '')], [';=', get(response, 'out', '')]] +
1272 |           \ map(copy(get(response, 'value', [])), { _, v -> ['', v]})
1273 |       let lines = split(value, "\n", 1)
1274 |       if empty(lines[-1])
1275 |         call remove(lines, -1)
1276 |       endif
1277 |       let buffer += map(lines, 'prefix . v:val')
1278 |     endfor
1279 |     call add(buffer, '')
1280 |     call writefile(buffer, a:state.history.tempfile, 'b')
1281 |     call insert(s:history, a:state.history)
1282 |     if len(s:history) > &history
1283 |       call remove(s:history, &history, -1)
1284 |     endif
1285 |     if get(a:state, 'bg')
1286 |       exe s:Last(1, 1)
1287 |     endif
1288 |     if a:state.history.buffer == bufnr('')
1289 |       try
1290 |         silent doautocmd User FireplaceEvalPost
1291 |       catch
1292 |       endtry
1293 |     endif
1294 |   endif
1295 | endfunction
1296 | 
1297 | function! fireplace#eval(...) abort
1298 |   let opts = {}
1299 |   let state = {'echo': v:false}
1300 |   let callbacks = []
1301 |   for l:Arg in a:000
1302 |     if type(Arg) == v:t_string
1303 |       let opts.code = Arg
1304 |     elseif type(Arg) == v:t_dict && type(get(Arg, 'Session')) ==# v:t_func
1305 |       let platform = Arg
1306 |     elseif type(Arg) == v:t_dict
1307 |       call extend(opts, Arg)
1308 |     elseif type(Arg) == v:t_func
1309 |       call add(callbacks, Arg)
1310 |     elseif type(Arg) == v:t_bool
1311 |       let state.echo = Arg
1312 |     elseif type(Arg) == v:t_number
1313 |       call s:add_pprint_opts(opts, Arg)
1314 |     endif
1315 |   endfor
1316 |   let code = remove(opts, 'code')
1317 | 
1318 |   let native = fireplace#native()
1319 |   let ext = matchstr(bufname(s:buf()), '\.\zs\w\+$')
1320 |   if !exists('platform') && !has_key(opts, 'session') && has_key(native, 'cljs_sessions') && ext =~# '^clj[csx]$' && code =~# '^\s*(\S\+/cljs-repl'
1321 |     let platform = native
1322 |   elseif !exists('platform')
1323 |     let platform = fireplace#platform()
1324 |   endif
1325 |   if !has_key(opts, 'ns')
1326 |     let opts.ns = v:true
1327 |   endif
1328 |   let ext = platform.Ext()
1329 | 
1330 |   let client = platform.Client()
1331 |   let state.code = code
1332 |   let state.history = {'buffer': bufnr(''), 'tempfile': tempname() . '.' . ext, 'ext': ext, 'code': code, 'ns': fireplace#ns(), 'messages': []}
1333 |   if !has_key(opts, 'session')
1334 |     let state.client = client
1335 |   endif
1336 |   let msg = client.Eval(code, opts, function('s:eval_callback', [state, callbacks]))
1337 | 
1338 |   if state.echo
1339 |     echo ""
1340 |   endif
1341 | 
1342 |   if len(callbacks)
1343 |     return msg
1344 |   endif
1345 | 
1346 |   try
1347 |     while !fireplace#wait(msg.id, 1)
1348 |       let peek = getchar(1)
1349 |       if state.echo && peek != 0 && !(has('win32') && peek == 128)
1350 |         let c = getchar()
1351 |         let c = type(c) == type(0) ? nr2char(c) : c
1352 |         if c ==# "\<C-D>"
1353 |           let state.echo = v:false
1354 |           let state.bg = v:true
1355 |           echo "\rBackgrounded"
1356 |           let finished = 1
1357 |           return []
1358 |         else
1359 |           call fireplace#transport#stdin(msg.id, c)
1360 |           echon c
1361 |         endif
1362 |       endif
1363 |     endwhile
1364 |     let finished = 1
1365 |   finally
1366 |     if !exists('l:finished')
1367 |       call fireplace#interrupt(msg.id)
1368 |     endif
1369 |   endtry
1370 | 
1371 |   if get(state, 'ex', '') !=# ''
1372 |     let err = 'Clojure: '.state.ex
1373 |   else
1374 |     return get(state.history.response, 'value', [])
1375 |   endif
1376 |   throw err
1377 | endfunction
1378 | 
1379 | function! fireplace#session_eval(...) abort
1380 |   return get(call('fireplace#eval', a:000), -1, '')
1381 | endfunction
1382 | 
1383 | function! s:DisplayWidth() abort
1384 |   if exists('g:fireplace_display_width') && g:fireplace_display_width < &columns
1385 |     return g:fireplace_display_width
1386 |   else
1387 |     return &columns
1388 |   endif
1389 | endfunction
1390 | 
1391 | function! s:RefreshLast() abort
1392 |   for win in range(1, winnr('$'))
1393 |     if getwinvar(win, '&previewwindow')
1394 |       let loclist = getloclist(win)
1395 |       if len(loclist) && map(loclist, 'v:val.text') == map(s:qfhistory()[0 : len(loclist)-1], 'v:val.text')
1396 |         exe s:Last(1, 1)
1397 |       endif
1398 |     endif
1399 |   endfor
1400 | endfunction
1401 | 
1402 | function! fireplace#echo_session_eval(...) abort
1403 |   try
1404 |     call call('fireplace#eval', [s:DisplayWidth(), v:true] + a:000)
1405 |     call s:RefreshLast()
1406 |   catch
1407 |     if v:exception =~# '^Clojure:'
1408 |       call s:RefreshLast()
1409 |     endif
1410 |     echohl ErrorMSG
1411 |     echomsg v:exception
1412 |     echohl NONE
1413 |   endtry
1414 |   return ''
1415 | endfunction
1416 | 
1417 | let g:fireplace#reader =
1418 |       \ '(symbol ((fn *vimify [x]' .
1419 |       \  ' (cond' .
1420 |       \    ' (map? x)     (str "{" (apply str (interpose ", " (map (fn [[k v]] (str (*vimify k) ": " (*vimify v))) x))) "}")' .
1421 |       \    ' (coll? x)    (str "[" (apply str (interpose ", " (map *vimify x))) "]")' .
1422 |       \    ' (true? x)    "v:true"' .
1423 |       \    ' (false? x)   "v:false"' .
1424 |       \    ' (nil? x)     "v:null"' .
1425 |       \    ' (number? x)  (pr-str x)' .
1426 |       \    ' (keyword? x) (pr-str (name x))' .
1427 |       \    ' :else        (pr-str (str x)))) %s))'
1428 | 
1429 | function! fireplace#query(...) abort
1430 |   let args = [{'ns': v:true}]
1431 |   let client = fireplace#platform()
1432 |   for l:Arg in a:000
1433 |     if type(Arg) == v:t_dict && type(get(Arg, 'Session')) ==# v:t_func
1434 |       let client = Arg
1435 |     else
1436 |       call add(args, Arg)
1437 |     endif
1438 |   endfor
1439 |   return call(client.Query, args, client)
1440 | endfunction
1441 | 
1442 | function! fireplace#evalparse(expr, ...) abort
1443 |   return fireplace#query(a:expr, a:0 ? a:1 : {})
1444 | endfunction
1445 | 
1446 | " Section: Quickfix
1447 | 
1448 | function! s:qfmassage(line, path) abort
1449 |   let item = {'text': a:line}
1450 |   let match = matchlist(a:line, '^\s*\(\S\+\)\s\=(\([^:()[:space:]]*\)\%(:\(\d\+\)\)\=)$')
1451 |   if !empty(match)
1452 |     let [_, class, file, lnum; __] = match
1453 |     let item.module = class
1454 |     let item.lnum = +lnum
1455 |     if file ==# 'NO_SOURCE_FILE' || !lnum
1456 |       let item.resource = ''
1457 |     else
1458 |       let truncated = substitute(class, '\.[A-Za-z0-9_]\+\%([$/].*\)$', '', '')
1459 |       let item.resource = tr(truncated, '.', '/') . '/' . file
1460 |     endif
1461 |     let item.filename = fireplace#findresource(item.resource, a:path)
1462 |     if has('patch-8.0.1782')
1463 |       let item.text = ''
1464 |     else
1465 |       let item.text = class
1466 |     endif
1467 |   endif
1468 |   return item
1469 | endfunction
1470 | 
1471 | function! fireplace#quickfix_for(stacktrace) abort
1472 |   let path = fireplace#path()
1473 |   return map(copy(a:stacktrace), 's:qfmassage(v:val, path)')
1474 | endfunction
1475 | 
1476 | function! fireplace#massage_list(...) abort
1477 |   let p = substitute(matchstr(','.&errorformat, '\C,\%(%\\&\)\=classpath=\=\zs\%(\\.\|[^\,]\)*'), '\\\ze[\,%]', '', 'g')
1478 |   if empty(p)
1479 |     return
1480 |   endif
1481 |   if a:0
1482 |     let l:GetList = function('getloclist', [a:1])
1483 |     let l:SetList = function('setloclist', [a:1])
1484 |   else
1485 |     let l:GetList = function('getqflist', [])
1486 |     let l:SetList = function('setqflist', [])
1487 |   endif
1488 |   let path = p =~# '^[:;]' ? split(p[1:-1], p[0]) : p[0] ==# ',' ? s:path_extract(p[1:-1], 1) : s:path_extract(p, 1)
1489 |   let qflist = l:GetList()
1490 |   for item in qflist
1491 |     if !item.bufnr && !entry.lnum
1492 |       call extend(item, s:qfmassage(get(item, 'text', ''), path))
1493 |     endif
1494 |   endfor
1495 |   let attrs = l:GetList({'title': 1})
1496 |   call l:SetList(qflist, 'r')
1497 |   call l:SetList([], 'r', attrs)
1498 | endfunction
1499 | 
1500 | " Section: Eval
1501 | 
1502 | let fireplace#skip = 'synIDattr(synID(line("."),col("."),1),"name") =~? "comment\\|string\\|char\\|regexp"'
1503 | 
1504 | function! s:opfunc(type) abort
1505 |   let sel_save = &selection
1506 |   let cb_save = &clipboard
1507 |   let reg_save = @@
1508 |   try
1509 |     set selection=inclusive clipboard-=unnamed clipboard-=unnamedplus
1510 |     if type(a:type) == type(0)
1511 |       let open = '[[{(]'
1512 |       let close = '[]})]'
1513 |       if getline('.')[col('.')-1] =~# close
1514 |         let [line1, col1] = searchpairpos(open, '', close, 'bn', g:fireplace#skip)
1515 |         let [line2, col2] = [line('.'), col('.')]
1516 |       else
1517 |         let [line1, col1] = searchpairpos(open, '', close, 'bcn', g:fireplace#skip)
1518 |         let [line2, col2] = searchpairpos(open, '', close, 'n', g:fireplace#skip)
1519 |       endif
1520 |       while col1 > 1 && getline(line1)[col1-2] =~# '[#''`~@]'
1521 |         let col1 -= 1
1522 |       endwhile
1523 |       call setpos("'[", [0, line1, col1, 0])
1524 |       call setpos("']", [0, line2, col2, 0])
1525 |       silent exe "normal! `[v`]y"
1526 |     elseif a:type =~# '^.$'
1527 |       silent exe "normal! `<" . a:type . "`>y"
1528 |     elseif a:type ==# 'line'
1529 |       silent exe "normal! '[V']y"
1530 |     elseif a:type ==# 'block'
1531 |       silent exe "normal! `[\<C-V>`]y"
1532 |     elseif a:type ==# 'outer'
1533 |       call searchpair('(','',')', 'Wbcr', g:fireplace#skip)
1534 |       silent exe "normal! vaby"
1535 |     else
1536 |       silent exe "normal! `[v`]y"
1537 |     endif
1538 |     redraw
1539 |     return {'code': @@, 'file': s:buffer_path(), 'line': line("'<"), 'column': col("'<")}
1540 |   finally
1541 |     let @@ = reg_save
1542 |     let &selection = sel_save
1543 |     let &clipboard = cb_save
1544 |   endtry
1545 | endfunction
1546 | 
1547 | function! s:filterop(type) abort
1548 |   let reg_save = @@
1549 |   let sel_save = &selection
1550 |   let cb_save = &clipboard
1551 |   try
1552 |     set selection=inclusive clipboard-=unnamed clipboard-=unnamedplus
1553 |     let opts = s:opfunc(a:type)
1554 |     let @@ = matchstr(opts.code, '^\n\+') . join(fireplace#eval(opts), ' ') . matchstr(opts.code, '\n\+$')
1555 |     if @@ !~# '^\n*$'
1556 |       normal! gvp
1557 |     endif
1558 |   catch /^Clojure:/
1559 |     return ''
1560 |   finally
1561 |     let @@ = reg_save
1562 |     let &selection = sel_save
1563 |     let &clipboard = cb_save
1564 |   endtry
1565 | endfunction
1566 | 
1567 | function! s:macroexpand(fn, form) abort
1568 |   return fireplace#echo_session_eval('('.a:fn.' (quote '.a:form.'))')
1569 | endfunction
1570 | 
1571 | function! s:macroexpandop(type) abort
1572 |   call s:macroexpand("clojure.walk/macroexpand-all", s:opfunc(a:type).code)
1573 | endfunction
1574 | 
1575 | function! s:macroexpand1op(type) abort
1576 |   call s:macroexpand("macroexpand-1", s:opfunc(a:type).code)
1577 | endfunction
1578 | 
1579 | function! s:printop(type) abort
1580 |   let s:todo = s:opfunc(a:type)
1581 |   call feedkeys("\<Plug>FireplacePrintLast")
1582 | endfunction
1583 | 
1584 | function! s:add_pprint_opts(msg, width) abort
1585 |   let a:msg['nrepl.middleware.print/stream?'] = 1
1586 |   if fireplace#op_available('info')
1587 |     let a:msg['nrepl.middleware.print/print'] = 'cider.nrepl.pprint/fipp-pprint'
1588 |     let a:msg['nrepl.middleware.print/options'] = {}
1589 |     if a:width > 0
1590 |       let a:msg['nrepl.middleware.print/options'].width = a:width
1591 |     endif
1592 |   endif
1593 |   return a:msg
1594 | endfunction
1595 | 
1596 | function! s:print_last() abort
1597 |   call fireplace#echo_session_eval(s:todo)
1598 |   return ''
1599 | endfunction
1600 | 
1601 | function! s:editop(type) abort
1602 |   call feedkeys(eval('"\'.&cedit.'"') . "\<Home>", 'n')
1603 |   let input = s:input(substitute(substitute(substitute(
1604 |         \ s:opfunc(a:type).code, "\s*;[^\n\"]*\\%(\n\\@=\\|$\\)", '', 'g'),
1605 |         \ '\n\+\s*', ' ', 'g'),
1606 |         \ '^\s*', '', ''))
1607 |   if input !=# ''
1608 |     call fireplace#echo_session_eval(input)
1609 |   endif
1610 | endfunction
1611 | 
1612 | function! s:Eval(type, line1, line2, range, bang, mods, args) abort
1613 |   let options = {}
1614 |   if a:args !=# ''
1615 |     let expr = a:args
1616 |   else
1617 |     if a:line2 < 0
1618 |       let open = '[[{(]'
1619 |       let close = '[]})]'
1620 |       let [line1, col1] = searchpairpos(open, '', close, 'bcrn', g:fireplace#skip)
1621 |       let [line2, col2] = searchpairpos(open, '', close, 'rn', g:fireplace#skip)
1622 |       if !line1 && !line2
1623 |         let [line1, col1] = searchpairpos(open, '', close, 'brn', g:fireplace#skip)
1624 |         let [line2, col2] = searchpairpos(open, '', close, 'crn', g:fireplace#skip)
1625 |       endif
1626 |       while col1 > 1 && getline(line1)[col1-2] =~# '[#''`~@]'
1627 |         let col1 -= 1
1628 |       endwhile
1629 |     else
1630 |       let line1 = a:line1
1631 |       let line2 = a:line2
1632 |       let col1 = 1
1633 |       let col2 = strlen(getline(line2))
1634 |     endif
1635 |     if !line1 || !line2
1636 |       return ''
1637 |     endif
1638 |     let options.file = s:buffer_path()
1639 |     let options.line = line1
1640 |     let options.column = col1
1641 |     if line1 == line2
1642 |       let expr = getline(line1)[col1-1 : col2-1]
1643 |     else
1644 |       let expr = getline(line1)[col1-1 : -1] . "\n"
1645 |             \ . join(map(getline(line1+1, line2-1), 'v:val . "\n"'))
1646 |             \ . getline(line2)[0 : col2-1]
1647 |     endif
1648 |     if a:bang
1649 |       exe line1.','.line2.'delete _'
1650 |     endif
1651 |   endif
1652 |   try
1653 |     let args = (a:type ==# 'platform' || a:type ==# 'client' ? [{'ns': v:true}] : [fireplace#{a:type}(), {'ns': v:null}]) + [expr, options]
1654 |     if a:bang
1655 |       let result = split(join(map(call('fireplace#eval', [&textwidth] + args), 'substitute(v:val, "\n*$", "", "")'), "\n"), "\n")
1656 |       if a:args !=# ''
1657 |         call append(a:line1, result)
1658 |         exe a:line1
1659 |       else
1660 |         call append(a:line1-1, result)
1661 |         exe a:line1-1
1662 |       endif
1663 |     else
1664 |       call call('fireplace#echo_session_eval', args)
1665 |     endif
1666 |   catch /^Clojure:/
1667 |   catch /^Fireplace:/
1668 |     return 'echoerr ' . string(v:exception)
1669 |   endtry
1670 |   return ''
1671 | endfunction
1672 | 
1673 | function! fireplace#CljEvalCommand(line1, line2, range, bang, mods, args) abort
1674 |   return s:Eval('clj', a:line1, a:line2, a:range, a:bang, a:mods, a:args)
1675 | endfunction
1676 | 
1677 | function! fireplace#CljsEvalCommand(line1, line2, range, bang, mods, args) abort
1678 |   return s:Eval('cljs', a:line1, a:line2, a:range, a:bang, a:mods, a:args)
1679 | endfunction
1680 | 
1681 | function! s:stacktrace_list(all) abort
1682 |   let response = fireplace#message({'op': 'stacktrace'}, v:t_dict)
1683 |   if !has_key(response, 'stacktrace')
1684 |     throw 'Fireplace: no error available'
1685 |   endif
1686 |   let path = fireplace#path()
1687 |   let qf = {
1688 |         \ 'title': response.class . ': ' . response.message,
1689 |         \ 'context': {'fireplace': response},
1690 |         \ 'items': []}
1691 |   for entry in response.stacktrace
1692 |     let flags = get(entry, 'flags', [])
1693 |     if !a:all && (index(flags, 'dup') != -1 || index(flags, 'repl') != -1 || index(flags, 'tooling') != -1)
1694 |       continue
1695 |     endif
1696 |     let item = {
1697 |           \ 'module': get(entry, 'var', entry.name),
1698 |           \ 'lnum': get(entry, 'line'),
1699 |           \ }
1700 |     if get(entry, 'file', '') =~# '^\%(NO_SOURCE_FILE\)\=$' || !item.lnum || !has_key(entry, 'class')
1701 |       let item.resource = ''
1702 |     else
1703 |       let item.resource = tr(entry.class, '.', '/') . '/' . entry.file
1704 |     endif
1705 |     let item.filename = fireplace#findresource(item.resource, path)
1706 |     if empty(item.filename) && !empty(get(entry, 'file-url', ''))
1707 |       let item.filename = substitute(substitute(entry['file-url'],
1708 |             \ '^jar:file:\([^!]*\)!/', '\=s:zipfile_url(submatch(1), "")', ''),
1709 |             \ '^file:', '', '')
1710 |     endif
1711 |     if has('patch-8.0.1782')
1712 |       let item.text = join(flags, ' ')
1713 |     else
1714 |       let item.text = item.module
1715 |     endif
1716 |     if index(flags, 'dup') == -1
1717 |       call add(qf.items, item)
1718 |     endif
1719 |   endfor
1720 |   return qf
1721 | endfunction
1722 | 
1723 | function! s:StacktraceCommand(bang, args) abort
1724 |   exe s:op_guard('stacktrace', 'cider-nrepl')
1725 |   try
1726 |     let list = s:stacktrace_list(a:bang)
1727 |     call setqflist(remove(list, 'items'))
1728 |     call setqflist([], 'a', list)
1729 |     return 'copen'
1730 |   catch /^Fireplace:/
1731 |     return 'echoerr ' . string(v:exception)
1732 |   endtry
1733 | endfunction
1734 | 
1735 | " If we call input() directly inside a try, and the user opens the command
1736 | " line window and tries to switch out of it (such as with ctrl-w), Vim will
1737 | " crash when the command line window closes.  Adding an indirect function call
1738 | " works around this.
1739 | function! s:actually_input(...) abort
1740 |   return call(function('input'), a:000)
1741 | endfunction
1742 | 
1743 | function! s:input(default) abort
1744 |   if !exists('g:FIREPLACE_HISTORY') || type(g:FIREPLACE_HISTORY) != type([])
1745 |     unlet! g:FIREPLACE_HISTORY
1746 |     let g:FIREPLACE_HISTORY = []
1747 |   endif
1748 |   try
1749 |     let s:input = bufnr('%')
1750 |     let s:oldhist = s:histswap(g:FIREPLACE_HISTORY)
1751 |     return s:actually_input(fireplace#ns().'=> ', a:default, 'customlist,fireplace#eval_complete')
1752 |   finally
1753 |     unlet! s:input
1754 |     if exists('s:oldhist')
1755 |       let g:FIREPLACE_HISTORY = s:histswap(s:oldhist)
1756 |     endif
1757 |   endtry
1758 | endfunction
1759 | 
1760 | function! s:inputclose() abort
1761 |   let l = substitute(getcmdline(), '"\%(\\.\|[^"]\)*"\|\\.', '', 'g')
1762 |   let open = len(substitute(l, '[^(]', '', 'g'))
1763 |   let close = len(substitute(l, '[^)]', '', 'g'))
1764 |   if open - close == 1
1765 |     return ")\<CR>"
1766 |   else
1767 |     return ")"
1768 |   endif
1769 | endfunction
1770 | 
1771 | function! s:inputeval() abort
1772 |   let input = s:input('')
1773 |   redraw
1774 |   if input !=# ''
1775 |     call fireplace#echo_session_eval(input)
1776 |   endif
1777 |   return ''
1778 | endfunction
1779 | 
1780 | function! s:recall() abort
1781 |   try
1782 |     cnoremap <expr> ) <SID>inputclose()
1783 |     let input = s:input('(')
1784 |     if input =~# '^(\=$'
1785 |       return ''
1786 |     else
1787 |       return join(fireplace#eval(input), ' ')
1788 |     endif
1789 |   catch /^Clojure:/
1790 |     return ''
1791 |   finally
1792 |     silent! cunmap )
1793 |   endtry
1794 | endfunction
1795 | 
1796 | function! s:histswap(list) abort
1797 |   let old = []
1798 |   for i in range(1, histnr('@') * (histnr('@') > 0))
1799 |     call extend(old, [histget('@', i)])
1800 |   endfor
1801 |   call histdel('@')
1802 |   for entry in a:list
1803 |     call histadd('@', entry)
1804 |   endfor
1805 |   return old
1806 | endfunction
1807 | 
1808 | nnoremap <silent> <Plug>FireplacePrintLast :exe <SID>print_last()<CR>
1809 | nnoremap <silent> <Plug>FireplacePrint  :<C-U>set opfunc=<SID>printop<CR>g@
1810 | xnoremap <silent> <Plug>FireplacePrint  :<C-U>call <SID>printop(visualmode())<CR>
1811 | nnoremap <silent> <Plug>FireplaceCountPrint  :<C-U>call <SID>printop(v:count)<CR>
1812 | 
1813 | nnoremap <silent> <Plug>FireplaceFilter :<C-U>set opfunc=<SID>filterop<CR>g@
1814 | xnoremap <silent> <Plug>FireplaceFilter :<C-U>call <SID>filterop(visualmode())<CR>
1815 | nnoremap <silent> <Plug>FireplaceCountFilter :<C-U>call <SID>filterop(v:count)<CR>
1816 | 
1817 | nnoremap <silent> <Plug>FireplaceMacroExpand  :<C-U>set opfunc=<SID>macroexpandop<CR>g@
1818 | xnoremap <silent> <Plug>FireplaceMacroExpand  :<C-U>call <SID>macroexpandop(visualmode())<CR>
1819 | nnoremap <silent> <Plug>FireplaceCountMacroExpand  :<C-U>call <SID>macroexpandop(v:count)<CR>
1820 | nnoremap <silent> <Plug>Fireplace1MacroExpand :<C-U>set opfunc=<SID>macroexpand1op<CR>g@
1821 | xnoremap <silent> <Plug>Fireplace1MacroExpand :<C-U>call <SID>macroexpand1op(visualmode())<CR>
1822 | nnoremap <silent> <Plug>FireplaceCount1MacroExpand :<C-U>call <SID>macroexpand1op(v:count)<CR>
1823 | 
1824 | nnoremap <silent> <Plug>FireplaceEdit   :<C-U>set opfunc=<SID>editop<CR>g@
1825 | xnoremap <silent> <Plug>FireplaceEdit   :<C-U>call <SID>editop(visualmode())<CR>
1826 | nnoremap <silent> <Plug>FireplaceCountEdit :<C-U>call <SID>editop(v:count)<CR>
1827 | 
1828 | nnoremap          <Plug>FireplacePrompt :exe <SID>inputeval()<CR>
1829 | 
1830 | noremap!          <Plug>FireplaceRecall <C-R>=<SID>recall()<CR>
1831 | 
1832 | function! s:Last(bang, count) abort
1833 |   if len(s:history) < a:count
1834 |     return 'echoerr "History entry not found"'
1835 |   endif
1836 |   let history = s:qfhistory()
1837 |   let last = s:qfhistory()[a:count-1]
1838 |   execute 'pedit '.last.filename
1839 |   if !&previewwindow
1840 |     let nr = winnr()
1841 |     wincmd p
1842 |     wincmd P
1843 |   endif
1844 |   call setloclist(0, history)
1845 |   silent exe 'llast '.(len(history)-a:count+1)
1846 |   if exists('nr') && a:bang
1847 |     wincmd p
1848 |     exe nr.'wincmd w'
1849 |   endif
1850 |   return ''
1851 | endfunction
1852 | 
1853 | function! s:set_up_eval() abort
1854 |   command! -buffer -bang -range -nargs=? -complete=customlist,fireplace#eval_complete Eval :exe s:Eval('platform', <line1>, <count>, +'<range>', <bang>0, <q-mods>, <q-args>)
1855 |   command! -buffer -bang -bar -count=1 Last exe s:Last(<bang>0, <count>)
1856 |   command! -buffer -bang -bar -nargs=* Stacktrace exe s:StacktraceCommand(<bang>0, [<f-args>])
1857 | 
1858 |   if get(g:, 'fireplace_no_maps') | return | endif
1859 | 
1860 |   call s:map('n', 'cp', '<Plug>FireplacePrint')
1861 |   call s:map('n', 'cpp', '<Plug>FireplaceCountPrint')
1862 | 
1863 |   call s:map('n', 'c!', '<Plug>FireplaceFilter')
1864 |   call s:map('n', 'c!!', '<Plug>FireplaceCountFilter')
1865 | 
1866 |   call s:map('n', 'cm', '<Plug>FireplaceMacroExpand')
1867 |   call s:map('n', 'cmm', '<Plug>FireplaceCountMacroExpand')
1868 |   call s:map('n', 'c1m', '<Plug>Fireplace1MacroExpand')
1869 |   call s:map('n', 'c1mm', '<Plug>FireplaceCount1MacroExpand')
1870 | 
1871 |   call s:map('n', 'cq', '<Plug>FireplaceEdit')
1872 |   call s:map('n', 'cqq', '<Plug>FireplaceCountEdit')
1873 | 
1874 |   call s:map('n', 'cqp', '<Plug>FireplacePrompt')
1875 |   call s:map('n', 'cqc', '<Plug>FireplacePrompt' . &cedit . 'i')
1876 | 
1877 |   call s:map('i', '<C-R>(', '<Plug>FireplaceRecall')
1878 |   call s:map('c', '<C-R>(', '<Plug>FireplaceRecall')
1879 |   call s:map('s', '<C-R>(', '<Plug>FireplaceRecall')
1880 | endfunction
1881 | 
1882 | function! s:set_up_historical() abort
1883 |   setlocal readonly nomodifiable
1884 |   call s:map('n', 'q', ':bdelete<CR>', '<silent>')
1885 | endfunction
1886 | 
1887 | function! s:cmdwinenter() abort
1888 |   setlocal filetype=clojure
1889 | endfunction
1890 | 
1891 | function! s:cmdwinleave() abort
1892 |   setlocal filetype< omnifunc<
1893 | endfunction
1894 | 
1895 | augroup fireplace_eval
1896 |   autocmd!
1897 |   autocmd BufReadPost * if has_key(s:qffiles, expand('<amatch>:p')) |
1898 |         \   call s:set_up_historical() |
1899 |         \ endif
1900 |   autocmd CmdWinEnter @ if exists('s:input') | call s:cmdwinenter() | endif
1901 |   autocmd CmdWinLeave @ if exists('s:input') | call s:cmdwinleave() | endif
1902 | augroup END
1903 | 
1904 | " Section: :Require
1905 | 
1906 | function! s:Require(bang, ns) abort
1907 |   if &autowrite || &autowriteall
1908 |     silent! wall
1909 |   endif
1910 |   if s:impl_ns() ==# 'cljs'
1911 |     let cmd = '(ns cljs.user (:require '.(a:ns ==# '' ? fireplace#ns() : a:ns).' :reload'.(a:bang ? '-all' : '').'))'
1912 |   else
1913 |     let cmd = '(' . s:impl_ns() . '.core/require '.s:qsym(a:ns ==# '' ? fireplace#ns() : a:ns).' :reload'.(a:bang ? '-all' : '').')'
1914 |   endif
1915 |   try
1916 |     call fireplace#echo_session_eval(cmd, {'ns': s:user_ns()})
1917 |     return ''
1918 |   catch /^Clojure:.*/
1919 |     return ''
1920 |   catch /^Fireplace:.*/
1921 |     return 'echoerr ' . string(v:exception)
1922 |   endtry
1923 | endfunction
1924 | 
1925 | function! s:set_up_require() abort
1926 |   command! -buffer -bar -bang -complete=customlist,fireplace#ns_complete -nargs=? Require :exe s:Require(<bang>0, <q-args>)
1927 | 
1928 |   call s:map('n', 'cpr', ":<C-R>=<SID>impl_ns() ==# 'cljs' ? 'Require' : 'RunTests'<CR><CR>", '<silent>')
1929 | endfunction
1930 | 
1931 | " Section: Go to source
1932 | 
1933 | function! fireplace#info(symbol) abort
1934 |   if fireplace#op_available('info')
1935 |     let response = fireplace#message({'op': 'info', 'symbol': a:symbol}, v:t_dict)
1936 |     if type(get(response, 'value')) == type({})
1937 |       return response.value
1938 |     elseif has_key(response, 'file') || has_key(response, 'doc')
1939 |       return response
1940 |     endif
1941 |   endif
1942 | 
1943 |   let sym = s:qsym(a:symbol)
1944 |   let cmd =
1945 |         \ '(clojure.core/cond'
1946 |         \ . '(clojure.core/not (clojure.core/symbol? ' . sym . '))'
1947 |         \ . '{}'
1948 |         \ . '(clojure.core/special-symbol? ' . sym . ')'
1949 |         \ . "(clojure.core/if-let [m (#'clojure.repl/special-doc " . sym . ")]"
1950 |         \ .   ' {:name (:name m)'
1951 |         \ .    ' :special-form "true"'
1952 |         \ .    ' :doc (:doc m)'
1953 |         \ .    ' :url (:url m)'
1954 |         \ .    ' :forms-str (clojure.core/str "  " (:forms m))}'
1955 |         \ .   ' {})'
1956 |         \ . '(clojure.core/find-ns ' . sym . ')'
1957 |         \ . "(clojure.core/if-let [m (#'clojure.repl/namespace-doc (clojure.core/find-ns " . sym . "))]"
1958 |         \ .   ' {:ns (:name m)'
1959 |         \ .   '  :doc (:doc m)}'
1960 |         \ .   ' {})'
1961 |         \ . ':else'
1962 |         \ . '(clojure.core/if-let [m (clojure.core/meta (clojure.core/resolve ' . sym .'))]'
1963 |         \ .   ' {:name (:name m)'
1964 |         \ .    ' :ns (:ns m)'
1965 |         \ .    ' :macro (clojure.core/when (:macro m) true)'
1966 |         \ .    ' :resource (:file m)'
1967 |         \ .    ' :line (:line m)'
1968 |         \ .    ' :doc (:doc m)'
1969 |         \ .    ' :arglists-str (clojure.core/str (:arglists m))}'
1970 |         \ .   ' {})'
1971 |         \ . ' )'
1972 |   return fireplace#query(cmd)
1973 | endfunction
1974 | 
1975 | function! fireplace#source(symbol) abort
1976 |   let info = fireplace#info(a:symbol)
1977 | 
1978 |   let file = ''
1979 |   if !empty(get(info, 'resource'))
1980 |     let file = fireplace#findresource(info.resource)
1981 |   endif
1982 | 
1983 |   if empty(file)
1984 |     if get(info, 'file', '') =~# '^file:'
1985 |       let file = substitute(strpart(info.file, 5), '/', s:slash(), 'g')
1986 |     elseif get(info, 'file', '') =~# '^jar:file:'
1987 |       let zip = matchstr(info.file, '^jar:file:\zs.*\ze!')
1988 |       let file = s:zipfile_url(zip, info.resource)
1989 |     else
1990 |       let file = get(info, 'file', '')
1991 |     endif
1992 |   endif
1993 | 
1994 |   if !empty(file) && !empty(get(info, 'line', ''))
1995 |     return '+' . info.line . ' ' . fnameescape(file)
1996 |   endif
1997 |   return ''
1998 | endfunction
1999 | 
2000 | function! fireplace#location(keyword) abort
2001 |   if a:keyword =~# '^\k\+[/.]$'
2002 |     return fireplace#findfile(a:keyword[0: -2])
2003 |   elseif a:keyword =~# '^\k\+\.[^/.]\+$'
2004 |     return fireplace#findfile(a:keyword)
2005 |   else
2006 |     return fireplace#source(a:keyword)
2007 |   endif
2008 | endfunction
2009 | 
2010 | function! s:Edit(cmd, keyword) abort
2011 |   try
2012 |     let location = fireplace#location(a:keyword)
2013 |   catch /^Clojure:/
2014 |     return ''
2015 |   endtry
2016 |   if location !=# ''
2017 |     if matchstr(location, '^+\d\+ \zs.*') ==# fnameescape(expand('%:p')) && a:cmd ==# 'edit'
2018 |       normal! m'
2019 |       return matchstr(location, '\d\+')
2020 |     else
2021 |       return substitute(a:cmd, '^\%(<mods>\)\= ', '', '') . ' ' . location .
2022 |             \ '|let &l:path = ' . string(&l:path)
2023 |     endif
2024 |   endif
2025 |   let v:errmsg = "Couldn't find source for ".a:keyword
2026 |   return 'echoerr v:errmsg'
2027 | endfunction
2028 | 
2029 | nnoremap <silent> <Plug>FireplaceDjump :<C-U>exe <SID>Edit('edit', <SID>cword())<CR>
2030 | nnoremap <silent> <Plug>FireplaceDsplit :<C-U>exe <SID>Edit('split', <SID>cword())<CR>
2031 | nnoremap <silent> <Plug>FireplaceDtabjump :<C-U>exe <SID>Edit('tabedit', <SID>cword())<CR>
2032 | 
2033 | if !exists('s:tag_file')
2034 |   let s:tag_file = tempname() . '.fireplace.tags'
2035 | endif
2036 | 
2037 | function! s:Tag(cmd, keyword) abort
2038 |   try
2039 |     let location = fireplace#source(a:keyword)
2040 |   catch /^Clojure:/
2041 |     return ''
2042 |   endtry
2043 |   let after = ''
2044 |   let tag_contents = [
2045 |         \ "!_TAG_FILE_FORMAT\t2\t/extended format; --format=1 will not append ;\" to lines/",
2046 |         \ "!_TAG_FILE_SORTED\t1\t/0=unsorted, 1=sorted, 2=foldcase/",
2047 |         \ "!_TAG_PROGRAM_NAME\tfireplace.vim\t//"]
2048 |   if len(location)
2049 |     let line = matchstr(location, '^+\zs\d\+')
2050 |     let file = expand(matchstr(location, ' \zs.*'))
2051 |     if file =~# '^zipfile:.*::'
2052 |       let after = '|keepalt keepjumps edit +' . line . ' ' . fnameescape(file)
2053 |       let line = 1
2054 |       let file = matchstr(file, 'zipfile:\%([\/][\/]\)\=\zs.\{-\}\ze::')
2055 |     endif
2056 |     call add(tag_contents, a:keyword . "\t" . file . "\t" . line . ";\"\tlanguage:Clojure")
2057 |   endif
2058 |   call writefile(tag_contents, s:tag_file)
2059 |   let old_tags = &l:tags
2060 |   let &l:tags = escape(s:tag_file, ' ,')
2061 |   return a:cmd . ' ' . a:keyword . '|call setbufvar(' . bufnr('') . ', "&tags", ' . string(old_tags). ')' . after
2062 | endfunction
2063 | 
2064 | nnoremap <silent> <Plug>FireplaceTag :<C-U>exe <SID>Tag('tag', <SID>cword())<CR>
2065 | nnoremap <silent> <Plug>FireplaceTjump :<C-U>exe <SID>Tag('tjump', <SID>cword())<CR>
2066 | nnoremap <silent> <Plug>FireplaceTselect :<C-U>exe <SID>Tag('tselect', <SID>cword())<CR>
2067 | nnoremap <silent> <Plug>FireplaceStag :<C-U>exe <SID>Tag('stag', <SID>cword())<CR>
2068 | nnoremap <silent> <Plug>FireplaceStjump :<C-U>exe <SID>Tag('stjump', <SID>cword())<CR>
2069 | nnoremap <silent> <Plug>FireplaceStselect :<C-U>exe <SID>Tag('stselect', <SID>cword())<CR>
2070 | 
2071 | function! s:set_up_source() abort
2072 |   setlocal define=^\\s*(def\\w*
2073 |   command! -bar -buffer -nargs=1 -complete=customlist,fireplace#eval_complete Djump  :exe s:Edit('edit', <q-args>)
2074 |   command! -bar -buffer -nargs=1 -complete=customlist,fireplace#eval_complete Dsplit :exe s:Edit('<mods> split', <q-args>)
2075 | 
2076 |   call s:map('n', '[<C-D>',     '<Plug>FireplaceDjump')
2077 |   call s:map('n', ']<C-D>',     '<Plug>FireplaceDjump')
2078 |   call s:map('n', '<C-W><C-D>', '<Plug>FireplaceDsplit')
2079 |   call s:map('n', '<C-W>d',     '<Plug>FireplaceDsplit')
2080 |   call s:map('n', '<C-W>gd',    '<Plug>FireplaceDtabjump')
2081 | 
2082 |   call s:map('n', '<C-]>',         '<Plug>FireplaceTag')
2083 |   call s:map('n', 'g<LeftMouse>',  '<Plug>FireplaceTag')
2084 |   call s:map('n', '<C LeftMouse>', '<Plug>FireplaceTag')
2085 |   call s:map('n', 'g]',            '<Plug>FireplaceTselect')
2086 |   call s:map('n', 'g<C-]>',        '<Plug>FireplaceTjump')
2087 |   call s:map('n', '<C-W>]',        '<Plug>FireplaceStag')
2088 |   call s:map('n', '<C-W><C-]>',    '<Plug>FireplaceStag')
2089 |   call s:map('n', '<C-W>g]',       '<Plug>FireplaceStselect')
2090 |   call s:map('n', '<C-W>g<C-]>',   '<Plug>FireplaceStjump')
2091 | endfunction
2092 | 
2093 | " Section: Go to file
2094 | 
2095 | function! fireplace#findfile(path) abort
2096 |   let path = a:path
2097 |   if a:path !~# '/'
2098 |     let path = tr(a:path, '.-', '/_')
2099 |   else
2100 |     let path = substitute(a:path, '^/', '', '')
2101 |   endif
2102 |   let resource = fireplace#findresource(path, fireplace#path(), 0, &suffixesadd)
2103 |   if !empty(resource)
2104 |     return resource
2105 |   elseif fnamemodify(a:path, ':p') ==# a:path && filereadable(a:path)
2106 |     return path
2107 |   elseif a:path[0] !=# '/' && filereadable(expand('%:h') . '/' . path)
2108 |     return expand('%:h') . '/' . path
2109 |   endif
2110 |   return ''
2111 | endfunction
2112 | 
2113 | let s:iskeyword = '[[:alnum:]_=?!#$%&*+|./<>:''-]'
2114 | let s:token = '^\%(#"\%(\\\@<!\%(\\\\\)*\\"\|[^"]\)*"\|"\%(\\.\|[^"]\)*"\|[[:space:],]\+\|\%(;\|#!\)[^'."\n".']*\|\~@\|#[[:punct:]]\|''\@!'.s:iskeyword.'\+\|\\\%(space\|tab\|newline\|return\|.\)\|.\)'
2115 | function! s:read_token(str, pos) abort
2116 |   let pos = a:pos
2117 |   let match = ' '
2118 |   while match =~# '^[[:space:],;]'
2119 |     let match = matchstr(a:str, s:token, pos)
2120 |     let pos += len(match)
2121 |   endwhile
2122 |   if empty(match)
2123 |     throw 'Fireplace: Clojure parse error'
2124 |   endif
2125 |   return [match, pos]
2126 | endfunction
2127 | 
2128 | function! s:read(str, pos) abort
2129 |   let [token, pos] = s:read_token(a:str, a:pos)
2130 |   if token =~# '^#\=[[{(]'
2131 |     let list = []
2132 |     while index([')', ']', '}', ''], get(list, -1)) < 0
2133 |       unlet token
2134 |       let [token, pos] = s:read(a:str, pos)
2135 |       call add(list, token)
2136 |     endwhile
2137 |     call remove(list, -1)
2138 |     return [list, pos]
2139 |   elseif token ==# '#_'
2140 |     let pos = s:read(a:str, pos)[1]
2141 |     return s:read(a:str, pos)
2142 |   else
2143 |     return [token, pos]
2144 |   endif
2145 | endfunction
2146 | 
2147 | function! s:ns(...) abort
2148 |   let buffer = a:0 ? a:1 : s:buf()
2149 |   let head = getbufline(buffer, 1, 1000)
2150 |   let blank = '^\s*\%(;.*\)\=$'
2151 |   call filter(head, 'v:val !~# blank')
2152 |   let lines = join(head, "\n")
2153 |   let match = matchstr(lines, '\C^(\s*ns\s\+.*')
2154 |   if len(match)
2155 |     try
2156 |       return s:read(match, 0)[0]
2157 |     catch /^Fireplace: Clojure parse error$/
2158 |     endtry
2159 |   endif
2160 |   return []
2161 | endfunction
2162 | 
2163 | function! fireplace#resolve_alias(name) abort
2164 |   let _ = {}
2165 |   for refs in filter(copy(s:ns()), 'type(v:val) == type([])')
2166 |     if a:name =~# '^\u' && get(refs, 0) is# ':import'
2167 |       for _.ref in refs
2168 |         if type(_.ref) == type([]) && index(_.ref, a:name) > 0
2169 |           return _.ref[0] . '.' . a:name
2170 |         elseif type(_.ref) == type('') && _.ref =~# '\.'.a:name.'$'
2171 |           return _.ref
2172 |         endif
2173 |       endfor
2174 |     endif
2175 |     if get(refs, 0) is# ':require'
2176 |       for _.ref in refs
2177 |         if type(_.ref) == type([])
2178 |           let i = index(_.ref, ':as')
2179 |           if i > 0 && get(_.ref, i+1) ==# a:name
2180 |             return _.ref[0]
2181 |           endif
2182 |           for nref in filter(copy(_.ref), 'type(v:val) == type([])')
2183 |             let i = index(nref, ':as')
2184 |             if i > 0 && get(nref, i+1) ==# a:name
2185 |               return _.ref[0].'.'.nref[0]
2186 |             endif
2187 |           endfor
2188 |         endif
2189 |       endfor
2190 |     endif
2191 |   endfor
2192 |   return a:name
2193 | endfunction
2194 | 
2195 | function! fireplace#cfile() abort
2196 |   let isfname = &isfname
2197 |   try
2198 |     set isfname+=',*
2199 |     let file = substitute(expand('<cfile>'), "^''*", '', '')
2200 |   finally
2201 |     let isfname = &isfname
2202 |   endtry
2203 |   if file =~# '^\w[[:alnum:]_/]*$' &&
2204 |         \ synIDattr(synID(line("."),col("."),1),"name") =~# 'String'
2205 |     let file = substitute(expand('%:p'), '[^\/:]*$', '', '').file
2206 |   elseif file =~# '^[^/]*/[^/.]*$' && file =~# '^\%(\k\|''\)\+$'
2207 |     let [file, jump] = split(file, "/")
2208 |     let file = fireplace#resolve_alias(file)
2209 |     if file !~# '\.' && fireplace#op_available('info')
2210 |       let res = fireplace#message({'op': 'info', 'symbol': file}, v:t_dict)
2211 |       let file = get(res, 'ns', file)
2212 |     endif
2213 |     let file = tr(file, '.-', '/_')
2214 |   elseif file =~# '^\w[[:alnum:].-]*''\=$'
2215 |     let file = tr(fireplace#resolve_alias(file), '.-', '/_')
2216 |   endif
2217 |   if exists('jump')
2218 |     return '+sil!dj\ ' . jump . ' ' . fnameescape(file)
2219 |   else
2220 |     return fnameescape(file)
2221 |   endif
2222 | endfunction
2223 | 
2224 | function! s:Find(find, edit) abort
2225 |   let cfile = fireplace#cfile()
2226 |   let prefix = matchstr(cfile, '^\%(+\%(\\.\|\S\)*\s\+\)')
2227 |   let file = fireplace#findfile(expand(strpart(cfile, len(prefix))))
2228 |   if file =~# '^zipfile:'
2229 |     let setpath = 'let\ &l:path=getbufvar('.bufnr('').",'&path')"
2230 |     if prefix =~# '^+[^+]'
2231 |       let prefix = substitute(prefix, '+', '\="+".setpath."\\|"', '')
2232 |     else
2233 |       let prefix = '+'.setpath.' '.prefix
2234 |     endif
2235 |   endif
2236 |   if len(file)
2237 |     return (len(a:edit) ? a:edit . ' ' : '') . prefix . fnameescape(file)
2238 |   else
2239 |     return len(a:find) ? a:find . ' ' . cfile : "\<C-R>\<C-P>"
2240 |   endif
2241 | endfunction
2242 | 
2243 | nnoremap <silent> <Plug>FireplaceEditFile    :<C-U>exe <SID>Find('find','edit')<CR>
2244 | nnoremap <silent> <Plug>FireplaceSplitFile   :<C-U>exe <SID>Find('sfind','split')<CR>
2245 | nnoremap <silent> <Plug>FireplaceTabeditFile :<C-U>exe <SID>Find('tabfind','tabedit')<CR>
2246 | 
2247 | function! s:set_up_go_to_file() abort
2248 |   if expand('%:e') ==# 'cljs'
2249 |     setlocal suffixesadd=.cljs,.cljc,.cljx,.clj,.java
2250 |   else
2251 |     setlocal suffixesadd=.clj,.cljc,.cljx,.cljs,.java
2252 |   endif
2253 | 
2254 |   cmap <buffer><script><expr> <Plug><cfile> substitute(fireplace#cfile(),'^$',"\022\006",'')
2255 |   cmap <buffer><script><expr> <Plug><cpath> <SID>Find('','')
2256 |   if get(g:, 'fireplace_no_maps') | return | endif
2257 |   call s:map('c', '<C-R><C-F>', '<Plug><cfile>')
2258 |   call s:map('c', '<C-R><C-P>', '<Plug><cpath>')
2259 |   call s:map('n', 'gf',         '<Plug>FireplaceEditFile',    '<unique>')
2260 |   call s:map('n', '<C-W>f',     '<Plug>FireplaceSplitFile',   '<unique>')
2261 |   call s:map('n', '<C-W><C-F>', '<Plug>FireplaceSplitFile',   '<unique>')
2262 |   call s:map('n', '<C-W>gf',    '<Plug>FireplaceTabeditFile', '<unique>')
2263 | endfunction
2264 | 
2265 | " Section: Spec
2266 | 
2267 | function! fireplace#qualify_keyword(kw) abort
2268 |   if a:kw =~# '^::.\+/'
2269 |     let kw = ':' . fireplace#resolve_alias(matchstr(a:kw, '^::\zs[^/]\+')) . matchstr(a:kw, '/.*')
2270 |   elseif a:kw =~# '^::'
2271 |     let kw = ':' . fireplace#ns() . '/' . strpart(a:kw, 2)
2272 |   else
2273 |     let kw = a:kw
2274 |   endif
2275 |   return kw
2276 | endfunction
2277 | 
2278 | function! s:SpecForm(kw) abort
2279 |   let op = "spec-form"
2280 |   exe s:op_guard(op, 'cider-nrepl')
2281 |   try
2282 |     let symbol = fireplace#qualify_keyword(a:kw)
2283 |     let response = fireplace#message({'op': op, 'spec-name': symbol}, v:t_dict)
2284 |     if !empty(get(response, op))
2285 |       echo s:pr(get(response, op))
2286 |     endif
2287 |   catch /^Fireplace:/
2288 |     return 'echoerr ' . string(v:exception)
2289 |   endtry
2290 |   return ''
2291 | endfunction
2292 | 
2293 | function! s:SpecExample(kw) abort
2294 |   let op = "spec-example"
2295 |   exe s:op_guard(op, 'cider-nrepl')
2296 |   try
2297 |     let symbol = fireplace#qualify_keyword(a:kw)
2298 |     let response = fireplace#message({'op': op, 'spec-name': symbol}, v:t_dict)
2299 |     echo get(response, op, '')
2300 |   catch /^Fireplace:/
2301 |     return 'echoerr ' . string(v:exception)
2302 |   endtry
2303 |   return ''
2304 | endfunction
2305 | 
2306 | function! s:set_up_spec() abort
2307 |   command! -buffer -bar -nargs=1 -complete=customlist,fireplace#eval_complete SpecForm    :exe s:SpecForm(<q-args>)
2308 |   command! -buffer -bar -nargs=1 -complete=customlist,fireplace#eval_complete SpecExample :exe s:SpecExample(<q-args>)
2309 | endfunction
2310 | 
2311 | " Section: Formatting
2312 | 
2313 | function! fireplace#format(lnum, count, char) abort
2314 |   if mode() =~# '[iR]' || getline(a:lnum) =~# '^\s*;'
2315 |     return -1
2316 |   endif
2317 |   let reg_save = @@
2318 |   let sel_save = &selection
2319 |   let cb_save = &clipboard
2320 |   try
2321 |     set selection=inclusive clipboard-=unnamed clipboard-=unnamedplus
2322 |     silent exe "normal! " . string(a:lnum) . "ggV" . string(a:count-1) . "jy"
2323 |     let code = @@
2324 |     let response = fireplace#message({'op': 'format-code', 'code': code}, v:t_dict)
2325 |     if !empty(get(response, 'formatted-code'))
2326 |       let @@ = get(response, 'formatted-code')
2327 |       if @@ !~# '^\n*$' && @@ !=# code
2328 |         normal! gvp
2329 |       endif
2330 |     endif
2331 |   finally
2332 |     let @@ = reg_save
2333 |     let &selection = sel_save
2334 |     let &clipboard = cb_save
2335 |   endtry
2336 | endfunction
2337 | 
2338 | " Section: Documentation
2339 | 
2340 | function! s:Lookup(ns, macro, arg) abort
2341 |   try
2342 |     let response = fireplace#client().Eval('('.a:ns.'/'.a:macro.' '.a:arg.')', {'session': '', 'ns': v:true})
2343 |     call s:output_response(response)
2344 |   catch /^Clojure:/
2345 |   catch /.*/
2346 |     echohl ErrorMSG
2347 |     echo v:exception
2348 |     echohl None
2349 |   endtry
2350 |   return ''
2351 | endfunction
2352 | 
2353 | function! s:inputlist(label, entries) abort
2354 |   let choices = [a:label]
2355 |   for i in range(len(a:entries))
2356 |     let choices += [printf('%2d. %s', i+1, a:entries[i])]
2357 |   endfor
2358 |   let choice = inputlist(choices)
2359 |   if choice
2360 |     return a:entries[choice-1]
2361 |   else
2362 |     return ''
2363 |   endif
2364 | endfunction
2365 | 
2366 | function! s:Doc(symbol) abort
2367 |   if s:repl_ns() ==# 'clojure.repl'
2368 |     return s:Lookup(s:repl_ns(), 'doc', a:symbol)
2369 |   endif
2370 | 
2371 |   let info = fireplace#info(a:symbol)
2372 |   echo '-------------------------'
2373 |   if has_key(info, 'ns') && has_key(info, 'name')
2374 |     echo info.ns . '/' . info.name
2375 |   elseif has_key(info, 'ns')
2376 |     echo info.ns
2377 |   elseif has_key(info, 'name')
2378 |     echo info.name
2379 |   endif
2380 | 
2381 |   if get(info, 'forms-str', 'nil') !=# 'nil'
2382 |     echo info['forms-str']
2383 |   endif
2384 | 
2385 |   if get(info, 'arglists-str', '') !=# ''
2386 |     echo info['arglists-str']
2387 |   endif
2388 | 
2389 |   if get(info, 'special-form', 'nil') !=# 'nil'
2390 |     echo "Special Form"
2391 | 
2392 |     if has_key(info, 'url')
2393 |       if !empty(get(info, 'url', ''))
2394 |         echo '  Please see http://clojure.org/' . info.url
2395 |       else
2396 |         echo '  Please see http://clojure.org/special_forms#' . info.name
2397 |       endif
2398 |     endif
2399 | 
2400 |   elseif get(info, 'macro', '') !=# ''
2401 |     echo "Macro"
2402 |   endif
2403 | 
2404 |   if !empty(get(info, 'doc', ''))
2405 |     echo '  ' . info.doc
2406 |   endif
2407 | 
2408 |   return ''
2409 | endfunction
2410 | 
2411 | function! s:K() abort
2412 |   let word = s:cword()
2413 |   let java_candidate = matchstr(word, '^\%(\w\+\.\)*\u\l[[:alnum:]$]*\ze\%(\.\|\/\w\+\)\=$')
2414 |   if java_candidate !=# ''
2415 |     return 'Javadoc '.java_candidate
2416 |   elseif word =~# '^:'
2417 |     return 'SpecForm '.word
2418 |   else
2419 |     return 'Doc '.word
2420 |   endif
2421 | endfunction
2422 | 
2423 | nnoremap <Plug>FireplaceK :<C-R>=<SID>K()<CR><CR>
2424 | nnoremap <Plug>FireplaceSource :Source <C-R>=<SID>cword()<CR><CR>
2425 | 
2426 | function! s:set_up_doc() abort
2427 |   command! -buffer -nargs=1 FindDoc :exe s:Lookup(s:repl_ns(), 'find-doc', printf('#"%s"', <q-args>))
2428 |   command! -buffer -bar -nargs=1 Javadoc :exe s:Lookup('clojure.java.javadoc', 'javadoc', <q-args>)
2429 |   command! -buffer -bar -nargs=1 -complete=customlist,fireplace#eval_complete Doc     :exe s:Doc(<q-args>)
2430 |   command! -buffer -bar -nargs=1 -complete=customlist,fireplace#eval_complete Source  :exe s:Lookup(s:repl_ns(), 'source', <q-args>)
2431 |   command! -buffer -bar -nargs=1 -complete=customlist,fireplace#eval_complete Dlist   :exe s:Lookup(s:repl_ns(), 'source', <q-args>)
2432 |   command! -buffer -bar -nargs=1 -complete=customlist,fireplace#eval_complete Dsearch :exe s:Lookup(s:repl_ns(), 'source', <q-args>)
2433 |   setlocal keywordprg=:Doc
2434 | 
2435 |   call s:map('n', 'K', '<Plug>FireplaceK', '<unique>')
2436 |   call s:map('n', '[D', '<Plug>FireplaceSource')
2437 |   call s:map('n', ']D', '<Plug>FireplaceSource')
2438 |   call s:map('n', '[d', '<Plug>FireplaceSource', '<unique>')
2439 |   call s:map('n', ']d', '<Plug>FireplaceSource', '<unique>')
2440 | endfunction
2441 | 
2442 | " Section: Tests
2443 | 
2444 | function! s:capture_test_run(expr, pre, bang) abort
2445 |   let expr = '(try'
2446 |         \ . ' ' . a:pre
2447 |         \ . ' (clojure.core/require ''clojure.test)'
2448 |         \ . ' (clojure.core/binding [clojure.test/report (fn [m]'
2449 |         \ .  ' (clojure.core/case (:type m)'
2450 |         \ .    ' (:fail :error)'
2451 |         \ .    ' (clojure.core/let [{file :file line :line test :name} (clojure.core/meta (clojure.core/last clojure.test/*testing-vars*))]'
2452 |         \ .      ' (clojure.test/with-test-out'
2453 |         \ .        ' (clojure.test/inc-report-counter (:type m))'
2454 |         \ .        ' (clojure.core/println (clojure.string/join "\t" [file line (clojure.core/name (:type m)) test]))'
2455 |         \ .        ' (clojure.core/when (clojure.core/seq clojure.test/*testing-contexts*) (clojure.core/println (clojure.test/testing-contexts-str)))'
2456 |         \ .        ' (clojure.core/when-let [message (:message m)] (clojure.core/println message))'
2457 |         \ .        ' (clojure.core/println "expected:" (clojure.core/pr-str (:expected m)))'
2458 |         \ .        ' (clojure.core/println "  actual:" (clojure.core/pr-str (:actual m)))))'
2459 |         \ .    ' ((.getRawRoot #''clojure.test/report) m)))]'
2460 |         \ . ' ' . a:expr . ')'
2461 |         \ . ' (catch Exception e'
2462 |         \ . '   (clojure.core/println (clojure.core/str e))'
2463 |         \ . '   (clojure.core/println (clojure.string/join "\n" (.getStackTrace e)))))'
2464 |   call setqflist([], ' ', {'title': a:expr})
2465 |   echo 'Started: ' . a:expr
2466 |   call fireplace#message({'op': 'eval', 'code': expr, 'session': 0},
2467 |         \ function('s:handle_test_response', [[], get(getqflist({'id': 0}), 'id'), fireplace#path(), a:expr, a:bang]))
2468 | endfunction
2469 | 
2470 | function! s:handle_test_response(buffer, id, path, expr, bang, message) abort
2471 |   let str = get(a:message, 'out', '') . get(a:message, 'err', '')
2472 |   if empty(a:buffer)
2473 |     let str = substitute(str, "^\r\\=\n", "", "")
2474 |     call add(a:buffer, '')
2475 |   endif
2476 |   let lines = split(a:buffer[0] . str, "\r\\=\n", 1)
2477 |   if !has_key(a:message, 'status') || empty(lines[-1])
2478 |     let a:buffer[0] = remove(lines, -1)
2479 |   else
2480 |     let a:buffer[0] = ''
2481 |   endif
2482 |   let items = []
2483 |   for line in lines
2484 |     if line =~# '\t.*\t.*\t'
2485 |       let item = {'text': line}
2486 |       let [resource, lnum, type, name] = split(line, "\t", 1)
2487 |       let item.lnum = lnum
2488 |       let item.type = (type ==# 'fail' ? 'W' : 'E')
2489 |       let item.text = name
2490 |       if resource ==# 'NO_SOURCE_FILE'
2491 |         let resource = ''
2492 |         let item.lnum = 0
2493 |       endif
2494 |       let item.filename = fireplace#findresource(resource, a:path)
2495 |       if empty(item.filename)
2496 |         let item.lnum = 0
2497 |       endif
2498 |     else
2499 |       let item = s:qfmassage(line, a:path)
2500 |     endif
2501 |     call add(items, item)
2502 |   endfor
2503 |   if a:id
2504 |     call setqflist([], 'a', {'id': a:id, 'items': items})
2505 |   else
2506 |     call setqflist(items, 'a')
2507 |   endif
2508 |   if has_key(a:message, 'status')
2509 |     if !a:bang && get(getqflist({'id': 0}), 'id') ==# a:id
2510 |       let my_winid = win_getid()
2511 |       botright cwindow
2512 |       if my_winid !=# win_getid()
2513 |         call win_gotoid(my_winid)
2514 |       endif
2515 |     endif
2516 |     let list = a:id ? getqflist({'id': a:id, 'items': 1}).items : getqflist()
2517 |     redraw
2518 |     if empty(filter(list, 'v:val.valid'))
2519 |       echo 'Success: ' . a:expr
2520 |     else
2521 |       echo 'Failure: ' . a:expr
2522 |     endif
2523 |   endif
2524 | endfunction
2525 | 
2526 | function! s:RunTests(bang, count, ...) abort
2527 |   if &autowrite || &autowriteall
2528 |     silent! wall
2529 |   endif
2530 |   if a:count < 0
2531 |     let pre = ''
2532 |     if a:0
2533 |       let expr = ['(clojure.test/run-all-tests #"'.join(a:000, '|').'")']
2534 |     else
2535 |       let expr = ['(clojure.test/run-all-tests)']
2536 |     endif
2537 |   else
2538 |     if a:0 && a:000 !=# [fireplace#ns()]
2539 |       let args = a:000
2540 |     else
2541 |       let args = [fireplace#ns()]
2542 |       if a:count
2543 |         let pattern = '^\s*(\%(\h\k*/\)\=def\k*\s\+\%(\^:\h\k*\s\+\)*\(\h\k*\)'
2544 |         let line = search(pattern, 'bcWn')
2545 |         if line
2546 |           let args[0] .= '/' . matchlist(getline(line), pattern)[1]
2547 |         endif
2548 |       endif
2549 |     endif
2550 |     let reqs = map(copy(args), '"''".v:val')
2551 |     let pre = '(clojure.core/require '.substitute(join(reqs, ' '), '/\k\+', '', 'g').' :reload) '
2552 |     let expr = []
2553 |     let vars = filter(copy(reqs), 'v:val =~# "/"')
2554 |     let nses = filter(copy(reqs), 'v:val !~# "/"')
2555 |     if len(vars) == 1
2556 |       call add(expr, '(clojure.test/test-vars [#' . vars[0] . '])')
2557 |     elseif !empty(vars)
2558 |       call add(expr, join(['(clojure.test/test-vars'] + map(vars, '"#".v:val'), ' ').')')
2559 |     endif
2560 |     if !empty(nses)
2561 |       call add(expr, join(['(clojure.test/run-tests'] + nses, ' ').')')
2562 |     endif
2563 |   endif
2564 |   call s:capture_test_run(join(expr, ' '), pre, a:bang)
2565 | endfunction
2566 | 
2567 | function! s:set_up_tests() abort
2568 |   command! -buffer -bar -bang -range=0 -nargs=*
2569 |         \ -complete=customlist,fireplace#ns_complete RunTests
2570 |         \ call s:RunTests(<bang>0, <line1> == 0 ? -1 : <count>, <f-args>)
2571 |   command! -buffer -bang -nargs=* RunAllTests
2572 |         \ call s:RunTests(<bang>0, -1, <f-args>)
2573 | endfunction
2574 | 
2575 | " Section: Activation
2576 | 
2577 | function! fireplace#activate() abort
2578 |   setlocal omnifunc=fireplace#omnicomplete
2579 |   setlocal formatexpr=fireplace#format(v:lnum,v:count,v:char)
2580 |   call s:set_up_connect()
2581 |   call s:set_up_eval()
2582 |   call s:set_up_require()
2583 |   call s:set_up_source()
2584 |   call s:set_up_go_to_file()
2585 |   call s:set_up_spec()
2586 |   call s:set_up_doc()
2587 |   call s:set_up_tests()
2588 |   if exists('#User#FireplaceActivate')
2589 |     doautocmd <nomodeline> User FireplaceActivate
2590 |   endif
2591 | endfunction
2592 | 


--------------------------------------------------------------------------------
/autoload/fireplace/session.vim:
--------------------------------------------------------------------------------
 1 | " Location:     autoload/session/fireplace.vim
 2 | 
 3 | if exists("g:autoloaded_fireplace_session")
 4 |   finish
 5 | endif
 6 | let g:autoloaded_fireplace_session = 1
 7 | 
 8 | function! s:function(name) abort
 9 |   return function(substitute(a:name,'^s:',matchstr(expand('<sfile>'), '.*\zs<SNR>\d\+_'),''))
10 | endfunction
11 | 
12 | function! fireplace#session#for(transport, ...) abort
13 |   let session = copy(s:session)
14 |   let session.callbacks = []
15 |   if a:0 > 1 && type(a:2) == v:t_func
16 |     call add(session.callbacks, function(a:2, a:000[2:-1]))
17 |   endif
18 |   let session.transport = a:transport
19 |   let session.id = a:transport.Message({'op': 'clone', 'session': a:0 ? a:1 : ''}, v:t_dict)['new-session']
20 |   let session.session = session.id
21 |   let session.url = a:transport.url . '#' . session.id
22 |   let a:transport.sessions[session.id] = function('s:session_callback', [], session)
23 |   return session
24 | endfunction
25 | 
26 | function! s:session_callback(msg) dict abort
27 |   if index(get(a:msg, 'status', []), 'session-closed') >= 0
28 |     call filter(self, 'v:key !=# "id" && v:key !=# "session"')
29 |   endif
30 |   for l:Callback in self.callbacks
31 |     try
32 |       call call(Callback, [a:msg])
33 |     catch
34 |     endtry
35 |   endfor
36 | endfunction
37 | 
38 | function! s:session_close() dict abort
39 |   if has_key(self, 'id')
40 |     try
41 |       call self.Message({'op': 'close'}, '')
42 |     catch
43 |     finally
44 |       call filter(self, 'v:key !=# "id" && v:key !=# "session"')
45 |     endtry
46 |   endif
47 |   return self
48 | endfunction
49 | 
50 | function! s:session_clone(...) dict abort
51 |   let session = call('fireplace#session#for', [self.transport, self.id] + a:000)
52 |   if has_key(self, 'ns')
53 |     let session.ns = self.ns
54 |   endif
55 |   return session
56 | endfunction
57 | 
58 | function! s:session_path() dict abort
59 |   return self.transport._path
60 | endfunction
61 | 
62 | function! s:close_on_first_done(transport, msg) abort
63 |   if index(get(a:msg, 'status', []), 'done') >= 0
64 |     call a:transport.Message({'op': 'close', 'session': a:msg.session}, '')
65 |   endif
66 | endfunction
67 | 
68 | function! s:session_message(msg, ...) dict abort
69 |   if !has_key(self, 'id')
70 |     throw 'Fireplace: session closed'
71 |   endif
72 |   let msg = a:msg
73 |   if !has_key(msg, 'session')
74 |     let msg = copy(msg)
75 |     let msg.session = self.id
76 |   elseif empty(msg.session) && msg.session isnot# v:null || msg.session is# v:true
77 |     let session = self.Clone(function('s:close_on_first_done', [self.transport]))
78 |     let msg = copy(msg)
79 |     let msg.session = session.id
80 |   endif
81 |   return call(self.transport.message, [msg] + a:000, self.transport)
82 | endfunction
83 | 
84 | function! s:session_has_op(op) dict abort
85 |   return self.transport.HasOp(a:op)
86 | endfunction
87 | 
88 | let s:session = {
89 |       \ 'Close': s:function('s:session_close'),
90 |       \ 'Clone': s:function('s:session_clone'),
91 |       \ 'HasOp': s:function('s:session_has_op'),
92 |       \ 'Message': s:function('s:session_message'),
93 |       \ 'Path': s:function('s:session_path'),
94 |       \ 'close': s:function('s:session_close'),
95 |       \ 'clone': s:function('s:session_clone'),
96 |       \ 'has_op': s:function('s:session_has_op'),
97 |       \ 'message': s:function('s:session_message'),
98 |       \ 'path': s:function('s:session_path')}
99 | 


--------------------------------------------------------------------------------
/autoload/fireplace/transport.vim:
--------------------------------------------------------------------------------
  1 | " Location: autoload/fireplace/transport.vim
  2 | " Author: Tim Pope <http://tpo.pe/>
  3 | 
  4 | if exists('g:autoloaded_fireplace_transport')
  5 |   finish
  6 | endif
  7 | let g:autoloaded_fireplace_transport = 1
  8 | 
  9 | let s:python_dir = fnamemodify(expand("<sfile>"), ':p:h:h:h') . '/pythonx'
 10 | if !exists('g:fireplace_python_executable')
 11 |   let g:fireplace_python_executable = exepath('python3') =~? '^$\|\<appinstallerpythonredirector\.exe$' && executable('python') ? 'python' : 'python3'
 12 | endif
 13 | 
 14 | if !exists('s:id')
 15 |   let s:vim_id = 'fireplace-' . hostname() . '-' . localtime()
 16 |   let s:id = 0
 17 | endif
 18 | function! fireplace#transport#id() abort
 19 |   let s:id += 1
 20 |   let sha = sha256(s:vim_id . '-' . s:id . '-' . reltimestr(reltime()))
 21 |   return printf('%s-%s-4%s-%s-%s', sha[0:7], sha[8:11], sha[13:15], sha[16:19], sha[20:31])
 22 | endfunction
 23 | 
 24 | function! fireplace#transport#combine(responses) abort
 25 |   if type(a:responses) == type({})
 26 |     return a:responses
 27 |   endif
 28 |   let combined = {'status': [], 'session': [], 'value': ['']}
 29 |   for response in a:responses
 30 |     for key in keys(response)
 31 |       if key ==# 'id'
 32 |         let combined[key] = response[key]
 33 |       elseif key ==# 'ns'
 34 |         let combined[key] = response[key]
 35 |         if !has_key(response, 'value')
 36 |           call add(combined.value, '')
 37 |         endif
 38 |       elseif key ==# 'value'
 39 |         let combined.value[-1] .= response.value
 40 |         if has_key(response, 'ns')
 41 |           call add(combined.value, '')
 42 |         endif
 43 |       elseif key ==# 'status'
 44 |         for entry in response[key]
 45 |           if index(combined[key], entry) < 0
 46 |             call extend(combined[key], [entry])
 47 |           endif
 48 |         endfor
 49 |       elseif key ==# 'session'
 50 |         if index(combined[key], response[key]) < 0
 51 |           call extend(combined[key], [response[key]])
 52 |         endif
 53 |       elseif type(response[key]) == type('')
 54 |         let combined[key] = get(combined, key, '') . response[key]
 55 |       else
 56 |         let combined[key] = response[key]
 57 |       endif
 58 |     endfor
 59 |   endfor
 60 |   call filter(combined.value, 'len(v:val)')
 61 |   if empty(combined.value)
 62 |     call remove(combined, 'value')
 63 |   endif
 64 |   return combined
 65 | endfunction
 66 | 
 67 | function! s:json_send(job, msg) abort
 68 |   if type(a:job) == v:t_number
 69 |     call chansend(a:job, json_encode(a:msg) . "\n")
 70 |   else
 71 |     call ch_sendexpr(a:job, a:msg)
 72 |   endif
 73 | endfunction
 74 | 
 75 | function! s:close(job) abort
 76 |   if type(a:job) == v:t_number
 77 |     return chanclose(a:job, 'stdin')
 78 |   else
 79 |     return ch_close_in(a:job)
 80 |   endif
 81 | endfunction
 82 | 
 83 | function! s:stop(job) abort
 84 |   if type(a:job) == v:t_number
 85 |     return jobstop(a:job)
 86 |   else
 87 |     call ch_close_in(a:job)
 88 |     return job_stop(a:job, 'kill')
 89 |   endif
 90 | endfunction
 91 | 
 92 | function! s:wrap_nvim_callback(cb, buffer, job, msgs, _) abort
 93 |   let a:msgs[0] = a:buffer[0] . a:msgs[0]
 94 |   let a:buffer[0] = remove(a:msgs, -1)
 95 |   for msg in a:msgs
 96 |     call call(a:cb, [a:job, json_decode(msg)[1]])
 97 |   endfor
 98 | endfunction
 99 | 
100 | function! s:json_start(command, out_cb, exit_cb) abort
101 |   if exists('*job_start') || !exists('*jobstart')
102 |     return job_start(a:command, {
103 |           \ "in_mode": "json",
104 |           \ "out_mode": "json",
105 |           \ "out_cb": a:out_cb,
106 |           \ "exit_cb": a:exit_cb,
107 |           \ })
108 |   else
109 |     let buf = ['']
110 |     return jobstart(a:command, {
111 |           \ "on_stdout": { job, data, type -> timer_start(0, { t -> s:wrap_nvim_callback(a:out_cb, buf, job, data, type) }) },
112 |           \ "on_exit": { job, status, type -> call(a:exit_cb, [job, status])},
113 |           \ })
114 |   endif
115 | endfunction
116 | 
117 | function! s:json_callback(url, state, requests, sessions, job, msg) abort
118 |   if type(a:msg) ==# v:t_list && len(a:msg) == 2
119 |     if a:msg[0] ==# 'exception'
120 |       let g:fireplace_last_python_exception = a:msg[1]
121 |     elseif a:msg[0] ==# 'status'
122 |       let a:state.status = a:msg[1]
123 |     endif
124 |   endif
125 |   if type(a:msg) !=# v:t_dict
126 |     return
127 |   endif
128 |   if has_key(a:msg, 'new-session') && !has_key(a:sessions, a:msg['new-session'])
129 |     let a:sessions[a:msg['new-session']] = 'len'
130 |   endif
131 |   if has_key(a:requests, get(a:msg, 'id'))
132 |     for l:Callback in a:requests[a:msg.id].callbacks
133 |       try
134 |         call call(l:Callback, [a:msg])
135 |       catch
136 |       endtry
137 |     endfor
138 |     if index(get(a:msg, 'status', []), 'done') >= 0
139 |       call remove(a:requests, a:msg.id)
140 |     endif
141 |   endif
142 |   if has_key(a:sessions, get(a:msg, 'session'))
143 |     try
144 |       call call(a:sessions[a:msg.session], [a:msg])
145 |     catch
146 |     endtry
147 |     if index(get(a:msg, 'status', []), 'session-closed') >= 0
148 |       call remove(a:sessions, a:msg.session)
149 |     endif
150 |   endif
151 | endfunction
152 | 
153 | function! s:exit_callback(url, state, requests, sessions, job, status) abort
154 |   if has_key(s:urls, a:url)
155 |     call remove(s:urls, a:url)
156 |   endif
157 |   let a:state.exit = a:status
158 | endfunction
159 | 
160 | if !exists('s:urls')
161 |   let s:urls = {}
162 | endif
163 | 
164 | augroup fireplace_transport
165 |   autocmd!
166 |   autocmd VimLeave for s:dict in values(s:urls)
167 |         \ |   call s:dict.transport.Close()
168 |         \ | endfor
169 | augroup END
170 | 
171 | function! fireplace#transport#connect(arg) abort
172 |   let url = substitute(a:arg, '#.*', '', '')
173 |   if url =~# '^\d\+$'
174 |     let url = 'nrepl://localhost:' . url
175 |   elseif url =~# '^[^:/@]\+\(:\d\+\)\=$'
176 |     let url = 'nrepl://' . url
177 |   elseif url !~# '^\a\+://'
178 |     throw "Fireplace: invalid connection string " . string(a:arg)
179 |   endif
180 |   let url = substitute(url, '^\a\+://[^/]*\zs$', '/', '')
181 |   let url = substitute(url, '^nrepl://[^/:]*\zs/', ':7888/', '')
182 |   if has_key(s:urls, url)
183 |     return s:urls[url].transport
184 |   endif
185 |   let scheme = matchstr(url, '^\a\+')
186 |   if scheme ==# 'nrepl'
187 |     let command = [g:fireplace_python_executable, s:python_dir.'/fireplace.py']
188 |   elseif exists('g:fireplace_argv_' . scheme)
189 |     let command = g:fireplace_argv_{scheme}
190 |   else
191 |     throw 'Fireplace: unsupported protocol ' . scheme
192 |   endif
193 |   let transport = deepcopy(s:transport)
194 |   let transport.url = url
195 |   let transport.state = {}
196 |   let transport.sessions = {}
197 |   let transport.requests = {}
198 |   let cb_args = [url, transport.state, transport.requests, transport.sessions]
199 |   let transport.job = s:json_start(command + [url], function('s:json_callback', cb_args), function('s:exit_callback', cb_args))
200 |   while !has_key(transport.state, 'status') && transport.Alive()
201 |     sleep 1m
202 |   endwhile
203 |   if get(transport.state, 'status') is# ''
204 |     let s:urls[transport.url] = {'transport': transport}
205 |     let transport.describe = transport.Message({'op': 'describe', 'verbose?': 1}, v:t_dict)
206 |     if transport.HasOp('classpath')
207 |       let response = transport.Message({'op': 'classpath', 'session': ''}, v:t_dict)
208 |       if type(get(response, 'classpath')) == type([])
209 |         let transport._path = response.classpath
210 |       endif
211 |     endif
212 |     if !has_key(transport, '_path')
213 |       let response = transport.Message({'op': 'eval', 'code':
214 |             \ '(System/getProperty "path.separator") (or' .
215 |             \ ' (System/getProperty "fake.class.path")' .
216 |             \ ' (System/getProperty "java.class.path") "") ' .
217 |             \ '(System/getProperty "user.dir") ' .
218 |             \ "(require 'clojure.repl 'clojure.java.javadoc)"}, v:t_dict)
219 |       let transport._path = split(eval(response.value[1]), response.value[0][1])
220 |       let cwd = eval(response.value[2])
221 |       for i in range(len(transport._path))
222 |         if transport._path[i] !~# '^/\|^\a\+:'
223 |           let transport._path[i] = cwd . matchstr(cwd, '[\/]') . transport._path[i]
224 |         endif
225 |       endfor
226 |     endif
227 |     return transport
228 |   endif
229 |   throw 'Fireplace: Connection Error: ' . get(transport.state, 'status', 'Failed to run command ' . join(command, ' '))
230 | endfunction
231 | 
232 | function! s:transport_alive() dict abort
233 |   return !has_key(self.state, 'exit')
234 | endfunction
235 | 
236 | function! s:transport_clone(...) dict abort
237 |   return call('fireplace#session#for', [self, ''] + a:000)
238 | endfunction
239 | 
240 | function! s:transport_close() dict abort
241 |   if has_key(self, 'job')
242 |     for session in keys(self.sessions)
243 |       call self.Message({'op': 'close', 'session': session}, '')
244 |       call remove(self.sessions, session)
245 |     endfor
246 |     call s:close(self.job)
247 |     for i in range(50)
248 |       if !has_key(s:urls, self.url)
249 |         return self
250 |       endif
251 |       sleep 1m
252 |     endfor
253 |     call s:stop(self.job)
254 |   endif
255 |   return self
256 | endfunction
257 | 
258 | function! s:transport_has_op(op) dict abort
259 |   return has_key(self.describe.ops, a:op)
260 | endfunction
261 | 
262 | function! s:transport_message(request, ...) dict abort
263 |   let request = copy(a:request)
264 |   if empty(get(request, 'id'))
265 |     let request.id = fireplace#transport#id()
266 |   endif
267 |   if empty(get(request, 'session', 1))
268 |     unlet request.session
269 |   endif
270 |   if empty(get(request, 'ns', 1))
271 |     unlet request.ns
272 |   endif
273 | 
274 |   if empty(get(request, 'id', 1))
275 |     call s:json_send(self.job, request)
276 |     return {}
277 |   endif
278 | 
279 |   let args = copy(a:000)
280 | 
281 |   if len(args) && type(args[0]) == v:t_number
282 |     let ret_type = remove(args, 0)
283 |   endif
284 | 
285 |   let received = []
286 |   let message = {'id': request.id}
287 |   if has_key(request, 'session')
288 |     let message.session = request.session
289 |   endif
290 |   let callbacks = [function('add', [received])]
291 |   if len(args) && type(args[0]) ==# v:t_list
292 |     call extend(callbacks, map(copy(args), 'function(v:val, args[1:-1])'))
293 |   elseif len(args) && (type(args[0]) == v:t_func || type(args[0]) == v:t_string && len(args[0]))
294 |     call add(callbacks, function(args[0], args[1:-1]))
295 |   endif
296 | 
297 |   let self.requests[request.id] = {'callbacks': callbacks}
298 |   if has_key(request, 'session')
299 |     let self.requests[request.id].session = request.session
300 |   endif
301 |   call s:json_send(self.job, request)
302 |   if !exists('ret_type')
303 |     return message
304 |   endif
305 |   try
306 |     while has_key(self.requests, request.id)
307 |       sleep 1m
308 |     endwhile
309 |   finally
310 |     if has_key(self.requests, request.id) && has_key(request, 'session')
311 |       call s:json_send(self.job, {'op': 'interrupt', 'id': fireplace#transport#id(), 'session': request.session, 'interrupt-id': request.id})
312 |     endif
313 |   endtry
314 |   if ret_type is# v:t_list
315 |     return received
316 |   elseif ret_type is# v:t_dict
317 |     return fireplace#transport#combine(received)
318 |   elseif ret_type is# v:t_number
319 |     return len(received)
320 |   else
321 |     return message
322 |   endif
323 | endfunction
324 | 
325 | function! fireplace#transport#interrupt(id) abort
326 |   for [url, dict] in items(s:urls)
327 |     if has_key(dict.transport.requests, a:id)
328 |       let request = dict.transport.requests[a:id]
329 |       if has_key(dict.transport, 'job') && has_key(request, 'session')
330 |         call s:json_send(dict.transport.job, {'op': 'interrupt', 'id': fireplace#transport#id(), 'session': request.session, 'interrupt-id': a:id})
331 |       endif
332 |     endif
333 |   endfor
334 | endfunction
335 | 
336 | function! fireplace#transport#stdin(session_or_id, data) abort
337 |   let str = type(a:data) == v:t_string ? a:data : nr2char(a:data)
338 |   let id = a:session_or_id
339 |   for [url, dict] in items(s:urls)
340 |     if has_key(dict.transport, 'job') && has_key(dict.transport.sessions, id)
341 |       call s:json_send(dict.transport.job, {'op': 'stdin', 'id': fireplace#transport#id(), 'session': id, 'stdin': str})
342 |       return v:true
343 |     elseif has_key(dict.transport, 'job') && has_key(dict.transport.requests, id)
344 |       call s:json_send(dict.transport.job, {'op': 'stdin', 'id': fireplace#transport#id(), 'session': dict.transport.requests[id].session, 'stdin': str})
345 |       return v:true
346 |     endif
347 |   endfor
348 |   return v:false
349 | endfunction
350 | 
351 | function! s:done(id) abort
352 |   for [url, dict] in items(s:urls)
353 |     if has_key(dict.transport, 'job') && has_key(dict.transport.requests, a:id)
354 |       return v:false
355 |     endif
356 |   endfor
357 |   return v:true
358 | endfunction
359 | 
360 | function! fireplace#transport#wait(id, ...) abort
361 |   let max = a:0 ? a:1 : -1
362 |   let ms = 0
363 |   while !s:done(a:id)
364 |     if ms == max
365 |       return v:false
366 |     endif
367 |     let ms += 1
368 |     if exists('*wait')
369 |       call wait(1, { -> v:false })
370 |     else
371 |       sleep 1m
372 |     endif
373 |   endwhile
374 |   return v:true
375 | endfunction
376 | 
377 | let s:transport = {
378 |       \ 'Alive': function('s:transport_alive'),
379 |       \ 'Clone': function('s:transport_clone'),
380 |       \ 'Close': function('s:transport_close'),
381 |       \ 'HasOp': function('s:transport_has_op'),
382 |       \ 'Message': function('s:transport_message'),
383 |       \ 'alive': function('s:transport_alive'),
384 |       \ 'clone': function('s:transport_clone'),
385 |       \ 'close': function('s:transport_close'),
386 |       \ 'has_op': function('s:transport_has_op'),
387 |       \ 'message': function('s:transport_message')}
388 | 


--------------------------------------------------------------------------------
/doc/fireplace.txt:
--------------------------------------------------------------------------------
  1 | *fireplace.txt*  Clojure REPL support
  2 | 
  3 | Author:  Tim Pope <http://tpo.pe/>
  4 | License: Same terms as Vim itself (see |license|)
  5 | 
  6 | This plugin is only available if 'compatible' is not set.
  7 | 
  8 |                                                 *fireplace*
  9 | While not a hard dependency of Fireplace itself, many features require
 10 | <https://github.com/clojure-emacs/cider-nrepl> for full functionality.
 11 | 
 12 | CONNECTING TO A REPL                            *fireplace-connect*
 13 | 
 14 | Connecting to lein repl happens automatically.  If you have a different setup,
 15 | you can connect by hand.
 16 | 
 17 |                                                 *fireplace-:Connect*
 18 | :Connect nrepl://{host}:{port} [path]
 19 | :Connect {port} [path]
 20 |                         Connect to a REPL server.  The path is the root of the
 21 |                         project that the REPL applies to (try ".").
 22 | 
 23 | The REPL is used for the commands below. If no REPL is found for the current
 24 | buffer and 'path' contains at least one jar file, java (or $JAVA_CMD) is
 25 | invoked directly, which can be quite slow depending on your setup.
 26 | 
 27 | The only adapter shipped with fireplace.vim is for nREPL.  You need either
 28 | `python` or `python3` in your path.
 29 | 
 30 |                         *fireplace-piggieback* *fireplace-clojurescript*
 31 | To use a ClojureScript, invoke |:CljEval| with the command you would normally
 32 | use to start a ClojureScript REPL.  For example:
 33 | >
 34 |         :CljEval (cider.piggieback/cljs-repl (cljs.repl.nashorn/repl-env))
 35 | <
 36 | Be aware that your ClojureScript files must be available on the classpath for
 37 | this to work properly, and that not all operations are supported.
 38 | 
 39 | The :Piggieback command is softly deprecated wrapper for invoking Piggieback.
 40 | 
 41 |                                                 *fireplace-:Piggieback*
 42 | :Piggieback ({ns}/repl-env [...])
 43 |                         Create a new nREPL session and invoke
 44 |                         cider.piggieback/cljs-repl with the given environment.
 45 | 
 46 | :Piggieback ({ns}/cljs-repl [...])
 47 |                         If the argument is a call to a function not named
 48 |                         repl-env, it is invoked directly, without
 49 |                         cider.piggieback/cljs-repl.  This is useful for
 50 |                         (figwheel.main.api/cljs-repl) and similar functions.
 51 | 
 52 | :Piggieback {port}      If the argument looks like a port number,
 53 |                         weasel.repl.websocket (if available) or
 54 |                         cljs.repl.browser will be used to provide the REPL
 55 |                         environment.
 56 | 
 57 | :Piggieback             If no argument is given, :Piggieback defaults to
 58 |                         the ClojureScript environment specified in
 59 |                         *b:fireplace_cljs_repl* or *g:fireplace_cljs_repl* .
 60 |                         If projectionist.vim is installed, the "cljsRepl"
 61 |                         projectionist key is also checked.  This default will
 62 |                         be invoked automatically on first eval in a
 63 |                         ClojureScript buffer if :Piggieback is not invoked
 64 |                         explicitly.  To restore the old behavior of defaulting
 65 |                         to Nashorn, add this line to your vimrc:
 66 | >
 67 |         let g:fireplace_cljs_repl =
 68 |               \ '(cider.piggieback/cljs-repl (cljs.repl.nashorn/repl-env))'
 69 | <
 70 | :Piggieback!            Terminate the most recently created piggieback
 71 |                         session.
 72 | 
 73 | DOCUMENTATION                                   *fireplace-documentation*
 74 | 
 75 |                                                 *fireplace-:Doc*
 76 | :Doc {symbol}           Show the docs for the given symbol.
 77 | 
 78 |                                                 *fireplace-:Javadoc*
 79 | :Javadoc {class}        Open the java docs for the given class in a browser.
 80 | 
 81 |                                                 *fireplace-K*
 82 | K                       Look up the doc, javadoc, or spec-form for the
 83 |                         identifier under the cursor.
 84 | 
 85 |                                                 *fireplace-:FindDoc*
 86 | :FindDoc {arg}          Wrapper around (clojure.repl/find-doc ...).
 87 | 
 88 |                                                 *fireplace-:SpecForm*
 89 | :SpecForm {keyword}     Show the form of the spec given.
 90 |                         Like (spec/form keyword).
 91 | 
 92 |                                                 *fireplace-:SpecExample*
 93 | :SpecExample {keyword}  Generate one example for the spec given.
 94 |                         Like (gen/generate keyword).
 95 | 
 96 |                                                 *fireplace-:Source*
 97 | :Source {symbol}        Show the source for the given symbol.
 98 | 
 99 |                                                 *fireplace-[D*
100 | [D                      Show source for symbol under cursor.
101 | ]D
102 | 
103 | NAVIGATING                                      *fireplace-navigating*
104 | 
105 | These commands will never use a remote REPL, only a local one, as file paths
106 | on a remote server wouldn't be very useful locally.
107 | 
108 |                                                 *fireplace-[_CTRL-D*
109 | [<C-D>                  Jump to the source of the symbol under the cursor.
110 | ]<C-D>
111 | 
112 |                                                 *fireplace-CTRL-W_CTRL-D*
113 | <C-W><C-D>              Jump to the source of the symbol under the cursor in
114 | <C-W>d                  a split.
115 | 
116 |                                                 *fireplace-gf*
117 | gf                      Go to the file for the namespace under the cursor.
118 | 
119 |                                                 *fireplace-CTRL-]*
120 | <C-]>                   Jump to the source of the symbol under the cursor
121 | g]                      and put the symbol on the tag stack.  See the help for
122 | g<C-]>                  the built-in |CTRL-]|.  All other tag maps are provided
123 | <C-W>]                  as well.
124 | <C-W>g]
125 | <C-W>g<C-]>
126 | 
127 |                                                 *fireplace-:Djump*
128 | :Djump {symbol}         Jump to the definition for the given symbol.
129 | 
130 |                                                 *fireplace-:Dsplit*
131 | :Dsplit {symbol}        Jump to the definition for the given symbol in a
132 |                         split.
133 | 
134 | EVALUATING CODE                                 *fireplace-eval*
135 | 
136 | All code is evaluated in the namespace of the current file, requiring it if
137 | necessary.  If the current file sits outside the class path (project.clj, for
138 | example), the user namespace is used instead.  ClojureScript is used for .cljs
139 | files always and for .cljc files if a ClojureScript repl has already been
140 | initialized.
141 | 
142 | Evaluation happens in the foreground and blocks Vim by default.  Press <C-D>
143 | during a prolonged execution to detach from it and return Vim.  When
144 | evaluation is complete, results will load into the preview window.
145 | 
146 |                                                 *fireplace-:Require*
147 | :Require [ns]           Require :reload the given/current namespace.
148 | 
149 |                                                 *fireplace-:Require!*
150 | :Require! [ns]          Require :reload-all the given/current namespace.
151 | 
152 |                                                 *fireplace-:Eval*
153 | :Eval                   Eval/print the outermost form for the current line.
154 | 
155 | :{range}Eval            Eval/print the given range.
156 | 
157 | :Eval {expr}            Eval/print the given expression.
158 | 
159 |                                                 *fireplace-:Eval!*
160 | :[range]Eval!           Eval the given range or outermost expression and
161 |                         replace it with its result.
162 | 
163 | :[range]Eval! {expr}    Eval the given expression and insert it after
164 |                         the given range or current line.
165 | 
166 |                                                 *fireplace-:CljEval*
167 | :CljEval [...]          Like :Eval, but always use the user namespace and
168 |                         Clojure platform.  This command is available globally.
169 | 
170 |                                                 *fireplace-:CljsEval*
171 | :CljsEval [...]         Like :Eval, but always use the cljs.user namespace and
172 |                         ClojureScript platform.  This command is available
173 |                         globally.
174 | 
175 |                                                 *fireplace-:RunTests*
176 | :RunTests [ns] [...]    Call clojure.test/run-tests on the given namespaces
177 |                         and load the results into the quickfix list.
178 | 
179 | :[range]RunTests        Call clojure.test/test-var on the var defined at or
180 |                         above the specified line and load the results into the
181 |                         quickfix list.  Typically invoked as :.RunTests to run
182 |                         the test under the cursor.
183 | 
184 | :0RunTests [pattern]    Call clojure.test/run-all-tests with the given pattern
185 |                         and load the results into the quickfix list.
186 | 
187 |                                                 *fireplace-cp*
188 | cp{motion}              Eval/print the code indicated by {motion}.
189 | 
190 | cpp                     Eval/print the innermost form at the cursor.
191 | 
192 |                                                 *fireplace-cpr*
193 | cpr                     :Require|RunTests
194 | 
195 |                                                 *fireplace-c!*
196 | c!{motion}              Eval/replace the code indicated by {motion}.
197 | 
198 | c!!                     Eval/replace the innermost form at the cursor.
199 | 
200 |                                                 *fireplace-cm*
201 | cm{motion}              Fully macroexpand the code indicated by {motion}.
202 | 
203 |                                                 *fireplace-cmm*
204 | cmm                     Fully macroexpand the innermost form at the cursor.
205 | 
206 |                                                 *fireplace-c1m*
207 | c1m{motion}             Macroexpand the code indicated by {motion} once.
208 | 
209 |                                                 *fireplace-c1mm*
210 | c1mm                    Macroexpand the innermost form at the cursor once.
211 | 
212 |                                                 *fireplace-cqp*
213 | cqp                     Bring up a prompt for code to eval/print.
214 | 
215 |                                                 *fireplace-cqq*
216 | cqq                     Bring up a |command-line-window| with innermost form
217 |                         at the cursor prepopulated.
218 | 
219 |                                                 *fireplace-cqc*
220 | cqc                     Bring up a |command-line-window| for code to
221 |                         eval/print.  Equivalent to cqp<C-F>i.
222 | 
223 |                                                 *fireplace-cq*
224 | cq{motion}              Bring up a |command-line-window| with text indicated
225 |                         by {motion} prepopulated.
226 | 
227 |                                                 *fireplace-:Last*
228 | :Last                   Open the result of the last evaluation in the preview
229 |                         window.  Use :2Last to get the next-to-last result,
230 |                         and so on.  Once the window is open, cycle to older
231 |                         and newer entries with |:lprevious| and |:lnext|.
232 | 
233 |                                                 *fireplace-:Stacktrace*
234 | :Stacktrace             Retrieve the most recent Clojure error and load the
235 |                         stacktrace into the quickfix list.  By default this is
236 |                         filtered to exclude duplicates and tooling (e.g.,
237 |                         nREPL internals).  Use :Stacktrace! to get an
238 |                         unfiltered version.
239 | 
240 | And insert mode:
241 | 
242 |                                                 *fireplace-i_CTRL-R_(*
243 | <C-R>(                  Evaluate the given expression and insert the result.
244 | 
245 | There's omnicomplete on |CTRL-X_CTRL-O|, which works in Clojure buffers and
246 | in the |command-line-window|, and tab complete at the cqp prompt.
247 | 
248 | API                                             *fireplace-api*
249 | 
250 | Use fireplace#clj() or fireplace#cljs() to get a "platform" object for Clojure
251 | or ClojureScript, or fireplace#platform() to pick automatically for the
252 | current buffer.  The following instance methods are available:
253 | >
254 |         let ext = platform.Ext()
255 | <
256 | Retrieve the appropriate file extension, either "clj" or "cljs".
257 | >
258 |         let user_ns = platform.UserNs()
259 | <
260 | Retrieve the user namespace, either "user" or "cljs.user".
261 | >
262 |         let ns = platform.BufferNs()
263 |         let ns = platform.BufferNs(bufnr(''))
264 | <
265 | Retrieve the namespace for the current or given buffer number, determined by
266 | looking for a (ns) declaration and falling back to a using the class path
267 | relative filename.  This is the same namespace used by operations like :Eval.
268 | >
269 |         call platform.Message({"op": "some-op"})
270 |         call platform.Message({"op": "some-op"}, function("Callback"))
271 | <
272 | Send an nREPL message asynchronously.  If given, invoke the callback on each
273 | message.
274 | >
275 |         let list = platform.Message({"op": "..."}, v:t_list)
276 |         let list = platform.Message({"op": "..."}, v:t_list,
277 |               \ function("Callback"))
278 | <
279 | Send an nREPL message and return all response messages as a list.  If given,
280 | invoke the callback on each message.
281 | >
282 |         let dict = platform.Message({"op": "some-op"}, v:t_dict)
283 |         let dict = platform.Message({"op": "some-op"}, v:t_dict,
284 |               \ function("Callback"))
285 | <
286 | Send an nREPL message and return all response messages as a single combined
287 | dictionary.  If given, invoke the callback on each message.
288 | >
289 |         let list = platform.Message({"op": "some-op", "ns": bufnr('')})
290 | <
291 | If a buffer number is given as an "ns" parameter, it is replaced with the
292 | namespace for that buffer, as retrieved by platform.BufferNs().
293 | >
294 |         let list = platform.Message({"op": "some-op", "session": v:true})
295 | <
296 | If v:true is given as "session", the current session is cloned for the given
297 | operation, and closed when the operation completes.  Use this to do an
298 | arbitrary eval without tainting *1, etc.  (Although platform.Query() is
299 | generally a better choice for such operations.)
300 | >
301 |         if platform.HasOp("some-op")
302 | <
303 | Check for the presence of an nREPL op.  Always returns false if no live
304 | connection is available.
305 | >
306 |         let msg1 = platform.Message({"op": "some-op"})
307 |         let msg2 = platform.Message({"op": "other-op"}, function("Callback"))
308 |         call fireplace#wait([msg1, msg2])
309 | <
310 | Wait on one or more asynchronous messages to finish.  If CTRL-C is pressed by
311 | the user, all messages will be interrupted with {"op": "interrupt"}.
312 | >
313 |         let classpath = platform.Path()
314 | <
315 | Retrieve the class path, either from a REPL connection or from 'path' as set
316 | by classpath.vim or salve.vim.
317 | >
318 |         let data = platform.Query("code")
319 |         let data = platform.Query("code", {"ns": bufnr('')})
320 | <
321 | Evaluate the given code on the REPL and return it as a Vim data structure.
322 | Works offline if a class path is available.
323 | >
324 |         let msg = platform.Query("code", function("Callback"))
325 | <
326 | Evaluate the given code on the REPL and pass it to the callback as a Vim data
327 | structure.  Works offline if a class path is available.
328 | 
329 | ABOUT                                           *fireplace-about*
330 | 
331 | Grab the latest version or report a bug on GitHub:
332 | 
333 | http://github.com/tpope/vim-fireplace
334 | 
335 |  vim:tw=78:et:ft=help:norl:
336 | 


--------------------------------------------------------------------------------
/plugin/fireplace.vim:
--------------------------------------------------------------------------------
 1 | " fireplace.vim - Clojure REPL support
 2 | " Maintainer:   Tim Pope <http://tpo.pe/>
 3 | " Version:      2.1
 4 | " GetLatestVimScripts: 4978 1 :AutoInstall: fireplace.vim
 5 | 
 6 | if exists("g:loaded_fireplace")
 7 |   finish
 8 | endif
 9 | let g:loaded_fireplace = 1
10 | 
11 | augroup fireplace
12 |   autocmd!
13 | 
14 |   if v:version >= 800
15 |     autocmd FileType clojure call fireplace#activate()
16 | 
17 |     autocmd QuickFixCmdPost make,cfile,cgetfile
18 |           \ if &efm =~# 'classpath' | call fireplace#massage_list() | endif
19 |     autocmd QuickFixCmdPost lmake,lfile,lgetfile
20 |           \ if &efm =~# 'classpath' | call fireplace#massage_list(0) | endif
21 |   else
22 |     autocmd FileType clojure
23 |           \ if !exists('s:did_warning') |
24 |           \    let s:did_warning = 1 |
25 |           \    echohl WarningMsg |
26 |           \    echo 'Fireplace not loaded: Vim 8.0 or higher required' |
27 |           \    echohl None
28 |           \ endif
29 |   endif
30 | 
31 |   autocmd User ProjectionistActivate
32 |         \ for b:fireplace_cljs_repl in projectionist#query_scalar('fireplaceCljsRepl') + projectionist#query_scalar('cljsRepl') |
33 |         \   break |
34 |         \ endfor
35 | augroup END
36 | 
37 | command! -bar -bang -complete=customlist,fireplace#ConnectComplete -nargs=* FireplaceConnect
38 |       \ exe fireplace#ConnectCommand(<line1>, <count>, +'<range>', <bang>0, <q-mods>, <q-args>, [<f-args>])
39 | command! -bang -range -complete=customlist,fireplace#CljEvalComplete -nargs=* CljEval
40 |       \ exe fireplace#CljEvalCommand( <line1>, <count>, +'<range>', <bang>0, <q-mods>, <q-args>)
41 | command! -bang -range -complete=customlist,fireplace#CljsEvalComplete -nargs=* CljsEval
42 |       \ exe fireplace#CljsEvalCommand(<line1>, <count>, +'<range>', <bang>0, <q-mods>, <q-args>)
43 | 


--------------------------------------------------------------------------------
/pythonx/fireplace.py:
--------------------------------------------------------------------------------
  1 | import json
  2 | import os
  3 | import re
  4 | import socket
  5 | import sys
  6 | import traceback
  7 | import threading
  8 | 
  9 | def bencode(data, f):
 10 |     if isinstance(data, list):
 11 |         f.write(b'l')
 12 |         for x in data:
 13 |             bencode(x, f)
 14 |         f.write(b'e')
 15 |     elif isinstance(data, dict):
 16 |         f.write(b'd')
 17 |         for x in sorted(data.keys()):
 18 |             bencode(x, f)
 19 |             bencode(data[x], f)
 20 |         f.write(b'e')
 21 |     elif isinstance(data, int) or isinstance(data, bool):
 22 |         f.write(b'i')
 23 |         f.write(str(int(data)).encode('UTF-8'))
 24 |         f.write(b'e')
 25 |     elif isinstance(data, str) or type(data).__name__ == 'unicode':
 26 |         data = data.encode('UTF-8')
 27 |         f.write(str(len(data)).encode('UTF-8'))
 28 |         f.write(b':')
 29 |         f.write(data)
 30 |     else:
 31 |         raise TypeError("can't bencode a " + type(data).__name__)
 32 | 
 33 | def binread(f, count=1):
 34 |     buf = f.read(count)
 35 |     length = len(buf)
 36 |     while len(buf) != count and length > 0:
 37 |         more = f.read(count - len(buf))
 38 |         length = len(more)
 39 |         buf += more
 40 |     return buf
 41 | 
 42 | def bdecode(f, char=None):
 43 |     if char == None:
 44 |         char = binread(f)
 45 |     if char == b'l':
 46 |         l = []
 47 |         while True:
 48 |             char = binread(f)
 49 |             if char == b'e':
 50 |                 return l
 51 |             l.append(bdecode(f, char))
 52 |     elif char == b'd':
 53 |         d = {}
 54 |         while True:
 55 |             char = binread(f)
 56 |             if char == b'e':
 57 |                 return d
 58 |             key = bdecode(f, char)
 59 |             d[key] = bdecode(f)
 60 |     elif char == b'i':
 61 |         i = b''
 62 |         while True:
 63 |             char = binread(f)
 64 |             if char == b'e':
 65 |                 return int(i)
 66 |             i += char
 67 |     elif char.isdigit():
 68 |         i = int(char)
 69 |         while True:
 70 |             char = binread(f)
 71 |             if char == b':':
 72 |                 return binread(f, i).decode('UTF-8')
 73 |             i = 10 * i + int(char)
 74 |     elif char == b'':
 75 |         raise EOFError("unexpected end of bencode data")
 76 |     else:
 77 |         raise TypeError("unexpected type "+char.decode('UTF-8')+" in bencode data")
 78 | 
 79 | def quickfix(t, e, tb):
 80 |     items = []
 81 |     stack = traceback.extract_tb(tb)
 82 |     for frame in stack:
 83 |         (filename, lineno, name, line) = frame
 84 |         module = ''
 85 |         if filename and filename[0] == '<':
 86 |             module = filename
 87 |             filename = ''
 88 |         items.append({
 89 |             'filename': filename,
 90 |             'lnum': lineno,
 91 |             'module': module,
 92 |             'text': line})
 93 |     return {'title': str(e), 'items': items}
 94 | 
 95 | class Connection:
 96 |     def __init__(self, host, port, keepalive_file=None):
 97 |         self.keepalive_file = keepalive_file
 98 |         self.connected = False
 99 |         self.host = host
100 |         self.port = int(port)
101 | 
102 |     def socket(self):
103 |         if not self.connected:
104 |             s = socket.socket(socket.AF_INET, socket.SOCK_STREAM)
105 |             s.settimeout(8)
106 |             s.connect((self.host, self.port))
107 |             s.setblocking(1)
108 |             self._socket = s
109 |             self.connected = True
110 |         return self._socket
111 | 
112 |     def close(self):
113 |         if self.connected:
114 |             return self.socket().close()
115 | 
116 |     def send(self, payload):
117 |         f = self.socket().makefile('wb')
118 |         try:
119 |             if isinstance(payload, dict):
120 |                 bencode(payload, f)
121 |             else:
122 |                 f.write(payload.encode('UTF-8'))
123 |         finally:
124 |             f.close()
125 |         return ''
126 | 
127 |     def receive(self, char=None):
128 |         f = self.socket().makefile('rb', False)
129 |         try:
130 |             return bdecode(f)
131 |         finally:
132 |             f.close()
133 | 
134 |     def notify(self, data, i = 0):
135 |         json.dump([i, data], sys.stdout)
136 |         sys.stdout.write("\n")
137 |         sys.stdout.flush()
138 | 
139 |     def tunnel_socket_to_stdout(self):
140 |         socket_in = self.socket().makefile('rb', False)
141 |         try:
142 |             while True:
143 |                 msg = self.receive()
144 |                 self.notify(msg)
145 |         except EOFError:
146 |             os._exit(0)
147 |         except Exception:
148 |             self.notify(["exception", quickfix(*sys.exc_info())])
149 |             os._exit(4)
150 |         finally:
151 |             socket_in.close()
152 | 
153 |     def tunnel(self):
154 |         try:
155 |             self.socket()
156 |             t = threading.Thread(target = self.tunnel_socket_to_stdout)
157 |             t.daemon = True
158 |             t.start()
159 |             self.notify(["status", ""])
160 |             line = sys.stdin.readline()
161 |             while len(line) > 0:
162 |                 try:
163 |                     obj = json.loads(line)
164 |                     if isinstance(obj, list):
165 |                         obj = obj[1]
166 |                     self.send(obj)
167 |                 except Exception:
168 |                     self.notify(["exception", quickfix(*sys.exc_info())])
169 |                 line = sys.stdin.readline()
170 |             t.join(0.1)
171 |         except socket.error as e:
172 |             self.notify(["status", e.strerror])
173 |             os._exit(2)
174 |         except Exception as e:
175 |             self.notify(["status", str(e)])
176 |             self.notify(["exception", quickfix(*sys.exc_info())])
177 |             os._exit(3)
178 | 
179 | def main(host = None, port = None, *args):
180 |     try:
181 |         match = re.search('//([^:/@]+)(?::(\d+))?', host)
182 |         if match:
183 |             host = match.groups()[0]
184 |             port = match.groups()[1]
185 |         conn = Connection(host, int(port or 7888))
186 |         try:
187 |             conn.tunnel()
188 |         finally:
189 |             conn.close()
190 |     except Exception:
191 |         json.dump([0, ["exception", quickfix(*sys.exc_info())]], sys.stdout)
192 |         exit(1)
193 | 
194 | if __name__ == "__main__":
195 |     main(*sys.argv[1:])
196 | 


--------------------------------------------------------------------------------