├── README
├── autoload
    └── camelcasemotion.vim
├── doc
    └── camelcasemotion.txt
└── plugin
    └── camelcasemotion.vim


/README:
--------------------------------------------------------------------------------
 1 | This is a mirror of http://www.vim.org/scripts/script.php?script_id=1905
 2 | 
 3 | DESCRIPTION
 4 | Vim provides many built-in motions, e.g. to move to the next word, or end of
 5 | the current word. Most programming languages use either CamelCase
 6 | ("anIdentifier") or underscore_notation ("an_identifier") naming conventions
 7 | for identifiers. The best way to navigate inside those identifiers using Vim
 8 | built-in motions is the [count]f{char} motion, i.e. f{uppercase-char} or f_,
 9 | respectively. But we can make this easier: 
10 | 
11 | This plugin defines motions ',w', ',b' and ',e' (similar to 'w', 'b', 'e'),
12 | which do not move word-wise (forward/backward), but Camel-wise; i.e. to word
13 | boundaries and uppercase letters. The motions also work on underscore notation,
14 | where words are delimited by underscore ('_') characters. From here on, both
15 | CamelCase and underscore_notation entities are referred to as "words" (in double
16 | quotes). Just like with the regular motions, a [count] can be prepended to move
17 | over multiple "words" at once. Outside of "words" (e.g. in non-keyword
18 | characters like // or ;), the new motions move just like the regular motions. 
19 | 
20 | Vim provides a built-in 'iw' text object called 'inner word', which works in
21 | operator-pending and visual mode. Analog to that, this plugin defines inner
22 | "word" motions 'i,w', 'i,b' and 'i,e', which select the "word" (or multiple
23 | "words" if a [count] is given) where the cursor is located. 
24 | 
25 | USAGE
26 | Use the new motions',w',',b' and ',e' in normal mode, operator-pending mode (cp.
27 | :help operator), and visual mode. For example, type 'bc,w' to change 'Camel' in
28 | 'CamelCase' to something else. 
29 | 
30 | EXAMPLE: motions
31 | Given the following CamelCase identifiers in a source code fragment:
32 |     set Script31337PathAndNameWithoutExtension11=%~dpn0
33 |     set Script31337PathANDNameWITHOUTExtension11=%~dpn0
34 | and the corresponding identifiers in underscore_notation:
35 |     set script_31337_path_and_name_without_extension_11=%~dpn0
36 |     set SCRIPT_31337_PATH_AND_NAME_WITHOUT_EXTENSION_11=%~dpn0
37 | 
38 | ,w moves to ([x] is cursor position): [s]et, [s]cript, [3]1337, [p]ath,
39 |     [a]nd, [n]ame, [w]ithout, [e]xtension, [1]1, [d]pn0, dpn[0], [s]et
40 | ,b moves to: [d]pn0, [1]1, [e]xtension, [w]ithout, ...
41 | ,e moves to: se[t], scrip[t], 3133[7], pat[h], an[d], nam[e], withou[t],
42 |     extensio[n], 1[1], dpn[0]
43 | 
44 | EXAMPLE: inner motions
45 | Given the following identifier, with the cursor positioned at [x]:
46 |     script_31337_path_and_na[m]e_without_extension_11
47 | 
48 | v3i,w selects script_31337_path_and_[name_without_extension_]11
49 | v3i,b selects script_31337_[path_and_name]_without_extension_11
50 | v3i,e selects script_31337_path_and_[name_without_extension]_11
51 | Instead of visual mode, you can also use c3i,w to change, d3i,w to delete,
52 | gU3i,w to upper-case, and so on. 
53 | 
54 | Source: Based on http://vim.wikia.com/wiki/Moving_through_camel_case_words by
55 | Anthony Van Ham.
56 | 


--------------------------------------------------------------------------------
/autoload/camelcasemotion.vim:
--------------------------------------------------------------------------------
  1 | " camelcasemotion.vim: Motion through CamelCaseWords and underscore_notation. 
  2 | "
  3 | " DEPENDENCIES:
  4 | "   - Requires Vim 7.0 or higher. 
  5 | "
  6 | " Copyright: (C) 2007-2011 Ingo Karkat
  7 | "   The VIM LICENSE applies to this script; see ':help copyright'. 
  8 | "
  9 | " Maintainer:	Ingo Karkat <ingo@karkat.de>
 10 | " REVISION	DATE		REMARKS 
 11 | "   1.52.002	18-Oct-2011	FIX: Correct forward-to-end motion over
 12 | "				lowercase part in "lowerCamel". Found this by
 13 | "				chance in GitHub fork by Kevin Lee (bkad). 
 14 | "				BUG: Correct wrong stop on second letter of
 15 | "				ACRONYM at the beginning of a word "AXBCText". 
 16 | "   1.50.001	05-May-2009	Do not create mappings for select mode;
 17 | "				according to|Select-mode|, printable character
 18 | "				commands should delete the selection and insert
 19 | "				the typed characters. 
 20 | "				Moved functions from plugin to separate autoload
 21 | "				script. 
 22 | "   				file creation
 23 | 
 24 | "- functions ------------------------------------------------------------------"
 25 | function! s:Move( direction, count, mode )
 26 |     " Note: There is no inversion of the regular expression character class
 27 |     " 'keyword character' (\k). We need an inversion "non-keyword" defined as
 28 |     " "any non-whitespace character that is not a keyword character" (e.g.
 29 |     " [!@#$%^&*()]). This can be specified via a non-whitespace character in
 30 |     " whose place no keyword character matches (\k\@!\S). 
 31 | 
 32 |     "echo "count is " . a:count
 33 |     let l:i = 0
 34 |     while l:i < a:count
 35 | 	if a:direction == 'e'
 36 | 	    " "Forward to end" motion. 
 37 | 	    "call search( '\>\|\(\a\|\d\)\+\ze_', 'We' )
 38 | 	    " end of ...
 39 | 	    " number | ACRONYM followed by CamelCase or number | lowercase followed by CamelCase, ACRONYM, or number | CamelCase | underscore_notation | non-keyword | word
 40 | 	    " Note: Branches are ordered from specific to unspecific so that
 41 | 	    " in case of multiple matches, the more specific (and usually
 42 | 	    " longer) one it used. 
 43 | 	    call search( '\d\+\|\u\+\ze\%(\u\l\|\d\)\|\l\+\ze\%(\u\|\d\)\|\u\l\+\|\%(\a\|\d\)\+\ze_\|\%(\k\@!\S\)\+\|\%(_\@!\k\)\+\>', 'We' )
 44 | 	    " Note: word must be defined as '\k\>'; '\>' on its own somehow
 45 | 	    " dominates over the previous branch. Plus, \k must exclude the
 46 | 	    " underscore, or a trailing one will be incorrectly moved over:
 47 | 	    " '\%(_\@!\k\)'. 
 48 | 	    if a:mode == 'o'
 49 | 		" Note: Special additional treatment for operator-pending mode
 50 | 		" "forward to end" motion. 
 51 | 		" The difference between normal mode, operator-pending and visual
 52 | 		" mode is that in the latter two, the motion must go _past_ the
 53 | 		" final "word" character, so that all characters of the "word" are
 54 | 		" selected. This is done by appending a 'l' motion after the
 55 | 		" search for the next "word". 
 56 | 		"
 57 | 		" In operator-pending mode, the 'l' motion only works properly
 58 | 		" at the end of the line (i.e. when the moved-over "word" is at
 59 | 		" the end of the line) when the 'l' motion is allowed to move
 60 | 		" over to the next line. Thus, the 'l' motion is added
 61 | 		" temporarily to the global 'whichwrap' setting. 
 62 | 		" Without this, the motion would leave out the last character in
 63 | 		" the line. I've also experimented with temporarily setting
 64 | 		" "set virtualedit=onemore" , but that didn't work. 
 65 | 		let l:save_ww = &whichwrap
 66 | 		set whichwrap+=l
 67 | 		normal! l
 68 | 		let &whichwrap = l:save_ww
 69 | 	    endif
 70 | 	else
 71 | 	    " Forward (a:direction == '') and backward (a:direction == 'b')
 72 | 	    " motion. 
 73 | 
 74 | 	    let l:direction = (a:direction == 'w' ? '' : a:direction)
 75 | 
 76 | 	    " CamelCase: Jump to beginning of either (start of word, Word, WORD,
 77 | 	    " 123). 
 78 | 	    " Underscore_notation: Jump to the beginning of an underscore-separated
 79 | 	    " word or number. 
 80 | 	    "call search( '\<\|\u', 'W' . l:direction )
 81 | 	    "call search( '\<\|\u\(\l\+\|\u\+\ze\u\)\|\d\+', 'W' . l:direction )
 82 | 	    "call search( '\<\|\u\(\l\+\|\u\+\ze\u\)\|\d\+\|_\zs\(\a\|\d\)\+', 'W' . l:direction )
 83 | 	    " beginning of ...
 84 | 	    " word | empty line | non-keyword after whitespaces | non-whitespace after word | number | start of ACRONYM followed by CamelCase or number | CamelCase | underscore followed by ACRONYM, Camel, lowercase or number
 85 | 	    " Note: Branches are ordered from unspecific to specific, so that
 86 | 	    " the cursor moves the least amount of text. 
 87 | 	    call search( '\<\D\|^$\|\%(^\|\s\)\+\zs\k\@!\S\|\>\S\|\d\+\|\u\@<!\u\+\ze\%(\u\l\|\d\)\|\u\l\+\|_\zs\%(\u\+\|\u\l\+\|\l\+\|\d\+\)', 'W' . l:direction )
 88 | 	    " Note: word must be defined as '\<\D' to avoid that a word like
 89 | 	    " 1234Test is moved over as [1][2]34[T]est instead of [1]234[T]est
 90 | 	    " because \< matches with zero width, and \d\+ will then start
 91 | 	    " matching '234'. To fix that, we make \d\+ be solely responsible
 92 | 	    " for numbers by taken this away from \< via \<\D. (An alternative
 93 | 	    " would be to replace \d\+ with \D\%#\zs\d\+, but that one is more
 94 | 	    " complex.) All other branches are not affected, because they match
 95 | 	    " multiple characters and not the same character multiple times. 
 96 | 	endif
 97 | 	let l:i = l:i + 1
 98 |     endwhile
 99 | endfunction
100 | 
101 | function! camelcasemotion#Motion( direction, count, mode )
102 | "*******************************************************************************
103 | "* PURPOSE:
104 | "   Perform the motion over CamelCaseWords or underscore_notation. 
105 | "* ASSUMPTIONS / PRECONDITIONS:
106 | "   none
107 | "* EFFECTS / POSTCONDITIONS:
108 | "   Move cursor / change selection. 
109 | "* INPUTS:
110 | "   a:direction	one of 'w', 'b', 'e'
111 | "   a:count	number of "words" to move over
112 | "   a:mode	one of 'n', 'o', 'v', 'iv' (latter one is a special visual mode
113 | "		when inside the inner "word" text objects. 
114 | "* RETURN VALUES: 
115 | "   none
116 | "*******************************************************************************
117 |     " Visual mode needs special preparations and postprocessing; 
118 |     " normal and operator-pending mode breeze through to s:Move(). 
119 | 
120 |     if a:mode == 'v'
121 | 	" Visual mode was left when calling this function. Reselecting the current
122 | 	" selection returns to visual mode and allows to call search() and issue
123 | 	" normal mode motions while staying in visual mode. 
124 | 	normal! gv
125 |     endif
126 |     if a:mode == 'v' || a:mode == 'iv'
127 | 
128 | 	" Note_1a:
129 | 	if &selection != 'exclusive' && a:direction == 'w'
130 | 	    normal! l
131 | 	endif
132 |     endif
133 | 
134 |     call s:Move( a:direction, a:count, a:mode )
135 | 
136 |     if a:mode == 'v' || a:mode == 'iv'
137 | 	" Note: 'selection' setting. 
138 | 	if &selection == 'exclusive' && a:direction == 'e'
139 | 	    " When set to 'exclusive', the "forward to end" motion (',e') does not
140 | 	    " include the last character of the moved-over "word". To include that, an
141 | 	    " additional 'l' motion is appended to the motion; similar to the
142 | 	    " special treatment in operator-pending mode. 
143 | 	    normal! l
144 | 	elseif &selection != 'exclusive' && a:direction != 'e'
145 | 	    " Note_1b:
146 | 	    " The forward and backward motions move to the beginning of the next "word".
147 | 	    " When 'selection' is set to 'inclusive' or 'old', this is one character too far. 
148 | 	    " The appended 'h' motion undoes this. Because of this backward step,
149 | 	    " though, the forward motion finds the current "word" again, and would
150 | 	    " be stuck on the current "word". An 'l' motion before the CamelCase
151 | 	    " motion (see Note_1a) fixes that. 
152 | 	    normal! h
153 | 	endif
154 |     endif
155 | endfunction
156 | 
157 | function! camelcasemotion#InnerMotion( direction, count )
158 |     " If the cursor is positioned on the first character of a CamelWord, the
159 |     " backward motion would move to the previous word, which would result in a
160 |     " wrong selection. To fix this, first move the cursor to the right, so that
161 |     " the backward motion definitely will cover the current "word" under the
162 |     " cursor. 
163 |     normal! l
164 |     
165 |     " Move "word" backwards, enter visual mode, then move "word" forward. This
166 |     " selects the inner "word" in visual mode; the operator-pending mode takes
167 |     " this selection as the area covered by the motion. 
168 |     if a:direction == 'b'
169 | 	" Do not do the selection backwards, because the backwards "word" motion
170 | 	" in visual mode + selection=inclusive has an off-by-one error. 
171 | 	call camelcasemotion#Motion( 'b', a:count, 'n' )
172 | 	normal! v
173 | 	" We decree that 'b' is the opposite of 'e', not 'w'. This makes more
174 | 	" sense at the end of a line and for underscore_notation. 
175 | 	call camelcasemotion#Motion( 'e', a:count, 'iv' )
176 |     else
177 | 	call camelcasemotion#Motion( 'b', 1, 'n' )
178 | 	normal! v
179 | 	call camelcasemotion#Motion( a:direction, a:count, 'iv' )
180 |     endif
181 | endfunction
182 | 
183 | " vim: set sts=4 sw=4 noexpandtab ff=unix fdm=syntax :
184 | 


--------------------------------------------------------------------------------
/doc/camelcasemotion.txt:
--------------------------------------------------------------------------------
  1 | *camelcasemotion.txt*   Motion through CamelCaseWords and underscore_notation. 
  2 | 
  3 | 		     CAMEL CASE MOTION    by Ingo Karkat
  4 | 							 *camelcasemotion.vim*
  5 | description			|camelcasemotion-description|
  6 | usage				|camelcasemotion-usage|
  7 | installation			|camelcasemotion-installation|
  8 | configuration			|camelcasemotion-configuration|
  9 | known problems			|camelcasemotion-known-problems|
 10 | todo				|camelcasemotion-todo|
 11 | history				|camelcasemotion-history|
 12 | 
 13 | ==============================================================================
 14 | DESCRIPTION					 *camelcasemotion-description*
 15 | 
 16 | Vim provides many built-in motions, e.g. to move to the next word, or end of
 17 | the current word. Most programming languages use either CamelCase
 18 | ("anIdentifier") or underscore_notation ("an_identifier") naming conventions
 19 | for identifiers. The best way to navigate inside those identifiers using Vim
 20 | built-in motions is the [count]f{char} motion, i.e. f{uppercase-char} or f_,
 21 | respectively. But we can make this easier: 
 22 | 
 23 | This plugin defines motions |,w| |,b| and |,e| (similar to |w| |b| |e|), which do
 24 | not move word-wise (forward/backward), but Camel-wise; i.e. to word boundaries
 25 | and uppercase letters. The motions also work on underscore notation, where
 26 | words are delimited by underscore ('_') characters. From here on, both
 27 | CamelCase and underscore_notation entities are referred to as "words" (in
 28 | double quotes). Just like with the regular motions, a [count] can be prepended
 29 | to move over multiple "words" at once. Outside of "words" (e.g. in non-keyword
 30 | characters like // or ;), the new motions move just like the regular motions. 
 31 | 
 32 | Vim provides a built-in |iw| text object called 'inner word', which works in
 33 | operator-pending and visual mode. Analog to that, this plugin defines inner
 34 | "word" motions |i,w| |i,b| and |i,e|, which select the "word" (or multiple
 35 | "words" if a [count] is given) where the cursor is located. 
 36 | 
 37 | ==============================================================================
 38 | USAGE						       *camelcasemotion-usage*
 39 | 								*,w* *,b* *,e*
 40 | Use the new motions |,w| |,b| and |,e| in normal mode, operator-pending mode
 41 | (cp. |operator|), and visual mode. For example, type bc,w to change "Camel"
 42 | in "CamelCase" to something else. 
 43 | 
 44 | 
 45 | EXAMPLE: motions
 46 | Given the following CamelCase identifiers in a source code fragment:
 47 |     set Script31337PathAndNameWithoutExtension11=%~dpn0 ~
 48 |     set Script31337PathANDNameWITHOUTExtension11=%~dpn0 ~
 49 | and the corresponding identifiers in underscore_notation:
 50 |     set script_31337_path_and_name_without_extension_11=%~dpn0 ~
 51 |     set SCRIPT_31337_PATH_AND_NAME_WITHOUT_EXTENSION_11=%~dpn0 ~
 52 | 
 53 | ,w moves to ([x] is cursor position): [s]et, [s]cript, [3]1337, [p]ath,
 54 |     [a]nd, [n]ame, [w]ithout, [e]xtension, [1]1, [d]pn0, dpn[0], [s]et
 55 | ,b moves to: [d]pn0, [1]1, [e]xtension, [w]ithout, ...
 56 | ,e moves to: se[t], scrip[t], 3133[7], pat[h], an[d], nam[e], withou[t],
 57 |     extensio[n], 1[1], dpn[0]
 58 | 
 59 | 
 60 | EXAMPLE: inner motions
 61 | Given the following identifier, with the cursor positioned at [x]:
 62 |     script_31337_path_and_na[m]e_without_extension_11 ~
 63 | 
 64 | v3i,w selects script_31337_path_and_[name_without_extension_]11
 65 | v3i,b selects script_31337_[path_and_name]_without_extension_11
 66 | v3i,e selects script_31337_path_and_[name_without_extension]_11
 67 | Instead of visual mode, you can also use c3i,w to change, d3i,w to delete,
 68 | gU3i,w to upper-case, and so on. 
 69 | 
 70 | ==============================================================================
 71 | INSTALLATION					*camelcasemotion-installation*
 72 | 
 73 | This script is packaged as a |vimball|. If you have the "gunzip" decompressor
 74 | in your PATH, simply edit the *.vba.gz package in Vim; otherwise, decompress
 75 | the archive first, e.g. using WinZip. Inside Vim, install by sourcing the
 76 | vimball or via the |:UseVimball| command. >
 77 |     vim camelcasemotion.vba.gz
 78 |     :so %
 79 | To uninstall, use the |:RmVimball| command. 
 80 | 
 81 | DEPENDENCIES					*camelcasemotion-dependencies*
 82 | 
 83 | - Requires Vim 7.0 or higher. 
 84 | 
 85 | ==============================================================================
 86 | CONFIGURATION				       *camelcasemotion-configuration*
 87 | 
 88 | By default, all mappings start with |,| (comma) as the map leader instead of
 89 | using <Leader>. I personally find the default <Leader> key too far off the
 90 | keyboard to be useful for custom motions (which also cannot be repeated via
 91 | the |.| (dot) command, so they should be very fast to type repeatedly), but
 92 | quite suitable for general, less frequently used custom mappings. 
 93 | To avoid losing the (rarely used) |,| mapping (which repeats latest f, t, F or
 94 | T in opposite direction), you can remap it to ,,: >
 95 |     nnoremap ,, ,
 96 |     xnoremap ,, ,
 97 |     onoremap ,, ,
 98 | 
 99 | If you want to use different mappings, map your keys to the
100 | <Plug>CamelCaseMotion_? mapping targets _before_ sourcing this script (e.g. in
101 | your |vimrc|).  
102 | 
103 | EXAMPLE: Replace the default |w|, |b| and |e| mappings instead of defining
104 | additional mappings |,w|, |,b|  and |,e| : >
105 |     map w <Plug>CamelCaseMotion_w
106 |     map b <Plug>CamelCaseMotion_b
107 |     map e <Plug>CamelCaseMotion_e
108 |     sunmap w
109 |     sunmap b
110 |     sunmap e
111 | 
112 | EXAMPLE: Replace default |iw| text-object and define |ib| and  |ie| motions: >
113 |     omap iw <Plug>CamelCaseMotion_iw
114 |     xmap iw <Plug>CamelCaseMotion_iw
115 |     omap ib <Plug>CamelCaseMotion_ib
116 |     xmap ib <Plug>CamelCaseMotion_ib
117 |     omap ie <Plug>CamelCaseMotion_ie
118 |     xmap ie <Plug>CamelCaseMotion_ie
119 | 
120 | ==============================================================================
121 | KNOWN PROBLEMS				      *camelcasemotion-known-problems*
122 | 
123 | - A degenerate CamelCaseWord containing '\U\u\d' (e.g. "MaP1Roblem") confuses
124 |   the operator-pending and visual mode ,e mapping if 'selection' is not set to
125 |   "exclusive". It'll skip "P" and select "P1" in one step. As a workaround,
126 |   use ',w' instead of ',e'; those two mappings have the same effect inside
127 |   CamelCaseWords, anyway. 
128 | - The operator-pending and visual mode ,e mapping doesn't work properly when
129 |   it reaches the end of the buffer; the final character of the moved-over
130 |   "word" remains, and a beep is issued. As a workaround, use the default 'e'
131 |   motion instead of ',e'. 
132 | - When the Vim setting 'selection' is not set to "exclusive", a
133 |   forward-backward combination in visual mode (e.g. 'v,w,b') selects one
134 |   additional character to the left, instead of only the character where the
135 |   motion started. Likewise, extension of the visual selection from the front
136 |   end is off by one additional character. 
137 | 
138 | ==============================================================================
139 | TODO							*camelcasemotion-todo*
140 | 
141 | IDEAS						       *camelcasemotion-ideas*
142 | 
143 | - Use search('\%#.\%$', 'cnW') to detect the operator-pending motion to the
144 |   end of the buffer and temporarily append a new line / space character to
145 |   work around the end-of-buffer problem. Unfortunately, the addition cannot be
146 |   undone as part of the motion (won't work then), so we'd have to use an
147 |   autocmd to remove it later. 
148 | 
149 | - Make separator character (currently underscore) configurable so that dashes,
150 |   asterisks, etc. can be added as well. Idea is to replace the single /_/ with
151 |   a collection /[-_*]/ built from g:CamelCaseMotion_SeparatorCharacters. Check
152 |   out interference with containment in 'iskeyword' and think through need to
153 |   buffer-local setting. (Submitted anonymously 13-Nov-2010 on Vim Tips Wiki.) 
154 | 
155 | ==============================================================================
156 | HISTORY						     *camelcasemotion-history*
157 | 
158 | 1.52	12-Nov-2011
159 | - FIX: Correct forward-to-end motion over lowercase part in "lowerCamel".
160 |   Found this by chance in GitHub fork by Kevin Lee (bkad). 
161 | - BUG: Correct wrong stop on second letter of ACRONYM at the beginning of a
162 |   word "AXBCText". 
163 | - The motion functionality is automatically tested via a runVimTests
164 |   (vimscript #2565) test suite. 
165 | 
166 | 1.51	30-Sep-2011
167 | Use <silent> for <Plug> mapping instead of default mapping. 
168 | 
169 | 1.50	05-May-2009
170 | - Do not create mappings for select mode; according to |Select-mode|,
171 |   printable character commands should delete the selection and insert the
172 |   typed characters. Now using :xmap to only target visual mode. 
173 | - Moved functions from plugin to separate autoload script. 
174 | - Split off documentation into separate help file. Now packaging as VimBall. 
175 | 
176 | 1.40	30-Jun-2008
177 | BF: Now using :normal! to be independent from any user mappings. Thanks to
178 | Neil Walker for the patch.
179 | 
180 | 1.40	19-May-2008
181 | BF: Wrong forward motion stop at the second digit if a word starts with
182 | multiple numbers (e.g. 1234.56789). Thanks to Wasim Ahmed for reporting this.
183 | 
184 | 1.40	24-Apr-2008
185 | ENH: Added inner "word" text objects 'i,w' etc. that work analoguous to the
186 | built-in |iw| text object. Thanks to David Kotchan for this suggestion.
187 | 
188 | 1.30	20-Apr-2008
189 | The motions now also stop at non-keyword boundaries, just like the regular
190 | motions. This has no effect inside a CamelCaseWord or inside
191 | underscore_notation, but it makes the motions behave like the regular motions
192 | (which is important if you replace the default motions). Thanks to Mun Johl
193 | for reporting this. 
194 | 
195 | 1.30	09-Apr-2008
196 | - Allowing users to use mappings different than ,w ,b ,e by defining
197 |   <Plug>CamelCaseMotion_? target mappings. This can even be used to replace
198 |   the default 'w', 'b' and 'e' mappings, as suggested by Mun Johl.
199 | - Now requires VIM 7.0 or higher. 
200 | 
201 | 1.20	29-May-2007
202 | ENH: The visual mode motions now also (mostly) work with the (default) setting
203 | 'set selection=inclusive', instead of selecting one character too much. 
204 | 
205 | 1.10	28-May-2007
206 | Incorporated major improvements and simplifications done by Joseph Barker. 
207 | 
208 | 1.00	22-May-2007
209 | First published version. 
210 | 
211 | 0.01	11-Oct-2005
212 | Started development based on vimtip #1016 by Anthony Van Ham. 
213 | 
214 | ==============================================================================
215 | Copyright: (C) 2007-2011 Ingo Karkat
216 | The VIM LICENSE applies to this script; see |copyright|. 
217 | 
218 | Maintainer:	Ingo Karkat <ingo@karkat.de>
219 | ==============================================================================
220 |  vim:tw=78:ts=8:ft=help:norl:
221 | 


--------------------------------------------------------------------------------
/plugin/camelcasemotion.vim:
--------------------------------------------------------------------------------
  1 | " camelcasemotion.vim: Motion through CamelCaseWords and underscore_notation. 
  2 | "
  3 | " DEPENDENCIES:
  4 | "   - Requires Vim 7.0 or higher. 
  5 | "   - camelcasemotion.vim autoload script. 
  6 | "
  7 | " Copyright: (C) 2007-2011 Ingo Karkat
  8 | "   The VIM LICENSE applies to this script; see ':help copyright'. 
  9 | "
 10 | " Source: Based on vimtip #1016 by Anthony Van Ham. 
 11 | " Maintainer:	Ingo Karkat <ingo@karkat.de>
 12 | " REVISION	DATE		REMARKS 
 13 | "   1.51.020	30-Sep-2011	Use <silent> for <Plug> mapping instead of
 14 | "				default mapping. 
 15 | "   1.50.019	05-May-2009	Do not create mappings for select mode;
 16 | "				according to|Select-mode|, printable character
 17 | "				commands should delete the selection and insert
 18 | "				the typed characters. 
 19 | "   				Moved functions from plugin to separate autoload
 20 | "				script. 
 21 | "   				Split off documentation into separate help file. 
 22 | "   				Now cleaning up Create...Mappings functions. 
 23 | "   1.40.018	30-Jun-2008	Minor: Removed unnecessary <script> from
 24 | "				mappings. 
 25 | "   1.40.017	19-May-2008	BF: Now using :normal! to be independent from
 26 | "				any user mappings. Thanks to Neil Walker for the
 27 | "				patch. 
 28 | "   1.40.016	28-Apr-2008	BF: Wrong forward motion stop at the second
 29 | "				digit if a word starts with multiple numbers
 30 | "				(e.g. 1234.56789). Thanks to Wasim Ahmed for
 31 | "				reporting this. 
 32 | "   1.40.015	24-Apr-2008	ENH: Added inner "word" text objects 'i,w' etc.
 33 | "				that work analogous to the built-in 'iw' text
 34 | "				object. Thanks to David Kotchan for this
 35 | "				suggestion. 
 36 | "   1.30.014	20-Apr-2008	The motions now also stop at non-keyword
 37 | "				boundaries, just like the regular motions. This
 38 | "				has no effect inside a CamelCaseWord or inside
 39 | "				underscore_notation, but it makes the motions
 40 | "				behave like the regular motions (which is
 41 | "				important if you replace the default motions). 
 42 | "				Thanks to Mun Johl for reporting this. 
 43 | "				Now using non-capturing parentheses \%() in the
 44 | "				patterns. 
 45 | "   1.30.013	09-Apr-2008	Refactored away s:VisualCamelCaseMotion(). 
 46 | "				Allowing users to use mappings different than
 47 | "				,w ,b ,e by defining <Plug>CamelCaseMotion_?
 48 | "				target mappings. This can even be used to
 49 | "				replace the default 'w', 'b' and 'e' mappings,
 50 | "				as suggested by Mun Johl. 
 51 | "				Mappings are now created in a generic function. 
 52 | "				Now requires Vim 7.0 or higher. 
 53 | "   1.20.012	02-Jun-2007	BF: Corrected motions through mixed
 54 | "				CamelCase_and_UnderScore words by re-ordering
 55 | "				and narrowing the search patterns.  
 56 | "   1.20.011	02-Jun-2007	Thanks again to Joseph Barker for discussing the
 57 | "				complicated visual mode mapping on the vim-dev
 58 | "				mailing list and coming up with a great
 59 | "				simplification:
 60 | "				Removed s:CheckForChangesToTheSelectionSetting().
 61 | "				Introduced s:VisualCamelCaseMotion(), which
 62 | "				handles the differences depending on the
 63 | "				'selection' setting. 
 64 | "				Visual mode mappings now directly map to the
 65 | "				s:VisualCamelCaseMotion() function; no mark is
 66 | "				clobbered, the complex mapping with the inline
 67 | "				expression has been retired. 
 68 | "   1.20.010	29-May-2007	BF: The operator-pending and visual mode ,e
 69 | "				mapping doesn't work properly when it reaches
 70 | "				the end of line; the final character of the
 71 | "				moved-over "word" remains. Fixed this problem
 72 | "				unless the "word" is at the very end of the
 73 | "				buffer. 
 74 | "				ENH: The visual mode motions now also (mostly)
 75 | "				work with the (default) setting
 76 | "				'set selection=inclusive', instead of selecting
 77 | "				one character too much. 
 78 | "				ENH: All mappings will check for changes to the
 79 | "				'selection' setting and remap the visual mode
 80 | "				mappings via function
 81 | "				s:SetupVisualModeMappings(). We cannot rely on
 82 | "				the setting while sourcing camelcasemotion.vim
 83 | "				because the mswin.vim script may be sourced
 84 | "				afterwards, and its 'behave mswin' changes
 85 | "				'selection'. 
 86 | "				Refactored the arguments of function 
 87 | "				s:CamelCaseMotion(...). 
 88 | "   1.10.009	28-May-2007	BF: Degenerate CamelCaseWords that consist of
 89 | "				only a single uppercase letter (e.g. "P" in
 90 | "				"MapPRoblem") are skipped by all motions. Thanks
 91 | "				to Joseph Barker for reporting this. 
 92 | "				BF: In CamelCaseWords that consist of uppercase
 93 | "				letters followed by decimals (e.g.
 94 | "				"MyUPPER123Problem", the uppercase "word" is
 95 | "				skipped by all motions. 
 96 | "   1.10.008	28-May-2007	Incorporated major improvements and
 97 | "				simplifications done by Joseph Barker:
 98 | "				Operator-pending and visual mode motions now
 99 | "				accept [count] of more than 9. 
100 | "				Visual selections can now be extended from
101 | "				either end. 
102 | "				Instead of misusing the :[range], the special
103 | "				variable v:count1 is used. Custom commands are
104 | "				not needed anymore. 
105 | "				Operator-pending and visual mode mappings are
106 | "				now generic: There's only a single mapping for
107 | "				,w that can be repeated, rather than having a
108 | "				separate mapping for 1,w 2,w 3,w ...
109 | "   1.00.007	22-May-2007	Added documentation for publication. 
110 | "	006	20-May-2007	BF: visual mode [1,2,3],e on pure CamelCase
111 | "				mistakenly marks [2,4,6] words. If the cursor is
112 | "				on a uppercase letter, the search pattern
113 | "				'\u\l\+' doesn't match at the cursor position,
114 | "				so another match won. Changed search pattern
115 | "				from '\l\+', 
116 | "	005	16-May-2007	Added support for underscore notation. 
117 | "				Added support for "forward to end of word"
118 | "				(',e') motion. 
119 | "	004	16-May-2007	Improved search pattern so that
120 | "				UppercaseWORDSInBetween and digits are handled,
121 | "				too. 
122 | "	003	15-May-2007	Changed mappings from <Leader>w to ,w; 
123 | "				other \w mappings interfere here, because it's
124 | "				irritating when the cursor jump doesn't happen
125 | "				immediately, because Vim waits whether the
126 | "				mapping is complete. ,w is faster to type that
127 | "				\w (and, because of the left-right touch,
128 | "				preferred over gw). 
129 | "				Added visual mode mappings. 
130 | "	0.02	15-Feb-2006	BF: missing <SID> for omaps. 
131 | "	0.01	11-Oct-2005	file creation
132 | 
133 | " Avoid installing twice or when in compatible mode
134 | if exists('g:loaded_camelcasemotion') || (v:version < 700)
135 |     finish
136 | endif
137 | let g:loaded_camelcasemotion = 1
138 | 
139 | "- mappings -------------------------------------------------------------------
140 | " The count is passed into the function through the special variable 'v:count1',
141 | " which is easier than misusing the :[range] that :call supports. 
142 | " <C-U> is used to delete the unused range. 
143 | " Another option would be to use a custom 'command! -count=1', but that doesn't
144 | " work with the normal mode mapping: When a count is typed before the mapping,
145 | " the ':' will convert a count of 3 into ':.,+2MyCommand', but ':3MyCommand'
146 | " would be required to use -count and <count>. 
147 | "
148 | " We do not provide the fourth "backward to end" motion (,E), because it is
149 | " seldomly used. 
150 | 
151 | function! s:CreateMotionMappings()
152 |     " Create mappings according to this template:
153 |     " (* stands for the mode [nov], ? for the underlying motion [wbe].) 
154 |     "
155 |     " *noremap <silent> <Plug>CamelCaseMotion_? :<C-U>call camelcasemotion#Motion('?',v:count1,'*')<CR>
156 |     " if ! hasmapto('<Plug>CamelCaseMotion_?', '*')
157 |     "	  *map ,? <Plug>CamelCaseMotion_?
158 |     " endif
159 | 
160 |     for l:mode in ['n', 'o', 'v']
161 | 	for l:motion in ['w', 'b', 'e']
162 | 	    let l:targetMapping = '<Plug>CamelCaseMotion_' . l:motion
163 | 	    execute l:mode . 'noremap <silent> ' . l:targetMapping . ' :<C-U>call camelcasemotion#Motion(''' . l:motion . ''',v:count1,''' . l:mode . ''')<CR>'
164 | 	    if ! hasmapto(l:targetMapping, l:mode)
165 | 		execute (l:mode ==# 'v' ? 'x' : l:mode) . 'map ,' . l:motion . ' ' . l:targetMapping 
166 | 	    endif
167 | 	endfor
168 |     endfor
169 | endfunction
170 | 
171 | " To create a text motion, a mapping for operator-pending mode needs to be
172 | " defined. This mapping should move the cursor according to the implemented
173 | " motion, or mark the covered text via a visual selection. As inner text motions
174 | " need to mark both to the left and right of the cursor position, the visual
175 | " selection needs to be used. 
176 | "
177 | " Vim's built-in inner text objects also work in visual mode; they have
178 | " different behavior depending on whether visual mode has just been entered or
179 | " whether text has already been selected. 
180 | " We deviate from that and always override the existing selection. 
181 | function! s:CreateInnerMotionMappings()
182 |     " Create mappings according to this template:
183 |     " (* stands for the mode [ov], ? for the underlying motion [wbe].) 
184 |     "
185 |     " *noremap <silent> <Plug>CamelCaseMotion_i? :<C-U>call camelcasemotion#InnerMotion('?',v:count1)<CR>
186 |     " if ! hasmapto('<Plug>CamelCaseInnerMotion_i?', '*')
187 |     "	  *map i,? <Plug>CamelCaseInnerMotion_i?
188 |     " endif
189 | 
190 |     for l:mode in ['o', 'v']
191 | 	for l:motion in ['w', 'b', 'e']
192 | 	    let l:targetMapping = '<Plug>CamelCaseMotion_i' . l:motion
193 | 	    execute l:mode . 'noremap <silent> ' . l:targetMapping . ' :<C-U>call camelcasemotion#InnerMotion(''' . l:motion . ''',v:count1)<CR>'
194 | 	    if ! hasmapto(l:targetMapping, l:mode)
195 | 		execute (l:mode ==# 'v' ? 'x' : l:mode) . 'map i,' . l:motion . ' ' . l:targetMapping 
196 | 	    endif
197 | 	endfor
198 |     endfor
199 | endfunction
200 | 
201 | call s:CreateMotionMappings()
202 | call s:CreateInnerMotionMappings()
203 | 
204 | delfunction s:CreateMotionMappings
205 | delfunction s:CreateInnerMotionMappings
206 | 
207 | " vim: set sts=4 sw=4 noexpandtab ff=unix fdm=syntax :
208 | 


--------------------------------------------------------------------------------