├── .github
    └── FUNDING.yml
├── .gitignore
├── CONTRIBUTING.markdown
├── README.markdown
├── doc
    └── ragtag.txt
└── plugin
    └── ragtag.vim


/.github/FUNDING.yml:
--------------------------------------------------------------------------------
1 | github: tpope
2 | custom: ["https://www.paypal.me/vimpope"]
3 | 


--------------------------------------------------------------------------------
/.gitignore:
--------------------------------------------------------------------------------
1 | doc/tags
2 | 


--------------------------------------------------------------------------------
/CONTRIBUTING.markdown:
--------------------------------------------------------------------------------
1 | See the [contribution guidelines for pathogen.vim](https://github.com/tpope/vim-pathogen/blob/master/CONTRIBUTING.markdown).
2 | 


--------------------------------------------------------------------------------
/README.markdown:
--------------------------------------------------------------------------------
 1 | # ragtag.vim
 2 | 
 3 | A set of mappings for HTML, XML, PHP, ASP, eRuby, JSP, and more (formerly allml) 
 4 | 
 5 | This plugin started out as a set of personal mappings, but there was enough enjoyment among those I shared it with for me to clean it up and release it. 
 6 | 
 7 | ## Features
 8 | 
 9 | A huge variety of filetypes are supported:  html, xhtml, wml, xml, xslt, xsd, jsp, php, aspperl, aspvbs, cf, mason, htmldjango, and eruby.  (Let me know if I missed any).  Some features take note of the filetype and adapt to it.
10 | 
11 | Maps for editing tags are provided.  This includes a couple of "make last word into a tag pair" maps, a doctype map (inserts <?xml ...?> in XML), a "close last tag" map, and a few extra goodies. 
12 | 
13 | For templating languages (ASP, PHP, etc.), there are maps for inserting template code.  The maps are dependent on the filetype: in ASP, you get `<% %>` and `<%= %>`, in PHP, `<?php ?>` and `<?php print ?>`, etc.  If said template language has a comment syntax, there is a map for it, otherwise, that map points to `<!-- -->`. 
14 | 
15 | Maps for XML/HTML escaping and URL encoding have been moved to [unimpaired.vim](https://github.com/tpope/vim-unimpaired).
16 | 
17 | Enhances [surround.vim](https://github.com/tpope/vim-surround).
18 | 
19 | ## Self-Promotion
20 | 
21 | Like ragtag.vim? Follow the repository on
22 | [GitHub](https://github.com/tpope/vim-ragtag) and vote for it on
23 | [vim.org](http://www.vim.org/scripts/script.php?script_id=1896).  And if
24 | you're feeling especially charitable, follow [tpope](http://tpo.pe/) on
25 | [Twitter](http://twitter.com/tpope) and
26 | [GitHub](https://github.com/tpope).
27 | 
28 | ## License
29 | 
30 | Copyright (c) Tim Pope.  Distributed under the same terms as Vim itself.
31 | See `:help license`.
32 | 


--------------------------------------------------------------------------------
/doc/ragtag.txt:
--------------------------------------------------------------------------------
 1 | *ragtag.txt*  Ghetto XML/HTML mappings (formerly allml.vim)
 2 | 
 3 | Author:  Tim Pope <http://tpo.pe/>
 4 | License: Same terms as Vim itself (see |license|)
 5 | 
 6 | This plugin is only available if 'compatible' is not set.
 7 | 
 8 | INTRODUCTION                                    *ragtag*
 9 | 
10 | These are my personal mappings for XML/XHTML editing, particularly with
11 | dynamic content like PHP/ASP/eRuby.  Because they are personal, less effort
12 | has been put into customizability (if you like these mappings but the lack of
13 | customizability poses an issue for you, let me know).  Examples shown are for
14 | eRuby.
15 | 
16 | You might find these helpful in your vimrc:
17 | >
18 |         inoremap <M-o>       <Esc>o
19 |         inoremap <C-j>       <Down>
20 |         let g:ragtag_global_maps = 1
21 | <
22 | MAPPINGS                                        *ragtag-mappings*
23 | 
24 | The table below shows what happens if the binding is pressed on the end of a
25 | line consisting of "foo".
26 | 
27 | Mapping       Changed to   (cursor = ^) ~
28 | <C-X>=        foo<%= ^ %>                               *ragtag-CTRL-X_=*
29 | <C-X>+        <%= foo^ %>                               *ragtag-CTRL-X_+*
30 | <C-X>-        foo<% ^ %>                                *ragtag-CTRL-X_-*
31 | <C-X>_        <% foo^ %>                                *ragtag-CTRL-X__*
32 | <C-X>'        foo<%# ^ %>                               *ragtag-CTRL-X_'*
33 |               (mnemonic: ' is a comment in ASP VBS)
34 | <C-X>"        <%# foo^ %>                               *ragtag-CTRL-X_quote*
35 | <C-X><Space>  <foo>^</foo>                              *ragtag-CTRL-X_<Space>*
36 | <C-X><CR>     <foo>\n^\n</foo>                          *ragtag-CTRL-X_<CR>*
37 | <C-X>/        Last HTML tag closed                      *ragtag-CTRL-X_/*
38 | <C-X>!        <!DOCTYPE...>/<?xml ...?> (menu)          *ragtag-CTRL-X_!*
39 | <C-X>@        <link rel="stylesheet" ...>               *ragtag-CTRL-X_@*
40 |               (mnemonic: @ is used for importing in a CSS file)
41 | <C-X>#        <meta http-equiv="Content-Type" ... />    *ragtag-CTRL-X_#*
42 | <C-X>$        <script src="/javascripts/^.js"></script> *ragtag-CTRL-X_$*
43 |               (mnemonic: $ is valid in javascript identifiers)
44 | 
45 | For the bindings that generate HTML tag pairs, in a few cases, attributes will
46 | be automatically added.  For example, script becomes >
47 |         <script type="text/javascript">
48 | <
49 | ENCODING                                        *ragtag-encoding*
50 | 
51 | This plugin used to provide a set of general purpose XML/URL encoding/decoding
52 | mappings.  These mappings have been extracted to a (highly recommended) plugin
53 | named unimpaired.vim.  Left behind were the following four insert mode
54 | mappings (mostly useful as stupid party tricks).
55 | 
56 |                                                 *ragtag-CTRL-V_%*
57 | <Plug>ragtagUrlV        URL encode the next character.
58 | <C-V>%
59 | 
60 |                                                 *ragtag-CTRL-V_&*
61 | <Plug>ragtagXmlV        XML encode the next character.
62 | <C-V>&
63 | 
64 |                                                 *ragtag-CTRL-X_%*
65 | <Plug>ragtagUrlEncode   Toggle a mode that automatically URL encodes unsafe
66 | <C-X>%                  characters.
67 | 
68 |                                                 *ragtag-CTRL-X_&*
69 | <Plug>ragtagXmlEncode   Toggle a mode that automatically XML encodes unsafe
70 | <C-X>&                  characters.
71 | 
72 | SURROUNDINGS                                    *ragtag-surroundings*
73 | 
74 | Combined with surround.vim, you also get three "replacements".  Below, the ^
75 | indicates the location of the wrapped text.  See |surround| for details.
76 | 
77 | Character     Replacement ~
78 | -             <% ^ %>
79 | =             <%= ^ %>
80 | #             <%# ^ %>
81 | 
82 |  vim:tw=78:et:ft=help:norl:
83 | 


--------------------------------------------------------------------------------
/plugin/ragtag.vim:
--------------------------------------------------------------------------------
  1 | " ragtag.vim - Ghetto XML/HTML mappings (formerly allml.vim)
  2 | " Author:       Tim Pope <http://tpo.pe/>
  3 | " Version:      2.0
  4 | " GetLatestVimScripts: 1896 1 :AutoInstall: ragtag.vim
  5 | 
  6 | if exists("g:loaded_ragtag") || &cp || v:version < 700
  7 |   finish
  8 | endif
  9 | let g:loaded_ragtag = 1
 10 | 
 11 | if !exists('g:html_indent_inctags')
 12 |   let g:html_indent_inctags = 'body,head,html,tbody,p,li,dt,dd'
 13 | endif
 14 | if !exists('g:html_indent_autotags')
 15 |   let g:html_indent_autotags = 'wbr'
 16 | endif
 17 | if !exists('g:html_indent_script1')
 18 |   let g:html_indent_script1 = 'inc'
 19 | endif
 20 | if !exists('g:html_indent_style1')
 21 |   let g:html_indent_style1 = 'inc'
 22 | endif
 23 | 
 24 | augroup ragtag
 25 |   autocmd!
 26 |   autocmd BufReadPost * if ! did_filetype() && getline(1)." ".getline(2).
 27 |         \ " ".getline(3) =~? '<\%(!DOCTYPE \)\=html\>' | setf html | endif
 28 |   autocmd FileType *html*,wml,jsp,gsp,mustache,smarty             call s:Init()
 29 |   autocmd FileType php,asp*,cf,mason,eruby,liquid,jst,eelixir     call s:Init()
 30 |   autocmd FileType xml,xslt,xsd,docbk                             call s:Init()
 31 |   autocmd FileType vue                                            call s:Init()
 32 |   autocmd FileType javascript.jsx,jsx,javascriptreact,handlebars  call s:Init()
 33 |   autocmd FileType typescript.tsx,tsx,typescriptreact             call s:Init()
 34 |   autocmd InsertLeave * call s:Leave()
 35 |   autocmd CursorHold * if exists("b:loaded_ragtag") | call s:Leave() | endif
 36 | augroup END
 37 | 
 38 | inoremap <silent> <Plug>ragtagHtmlComplete <C-R>=<SID>htmlEn()<CR><C-X><C-O><C-P><C-R>=<SID>htmlDis()<CR><C-N>
 39 | 
 40 | " Public interface, for if you have your own filetypes to activate on
 41 | function! RagtagInit()
 42 |   call s:Init()
 43 | endfunction
 44 | 
 45 | function! AllmlInit()
 46 |   call s:Init()
 47 | endfunction
 48 | 
 49 | function! s:isFiletype(ft)
 50 |   return index(split(&filetype, '\.'), a:ft) >= 0
 51 | endfunction
 52 | 
 53 | function! s:Init()
 54 |   let b:loaded_ragtag = 1
 55 |   if s:subtype() == "xml"
 56 |     imap <script> <buffer> <C-X>! <?xml version="1.0" encoding="<C-R>=toupper(<SID>charset())<CR>"?>
 57 |   elseif s:subtype() == "xhtml"
 58 |     imap <script> <buffer> <C-X>! <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
 59 |   else
 60 |     imap <script> <buffer> <C-X>! <!DOCTYPE html>
 61 |   endif
 62 | 
 63 |   if empty(&l:define)
 64 |     let &l:define = '\<id=["'']\='
 65 |     let b:undo_ftplugin = get(b:, 'undo_ftplugin', 'exe') . '|setl def='
 66 |   endif
 67 | 
 68 |   imap <silent> <buffer> <C-X># <C-R>=<SID>charsetTag()<CR>
 69 |   inoremap <silent> <buffer> <SID>HtmlComplete <C-R>=<SID>htmlEn()<CR><C-X><C-O><C-P><C-R>=<SID>htmlDis()<CR><C-N>
 70 |   imap     <buffer> <C-X>H <SID>HtmlComplete
 71 |   inoremap <silent> <buffer> <C-X>$ <C-R>=<SID>javascriptIncludeTag()<CR>
 72 |   inoremap <silent> <buffer> <C-X>@ <C-R>=<SID>stylesheetTag()<CR>
 73 |   inoremap <silent> <buffer> <C-X><Space> <Esc>ciW<Lt><C-R>"<C-R>=<SID>tagextras()<CR>></<C-R>"><Esc>F<i
 74 |   inoremap <silent> <buffer> <C-X><CR> <Esc>ciW<Lt><C-R>"<C-R>=<SID>tagextras()<CR>><CR></<C-R>"><Esc>O
 75 |   if exists("&omnifunc")
 76 |     inoremap <silent> <buffer> <C-X>/ <Lt>/<C-R>=<SID>htmlEn()<CR><C-X><C-O><C-R>=<SID>htmlDis()<CR><C-R>=<SID>reindent()<CR>
 77 |     if exists(":XMLns")
 78 |       XMLns xhtml10s
 79 |     endif
 80 |   else
 81 |     inoremap <silent> <buffer> <C-X>/ <Lt>/><Left>
 82 |   endif
 83 |   let b:surround_{char2nr("p")} = "<p>\n\t\r\n</p>"
 84 |   let b:surround_{char2nr("d")} = "<div\1div: \r^[^ ]\r &\1>\n\t\r\n</div>"
 85 |   imap <buffer> <C-X><C-_> <C-X>/
 86 |   imap <buffer> <SID>ragtagOopen    <C-X><Lt><Space>
 87 |   imap <buffer> <SID>ragtagOclose   <Space><C-X>><Left><Left>
 88 |   if s:isFiletype('php')
 89 |     inoremap <buffer> <C-X><Lt> <?php
 90 |     inoremap <buffer> <C-X>>    ?>
 91 |     inoremap <buffer> <SID>ragtagOopen    <?php<Space>echo<Space>
 92 |     let b:surround_45 = "<?php \r ?>"
 93 |     let b:surround_61 = "<?= \r ?>"
 94 |   elseif s:isFiletype('htmltt') || s:isFiletype('tt2html')
 95 |     inoremap <buffer> <C-X><Lt> [%
 96 |     inoremap <buffer> <C-X>>    %]
 97 |     let b:surround_45  = "[% \r %]"
 98 |     let b:surround_61  = "[% \r %]"
 99 |     if !exists("b:surround_101")
100 |       let b:surround_101 = "[% \r %]\n[% END %]"
101 |     endif
102 |   elseif s:isFiletype('mustache')
103 |     inoremap <buffer> <SID>ragtagOopen    {{<Space>
104 |     inoremap <buffer> <SID>ragtagOclose   <Space>}}<Left><Left>
105 |     inoremap <buffer> <C-X><Lt> {{
106 |     inoremap <buffer> <C-X>>    }}
107 |     let b:surround_45 = "{{ \r }}"
108 |     let b:surround_61 = "{{ \r }}"
109 |   elseif s:isFiletype('django') || s:isFiletype('htmldjango') || s:isFiletype('liquid') || s:isFiletype('htmljinja')
110 |     inoremap <buffer> <SID>ragtagOopen    {{<Space>
111 |     inoremap <buffer> <SID>ragtagOclose   <Space>}}<Left><Left>
112 |     inoremap <buffer> <C-X><Lt> {%
113 |     inoremap <buffer> <C-X>>    %}
114 |     let b:surround_45 = "{% \r %}"
115 |     let b:surround_61 = "{{ \r }}"
116 |   elseif s:isFiletype('mason')
117 |     inoremap <buffer> <SID>ragtagOopen    <&<Space>
118 |     inoremap <buffer> <SID>ragtagOclose   <Space>&><Left><Left>
119 |     inoremap <buffer> <C-X><Lt> <%
120 |     inoremap <buffer> <C-X>>    %>
121 |     let b:surround_45 = "<% \r %>"
122 |     let b:surround_61 = "<& \r &>"
123 |   elseif s:isFiletype('cf')
124 |     inoremap <buffer> <SID>ragtagOopen    <cfoutput>
125 |     inoremap <buffer> <SID>ragtagOclose   </cfoutput><Left><C-Left><Left>
126 |     inoremap <buffer> <C-X><Lt> <cf
127 |     inoremap <buffer> <C-X>>    >
128 |     let b:surround_45 = "<cf\r>"
129 |     let b:surround_61 = "<cfoutput>\r</cfoutput>"
130 |   elseif s:isFiletype('smarty')
131 |     inoremap <buffer> <SID>ragtagOopen    {
132 |     inoremap <buffer> <SID>ragtagOclose   }
133 |     inoremap <buffer> <C-X><Lt> {
134 |     inoremap <buffer> <C-X>>    }
135 |     let b:surround_45 = "{\r}"
136 |     let b:surround_61 = "{\r}"
137 |   elseif s:isFiletype('handlebars')
138 |     inoremap <buffer> <SID>ragtagOopen    {{
139 |     inoremap <buffer> <SID>ragtagOclose   }}
140 |     inoremap <buffer> <C-X><Lt> {{
141 |     inoremap <buffer> <C-X>>    }}
142 |     let b:surround_45 = "{{\r}}"
143 |     let b:surround_61 = "{{\r}}"
144 |   elseif &filetype ==# 'html'
145 |     inoremap <buffer> <SID>ragtagOopen    <!--#echo var=
146 |     inoremap <buffer> <C-X><Lt> <!--#
147 |     inoremap <buffer> <C-X>>    -->
148 |     let b:surround_45 = "<!--#\r -->"
149 |     let b:surround_61 = "<!--#echo var=\r -->"
150 |   else
151 |     inoremap <buffer> <SID>ragtagOopen    <%=<Space>
152 |     inoremap <buffer> <C-X><Lt> <%
153 |     inoremap <buffer> <C-X>>    %>
154 |     let b:surround_45 = "<% \r %>"
155 |     let b:surround_61 = "<%= \r %>"
156 |   endif
157 |   imap <script> <buffer> <C-X>= <SID>ragtagOopen<SID>ragtagOclose<Left>
158 |   imap <script> <buffer> <C-X>+ <C-V><NL><Esc>I<SID>ragtagOopen<Esc>A<SID>ragtagOclose<Esc>F<NL>s
159 |   " <%\n\n%>
160 |   if s:isFiletype('cf')
161 |     inoremap <buffer> <C-X>] <cfscript><CR></cfscript><Esc>O
162 |   elseif s:isFiletype('mason')
163 |     inoremap <buffer> <C-X>] <%perl><CR></%perl><Esc>O
164 |   elseif &filetype ==# 'html' || &filetype ==# 'xml' || &filetype ==# 'xhtml'
165 |     imap     <buffer> <C-X>] <script<C-R>=<SID>javascriptType()<CR>><CR></script><Esc>O
166 |   else
167 |     imap     <buffer> <C-X>] <C-X><Lt><CR><C-X>><Esc>O
168 |   endif
169 |   " <% %>
170 |   if s:isFiletype('eruby') || s:isFiletype('jst')
171 |     inoremap  <buffer> <C-X>- <%<Space><Space>%><Esc>2hi
172 |     inoremap  <buffer> <C-X>_ <C-V><NL><Esc>I<%<Space><Esc>A<Space>%><Esc>F<NL>s
173 |   elseif s:isFiletype('cf')
174 |     inoremap  <buffer> <C-X>- <cf><Left>
175 |     inoremap  <buffer> <C-X>_ <cfset ><Left>
176 |   elseif s:isFiletype('smarty')
177 |     imap <buffer> <C-X>- <C-X><Lt><C-X>><Esc>i
178 |     imap <buffer> <C-X>_ <C-V><NL><Esc>I<C-X><Lt><Esc>A<C-X>><Esc>F<NL>s
179 |   else
180 |     imap <buffer> <C-X>- <C-X><Lt><Space><Space><C-X>><Esc>2hi
181 |     imap <buffer> <C-X>_ <C-V><NL><Esc>I<C-X><Lt><Space><Esc>A<Space><C-X>><Esc>F<NL>s
182 |   endif
183 |   " Comments
184 |   if s:isFiletype('aspperl') || s:isFiletype('aspvbs')
185 |     imap <buffer> <C-X>' <C-X><Lt>'<Space><Space><C-X>><Esc>2hi
186 |     imap <buffer> <C-X>" <C-V><NL><Esc>I<C-X><Lt>'<Space><Esc>A<Space><C-X>><Esc>F<NL>s
187 |     let b:surround_35 = maparg("<C-X><Lt>","i")."' \r ".maparg("<C-X>>","i")
188 |   elseif s:isFiletype('jsp') || s:isFiletype('gsp')
189 |     inoremap <buffer> <C-X>'     <Lt>%--<Space><Space>--%><Esc>4hi
190 |     inoremap <buffer> <C-X>"     <C-V><NL><Esc>I<%--<Space><Esc>A<Space>--%><Esc>F<NL>s
191 |     let b:surround_35 = "<%-- \r --%>"
192 |   elseif s:isFiletype('cf')
193 |     inoremap <buffer> <C-X>'     <Lt>!---<Space><Space>---><Esc>4hi
194 |     inoremap <buffer> <C-X>"     <C-V><NL><Esc>I<!---<Space><Esc>A<Space>---><Esc>F<NL>s
195 |     setlocal commentstring=<!---%s--->
196 |     let b:surround_35 = "<!--- \r --->"
197 |   elseif &filetype ==# 'html' || &filetype ==# 'xml' || &filetype ==# 'xhtml'
198 |     inoremap <buffer> <C-X>'     <Lt>!--<Space><Space>--><Esc>3hi
199 |     inoremap <buffer> <C-X>"     <C-V><NL><Esc>I<!--<Space><Esc>A<Space>--><Esc>F<NL>s
200 |     let b:surround_35 = "<!-- \r -->"
201 |   elseif s:isFiletype('django') || s:isFiletype('htmldjango') || s:isFiletype('htmljinja')
202 |     inoremap <buffer> <C-X>'     {#<Space><Space>#}<Esc>2hi
203 |     inoremap <buffer> <C-X>"     <C-V><NL><Esc>I<C-X>{#<Space><Esc>A<Space>#}<Esc>F<NL>s
204 |     let b:surround_35 = "{# \r #}"
205 |   elseif s:isFiletype('liquid')
206 |     inoremap <buffer> <C-X>'     {%<Space>comment<Space>%}{%<Space>endcomment<Space>%}<Esc>15hi
207 |     inoremap <buffer> <C-X>"     <C-V><NL><Esc>I<C-X>{%<Space>comment<Space>%}<Esc>A{%<Space>endcomment<Space>%}<Esc>F<NL>s
208 |     let b:surround_35 = "{% comment %}\r{% endcomment %}"
209 |   elseif s:isFiletype('smarty')
210 |     inoremap <buffer> <C-X>'     {*<Space><Space>*}<Esc>2hi
211 |     inoremap <buffer> <C-X>"     <C-V><NL><Esc>I<C-X>{*<Space><Esc>A<Space>*}<Esc>F<NL>s
212 |     let b:surround_35 = "{* \r *}"
213 |   elseif s:isFiletype('handlebars')
214 |     imap <script> <buffer> <C-X>= <SID>ragtagOopen<SID>ragtagOclose<Left><Left>
215 |     inoremap  <buffer> <C-X>_ <Esc>ciW{{#<C-R>"}}<CR>{{/<C-R>"}}<Esc>khi
216 |     inoremap  <buffer> <C-X>' {{!}}<Esc>hi
217 |     inoremap  <buffer> <C-X>" <C-V><NL><Esc>I{{!<Esc>A}}<Esc>F<NL>s
218 |   else
219 |     imap <buffer> <C-X>' <C-X><Lt>#<Space><Space><C-X>><Esc>2hi
220 |     imap <buffer> <C-X>" <C-V><NL><Esc>I<C-X><Lt>#<Space><Esc>A<Space><C-X>><Esc>F<NL>s
221 |     let b:surround_35 = maparg("<C-X><Lt>","i")."# \r ".maparg("<C-X>>","i")
222 |   endif
223 |   imap <buffer> <C-X>%           <Plug>ragtagUrlEncode
224 |   imap <buffer> <C-X>&           <Plug>ragtagXmlEncode
225 |   imap <buffer> <C-V>%           <Plug>ragtagUrlV
226 |   imap <buffer> <C-V>&           <Plug>ragtagXmlV
227 |   if !exists("b:did_indent")
228 |     if s:subtype() == "xml"
229 |       runtime! indent/xml.vim
230 |     else
231 |       runtime! indent/html.vim
232 |     endif
233 |   endif
234 |   if exists("g:html_indent_tags") && g:html_indent_tags !~ '\\|p\>'
235 |     let g:html_indent_tags = g:html_indent_tags.'\|p\|li\|dt\|dd'
236 |     let g:html_indent_tags = g:html_indent_tags.'\|article\|aside\|audio\|bdi\|canvas\|command\|datalist\|details\|figcaption\|figure\|footer\|header\|hgroup\|mark\|meter\|nav\|output\|progress\|rp\|rt\|ruby\|section\|summary\|time\|video'
237 |   endif
238 |   set indentkeys+=!^F
239 |   let b:surround_indent = 1
240 |   silent doautocmd User Ragtag
241 |   silent doautocmd User ragtag
242 | endfunction
243 | 
244 | function! s:Leave()
245 |   call s:disableescape()
246 | endfunction
247 | 
248 | function! s:length(str)
249 |   return strlen(substitute(a:str,'.','.','g'))
250 | endfunction
251 | 
252 | function! s:repeat(str,cnt)
253 |   let cnt = a:cnt
254 |   let str = ""
255 |   while cnt > 0
256 |     let str = str . a:str
257 |     let cnt = cnt - 1
258 |   endwhile
259 |   return str
260 | endfunction
261 | 
262 | function! s:reindent()
263 |   if (len(&indentexpr) || &cindent)
264 |     return "\<C-F>"
265 |   endif
266 |   return ""
267 | endfun
268 | 
269 | function! s:stylesheetType()
270 |   if s:subtype() == 'html5'
271 |     return ''
272 |   else
273 |     return ' type="text/css"'
274 |   endif
275 | endfunction
276 | 
277 | function! s:stylesheetTag()
278 |   if !exists("b:ragtag_stylesheet_link_tag")
279 |     if exists("b:allml_stylesheet_link_tag")
280 |       let b:ragtag_stylesheet_link_tag = b:allml_stylesheet_link_tag
281 |     else
282 |       let b:ragtag_stylesheet_link_tag = '<link rel="stylesheet"'.s:stylesheetType()." href=\"/stylesheets/\r.css\" />"
283 |     endif
284 |   endif
285 |   return s:insertTag(b:ragtag_stylesheet_link_tag)
286 | endfunction
287 | 
288 | function! s:javascriptType()
289 |   if s:subtype() == 'html5'
290 |     return ''
291 |   else
292 |     return ' type="text/javascript"'
293 |   endif
294 | endfunction
295 | 
296 | function! s:javascriptIncludeTag()
297 |   if !exists("b:ragtag_javascript_include_tag")
298 |     if exists("b:allml_javascript_include_tag")
299 |       let b:ragtag_javascript_include_tag = b:allml_javascript_include_tag
300 |     else
301 |       let b:ragtag_javascript_include_tag = '<script'.s:javascriptType()." src=\"/javascripts/\r.js\"></script>"
302 |     endif
303 |   endif
304 |   return s:insertTag(b:ragtag_javascript_include_tag)
305 | endfunction
306 | 
307 | function! s:insertTag(tag)
308 |   let tag = a:tag
309 |   if s:subtype() == "html"
310 |     let tag = substitute(a:tag,'\s*/>','>','g')
311 |   endif
312 |   let before = matchstr(tag,'^.\{-\}\ze\r')
313 |   let after  = matchstr(tag,'\r\zs\%(.*\r\)\@!.\{-\}$')
314 |   " middle isn't currently used
315 |   let middle = matchstr(tag,'\r\zs.\{-\}\ze\r')
316 |   return before.after.s:repeat("\<Left>",s:length(after))
317 | endfunction
318 | 
319 | function! s:htmlEn()
320 |   let b:ragtag_omni = &l:omnifunc
321 |   let b:ragtag_isk = &l:isk
322 |   let b:ragtag_completeopt = &l:completeopt
323 |   " : is for namespaced xml attributes
324 |   setlocal omnifunc=htmlcomplete#CompleteTags isk+=: completeopt=
325 |   return ""
326 | endfunction
327 | 
328 | function! s:htmlDis()
329 |   if exists("b:ragtag_omni")
330 |     let &l:omnifunc = b:ragtag_omni
331 |     unlet b:ragtag_omni
332 |   endif
333 |   if exists("b:ragtag_isk")
334 |     let &l:isk = b:ragtag_isk
335 |     unlet b:ragtag_isk
336 |   endif
337 |   if exists("b:ragtag_completeopt")
338 |     let &l:completeopt = b:ragtag_completeopt
339 |     unlet b:ragtag_completeopt
340 |   endif
341 |   return ""
342 | endfunction
343 | 
344 | function! s:subtype()
345 |   let top = getline(1)."\n".getline(2)
346 |   if (top =~ '<?xml\>' && &ft !~? 'html') || &ft =~? '^\%(xml\|xsd\|xslt\|docbk\)$'
347 |     return "xml"
348 |   elseif top =~? '\<xhtml\>'
349 |     return 'xhtml'
350 |   elseif top =~? '<!DOCTYPE html>'
351 |     return 'html5'
352 |   elseif top =~? '[^<]\<html\>'
353 |     return "html"
354 |   elseif s:isFiletype('xhtml')
355 |     return "xhtml"
356 |   elseif exists("b:loaded_ragtag")
357 |     return "html5"
358 |   else
359 |     return ""
360 |   endif
361 | endfunction
362 | 
363 | function! s:closetagback()
364 |   if s:subtype() == "html"
365 |     return ">\<Left>"
366 |   else
367 |     return " />\<Left>\<Left>\<Left>"
368 |   endif
369 | endfunction
370 | 
371 | function! s:closetag()
372 |   if s:subtype() == "html"
373 |     return ">"
374 |   else
375 |     return " />"
376 |   endif
377 | endfunction
378 | 
379 | function! s:charset()
380 |   let enc = &fileencoding
381 |   if enc == ""
382 |     let enc = &encoding
383 |   endif
384 |   if enc == "latin1"
385 |     return "ISO-8859-1"
386 |   elseif enc == ""
387 |     return "US-ASCII"
388 |   else
389 |     return enc
390 |   endif
391 | endfunction
392 | 
393 | function! s:charsetTag()
394 |   if s:subtype() == 'html5'
395 |     return '<meta charset="'.s:charset().'"'.s:closetag()
396 |   else
397 |     return '<meta http-equiv="Content-Type" content="text/html; charset='.s:charset().'"'.s:closetag()
398 |   endif
399 | endfunction
400 | 
401 | function! s:tagextras()
402 |   if s:subtype() == "xml"
403 |     return ""
404 |   elseif @" == 'html' && s:subtype() == 'xhtml'
405 |     let lang = "en"
406 |     if exists("$LANG") && $LANG =~ '^..'
407 |       let lang = strpart($LANG,0,2)
408 |     endif
409 |     return ' xmlns="http://www.w3.org/1999/xhtml" lang="'.lang.'" xml:lang="'.lang.'"'
410 |   elseif @" == 'style'
411 |     return s:stylesheetType()
412 |   elseif @" == 'script'
413 |     return s:javascriptType()
414 |   elseif @" == 'table'
415 |     return ' cellspacing="0"'
416 |   else
417 |     return ""
418 |   endif
419 | endfunction
420 | 
421 | inoremap <silent> <SID>urlspace <C-R>=<SID>getinput()=~?'\%([?&]\<Bar>&amp;\)[%a-z0-9._~+-]*=[%a-z0-9._~+-]*$'?'+':'%20'<CR>
422 | 
423 | function! s:urltab(htmlesc)
424 |   let line = s:getinput()
425 |   let g:line = line
426 |   if line =~ '[^ <>"'."'".']\@<!\w\+$'
427 |     return ":"
428 |   elseif line =~ '[^ <>"'."'".']\@<!\w\+:/\=/\=[%a-z0-9._~+-]*$'
429 |     return "/"
430 |   elseif line =~? '\%([?&]\|&amp;\)[%a-z0-9._~+-]*$'
431 |     return "="
432 |   elseif line =~? '\%([?&]\|&amp;\)[%a-z0-9._~+-]*=[%a-z0-9._~+-]*$'
433 |     if a:htmlesc || synIDattr(synID(line('.'),col('.')-1,1),"name") =~ 'mlString$'
434 |       return "&amp;"
435 |     else
436 |       return "&"
437 |     endif
438 |   elseif line =~ '/$\|\.\w\+$'
439 |     return "?"
440 |   else
441 |     return "/"
442 |   endif
443 | endfunction
444 | 
445 | function! s:toggleurlescape()
446 |   let htmllayer = 0
447 |   if exists("b:ragtag_escape_mode")
448 |     if b:ragtag_escape_mode == "url"
449 |       call s:disableescape()
450 |       return ""
451 |     elseif b:ragtag_escape_mode == "xml"
452 |       let htmllayer = 1
453 |     endif
454 |     call s:disableescape()
455 |   endif
456 |   let b:ragtag_escape_mode = "url"
457 |   imap     <buffer> <BS> <Plug>ragtagBSUrl
458 |   inoremap <buffer> <CR> %0A
459 |   imap <script> <buffer> <Space> <SID>urlspace
460 |   inoremap <buffer> <Tab> &
461 |   inoremap <buffer> <Bar> %7C
462 |   if htmllayer
463 |     inoremap <silent> <buffer> <Tab> <C-R>=<SID>urltab(1)<CR>
464 |   else
465 |     inoremap <silent> <buffer> <Tab> <C-R>=<SID>urltab(0)<CR>
466 |   endif
467 |   let i = 33
468 |   while i < 127
469 |     " RFC3986: reserved = :/?#[]@ !$&'()*+,;=
470 |     if nr2char(i) =~# '[|=A-Za-z0-9_.~-]'
471 |     else
472 |       call s:urlmap(nr2char(i))
473 |     endif
474 |     let i = i + 1
475 |   endwhile
476 |   return ""
477 | endfunction
478 | 
479 | function! s:urlencode(char)
480 |   let i = 0
481 |   let repl = ""
482 |   while i < strlen(a:char)
483 |     let repl  = repl . printf("%%%02X",char2nr(strpart(a:char,i,1)))
484 |     let i = i + 1
485 |   endwhile
486 |   return repl
487 | endfunction
488 | 
489 | function! s:urlmap(char)
490 |   let repl = s:urlencode(a:char)
491 |   exe "inoremap <buffer> ".a:char." ".repl
492 | endfunction
493 | 
494 | function! s:urlv()
495 |   return s:urlencode(nr2char(getchar()))
496 | endfunction
497 | 
498 | function! s:togglexmlescape()
499 |   if exists("b:ragtag_escape_mode")
500 |     if b:ragtag_escape_mode == "xml"
501 |       call s:disableescape()
502 |       return ""
503 |     endif
504 |     call s:disableescape()
505 |   endif
506 |   let b:ragtag_escape_mode = "xml"
507 |   imap <buffer> <BS> <Plug>ragtagBSXml
508 |   inoremap <buffer> <Lt> &lt;
509 |   inoremap <buffer> >    &gt;
510 |   inoremap <buffer> &    &amp;
511 |   inoremap <buffer> "    &quot;
512 |   return ""
513 | endfunction
514 | 
515 | function! s:disableescape()
516 |   if exists("b:ragtag_escape_mode")
517 |     if b:ragtag_escape_mode == "xml"
518 |       silent! iunmap <buffer> <BS>
519 |       silent! iunmap <buffer> <Lt>
520 |       silent! iunmap <buffer> >
521 |       silent! iunmap <buffer> &
522 |       silent! iunmap <buffer> "
523 |     elseif b:ragtag_escape_mode == "url"
524 |       silent! iunmap <buffer> <BS>
525 |       silent! iunmap <buffer> <Tab>
526 |       silent! iunmap <buffer> <CR>
527 |       silent! iunmap <buffer> <Space>
528 |       silent! iunmap <buffer> <Bar>
529 |       let i = 33
530 |       while i < 127
531 |         if nr2char(i) =~# '[|A-Za-z0-9_.~-]'
532 |         else
533 |           exe "silent! iunmap <buffer> ".nr2char(i)
534 |         endif
535 |         let i = i + 1
536 |       endwhile
537 |     endif
538 |     unlet b:ragtag_escape_mode
539 |   endif
540 | endfunction
541 | 
542 | function! s:getinput()
543 |   return strpart(getline('.'),0,col('.')-1)
544 | endfunction
545 | 
546 | function! s:bspattern(pattern)
547 |   let start = s:getinput()
548 |   let match = matchstr(start,'\%('.a:pattern.'\)$')
549 |   if match == ""
550 |     return "\<BS>"
551 |   else
552 |     return s:repeat("\<BS>",strlen(match))
553 |   endif
554 | endfunction
555 | 
556 | inoremap <silent> <Plug>ragtagBSUrl     <C-R>=<SID>bspattern('%\x\x\=\<Bar>&amp;')<CR>
557 | inoremap <silent> <Plug>ragtagBSXml     <C-R>=<SID>bspattern('&#\=\w*;\<Bar><[^><]*>\=')<CR>
558 | inoremap <silent>  <SID>ragtagUrlEncode <C-R>=<SID>toggleurlescape()<CR>
559 | inoremap <silent>  <SID>ragtagXmlEncode <C-R>=<SID>togglexmlescape()<CR>
560 | inoremap <silent> <Plug>ragtagUrlEncode <C-R>=<SID>toggleurlescape()<CR>
561 | inoremap <silent> <Plug>ragtagXmlEncode <C-R>=<SID>togglexmlescape()<CR>
562 | inoremap <silent> <Plug>ragtagUrlV      <C-R>=<SID>urlv()<CR>
563 | inoremap <silent> <Plug>ragtagXmlV      <C-R>="&#".getchar().";"<CR>
564 | 
565 | if get(g:, "ragtag_global_maps", 0)
566 |   imap     <C-X>H      <Plug>ragtagHtmlComplete
567 |   imap     <C-X>/    </<Plug>ragtagHtmlComplete
568 |   imap     <C-X>%      <Plug>ragtagUrlEncode
569 |   imap     <C-X>&      <Plug>ragtagXmlEncode
570 |   imap     <C-V>%      <Plug>ragtagUrlV
571 |   imap     <C-V>&      <Plug>ragtagXmlV
572 | endif
573 | 


--------------------------------------------------------------------------------