├── .gitignore
├── .travis.yml
├── README.md
├── lib
    └── oop.ex
├── logo
    ├── logo.png
    ├── logo.svg
    └── logotype_horizontal.png
├── mix.exs
└── test
    ├── oop_test.exs
    └── test_helper.exs


/.gitignore:
--------------------------------------------------------------------------------
1 | /_build
2 | /cover
3 | /deps
4 | erl_crash.dump
5 | *.ez
6 | 


--------------------------------------------------------------------------------
/.travis.yml:
--------------------------------------------------------------------------------
1 | language: elixir
2 | sudo: false
3 | elixir:
4 | - 1.3.4
5 | otp_release:
6 | - 18.2
7 | 


--------------------------------------------------------------------------------
/README.md:
--------------------------------------------------------------------------------
  1 | <h1 align="center"> <br><img src="logo/logotype_horizontal.png?raw=true" alt="oop" width="256"> <br>
  2 | 
  3 | # OOP
  4 | 
  5 | [![Build Status](https://travis-ci.org/wojtekmach/oop.svg?branch=master)](https://travis-ci.org/wojtekmach/oop)
  6 | 
  7 | Are you tired of all of that modules, processes and functions nonsense? Do you want to just use classes, objects and methods? If so, use OOP [1] library in Elixir [2]!
  8 | 
  9 | ## Demo
 10 | 
 11 | [![Lightning Talks - Wojtek Mach (ElixirConfEU 2016)](https://img.youtube.com/vi/5EtV2JUU0Z4/0.jpg)](https://www.youtube.com/watch?v=5EtV2JUU0Z4)
 12 | 
 13 | ## Example
 14 | 
 15 | ```elixir
 16 | import OOP
 17 | 
 18 | class Person do
 19 |   var :name
 20 | 
 21 |   def say_hello_to(who) do
 22 |     what = "Hello #{who.name}"
 23 |     IO.puts("#{this.name}: #{what}")
 24 |   end
 25 | end
 26 | 
 27 | joe = Person.new(name: "Joe")
 28 | mike = Person.new(name: "Mike")
 29 | robert = Person.new(name: "Robert")
 30 | 
 31 | joe.say_hello_to(mike)    # Joe: Hello Mike
 32 | mike.say_hello_to(joe)    # Mike: Hello Joe
 33 | mike.say_hello_to(robert) # Mike: Hello Robert
 34 | robert.say_hello_to(mike) # Robert: Hello Mike
 35 | 
 36 | joe.set_name("Hipster Joe")
 37 | joe.name # => Hipster Joe
 38 | ```
 39 | 
 40 | An OOP library wouldn't be complete without inheritance:
 41 | 
 42 | ```elixir
 43 | class Animal do
 44 |   var :name
 45 | end
 46 | 
 47 | class Dog < Animal do
 48 |   var :breed
 49 | end
 50 | 
 51 | snuffles = Dog.new(name: "Snuffles", breed: "Shih Tzu")
 52 | snuffles.name # => "Snuffles"
 53 | snuffles.breed # => "Shih Tzu"
 54 | ```
 55 | 
 56 | ... or multiple inheritance:
 57 | 
 58 | ```elixir
 59 | class Human do
 60 |   var :name
 61 | end
 62 | 
 63 | class Horse do
 64 |   var :horseshoes_on?
 65 | end
 66 | 
 67 | class Centaur < [Human, Horse] do
 68 | end
 69 | 
 70 | john = Centaur.new(name: "John", horseshoes_on?: true)
 71 | john.name # => "John"
 72 | john.horseshoes_on? # => true
 73 | ```
 74 | 
 75 | See more usage in the [test suite](test/oop_test.exs).
 76 | 
 77 | ## Installation
 78 | 
 79 | Add `oop` to your list of dependencies in `mix.exs`:
 80 | 
 81 | ```elixir
 82 | def deps do
 83 |   [{:oop, "~> 0.1.0"}]
 84 | end
 85 | ```
 86 | 
 87 | [1] According to Alan Kay, the inventor of OOP, "objects" is the lesser idea; the big idea is "messaging". In that sense, I can't agree more with Joe Armstrong's quote that Erlang is "possibly the only object-oriented language".
 88 | 
 89 | [2] Please don't. You've been warned.
 90 | 
 91 | ## License
 92 | 
 93 | The MIT License (MIT)
 94 | 
 95 | Copyright (c) 2015 Wojciech Mach
 96 | 
 97 | Permission is hereby granted, free of charge, to any person obtaining a copy of this software and associated documentation files (the "Software"), to deal in the Software without restriction, including without limitation the rights to use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software, and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
 98 | 
 99 | The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
100 | 
101 | THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
102 | 


--------------------------------------------------------------------------------
/lib/oop.ex:
--------------------------------------------------------------------------------
  1 | defmodule OOP.Registry do
  2 |   def start_link do
  3 |     Agent.start_link(fn -> %{} end, name: __MODULE__)
  4 |   end
  5 | 
  6 |   def register(pid, class) do
  7 |     Agent.update(__MODULE__, &Map.put(&1, pid, class))
  8 |   end
  9 | 
 10 |   def get(pid) do
 11 |     Agent.get(__MODULE__, &Map.get(&1, pid, nil))
 12 |   end
 13 | end
 14 | 
 15 | defmodule OOP.Application do
 16 |   use Application
 17 | 
 18 |   def start(_type, _args) do
 19 |     OOP.Registry.start_link()
 20 |   end
 21 | end
 22 | 
 23 | defmodule OOP.Builder do
 24 |   def create_class(class, superclasses, block, opts) do
 25 |     quote do
 26 |       defmodule unquote(class) do
 27 |         OOP.Builder.ensure_can_be_subclassed(unquote(superclasses))
 28 | 
 29 |         @final Keyword.get(unquote(opts), :final, false)
 30 | 
 31 |         def __final__? do
 32 |           @final
 33 |         end
 34 | 
 35 |         def new(data \\ [], descendant? \\ false) do
 36 |           OOP.Builder.ensure_can_be_instantiated(unquote(class), descendant?, unquote(opts))
 37 | 
 38 | 
 39 |           object = :"#{unquote(class)}#{:erlang.unique_integer()}"
 40 | 
 41 |           defmodule object do
 42 |             use GenServer
 43 | 
 44 |             def start_link(data) do
 45 |               GenServer.start_link(__MODULE__, data, name: __MODULE__)
 46 |             end
 47 | 
 48 |             def class do
 49 |               unquote(class)
 50 |             end
 51 | 
 52 |             def methods do
 53 |               built_ins = [
 54 |                 code_change: 3, handle_call: 3, handle_cast: 2, handle_info: 2,
 55 |                 init: 1, start_link: 1, terminate: 2,
 56 |                 class: 0, methods: 0,
 57 |               ]
 58 | 
 59 |               __MODULE__.__info__(:functions) -- built_ins
 60 |             end
 61 | 
 62 |             import Kernel, except: [def: 2]
 63 | 
 64 |             Module.register_attribute(__MODULE__, :friends, accumulate: true)
 65 | 
 66 |             unquote(block)
 67 | 
 68 |             Enum.each(unquote(superclasses), fn superclass ->
 69 |               parent = superclass.new(data, true)
 70 | 
 71 |               for {method, arity} <- parent.methods do
 72 |                 Code.eval_quoted(OOP.Builder.inherit_method(method, arity, parent), [], __ENV__)
 73 |               end
 74 |             end)
 75 |           end
 76 | 
 77 |           {:ok, pid} = object.start_link(Enum.into(data, %{}))
 78 |           OOP.Registry.register(pid, unquote(class))
 79 | 
 80 |           object
 81 |         end
 82 |       end
 83 |     end
 84 |   end
 85 | 
 86 |   def ensure_can_be_subclassed(superclasses) do
 87 |     Enum.each(superclasses, fn s ->
 88 |       if s.__final__?, do: raise "cannot subclass final class #{s}"
 89 |     end)
 90 |   end
 91 | 
 92 |   def ensure_can_be_instantiated(class, descendant?, opts) do
 93 |     abstract? = Keyword.get(opts, :abstract, false)
 94 | 
 95 |     if !descendant? and abstract? do
 96 |       raise "cannot instantiate abstract class #{class}"
 97 |     end
 98 |   end
 99 | 
100 |   def create_method(call, expr) do
101 |     # HACK: this is a really gross way of checking if the function is using `this`.
102 |     #       if so, we let it leak: `var!(this) = data`.
103 |     #       We do this so that we don't get the "unused variable this" warning when
104 |     #       we don't use `this`.
105 |     using_this? = String.match?(Macro.to_string(expr), ~r"\bthis\.")
106 | 
107 |     {method, args} = Macro.decompose_call(call)
108 | 
109 |     handle_call_quoted =
110 |       quote do
111 |         try do
112 |           [do: value] = unquote(expr)
113 |           {:reply, {:ok, value}, data}
114 |         rescue
115 |           e in [RuntimeError] ->
116 |             {:reply, {:error, e}, data}
117 |         end
118 |       end
119 | 
120 |     quote do
121 |       def unquote(call) do
122 |         case GenServer.call(__MODULE__, {:call, unquote(method), unquote(args)}) do
123 |           {:ok, value} -> value
124 |           {:error, e} -> raise e
125 |         end
126 |       end
127 | 
128 |       if unquote(using_this?) do
129 |         def handle_call({:call, unquote(method), unquote(args)}, _from, data) do
130 |           var!(this) = data
131 |           unquote(handle_call_quoted)
132 |         end
133 |       else
134 |         def handle_call({:call, unquote(method), unquote(args)}, _from, data) do
135 |           unquote(handle_call_quoted)
136 |         end
137 |       end
138 |     end
139 |   end
140 | 
141 |   def inherit_method(method, arity, parent) do
142 |     args = (0..arity) |> Enum.drop(1) |> Enum.map(fn i -> {:"arg#{i}", [], OOP} end)
143 | 
144 |     {:defdelegate, [context: OOP, import: Kernel],
145 |       [{method, [], args}, [to: parent]]}
146 |   end
147 | 
148 |   def create_var(field, opts) do
149 |     private? = Keyword.get(opts, :private, false)
150 | 
151 |     quote do
152 |       def unquote(field)() do
153 |         case GenServer.call(__MODULE__, {:get, unquote(field)}) do
154 |           {:ok, value} -> value
155 |           {:error, :private} -> raise "Cannot access private var #{unquote(field)}"
156 |         end
157 |       end
158 | 
159 |       def unquote(:"set_#{field}")(value) do
160 |         GenServer.call(__MODULE__, {:set, unquote(field), value})
161 |       end
162 | 
163 |       def handle_call({:get, unquote(field)}, {pid, _ref}, data) do
164 |         classes = [class() | @friends]
165 |         if unquote(private?) and ! OOP.Registry.get(pid) in classes do
166 |           {:reply, {:error, :private}, data}
167 |         else
168 |           {:reply, {:ok, Map.get(data, unquote(field))}, data}
169 |         end
170 |       end
171 | 
172 |       def handle_call({:set, unquote(field), value}, _from, data) do
173 |         {:reply, value, Map.put(data, unquote(field), value)}
174 |       end
175 |     end
176 |   end
177 | end
178 | 
179 | defmodule OOP do
180 |   defmacro class(class_expr, block, opts \\ []) do
181 |     {class, superclasses} =
182 |       case class_expr do
183 |         {:<, _, [class, superclasses]} when is_list(superclasses) ->
184 |           {class, superclasses}
185 | 
186 |         {:<, _, [class, superclass]} ->
187 |           {class, [superclass]}
188 | 
189 |         class ->
190 |           {class, []}
191 |       end
192 | 
193 |     OOP.Builder.create_class(class, superclasses, block, opts)
194 |   end
195 | 
196 |   defmacro abstract(class_expr, block) do
197 |     {:class, _, [class]} = class_expr
198 | 
199 |     quote do
200 |       OOP.class(unquote(class), unquote(block), abstract: true)
201 |     end
202 |   end
203 | 
204 |   defmacro final(class_expr, block) do
205 |     {:class, _, [class]} = class_expr
206 | 
207 |     quote do
208 |       OOP.class(unquote(class), unquote(block), final: true)
209 |     end
210 |   end
211 | 
212 |   defmacro def(call, expr \\ nil) do
213 |     OOP.Builder.create_method(call, expr)
214 |   end
215 | 
216 |   defmacro var(field, opts \\ []) do
217 |     OOP.Builder.create_var(field, opts)
218 |   end
219 | 
220 |   defmacro private_var(field) do
221 |     quote do
222 |       var(unquote(field), private: true)
223 |     end
224 |   end
225 | 
226 |   defmacro friend(class) do
227 |     quote do
228 |       @friends unquote(class)
229 |     end
230 |   end
231 | end
232 | 


--------------------------------------------------------------------------------
/logo/logo.png:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/wojtekmach/oop/b1ce8bf1dff77fc2b34322fcfa287946bd3ac58e/logo/logo.png


--------------------------------------------------------------------------------
/logo/logo.svg:
--------------------------------------------------------------------------------
 1 | <?xml version="1.0" encoding="utf-8"?>
 2 | <!-- Generator: Adobe Illustrator 16.0.0, SVG Export Plug-In . SVG Version: 6.00 Build 0)  -->
 3 | <!DOCTYPE svg PUBLIC "-//W3C//DTD SVG 1.1//EN" "http://www.w3.org/Graphics/SVG/1.1/DTD/svg11.dtd">
 4 | <svg version="1.1" id="Layer_1" xmlns="http://www.w3.org/2000/svg" xmlns:xlink="http://www.w3.org/1999/xlink" x="0px" y="0px"
 5 | 	 width="841.89px" height="595.28px" viewBox="0 0 841.89 595.28" enable-background="new 0 0 841.89 595.28" xml:space="preserve">
 6 | <path fill="none" d="M449.389,346.965c-0.336-0.416-0.654-0.848-1.01-1.248c-0.23-0.263-0.438-0.543-0.676-0.798
 7 | 	c-3.232-3.45-7.061-6.194-11.488-8.222c-4.43-2.026-9.197-3.044-14.301-3.044c-5.106,0-9.875,1.018-14.305,3.044
 8 | 	c-4.434,2.027-8.265,4.771-11.49,8.222c-3.226,3.453-5.781,7.474-7.659,12.057c-1.878,4.578-2.815,9.42-2.815,14.526
 9 | 	c0,5.11,0.938,9.954,2.815,14.529c1.878,4.585,4.434,8.638,7.659,12.171c3.226,3.529,7.057,6.308,11.49,8.333
10 | 	c4.43,2.026,9.198,3.039,14.305,3.039c2.223,0,4.375-0.207,6.471-0.593c0.105-0.02,0.213-0.033,0.318-0.054
11 | 	c2.604-0.504,5.109-1.291,7.512-2.393c4.428-2.025,8.256-4.804,11.488-8.333c3.225-3.533,5.742-7.586,7.545-12.171
12 | 	c1.801-4.575,2.705-9.419,2.705-14.529c0-5.106-0.904-9.948-2.705-14.526C453.785,353.25,451.801,349.938,449.389,346.965z"/>
13 | <path fill="#660099" d="M308.576,352.433c0-34.836,53.59-117.652,69.698-141.759c0.527,17.973,5.628,38.298,15.52,58.201
14 | 	c3.705,7.451,7.873,14.383,12.362,20.754c0.121-0.023,0.24-0.055,0.361-0.077c4.963-0.912,10.056-1.388,15.283-1.388
15 | 	c4.598,0,9.09,0.368,13.485,1.072c6.037,0.966,11.883,2.591,17.533,4.885c0.178,0.071,0.354,0.147,0.531,0.219
16 | 	c-9.227-7.316-18.195-16.18-26.576-26.379c-10.009-12.183-19.183-26.263-26.953-41.896c-14.069-28.306-21.321-57.211-22.073-82.771
17 | 	c-22.907,34.282-99.124,152.064-99.124,201.608c0,56.645,44.613,102.859,100.618,105.446c1.642,0.076,3.291,0.125,4.953,0.125
18 | 	c1.659,0,3.309-0.049,4.951-0.125c1.354-0.069,2.694-0.18,4.032-0.304c-1.31-0.483-2.61-0.997-3.899-1.551
19 | 	c-1.305-0.562-2.522-1.219-3.785-1.833c-8.606-4.167-16.274-9.448-22.877-15.983c-2.653-2.625-5.101-5.429-7.364-8.384
20 | 	c-0.331-0.435-0.632-0.895-0.956-1.335C327.455,409.783,308.576,383.322,308.576,352.433z"/>
21 | <path fill="#47076D" d="M338.107,371.614c0-11.476,2.188-22.273,6.574-32.403c4.386-10.12,10.363-18.966,17.936-26.542
22 | 	c7.568-7.567,16.459-13.547,26.662-17.929c5.439-2.337,11.072-4.021,16.877-5.111c-4.489-6.371-8.657-13.303-12.362-20.754
23 | 	c-9.892-19.903-14.992-40.229-15.52-58.201c-16.108,24.106-69.698,106.923-69.698,141.759c0,30.89,18.879,57.351,45.721,68.526
24 | 	c-3.766-5.135-6.992-10.721-9.615-16.826C340.295,393.936,338.107,383.092,338.107,371.614z"/>
25 | <path fill="#47076D" d="M494.67,340.884c-4.146-9.638-9.795-17.998-16.949-25.082c-7.154-7.077-15.553-12.688-25.191-16.828
26 | 	c-0.471-0.204-0.943-0.394-1.42-0.585c-5.338-2.167-10.861-3.703-16.566-4.616c-4.154-0.665-8.396-1.014-12.743-1.014
27 | 	c-4.308,0-8.512,0.362-12.627,1.021c-0.604,0.096-1.213,0.181-1.813,0.291c-5.607,1.027-11.042,2.647-16.29,4.902
28 | 	c-9.642,4.141-18.042,9.791-25.194,16.941c-7.155,7.159-12.804,15.519-16.947,25.081c-4.145,9.571-6.212,19.774-6.212,30.618
29 | 	c0,10.846,2.067,21.093,6.212,30.729c2.691,6.265,6.026,11.976,9.989,17.16c1.135,1.481,2.321,2.919,3.556,4.315
30 | 	c1.094,1.237,2.225,2.442,3.402,3.607c6.239,6.175,13.484,11.166,21.617,15.104c1.193,0.579,2.345,1.201,3.577,1.731
31 | 	c2.356,1.013,4.752,1.897,7.181,2.662c7.506,2.365,15.355,3.551,23.55,3.551c10.844,0,21.088-2.073,30.729-6.213
32 | 	c9.639-4.146,18.037-9.754,25.191-16.835c7.154-7.078,12.803-15.439,16.949-25.083c4.141-9.636,6.213-19.883,6.213-30.729
33 | 	C500.883,360.771,498.811,350.527,494.67,340.884z M455.248,386.031c-1.803,4.585-4.32,8.638-7.545,12.171
34 | 	c-3.232,3.529-7.061,6.308-11.488,8.333c-2.402,1.102-4.908,1.889-7.512,2.393c-0.105,0.021-0.213,0.034-0.318,0.054
35 | 	c-2.096,0.386-4.248,0.593-6.471,0.593c-5.106,0-9.875-1.013-14.305-3.039c-4.434-2.025-8.265-4.804-11.49-8.333
36 | 	c-3.226-3.533-5.781-7.586-7.659-12.171c-1.878-4.575-2.815-9.419-2.815-14.529c0-5.106,0.938-9.948,2.815-14.526
37 | 	c1.878-4.583,4.434-8.604,7.659-12.057c3.226-3.45,7.057-6.194,11.49-8.222c4.43-2.026,9.198-3.044,14.305-3.044
38 | 	c5.104,0,9.872,1.018,14.301,3.044c4.428,2.027,8.256,4.771,11.488,8.222c0.238,0.255,0.445,0.535,0.676,0.798
39 | 	c0.355,0.4,0.674,0.832,1.01,1.248c2.412,2.974,4.396,6.285,5.859,10.011c1.801,4.578,2.705,9.42,2.705,14.526
40 | 	C457.953,376.612,457.049,381.456,455.248,386.031z"/>
41 | </svg>
42 | 


--------------------------------------------------------------------------------
/logo/logotype_horizontal.png:
--------------------------------------------------------------------------------
https://raw.githubusercontent.com/wojtekmach/oop/b1ce8bf1dff77fc2b34322fcfa287946bd3ac58e/logo/logotype_horizontal.png


--------------------------------------------------------------------------------
/mix.exs:
--------------------------------------------------------------------------------
 1 | defmodule OOP.Mixfile do
 2 |   use Mix.Project
 3 | 
 4 |   def project do
 5 |     [app: :oop,
 6 |      version: "0.1.1",
 7 |      description: "OOP in Elixir!",
 8 |      package: package(),
 9 |      elixir: "~> 1.0",
10 |      build_embedded: Mix.env == :prod,
11 |      start_permanent: Mix.env == :prod,
12 |      deps: deps()]
13 |   end
14 | 
15 |   def application do
16 |     [mod: {OOP.Application, []}]
17 |   end
18 | 
19 |   defp deps do
20 |     []
21 |   end
22 | 
23 |   defp package do
24 |     [
25 |       maintainers: ["Wojtek Mach"],
26 |       licenses: ["MIT"],
27 |       links: %{"GitHub" => "https://github.com/wojtekmach/oop"},
28 |     ]
29 |   end
30 | end
31 | 


--------------------------------------------------------------------------------
/test/oop_test.exs:
--------------------------------------------------------------------------------
  1 | defmodule OOPTest do
  2 |   use ExUnit.Case
  3 |   import OOP
  4 | 
  5 |   test "define empty class" do
  6 |     c = class Person do
  7 |     end
  8 | 
  9 |     assert c
 10 |     purge Person
 11 |   end
 12 | 
 13 |   test "instantiate empty object" do
 14 |     class Person do
 15 |     end
 16 | 
 17 |     alice = Person.new
 18 |     assert alice.class == Person
 19 |     purge Person
 20 |   end
 21 | 
 22 |   test "define methods on objects" do
 23 |     class Person do
 24 |       def zero do
 25 |         0
 26 |       end
 27 | 
 28 |       def sum1(a) do
 29 |         a
 30 |       end
 31 | 
 32 |       def sum2(a, b) do
 33 |         a + b
 34 |       end
 35 |     end
 36 | 
 37 |     alice = Person.new
 38 |     assert alice.zero() == 0
 39 |     assert alice.sum1(1) == 1
 40 |     assert alice.sum2(1, 2) == 3
 41 |     purge Person
 42 |   end
 43 | 
 44 |   test "define fields" do
 45 |     class Person do
 46 |       var :name
 47 | 
 48 |       def title(prefix) do
 49 |         "#{prefix} #{this.name}"
 50 |       end
 51 |     end
 52 | 
 53 |     alice = Person.new
 54 |     assert alice.name == nil
 55 | 
 56 |     bob = Person.new(name: "Bob")
 57 |     assert bob.name == "Bob"
 58 |     bob.set_name("Hipster Bob")
 59 |     assert bob.name == "Hipster Bob"
 60 |     assert bob.title("Mr.") == "Mr. Hipster Bob"
 61 | 
 62 |     assert alice.name == nil
 63 | 
 64 |     purge Person
 65 |   end
 66 | 
 67 |   test "define private fields" do
 68 |     class AppleInc do
 69 |       private_var :registered_devices
 70 | 
 71 |       def registered_devices_count do
 72 |         length(this.registered_devices)
 73 |       end
 74 |     end
 75 | 
 76 |     apple = AppleInc.new(registered_devices: ["Alice's iPhone", "Bob's iPhone"])
 77 | 
 78 |     assert_raise RuntimeError, "Cannot access private var registered_devices", fn ->
 79 |       apple.registered_devices
 80 |     end
 81 | 
 82 |     assert apple.registered_devices_count == 2
 83 | 
 84 |     purge AppleInc
 85 |   end
 86 | 
 87 |   test "define friend class" do
 88 |     class NSA do
 89 |       def get_data(company) do
 90 |         company.registered_devices
 91 |       end
 92 |     end
 93 | 
 94 |     class Thief do
 95 |       def get_data(company) do
 96 |         company.registered_devices
 97 |       end
 98 |     end
 99 | 
100 |     class AppleInc do
101 |       friend NSA
102 |       private_var :registered_devices
103 |     end
104 | 
105 |     apple = AppleInc.new(registered_devices: ["Alice's iPhone", "Bob's iPhone"])
106 |     thief = Thief.new
107 |     nsa = NSA.new
108 | 
109 |     assert_raise RuntimeError, "Cannot access private var registered_devices", fn ->
110 |       thief.get_data(apple)
111 |     end
112 | 
113 |     assert nsa.get_data(apple) == ["Alice's iPhone", "Bob's iPhone"]
114 | 
115 |     purge [AppleInc, Thief, NSA]
116 |   end
117 | 
118 |   test "inheritance" do
119 |     class Animal do
120 |       var :name
121 | 
122 |       def title(prefix) do
123 |         "#{prefix} #{this.name}"
124 |       end
125 |     end
126 | 
127 |     class Dog < Animal do
128 |       var :breed
129 |     end
130 | 
131 |     snuffles = Dog.new(name: "Snuffles", breed: "Shih Tzu")
132 |     assert snuffles.name == "Snuffles"
133 |     assert snuffles.breed == "Shih Tzu"
134 |     assert snuffles.title("Mr.") == "Mr. Snuffles"
135 | 
136 |     purge [Animal, Dog]
137 |   end
138 | 
139 |   test "multiple inheritance" do
140 |     class Human do
141 |       var :name
142 |     end
143 | 
144 |     class Horse do
145 |       var :horseshoes_on?
146 |     end
147 | 
148 |     class Centaur < [Human, Horse] do
149 |     end
150 | 
151 |     john = Centaur.new(name: "John", horseshoes_on?: true)
152 |     assert john.name == "John"
153 |     assert john.horseshoes_on? == true
154 | 
155 |     purge [Human, Horse, Centaur]
156 |   end
157 | 
158 |   test "define abstract class" do
159 |     abstract class ActiveRecord.Base do
160 |     end
161 | 
162 |     assert_raise RuntimeError, "cannot instantiate abstract class #{ActiveRecord.Base}", fn ->
163 |       ActiveRecord.Base.new
164 |     end
165 | 
166 |     class Post < ActiveRecord.Base do
167 |       var :title
168 |     end
169 | 
170 |     assert Post.new(title: "Post 1").title == "Post 1"
171 |     purge [ActiveRecord.Base, Post]
172 |   end
173 | 
174 |   test "abstract class inheriting from abstract class" do
175 |     abstract class ActiveRecord.Base do
176 |     end
177 | 
178 |     abstract class ApplicationRecord < ActiveRecord.Base do
179 |     end
180 | 
181 |     assert_raise RuntimeError, "cannot instantiate abstract class #{ActiveRecord.Base}", fn ->
182 |       ActiveRecord.Base.new
183 |     end
184 | 
185 |     assert_raise RuntimeError, "cannot instantiate abstract class #{ApplicationRecord}", fn ->
186 |       ApplicationRecord.new
187 |     end
188 | 
189 |     class Post < ApplicationRecord do
190 |       var :title
191 |     end
192 | 
193 |     assert Post.new(title: "Post 1").title == "Post 1"
194 |     purge [ActiveRecord.Base, ApplicationRecord, Post]
195 |   end
196 | 
197 |   test "define final class" do
198 |     final class FriezaFourthForm do
199 |     end
200 | 
201 |     assert FriezaFourthForm.new
202 | 
203 |     assert_raise RuntimeError, "cannot subclass final class #{FriezaFourthForm}", fn ->
204 |       class FriezaFifthForm < FriezaFourthForm do
205 |       end
206 |     end
207 | 
208 |     purge [FriezaFourthForm, FriezaFifthForm]
209 |   end
210 | 
211 |   defp purge(module) when is_atom(module) do
212 |     :code.delete(module)
213 |     :code.purge(module)
214 |   end
215 |   defp purge(modules) when is_list(modules) do
216 |     Enum.each(modules, &purge/1)
217 |   end
218 | end
219 | 


--------------------------------------------------------------------------------
/test/test_helper.exs:
--------------------------------------------------------------------------------
1 | ExUnit.start()
2 | 


--------------------------------------------------------------------------------